這個標題是簡化後的，它其實是指「在 DOS 程式中使用三十二位元 80386 指令及暫存器」。DOS 是十六位元的作業系統，是否真的能使用三十二位元的 80386 CPU 指令呢？答案是肯定的，只要仔細設定好定址方式，並處理好暫存器的寬度問題，照樣可以使用三十二位元的 80386，甚至更高階的 CPU。
事實上，英特爾自民國 74 年（西元 1985 年）推出 80386 之後，在接下來的二十年內陸續推出 80486、Pentium，一直到 Pentium 4、 Pentium M，這一系列的三十二位元 CPU 合稱為「IA－32」（Intel Architecture 32-bit）。另外其他廠商販售的 CPU，包含 AMD 的 Am386、Am486……一直到 Athlon XP，以及 Cyrix（賽瑞克斯）公司的 Cyrix 486SRX2、Cyrix MII 等，都算是「IA－32」中的一員。
IA－32 是一種指令集架構，因此廣義上來說，x86 家族的「前輩」，例如 8086、8088、80286，也會符合此種架構。英特爾的使用手冊上，也將這三種 CPU 歸類於 IA－32。但這很容易讓人混淆，畢竟這三者是十六位元的 CPU。本章所說的 IA－32 並不包含這三種 CPU。
三十二位元的 CPU 不僅能執行 8086/8088 的指令，同時又增加一些新的指令，也強化某些指令。舉例來說，8086/8088 CPU 的乘法指令，MUL，被乘數最多為十六位元，乘數也是十六位元，所得的乘積最長就是三十二位元。但如果改用 80386 或是其他 IA－32 的 CPU，就能使用強化後的 MUL 指令，它可以進行三十二位元的數乘以三十二位元的數，最多可達六十四位元。
除了運算能力增強外，更高等級的 CPU 指令集比 8086/8088 指令集還多，使用上更方便，同時 MASM 6.1 也支援 Pentium 指令。基於上述種種原因，那麼為何不使用 80386 或更高階的 CPU 指令呢？本章因此誕生。
在 DOS 程式中要使用 80386 指令，須注意底下的事項。
ML.EXE 在組譯時，預設使用 8086/8088 指令集，如果要使用 80386 指令集，那就必須在原始程式開始之處宣告 「.386」，甚至也可以設定「.486」或更高階的 CPU 指令集。這些假指令都已在第五章提過，請按這裏閱讀。
雖然使用三十二位元的 80386 CPU 指令，但是 DOS 的定址方式仍是十六位元，所以其區段仍要設為十六位元的區段。有兩種方式能設定區段是十六位元或三十二位元：
①：「.MODEL」假指令是用來設定記憶體模式 ( memory model )、語言類型 ( language type ) 等，除此之外，還有項功能。它與「.386」的順序能決定使用區段是十六位元，抑或三十二位元。
⑴：「.MODEL」在前，「.386」在後，那麼會使用十六位元的區段，這是在 DOS 系統中的程式使用的方式
⑵：「.386」在前，「.MODEL」在後，那麼會使用三十二位元的區段，這是在 Windows 系統中的程式使用的方式。
②：如果不用上面方式決定區段是十六位元還是三十二位元，那麼也可以用完整的方式宣告區段。那就是用 SEGMENT/ENDS 假指令，其中可以設定 USE16 決定此區段是十六位元，或是設定 USE32 決定此區段是三十二位元。見第十一章以完整方式宣告區段。
如果宣告了「.386」或更高階的 CPU 指令集，那麼就可以使用三十二位元的暫存器了。80386 的暫存器分成四類：
①：八個三十二位元的通用暫存器（general-purpose registers），其名稱分別是 EAX、EBX、ECX、EDX、ESP、EBP、ESI、EDI。它們的名稱和 8086/8088 通用暫存器名稱很相似，前面的「E」表示「extended」，延伸之意，其實就是把原來十六位元的暫存器擴充為三十二位元。
EAX、EBX、ECX、EDX 這四個暫存器中，每一個較低的字組又可獨立使用，名稱與 8086 相同，就是 AX、BX、CX、DX。最低的十六個位元，又可分成兩個八位元的暫存器。例如累加器 EAX 較低字組的 16 位元為 AX 暫存器，AX 又可分成 AH 與 AL 兩個八位元的暫存器，但是 EAX 較高字組的 16 位元（也就是第 16∼31 位元）無法單獨使用了，也沒特殊的名稱，見下圖。至於 EBX、ECX、EDX 的情況也和 EAX 相同，可以分成一個十六位元和兩個八位元較小的暫存器。
ESP、EBP、ESI、EDI 可以把較低的字組單獨使用，名稱也與 8086 相同，就是 SP、BP、SI、DI；但是不能拆成兩個八位元的暫存器，同時高字組也不能單獨使用，也沒有名稱。
②：六個區段暫存器，除了 8086/8088 原來的 CS、DS、ES、SS 之外，又多了兩個區段暫存器，它們是 FS 與 GS，一般用來作為存放資料的區段。這六個區段暫存器都是十六位元的。
③：延伸旗標暫存器（EFLAGS Register），IA－32 的延伸旗標暫存器只有一個，長度是 32 位元，它是 8086/8088 旗標暫存器的延伸，延伸的部分幾乎與保護模式有關，設計 DOS 程式時用不到。
④：指令指標暫存器（instruction pointer），32 位元的暫存器，名稱是 EIP，是 8086/8088 的 IP 的延伸，功能都是指向將要執行的指令位址。
在 8086/8088 CPU 中，能用於定址的 CPU 只有 BX、BP、SP、DI、SI，但是在 IA－32 CPU 中，所有的通用暫存器都可以用來定址。而且定址的方式也比 8086/8088 來得多。底下來看看兩個例子，第一個例子是使用加強的 32 位元 MUL 指令，第二個例子是使用通用暫存器定址。
底下的 MUL32_1.ASM 程式能利用 IA－32 CPU 的 MUL 指令進行三十二位元的乘法，四十億乘以三十億。四十億換算成十六進位是 0EE6B 2800H，三十億則是 0B2D0 5E00H（四十億、三十億轉換成十六進位數，可以用小算盤進行換算），兩數均需以三十二位元表示才能容納得下。（三十二位元表示的正整數最大可以四十二億，範圍是 0∼4294967295）
三十二位元的數乘以三十二位元的數，最多可達六十四位元（六十四位元的數是四字組，以 QWORD 表示），這原理在第十章曾提過。但底下的 MUL32_1.ASM 第 8 行，儲存乘積的變數，product，卻用兩個雙字組表示，理由是使用 MUL 指令時，所得的乘積存於 EDX:EAX，它們都是三十二位元的暫存器。
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20 |
.MODEL SMALL
.386
.STACK
;*********************************************************************
.DATA
x DD 4000000000 ;被乘數＝四十億
y DD 3000000000 ;乘數＝三十億
product DD ?,? ;乘積
;*********************************************************************
.CODE
;---------------------------------------------------------------------
.STARTUP
xor edx,edx
mov eax,x
mul y ;執行x×y
mov product,eax ;把乘積存入product中
mov product[4],edx
.EXIT 0
;*********************************************************************
END |
將 MUL32_1.ASM 存入「E:\HomePage\SOURCE\DOS\MUL32\」子目錄裏，然後輸入下面指令組譯並連結：
E:\DOS\MUL32>ml mul32_1.asm [Enter] Microsoft (R) Macro Assembler Version 6.11 Copyright (C) Microsoft Corp 1981-1993. All rights reserved. Assembling: mul32_1.asm Microsoft (R) Segmented Executable Linker Version 5.31.009 Jul 13 1992 Copyright (C) Microsoft Corp 1984-1992. All rights reserved. Object Modules [.obj]: mul32_1.obj Run File [mul32_1.exe]: "mul32_1.exe" List File [nul.map]: NUL Libraries [.lib]: Definitions File [nul.def]: E:\DOS\MUL32>mul32_1 [Enter] →執行 MUL32_1.EXE E:\DOS\MUL32>
執行 MUL32_1.EXE 後會發現螢幕上毫無動靜，這是因為 MUL32_1 並沒有把結果印在螢幕上，必須用除錯器觀察觀察。以 DEBUG 及 SYMDEB 分別載入 MUL32_1.EXE 觀察如下表，左邊是用 DEBUG 觀察的結果，右邊是 SYMDEB 觀察的結果：
| 用 DEBUG 觀察 | 用 SYMDEB 觀察 |
E:\DOS\MUL32>debug mul32_1.exe [Enter] -u 0 28 [Enter] 0E28:0000 B82A0E MOV AX,0E2A 0E28:0003 8ED8 MOV DS,AX 0E28:0005 8CD3 MOV BX,SS 0E28:0007 2BD8 SUB BX,AX 0E28:0009 C1 DB C1 →出現奇怪的程式碼 0E28:000A E304 JCXZ 0010 0E28:000C 8ED0 MOV SS,AX 0E28:000E 03E3 ADD SP,BX 0E28:0010 66 DB 66 →出現奇怪的程式碼 0E28:0011 33D2 XOR DX,DX 0E28:0013 66 DB 66 →出現奇怪的程式碼 0E28:0014 A10A00 MOV AX,[000A] 0E28:0017 66 DB 66 →出現奇怪的程式碼 0E28:0018 F7260E00 MUL WORD PTR [000E] 0E28:001C 66 DB 66 →出現奇怪的程式碼 0E28:001D A31200 MOV [0012],AX 0E28:0020 66 DB 66 →出現奇怪的程式碼 0E28:0021 89161600 MOV [0016],DX 0E28:0025 B8004C MOV AX,4C00 0E28:0028 CD21 INT 21 - |
E:\DOS\MUL32>symdeb mul32_1.exe [Enter] Microsoft (R) Symbolic Debug Utility Version 4.00 Copyright (C) Microsoft Corp 1984, 1985. All rights reserved. Processor is [80286] -u 0 28 [Enter] 1176:0000 B87811 MOV AX,1178 →資料區段位於 1178 1176:0003 8ED8 MOV DS,AX 1176:0005 8CD3 MOV BX,SS 1176:0007 2BD8 SUB BX,AX 1176:0009 C1E304 SHL BX,04 1176:000C 8ED0 MOV SS,AX 1176:000E 03E3 ADD SP,BX 1176:0010 66 DB 66 →出現奇怪的程式碼 1176:0011 33D2 XOR DX,DX 1176:0013 66 DB 66 →出現奇怪的程式碼 1176:0014 A10A00 MOV AX,[000A] →x在位址000A 1176:0017 66 DB 66 →出現奇怪的程式碼 1176:0018 F7260E00 MUL Word Ptr [000E] 1176:001C 66 DB 66 →出現奇怪的程式碼 1176:001D A31200 MOV [0012],AX 1176:0020 66 DB 66 →出現奇怪的程式碼 1176:0021 89161600 MOV [0016],DX 1176:0025 B8004C MOV AX,4C00 1176:0028 CD21 INT 21 - |
位址 0000∼000E 的程式碼是因為 .STARTUP 假指令產生的，詳細情形見第十一章。位址 0025∼0028 的程式碼是由 .EXIT 假指令產生的。只有 0010∼0021 的程式碼才 MUL32_1 的主角。
你會發現，不管用哪一種除錯器，都會出現奇怪的程式碼（以淡藍色標示）。但如果比較之後，你又會發現：①它們的機械碼是一樣的、②SYMDEB 能順利反組譯「SHL BX,04」，但是 DEBUG 卻不行（在位址 CS:0009 處）。這原因應該很容易理解，在設計 DEBUG 時，80286 及更高階的 CPU 尚未設計出來，所以 DEBUG 只能反組譯 8086/8088 指令，而「SHL 運算元,立即值」是 80286 及其以後才新增的，難怪 DEBUG 認不得，只能用機械碼表示。
由此可以推論，那些剩下的「奇怪程式碼」也是 DEBUG 以及 SYMDEB 都認不出來的指令。沒錯，的確如此。事實上，66H 是用來切換運算元長度的機械碼。如果是在十六位元區段出現 66H，那麼運算元長度就變成三十二位元；如果是在三十二位元區段出現 66H，那麼運算元長度就變成十六位元（詳情見第 24 章運算元前置碼）。例如在位址 0010∼0011 的程式碼是
DB 66 XOR DX,DX
其實是「XOR EDX,EDX」。雖然除錯器無法正確反組譯這些機械碼，但不會影響 CPU 執行，底下來看看 MUL32_1.EXE 執行結果。剛剛提過，MUL32_1.EXE 沒有輸出，所以只能用除錯器觀察。不管用哪一個除錯器，先看看資料區段的 x、y、product 之值。假設以 SYMDEB 觀察：
-d 1178:0 l20 [Enter] 1178:0000 66 89 16 16 00 B8 00 4C-CD 21 00 28 6B EE 00 5E f....8.LM!.(kn.^ 1178:0010 D0 B2 00 00 00 00 00 00-00 00 36 B8 4A 1C 50 90 P2........68J.P. -g 25 [Enter] AX=0000 BX=0020 CX=003A DX=906B SP=0420 BP=0000 SI=0000 DI=0000 DS=1178 ES=1166 SS=1178 CS=1176 IP=0025 OV UP EI NG NZ NA PE CY 1176:0025 B8004C MOV AX,4C00 -d 0 l20 [Enter] 1178:0000 66 89 16 16 00 B8 00 4C-CD 21 00 28 6B EE 00 5E f....8.LM!.(kn.^ 1178:0010 D0 B2 00 00 B0 D8 6B 90-88 A6 36 B8 4A 1C 50 90 P2..0Xk..&68J.P. -
上面淡藍色的是 x，橙色的是 y，紫色的是 product。執行完後，product 已變成 0A688 906B D8B0 0000H（白色字），這是一個六十四位元長的正整數，換算成十進位是一千兩百京（1.2×1019）。
先複習 8086/8088 的定址方式。大致分成兩種：
①：直接定址。這種方式說穿了就是以一個變數當做記憶體位址，事實上，在原始程式中所定義的任何變數，都是某個記憶體位址。例如在 MUL32_1.ASM 中定義的 x 變數，其實 x 是在某個記憶體位址上，而存取它們的方法是
mov eax,x
反組譯後是
mov eax,[000A]
上面的程式碼是說讀取記憶體位址 000A 內的數值，然後存入 EAX 暫存器裏面。因為不必再經其他手續，直接表明了這個位址就是 000A，所以稱「直接定址」。
[ reg ]
-d ds:0 l10 [Enter] →觀察DS:0000∼DS:000F的記憶體內容 2000:0000 00 01 02 03 04 05 0A 8B-56 08 8B 46 06 D1 E9 D1 ........V..F.QiQ -d es:0 l10 [Enter] 3000:0000 0A 0B 0C 0D 0E 0F 00 00-00 00 00 00 00 00 00 00 ................ -d ss:0 l10 [Enter] 4000:0000 11 22 33 44 55 66 00 00-00 00 00 00 00 00 00 00 ."3DUf.......... -r [Enter] →注意！BX、SI、DI、BP之值依序是0、1、2、3 AX=4000 BX=0000 CX=005A DX=0000 SP=FFFE BP=0003 SI=0001 DI=0002 DS=2000 ES=3000 SS=4000 CS=1166 IP=0150 NV UP EI PL NZ NA PO NC 1166:0150 8A07 MOV AL,[BX] DS:0000=00 -u 150 158 [Enter] 1166:0150 8A07 MOV AL,[BX] 1166:0152 8A24 MOV AH,[SI] 1166:0154 8A0D MOV CL,[DI] 1166:0156 8A6E00 MOV CH,[BP+00] →CH將變成存於位址SS:0003的記憶體內容，44（見上面九行的紫色字） -g=150 159 [Enter] AX=0100 BX=0000 CX=4402 DX=0000 SP=FFFE BP=0003 SI=0001 DI=0002 DS=2000 ES=3000 SS=4000 CS=1166 IP=0159 NV UP EI PL NZ NA PO NC 1166:0159 90 NOP -
⑵：稍微複雜一點的間接定址是在「[ ]」內除了暫存器之外，再加上偏移位址。在原始程式中，偏移位址通常是變數名稱，變數名稱可以在「[ ]」內，也可以在「[ ]」之前。在除錯程式中，偏移位址常以數值表示，必須放在「[ ]」內。這種定址方式的語法如下：
var [ reg ] [ var＋reg ]
上面兩行程式意義相同，var 是變數名稱，在組譯時會把變數名稱轉變成偏移位址。在「[ ]」內的 reg 代表暫存器，只能是 BX、SI、DI、BP 中的其中一種，跟上面一樣，只有使用 BP 時，存取 SS 區段，其餘都存取 DS 區段。這種間接定址的方法，最常用在陣列中。例如底下的 prime2 是小於 50 的質數所形成的陣列，要使 AX 變成第 3 個元素（從第零個元素開始），程式如下：
prime2 DW 2,3,5,7,11,13,17,19,23,29,31,37,41,43,47
mov bx,3 ;要取得第 3 個元素
shl bx,1 ;「SHL BX,1」相當於使BX乘以2，因為每個元素佔兩個位元組
mov ax,prime2[bx] ;相當於 prime2[6]，後來AX會變成7
var [ reg1＋reg2 ] var [reg1] [reg2] [ var＋reg1＋reg2 ]
上面三行程式是一樣的，reg1、reg2 代表兩個暫存器，其中一個必須是 BX、BP 二者中的一個，另一個必須是 SI、DI 二者中的一個。也就是說在「[ ]」內如果有兩個暫存器，那麼必須一個是索引暫存器（SI、DI），另一個是基底暫存器（BX、BP），不能同時是索引暫存器，或同時是基底暫存器。如果沒有凌越區段，並且其中有一個暫存器是 BP，那麼就會存取 SS 區段，否則存取 DS 區段。var 是變數名稱，可看成偏移位址，如不需要可以省略。以下面的例子說明：
prime2 DW 2,3,5,7,11,13,17,19,23,29,31,37,41,43,47
mov si,2
mov di,si
mov bx,4
mov ax,prime2[bx][si] ;⒜。BX＋SI＝6，由 prime2 開始算起，
mov cx,prime2[bx+si] ;⒝。六個位元組的記憶體裡面存放的是7
mov dx,[prime2+bx+si] ;⒞
mov ax,prime2[si+di] ;⒟
對小木偶來說，習慣用「mov dx,prime2[bx+si]」的寫法，但是 ML.EXE 一樣能接受其他兩種寫法，組譯後的結果也一樣。上面程式中的⒟「mov ax,prime2[si+di]」是錯誤的 x86 指令，因為不能同時使用兩個索引暫存器。
IA－32 CPU 較 8086/8088 先進，只有 ESP 稍有限制，其餘任何一個三十二位元的通用暫存器都能用於定址。IA－32 的定址方式一樣區分成①直接定址與②間接定址。前者與 8086/8088 相同，但後者卻簡單得多。下面是 IA－32 的間接定址模式，雖然列出了三種表示方法，但它們都一樣，所以其實只有一種：
var [ reg1＋reg2*n ] var [reg1] [reg2*n ] [ var＋reg1＋reg2*n ]
其中 var 是是變數名稱或陣列名稱，組譯後會變成偏移位址。reg1 與 reg2 是三十二位元的暫存器，reg1 可以是 EAX、EBX、ECX、EDX、EBP、ESI、EDI、ESP 八種暫存器中的其中一種；reg2 可以是 EAX、EBX、ECX、EDX、EBP、ESI、EDI 七種暫存器中的其中一種，reg2 不能是 ESP。n 可以是 1、2、4、8 四個整數中的其中一個，如果是 1，可以省略。
最後在 IA－32 CPU 的間接定址中，還有一些規則，如下：
底下的例子，SCR.ASM 用 EDX 暫存器定址，將資料寫入視訊記憶體。有關視訊記憶體的資料，請閱讀第十三章，這裏不敘述原理。SCR.ASM 會印出兩列字串：「0123……9ABCDEF」，這些字元的顏色及背景色均不同。SCR.ASM 原始程式如下：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 |
.MODEL SMALL
.386
x EQU 2 ;第二行
y EQU 20 ;第二十列
.STACK
;*********************************************************************
screen SEGMENT AT 0b800h ;彩色螢幕的視訊記憶體區段位址
screen ENDS
;*********************************************************************
.DATA
string DB "0123456789ABCDEF"
;*********************************************************************
.CODE
;---------------------------------------------------------------------
.STARTUP
mov ax,screen ;取出視訊記憶體區段位址
mov fs,ax ;FS 指向視訊記憶體區段位址
cld
lea si,string
mov bx,0f00h ;BH＝第21列文字顏色
mov edx,x ;BL＝第20列文字顏色
mov cx,SIZEOF string
next: lodsb
mov ah,bl
mov fs:[160*y+2*edx],ax
shl ah,4 ;第21列文字背景色
or ah,bh
mov fs:[160*(y+1)+2*edx],ax
inc bl
inc dx
dec bh
loop next
.EXIT 0
;*********************************************************************
END |
SCR.ASM 的組譯與連結過程，以及執行畫面如下圖：
SCR.ASM 的第 25 行是「mov fs:[160*y+2*edx],ax」，其中 y 是 10 表示第二十列。電腦螢幕由左往右稱為一列，最上面是第零列，往下依序是第一列、第二列……一直到第 24 列。每列最多顯示 80 個字元，而每個字元的顏色及背景色佔一個位元組，每一列有 160 個位元組。式中的 160*y 就是第二十列第零個字元的位址。
EDX 是第幾個字元，因每個字元包含字元本身及顏色與背景色，共佔兩個位元組，所以要乘以二。「mov fs:[160*y+2*edx],ax」中的「FS:」，強迫把 AX 內的資料寫入到 FS 區段內，這樣的情形稱為「凌越區段」。如果沒有「FS:」，那麼 CPU 會把 AX 內的資料寫入 DS 區段內。最後總結，「fs:[160*y＋2*edx]」就是螢幕上第 y 列、第 EDX 個字元的位址。
觀察上圖，你會發現印出來的兩列文字，第二十列的背景均為黑色，文字顏色則是不同。這是因為背景色是由顏色的較高四個位元控制，文字顏色則是由較低的四個位元控制，而 BL 較高的四個位元都是 0，故背景都是黑色。而 BH 的較高四個位元與較低四個位元，會隨著迴圈每執行一次就改變一次，故每個文字顏色、背景色都不相同。
在 SCR.ASM 的第 3、4 行，使用 EQU 來設定文字要印在螢幕的哪一個位置上。下面來說明 EQU 指令。
EQU 與 = 用來把一個符號宣告為一個整數，而使得其後的程式能用此符號代替該整數。它們的語法是：
符號 EQU 算術運算式 符號 = 算術運算式
此處的算術運算式是指可以是用算術計算的數學式子，其運算元應該都是變數或數值。像底下的例子，宣告兩個符號，一個矩形的 length（長）為 12，width（寬）為 5：
length EQU 12 width EQU 5 area EQU length*width
這樣的話 area（面積）會等於 60。
EQU 與 = 的差別有二：
如果要把符號宣告為字串，其語法是
符號 EQU <字串>
雖然以 EQU 把某個符號指定為某數，該符號無法修改為另一個數值；但是以 EQU 把某個符號指定為某字串，卻是可以修改成另一個字串。
以這兩個假指令宣告符號，有兩個好處：
除了上面的好處之外，事實上，EQU 與 = 可以用在巨集中設定變數，用於在巨集中運算。見第二十五章巨集中的變數。
本章第一個範例，MUL32_1.ASM 並沒有把計算結果顯示在螢幕上，多少有一些遺憾，所以撰寫了 MUL32_2.ASM，以彌補這個缺點。
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88 |
.MODEL SMALL,C
.386
.STACK
;*********************************************************************
.DATA
x DD 4000000000,0 ;被乘數＝四十億
y DD 3000000000,0 ;乘數＝三十億
product DD ?,? ;乘積
;*********************************************************************
.CODE
;---------------------------------------------------------------------
;改良式除法，divide，能儘量避免除法溢位。
;divide使divident除以divisor，所得的商存於ptr_qut所指的位址，此位址為
;一四字組變數；餘數存於ptr_rmd所指位址，此為位址一四字組變數。
divide PROC divident:QWORD,divisor:QWORD,ptr_qut:WORD,ptr_rmd:WORD
mov eax,DWORD PTR divident[4]
xor edx,edx
mov si,ptr_qut
div DWORD PTR divisor
mov [si+4],eax
mov eax,DWORD PTR divident
div DWORD PTR divisor
mov [si],eax
mov si,ptr_rmd
mov [si],edx
mov DWORD PTR [si+4],0
ret
divide ENDP
;---------------------------------------------------------------------
;把四字組十六進位無號數轉換成十進位數值，並印在螢幕上
;輸入：value－四字組十六進位無號數值
;輸出：在螢幕上印出十進位數
hex_to_dec PROC value:QWORD
LOCAL ten:QWORD
LOCAL rmd:QWORD,qut:QWORD
LOCAL buffer[24]:BYTE
;把buffer字串變為23 DUP ("0"),"$"
mov cx,SIZEOF buffer
lea bx,buffer
dec cx
next: mov BYTE PTR [bx],"0"
inc bx
loop next
mov BYTE PTR [bx],"$"
;把ten設為10
mov DWORD PTR ten,10
mov DWORD PTR ten[4],0
;把qut設為value
mov eax,DWORD PTR value
mov edx,DWORD PTR value[4]
mov DWORD PTR qut,eax
mov DWORD PTR qut[4],edx
;每次qut除以10之後，所得的商存於qut，餘數存於rmd中。
;下次除法的被除數是此次除法的商數，直至商數為零才停止
mov cx,20 ;四字組無號數變成十進位最多有20位數
lea bx,buffer
add bx,SIZEOF buffer-2
.WHILE cx
invoke divide,qut,ten,ADDR qut,ADDR rmd
mov dl,BYTE PTR rmd
add [bx],dl
.BREAK .IF DWORD PTR qut==0
dec bx
dec cx
.ENDW
mov dx,bx
mov ah,9
int 21h
ret
hex_to_dec ENDP
;---------------------------------------------------------------------
.STARTUP
invoke hex_to_dec,QWORD PTR x
mov dl,"*"
mov ah,2
int 21h
invoke hex_to_dec,QWORD PTR y
mov dl,"="
mov ah,2
int 21h
mov eax,x ;把EAX設為四十億
mul y ;EDX:EAX＝x×y
mov product,eax
mov product[4],edx
invoke hex_to_dec,QWORD PTR product
.EXIT 0
;*********************************************************************
END |
將 MUL32_2.ASM 存入「E:\HomePage\SOURCE\DOS\MUL32\」子目錄裏，然後輸入下面指令組譯並連結：
E:\DOS\MUL32>ml mul32_2.asm [Enter] Microsoft (R) Macro Assembler Version 6.11 Copyright (C) Microsoft Corp 1981-1993. All rights reserved. Assembling: mul32_2.asm Microsoft (R) Segmented Executable Linker Version 5.31.009 Jul 13 1992 Copyright (C) Microsoft Corp 1984-1992. All rights reserved. Object Modules [.obj]: mul32_2.obj Run File [mul32_2.exe]: "mul32_2.exe" List File [nul.map]: NUL Libraries [.lib]: Definitions File [nul.def]: E:\DOS\MUL32>mul32_2 [Enter] →執行 MUL32_2.EXE 4000000000*3000000000=12000000000000000000 E:\DOS\MUL32>
MUL32_2 要能印出類似「4000000000*3000000000=12000000000000000000」的式子。所以 MUL32_2.ASM 中得要有個副程式，能把原本存於記憶體中的十六進位數值，變成十進位數，然後印在螢幕上。這個副程式稱為 hex_to_dec，它只有一個參數，就是要印在螢幕上的數，這個參數長度必須是四字組（QWORD）。呼叫 hex_to_dec 時，就用下面方式呼叫：
invoke hex_to_dec,四字組變數
這是因為三十二位元的數乘以三十二位元的數，所得的乘積最多可達六十四位元，也就是四字組。再加上能把六十四位元的數印出來的副程式，當然也能把三十二位元的數印出來，所以只要將參數設為四字組就可以。
但是看第 5∼8 行的資料區段，x、y、product 都定義成兩個雙字組（雙字組是 DWORD，長 32 個位元），像下面的程式碼：
x DD 4000000000,0 ;被乘數＝四十億 y DD 3000000000,0 ;乘數＝三十億 product DD ?,? ;乘積
為什麼這樣定義呢？原因是三十二位元的乘法，被乘數必須在 EAX，乘數是某個變數或暫存器，它們都是三十二位元的，這是 x86 乘法指令，MUL，所規定的。所以把 x、y 定義成兩個雙字組，而且其較高位址的雙字組均為零。之所以把較高位址的雙字組設為零，是因為兩個原因：①它們本來就是零，但不可不設，不可不設的原因跟下個原因有關；②參數為四字組時，呼叫時有點兒麻煩。
這個麻煩是 IA－32 CPU 無法一次將四字組資料推入堆疊，必須分兩次做，第一次先把高位址的雙字組推入堆疊，第二次再把低位址的雙字組推入堆疊。這也符合 x86 相容機種的性質，高位的數值放在高位址，低位的數值放在低位址，這就是所謂小序端。
雖然 ML.EXE 會處理好這件事情。而我們要做的就是在呼叫 hex_to_dec 時，加上「QWORD PTR」，強迫 ML.EXE 將它們視為四字組（像 MUL32_2.ASM 第 73、77、85 行）。此外在定義這些參數時，其資料類型設為兩個雙字組，且高位址的雙字組為零，讓 invoke 時，能先將這個零推入堆疊，然後才是低位址的雙字組。
如果像下面方式定義 x、y
x DD 4000000000 ;被乘數＝四十億 y DD 3000000000 ;乘數＝三十億
那麼在把 x、y 當做參數傳給 hex_to_dec 時，高位址的雙字組會產生錯誤。例如在把 x 作為參數傳給 hex_to_dec 時，第一次會把 y 推入堆疊，然後再把 x 推入堆疊，這是因為 y 恰好在 x 高位址的雙字組上，這樣就會發生錯誤。
如果將 x、y、product 定義成四字組，像下面那樣，也未嘗不可。但呼叫 hex_to_dec 時，就不須在參數前加上「QWORD PTR」了。
x DQ 4000000000 ;被乘數＝四十億 y DQ 3000000000 ;乘數＝三十億 product DQ ? ;乘積
反而在第 83、84 行的 product 要加上「DWORD PTR」，像下面那樣：
mov DWORD PTR product,eax
mov DWORD PTR product[4],edx
divide 副程式其實是除法指令 DIV 的改良。雖然在三十二位元的除法中，被除數本就是六十四位元，以 EDX:EAX 表示；商是三十二位元，存於 EAX。假如被除數很大而除數很小時，有可能所得的商會超過三十二位元的 EAX 所容納的範圍，就會發生溢位。舉個極端的例子，例如 7FFF FFFF FFFF FFFF 除以 1，所得的商仍是六十四位元，這樣就發生溢位。
在 hex_to_dec 副程式中需要做連續除以 10 的除法，因為除數不大，很容易造成溢位，所以才會用 divide 副程式取代 DIV 指令。關於 divide 防止溢位的方法，在第七章註一提過，divide 只是將其擴充成三十二位元的版本。
DEBUG 與 SYMDEB 無法正確地顯示三十二位元的程式碼，雖然不影響執行結果，但終究有些遺憾。那麼在 DOS 作業系統之下，有沒有能正確處理三十二位元程式碼的除錯器呢？還真的有呢！那就是 DEBUG32。
假如你按照在附錄一中的方式，已經安裝好 Virtual PC 2007 SP1，並且也已安裝好 MS－DOS 虛擬機器，那麼可以檢查是否也已經下載好小木偶準備的工具程式－TOOLS.IMA。它是軟碟片的影像檔，裏面的「\TOOLS\」子目錄有 DEBUG32.EXE 除錯程式，可以按照附錄一設定開機及組譯環境中所提到的方法將其拷貝到 MS－DOS 虛擬機器中，就能使用了。
DEBUG32 的使用方法與 DEBUG 幾乎一樣，用 DEBUG32 除錯某個程式時，語法如下：
DEBUG32 程式名稱
按下 Enter 鍵之後，就進入 DEBUG32 程式裏，電腦的控制權就由 DEBUG32 接管。DEBUG32 的提示符號是「-」，出現此符號就表示 DEBUG32 已準備好接受使用者的指令了。如果只單純執行 DEBUG32，不進行除錯，那麼「程式名稱」可以省略。現在假設我們要對 MUL32_1.EXE 進行除錯，依下面步驟輸入「C:\TOOLS\DEBUG32 MUL32_1.EXE」：
E:\DOS\MUL32>C:\TOOLS\DEBUG32 MUL32_1.EXE [Enter]
Debug32 - Version 1.0 - Copyright (C) Larson Computing 1994
CPU = 686, Virtual 8086 Mode, Id/Step = 06C3, A20 enabled
-
先來看看 DEBUG32 是否能正確反組譯，輸入「U」指令。DEBUG32 指令不區分大小寫，所以輸入「U」或「u」，都是一樣。「U」指令是反組譯（unassemble 或 disassemble）的意思，語法是「U [起始位址 [結束位址]]」，如果省略起始位址，那麼 DEBUG32 會從 IP 所指位址開始反組譯。
-u 0 28 [Enter]
2364:0000 B86623 MOV AX,2366h
2364:0003 8ED8 MOV DS,AX
2364:0005 8CD3 MOV BX,SS
2364:0007 2BD8 SUB BX,AX
2364:0009 C1E304 SHL BX,04
2364:000C 8ED0 MOV SS,AX
2364:000E 03E3 ADD SP,BX
2364:0010 6633D2 XOR EDX,EDX
2364:0013 66A10A00 MOV EAX,[000A]
2364:0017 66F7260E00 MUL Dword Ptr [000E]
2364:001C 66A31200 MOV [0012],EAX
2364:0020 6689161600 MOV [0016],EDX
2364:0025 B8004C MOV AX,4C00h
2364:0028 CD21 INT 21
-
看看暫存器的內容，輸入「R」指令：
-r [Enter]
AX=0000 BX=0000 CX=003A DX=0000 SP=0400 BP=0000 SI=0000 DI=0000
DS=2354 ES=2354 SS=2368 CS=2364 IP=0000 NV UP DI PL NZ NA PO NC
2364:0000 B86623 MOV AX,2366h
R 指令的用法跟 DEBUG 類似，也可以用它來修改暫存器的內容，但是既然是能除錯三十二位元的程式，當然也要能顯示三十二位元的暫存器。所以 DEBUG32 針對 R 指令進行了加強，可以輸入「R32」或「R16」，切換顯示三十二位元或十六位元的暫存器。來試試看「R32」：
-r32 [Enter]
EAX=00000000 EBX=00000000 ECX=0000003A EDX=00000000 EBP=00000000
ESI=00000000 EDI=00000000 FS=2354 GS=2354 SS=2368 ESP=00000400
DS=2354 ES=2354 CS=2364 EIP=00000000 NV UP DI PL NZ NA PO NC
2364:0000 B86623 MOV AX,2366h
-
果然變成了顯示三十二位元暫存器之值。現在萬事俱備，可以試試看單步追蹤，「T」指令：
-t [Enter] EAX=00002354 EBX=00000000 ECX=0000003A EDX=00000000 EBP=00000000 ESI=00000000 EDI=00000000 FS=2354 GS=2354 SS=2368 ESP=00000400 DS=2354 ES=2354 CS=2364 EIP=00000003 NV UP DI PL NZ NA PO NC 2364:0003 8ED8 MOV DS,AX Trace Interrupt -
你會發現，DEBUG32 會把單步追蹤的執行結果，以反白表示，有利於清楚看見改變了什麼。
另外，有一點值得說明。使用 DEBUG 或 SYMDEB 除錯時，如果程式有輸出資料，就會佔據螢幕一塊區域，而使得接下來的顯示畫面不會照原來設計的方式排版，畫面變得很亂。DEBUG32 改良了這個問題，DEBUG32 的執行畫面與除錯畫面是分開來的。所以如果被除錯的程式有輸出資料的話，必需切換到執行畫面才觀察得到。要觀察執行畫面可以輸入「FL」指令。FL 指令是 Flip 的意思。如果要切回除錯畫面時，按下任意鍵就可以了。
其他還有許多指令，例如設定中斷點、離開 DEBUG32 等等都與 DEBUG 或 SYMDEB 相似，也可以於 DEBUG32 提示符號之後，輸入「?」得到指令的說明。