Ch 07　十六進位數變成十進位數

在日常生活中，絕大部分的人都是使用十進位計數。因此如何把電腦中的十六進位數變成十進位數，也是常用的程式，本章就來談一談這個程式。

原理

不管是十進位數值或者是十六進位數值，其實只是表示方式不同，但是「量」是一樣的。舉個例子來說，下面的照片裏共有好幾個美女，用十進位表示是 10；用十六進位表示是 0A。不管用 10 還是 A，數量都是一樣的。這就是小木偶說的「數量是一樣」的，但是表示方式不同，只不過我們習慣了用十進位表示。

如果要用手與腦，把十六進位換算成十進位，可以參考附錄二。如果用電腦程式去計算，就不能用前面的方法，因為不管電腦怎麼算，儲存在記憶體裏的資料最終都以二進位存放，因此仍然不能表示出來，必須另起爐灶才行。

暫且先放下如何用程式把十六進位變成十進位的問題，思考底下的問題：如果要把存在記憶體內的正整數，43981，印在螢幕上，要如何做呢？要注意這不是字串，而是一個正整數。小木偶這樣思考，這個正整數有五位數，顯然要印五次，每次只印一個字元。如果把 43981 除以十，得到商為 4398 而餘數是 1，再將餘數轉換成 ASCII 字元 1 ( ASCII 字元的「1」其編碼是 31H )，就可以印在螢幕上了。

        MOV     DL,31H
        MOV     AH,2
        INT     21H

接下來再將前次除法的商數再除以 10，得到商為 439 而餘數是 8，將餘數轉換成 ASCII 碼字元，再呼叫 AH＝2/INT 21H；……依此繼續，最後就能得到每個位數來。當然這樣的方法是從個位數開始，所以要先調整好螢幕位置，從最右邊開始印出阿拉伯數字來。

如果瞭解上面的過程，再加上前面小木偶所說的「同一數，用十進位或用十六進位表示，只是表示法不同，但數量是一樣的」，在電腦記憶體內雖以十六進位方式 ( 嚴格說是二進位 ) 存放，但是數量與十進位一樣。要以電腦程式把一個整數變成十進位，其實並不是真的變成十進位數值存在記憶體內，而是把它以阿拉伯數字印在螢幕上。

其實所用方法很簡單，把此整數連續除以十，每一次的餘數就是從個位數、十位數、百位數……往上排，每次都把餘數變成 ASCII 碼先存在記憶體裏，這樣就形成一個字串，然後再用 AH＝09H/INT 21H DOS 服務程式把這個字串一次印出來，而不必用 AH＝02/INT 21H 分五次印。

既然要用到除法，先複習小學的數學。例如一個除法算式，十七除以三等於五餘二，17÷3＝5...2，其中十七叫做被除數，三叫做除數，五叫做商數，二叫做餘數。底下再介紹 x86 的除法指令。


x86 指令：DIV

DIV 指令是功用是計算正整數的除法，語法如下：

DIV     運算元

除法指令的被除數並沒有寫出來，一律都是 AX 或 DX:AX，或者是 EDX:EAX，至於是哪一個，要看運算元決定。運算元是除數，可以暫存器，也可以是變數，但不可以是常數。①如果運算元長度是八位元，那麼被除數就是 AX；②如果運算元長度是十六位元，那麼被除數就是 DX:AX；③如果運算元長度是三十二位元，那麼被除數就是 EDX:EAX。第③種情形，只有在 80386 或更高階的 CPU 才能使用，但話說回來，現在 ( 民國 110 年 )，哪一個人的 CPU 不是超過 80386 了？小木偶把它整理如下表：

運算元
( 除數 )		被除數商數 餘數範例商之
最大值
運算運算前運算後
8位元AXALAH00AAh除以12h
等於09h餘08h		 AX=00AAh
BL=12h		AX=0809h
(AL=商，AH=餘)
BL=12h		255
16位元DX:AXAXDX1234FEDCh除以5678h
等於35E7h餘2094h		 AX=FEDCh
DX=1234h
BX=5678h		AX=35E7h(商)
DX=2094h(餘)
BX=5678h		65535
32位元
只能用於
386等級以上		EDX:EAX EAXEDX0FEDCBA12345000h
除以10000000h等於
FEDCBA1h餘2345000h		EAX=12345000h
EDX=0FEDCBAh
EBX=10000000h		 EAX=0FEDCBA1h(商)
EDX=2345000h(餘)
EBX=10000000h		232－1
64位元
只能用於
x64等級以上		RDX:RAX RAXRDX1CDEFAB1234567890h
除以10000000h等於
1CDEFAB123h餘4567890h		RAX=CDEFAB1234567890h
RDX=1
RBX=10000000h		 RAX=1CDEFAB123h(商)
RDX=4567890h(餘)
RBX=10000000h		264－1

以上表中，16 位元的除法為例子，被除數是 1234FEDCH，顯然無法放入 AX 裏，因此以「DX:AX」當做被除數。在除之前，要讓較高位數的字組放入 DX 裏，較低的字組放入 AX 裏，以「DX:AX」方式表示三十二位元的數值。然後再把除數放入 BX 裏，如下面程式片段：

        MOV     AX,FEDC
        MOV     DX,1234
        MOV     BX,5678
        DIV     BX

執行完上述程式後，AX＝35E7h ( 商數 )，DX＝2094h ( 餘數 )，而 BX 之值不變。

DIV 指令最常發生的問題是「溢位」，就是商太大，以致於放不下暫存器裏。例如上表中十六位元的除法，把除數換小一點的數，那麼商數就會變大。例如：1234FEDCh÷0CDh＝16BC8Fh...59h，所得的商數已經超過 AX 所能容納的範圍了，AX 最多只能是 65535，亦即十六進位的 0FFFFh。像這種情形，目的運算元容納不下計算所得的結果，就會發生溢位 ( overflow )。假如發生這種情形，CPU 就會設定溢位旗標，在 DEBUG 裏的溢位旗標會變成「OV」，同時會離開原來的程式回到 DOS，請參閱註一。

DIV 除了會影響溢位旗標外，也會影響進位旗標、符號旗標、零值旗標、輔助進位旗標、同位旗標共六種旗標。


x86 指令：XOR

先介紹什麼是 XOR。XOR 中文稱為「互斥或」( exclusive or )，它是邏輯運算的一種，其真值表如下：

0 XOR 0＝0
1 XOR 0＝1
0 XOR 1＝1
1 XOR 1＝0

亦即兩個相同的運算元作互斥或運算為 0，相異的兩運算元作互斥或運算為 1。

在 x86 指令裏，XOR 的語法是：

XOR     目的運算元,來源運算元

XOR 的運算是目的運算元和來源算元作互斥或運算之後，再把結果寫入目的運算元裏。舉個例子，若 AL＝6B，BL＝C2，執行「XOR AL,BL」後的結果是什麼呢？請參考右圖，AL 的第零位元與 BL 的第零位元作互斥或運算，即「1 XOR 0」得「1」；AL 的第一位元與 BL 的第一位元作互斥或運算，即「1 XOR 1」得「0」……依此類推。

XOR 運算有一種很奇妙的特性，那就是「如果某個數與自己作互斥或運算，所得結果為零」。在程式中，如果要讓某個暫存器變成零，可以用這種方法。例如要使 DX 變為零，可以用「XOR DX,DX」。

DECIMAL.ASM 原始碼

底下就是把 0ABCDH 變為十進位的程式原始碼：DECIMAL.ASM。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
;把十六進位數0ABCDH變成十進位數，然後印出來。
.MODEL  TINY
;*************************************************************
.CODE  
ORG     100h
;-------------------------------------------------------------
start:  jmp     begin
value   dw      0abcdh
ten     dw      10
answer  db      "0ABCDH=",5 DUP ("0"),"$"
begin:  mov     ax,value
        mov     bx,OFFSET answer+SIZEOF answer-2
        mov     cx,5
.WHILE cx
        xor     dx,dx
        div     ten
        add     [bx],dl
.BREAK .IF ax==0
        dec     bx
        dec     cx
.ENDW
        mov     dx,OFFSET answer
        mov     ah,9
        int     21h
        int     20h
;*************************************************************
END     start

組譯 DECIMAL.ASM 原始程式很容易，在 DOS 提示符號下，輸入「ml decimal.asm」即可。這個程式結構很簡單，就是連續的除法而已，不需要多說。下面是值得說的地方：①DUP、②SIZEOF、③多變的 DB 指令、④.BREAK .IF。先說完這四個新的運算子或指令之後，再來講解新遇到的程式觀念，例如以 SYMDEB 追蹤、。


DUP 運算子

DUP 運算子是用來定義一個具有重複出現的數值，必須搭配 DB、DW、DD 等假指令使用，其語法是

次數 DUP ( 初始值[,初始值[,...]])

上式中的次數就是重複次數，要重複的部分在後面一對 ( ) 內的初始值，這初始值也可以是字串。如果不確定初始值，也可以用「?」代替。另外，在 ( ) 內也可以再度使用 DUP 運算子。底下是幾個例子：

a       BYTE    4 DUP (1)           ;相當於「a  DB  1,1,1,1」
b       DB      5 DUP (10 DUP (2))  ;相當於定義了 50 個位元組的 2
c       DB      3 DUP (1,2,3)       ;相當於定義三次「1,2,3」，也就是「c  DB  1,2,3,1,2,3,1,2,3」
d       DB      2 DUP ("so ")       ;相當於「d  DB  "so ","so "」，也就是「d DB "so so "」


三個運算子：TYPE、LENGTHOF 與 SIZEOF

TYPE、LENGTHOF、SIZEOF 三個運算子的語法類似，都是

LENGTHOF 變數
SIZEOF   變數或資料類型
TYPE     變數或資料類型

LENGTHOF 是用來讓組譯器計算所定義的變數成員有多少個，SIZEOF 用來讓組譯器計算後面的變數或資料類型共含有多少個位元組，TYPE 則是傳回每個成員有多少個位元組，也可以傳回此資料類型有幾個位元組。例如底下的例子：

                                          ;TYPE  LENGTHOF  SIZEOF
v1      DB      3 DUP (1,2,3)             ;  1       9         9
v2      DW      40 DUP (40 DUP (5))       ;  2    1600      3200
v3      DD      3 DUP (20,30)             ;  4       6        24
str1    DB      "After all, Tomorrow is", ;  1      35        35
                " another day."
str2    DB      "After all, Tomorrow is"  ;  1      22        22
        DB      " another day."

上面例子裏，v1 其實是「v1 DB 1,2,3,1,2,3,1,2,3」，所以每個成員大小為一個位元組，TYPE v1 為 1，此外 v1 有九個成員，故 LENGTHOF v1 為 9；v1 總共佔用 9 個位元組 ( 9×1 )，故 SIZEOF v1 為 9。

v2 是以 DW 定義，所以每個成員大小為兩個位元組，故 TYPE v2 為 2；此外在 DUP 的括號裏有 40 個成員，但要重複 40 次，因此有 40×40 個成員，所以 LENGTHOF v2 為 1600；v2 總共佔用 3200 個位元組 ( 1600×2 )，故 SIZEOF v2 為 3200。

因為 v3 是以 DD 定義，所以每個成員大小為四個位元組，故 TYPE v3 為 4；v3 在 DUP 的括號裏有 20、30 兩個成員，但要重複 3 次，因此總共有六個成員，所以 LENGTHOF v3 為 6；v3 總共佔用 24 個位元組 ( 6×4 )，故 SIZEOF v3 為 24。

最後兩個例子是有換行的字串，注意到 str1 在引號後面有逗號，表示 str1 字串會延伸到下一行，這時候下一行不需要以「DB」定義，也就是說 str1 是「After all,Tomorrow is another day.」，因此 SIZEOF 計算出來的結果為 35 個位元組。

最後一個例子，str2，引號後面沒有逗號，表示此字串只有一行而已；在 str2 底下的字串，在組譯器的視角中與 str2 是毫不相干的。也就是說 str2 字串是「After all, Tomorrow is」，因此 SIZEOF 計算出來的結果只有 22 個位元組。由此看來，有沒有「,」和「DB」意義完全不同，當定義的字串太長要換行時須小心注意。


多變的 DB 指令

DB 假指令除了以前講的

變數名  DB      數值
字串名  DB      字串

之外，其實也可以靈活的應用，像 DECIMAL.ASM 裏的第十行，answer，的定義，其實示一個字串；

answer  db      "0ABCDH=",5 DUP ("0"),"$"

前面的「"0ABCDH="」很明顯就是字串，然而中間卻穿插著像「5 DUP ("0")」的運算子，後面還可以再接上一個字串，"$"。像這樣的做法是沒有問題而且是允許的。在後面的程式第 17 行，執行「add [bx],dl」時，把 DL 內的數值加到這五個字元裏，這樣看起來就好像是變數一樣。

其實不管是變數名或字串名，在組譯器的眼裏都是一個位址，這個位址放著的是數值還是字串，其實組譯器是不在意的。而且不論是數值還是字串都是可以運算的，因此可以把 DB 寫成這樣奇怪的樣子，是毫無問題的。如果用 DEBUG 觀察：

E:\DOS\DECIMAL>DEBUG DECIMAL.COM [Enter]
-D 100 L20 [Enter]
11F4:0100  EB 11 CD AB 0A 00 30 41-42 43 44 48 3D 30 30 30   ......0ABCDH=000
11F4:0110  30 30 24 A1 02 01 BB 11-01 B9 05 00 EB 0E 33 D2   00$...........3.
-

上面白色的部分就是 answer 的內容。一開始程式尚未執行前，answer 字串是「0ABCDH=00000$」，經過程式運算後，會把其中的「00000」變成適當的阿拉伯數字的字元，就可以印出來了。前面提到，十六位元的數值最多可表示 65535，是五位數，所以連續除五次十，第一次的餘數是個位數，把它轉換成 ASCII 字元的阿拉伯數字後，應該放在最高位址，也就是位址 0111 處。

在 DECIMAL.ASM 裏，小木偶用 BX 當作這五位阿拉伯數字的指標，一開始讓 BX 指向 0110 處，每計算一個位數就讓 BX 減一，指向下一個位數。


.BREAK .IF

有關「.BREAK .IF」的說明請看前一章的這裏，此處要說的是為何要在這裏放一個「.BREAK .IF ax==0」，檢查 AX 為零時跳出「.WHILE/.ENDW」迴圈。

我想這個理由並不難，如果 value 之值是像 0FFH 這樣的數，換成十進位後是小於或等於四位數的數值，那麼後面的高位數必定是「0」，也就不必再去計算了。怎麼去檢查是否小於或等於四位數呢？這也不難，當做連續除法時，所得的商數為零時，就表示沒有更高位數了。

使用 SYMDEB 追蹤 DECIMAL.COM

SYMDEB.EXE 是附在 MASM 4.0 的一個除錯程式，雖然名氣不如 DEBUG 大，但是功能卻比 DEBUG 強得多。和 DEBUG 比較，SYMDEB 的新增功能中最重要是：①能在除錯時使用原始程式的符號名，不再是很難看懂的位址，所以名之為「符號除錯器」(symbolic debug)。②增加中斷點及相關指令群。③加強了許多 DEBUG 命令，例如顯示 IEEE 格式實數、8087/80287 指令集等等。

如果你沒有 SYMDEB 而現在要使用的話，可以到這裏閱讀附錄一，裏面有方法可取得 SYMDEB。

SYMDEB 的使用方式與 DEBUG 類似，數值都是以十六進位表示，而且不能用十進位；SYMDEB 的指令多以一個英文字母表示，且不區分大小寫，但是 SYMDEB 對某些指令，例如 D 指令，等做了強化，可以以字組、雙字組等方式甚至是浮點方式顯示，因此某些指令是一群指令組成的，待會兒小木偶就會介紹中斷點指令群 ( B 指令群 )。


除錯時使用原始程式的符號名

底下小木偶就如何在除錯時使用原始碼的符號名以及加強的指令來說明。

在 SYMDEB 裏的符號名稱包含變數名、標記名和副程式名三種，SYMDEB 可以在除錯階段以原始碼所定義的名稱顯示這三種名稱，而不必再使用位址，因此大大的增加了方便性與可讀性。

為了達到這個目的，必須把符號名稱都寫進一個稱為「符號檔」的檔案裏，符號檔的副檔名是 SYM，是由 MAPSYM.EXE 處理映射檔產生的；而映射檔副檔名為 MAP，是由 LINK.EXE 處理 OBJ 檔產生的，因此要生成符號檔的過程如下：

  1. 首先，要生成映射檔的符號名必須是「PUBLIC」的，有底下兩種方法：
  2. 連結時，要產生映射檔，必須在使用 MASM 6.x 的 ML.EXE 組譯時，用「/Fm」參數，可以讓 ML.EXE 在呼叫 LINK.EXE 時，把要產生 MAP 檔的訊息傳給 LINK.EXE。( 亦即「/Fm」會讓 LINK.EXE 自動生成「/m」參數。)
  3. 用 MAPSYM.EXE 製造出 SYM 檔。MAPSYM 能處理輸入的 MAP 檔，然後製造出 SYM 檔，它的使用方法是： 
    MAPSYM [/L] MAP檔名
    MAPSYM 只有一個參數，/L，加上 /L 表示把變數名列表顯示在螢幕上，不加 /L 表示不顯示。MAP 檔名可以省略副檔名也可以寫出來。製造出來的 SYM 檔主檔名必與 MAP 主檔名一樣，無法更改。

例如底下的過程，就能製造出 DECIMAL.SYM 檔來：

E:\DOS\DECIMAL>ml /Fm /Zf decimal.asm [Enter] →「/Fm」與「/Zf」要區分大小寫，哪個參數在前或後無所謂
Microsoft (R) Macro Assembler Version 6.11
Copyright (C) Microsoft Corp 1981-1993.  All rights reserved.

 Assembling: decimal.asm

Microsoft (R) Segmented Executable Linker  Version 5.31.009 Jul 13 1992
Copyright (C) Microsoft Corp 1984-1992.  All rights reserved.

Object Modules [.obj]: decimal.obj/t
Run File [decimal.com]: "decimal.com"
List File [nul.map]: "decimal.map" /m →「/m」參數使 LINK.EXE 生成 MAP 檔，「/m」參數是 ml.exe 指定了「/Fm」才有的
Libraries [.lib]: 
Definitions File [nul.def]:

E:\DOS\DECIMAL>mapsym decimal [Enter]
Microsoft (R) Symbol File Generator  Version 4.00
Copyright (C) Microsoft Corp 1984, 1985.  All rights reserved.

    Program entry point at 0000:0100

E:\DOS\DECIMAL>

「/Zf」是 ML.EXE 的一個參數，它的目的就是使原始程式裏，所有符號名稱都設定為公開的，「/Zf」參數有大小寫之分，不可寫成「/zf」、「/ZF」等等。「/Fm」參數則是指定 LINK.EXE 要製作出 MAP 檔來，同樣也有大小寫之分；「/Fm」也可以在 Fm 之後指定自己想要的 MAP 檔名，如果省略則跟原始程式主檔名相同。


PUBLIC 假指令

PUBLIC 假指令的語法是

PUBLIC  [langtype] name[,[[langtype] name]...]

上式中的 langtype 式程式語言，可以是 C、SYSCALL、STDCALL、PASCAL、FORTRAN 或 BASIC，如果在 .MODEL 中已經指定的話，以此處為準，這個欄位與呼叫協定有關，以後再說。name 就是要宣告為「PUBLIC」的符號名稱。「langtype name」可以有許多組，也可以只有一組，視情形決定。


用 SYMDEB 除錯

既然 SYMDEB 威力比 DEBUG 強大，待會就來試試。現在先介紹 SYMDEB 的完整語法：

SYMDEB [參數] [SYM檔] [欲除錯之可執行檔] [該可執行檔之參數]

SYMDEB 的參數有 5 個。

  1. /IBM：也可簡寫成「/I」，這個參數會強迫 SYMDEB 把 IBM PC 的相容機種當成 IBM PC 使用。
  2. /K：這個參數可以使鍵盤的「Scroll Lock」或「Break」鍵當作中斷鍵使用。
  3. /N：這個參數使非 IBM PC 但是執行 MS DOS 的機種發揮硬體中斷功能。
  4. /S：可以使 SYMDEB 在除錯畫面與執行畫面之間切換，對於圖形畫面很有用。
  5. /"指令"：「"」之間為 SYMDEB 指令，它可以指定 SYMDEB 一啟動就要執行的指令。

我們就來試試看。要注意，載入時，符號檔要寫在前面，可執行檔在後面，如下：

E:\DOS\DECIMAL>c:\tools\symdeb decimal.sym decimal.com [Enter] →注意！符號檔要在可執行檔之前
Microsoft (R) Symbolic Debug Utility  Version 4.00
Copyright (C) Microsoft Corp 1984, 1985.  All rights reserved.

Processor is [80286]
-u begin 137 [Enter] →先看看全部程式，此處的 begin 標記也可以用位址 0113 代替，但用標記名較易理解
DGROUP:begin:
1551:0113 A10201         MOV	AX,[value] →不是用位址表示，改用變數名稱 value 了
1551:0116 BB1101         MOV	BX,0111 
1551:0119 B90500         MOV	CX,0005 
1551:011C EB0E           JMP	@C0001 →不是用位址表示，改用標記名稱，因為此處我們用 .WHILE/ENDW 所以用內定標記名稱
DGROUP:@C0002:
1551:011E 33D2           XOR	DX,DX 
1551:0120 F7360401       DIV	Word Ptr [ten] →不是用位址表示，改用變數名稱 ten 了
1551:0124 0017           ADD	[BX],DL 
1551:0126 0BC0           OR     AX,AX
1551:0128 7406           JZ     @C0003
1551:012A 4B             DEC	BX 
1551:012B 49             DEC	CX 
DGROUP:@C0001:
1551:012C 0BC9           OR     CX,CX 
1551:012E 75EE           JNZ	@C0002 
DGROUP:@C0003:
1551:0130 BA0601         MOV	DX,0106 
1551:0133 B409           MOV	AH,09 
1551:0135 CD21           INT	21 
1551:0137 CD20           INT	20 
-d 100 l20 [Enter] →在先看看資料區 ( 底下白字的部分 )
1551:0100  EB 11 CD AB 0A 00 30 41-42 43 44 48 3D 30 30 30  k.M+..0ABCDH=000
1551:0110  30 30 24 A1 02 01 BB 11-01 B9 05 00 EB 0E 33 D2  00$!..;..9..k.3R
-

在尚未正式說明如何追蹤及設置中斷點之前，先來看一看上面反組譯的結果，對照原始程式的第 17、18 行，就能發現紅字的指令並不在原始程式裏面，而是經由「.BREAK .IF ax==0」轉換而來的。JZ 指令已經提過了，就是檢查零值旗標，如果零值旗標設定了就會跳躍至標記「@C0003」處。那「OR AX,AX」是什麼呢？


x86 指令：OR

OR 指令是邏輯運算指令，它使兩個運算原作「或」運算。所謂「或」運算是指有數個條件，只要其中之一成立就可以了。例如老師說：「明天考試，題目只有兩題，第一題答對或第二題答對就及格了。」所以如果你第一題對第二題錯，或第一題錯第二題對，或兩題都對，都算及格。

在邏輯運算裏，常以 0 代表偽、假、否定的，以 1 代表真、肯定的。OR 運算的真表如下：

0 OR 0＝0
1 OR 0＝1
0 OR 1＝1
1 OR 1＝1

x86 的指令 OR 指令的語法是

OR      目的運算元,來源運算元

OR 指令是將來源運算元的每個位元與目的運算元相對應的位元作 OR 運算，再將其結果存入目的運算元中。目的運算元可以是暫存器、變數，來源運算元可以是暫存器、變數與立即值。目的運算元與來源運算元不能同時是變數，而且度必須相同，都是八位元或十六位元寬。

例如，AL＝32H，執行「OR AL,0C3H」後的結果如右圖，最後結果為 F3，因此 AL 也會變成 F3。

OR 指令有一項特性，如果對自己作 OR 運算結果為零，則自己本身原來也是零。在組合語言裏，常常用這種性質去檢查某個暫存器是否為零。像上面用 SYMDEB 載入 DECIMAL.COM 後，在位址 0126 處，使 AX 與本身作 OR 運算，如果結果為零，那麼 AX 本身原本就是零。當然也可以用「CMP AX,0」來檢查 AX 是否為零，但這樣的話機械碼會多一個位元組。在程式 012C 處，也是以同樣的方法檢查 CX 是否為零。

解釋完 OR 指令後，底下小木偶再解釋 SYMDEB 的中斷指令。


SYMDEB 指令：B

SYMDEB 的中斷指令 ( 中斷是 break 的意思 )，「B」指令，非常強大，可再細分五個「子」指令：BP、BC、BD、BE、BL。

  1. BP 指令是 break point 的意思，可以在某個位址、標記設定中斷點，當 SYMDEB 執行到這個中斷點時會停下來，顯示所有暫存器、旗標，中斷點的設定必須是指令的起始位址才有效，設定後除非是清除，否則都會一直保持。這個功能對於追蹤分枝很有用。BP 指令的使用方法如下：

    BP[n] ADDRESS [次數] ["COMMAND"]

    n 表示中斷點號碼，可以從 0 到 9 共十個號碼，SYMDEB 最多可以設定 10 個中斷點，您可以指定號碼，也可以不指定。如果不指定的話就由 SYMDEB 由 0 開始依次加上去；如果指定號碼的話，號碼和「BP」之間不可以有空格。ADDRESS 表示所設定的中斷點位址，也可用標記表示。次數是指該中斷點不立即生效，必須執行過所指定的次數之後才生效，這個方法在偵測迴圈時特別有用。COMMAND 是指當執行到中斷點時，不僅停止執行顯示暫存器外，還要執行「"」之間的 SYMDEB 指令，如果後續要執行的指令不只一個，可用「;」分開。

  2. BC 是用來清除中斷點，其指令格式是 

    BC n

    當指定 n 時表示清除那一個中斷點號碼，如果 n 為『*』表示清除所有的中斷點。當中斷點被清除後，SYMDEB 執行到此處就不會停下來了。

  3. BD 是用來暫時使中斷點失去功能，但不是真正清除，可以用 BE 來使它恢復功能，BD、BE 的使用格式和 BC 相同。( D 和 E 其實分別是 disable 和 enable 之意 )

  4. BL 是把所有的中斷點列出來，第一欄是中斷點號碼，第二欄是是否失去功能或正常 ( 失去功能顯示「d」﹔正常則顯示「e」)，第三欄是中斷點位址，第四欄是該中斷點位址的標記名，第五欄是還要通過幾次才生效，第六欄是最初設定時的可通行次數，第七欄是中斷點中斷後的後繼動作。

再回到用 SYMDEB 載入 DECIMAL.SYM 及 DECIMAL.COM，再反組譯整個程式碼，如下。以框線框起來，紅色的部分是「.WHILE/.ENDW」迴圈。

  E:\DOS\DECIMAL>c:\tools\symdeb decimal.sym decimal.com [Enter]
  Microsoft (R) Symbolic Debug Utility  Version 4.00
  Copyright (C) Microsoft Corp 1984, 1985.  All rights reserved.

  Processor is [80286]
  -u 113 137 [Enter]
  DGROUP:begin:
  1551:0113 A10201         MOV    AX,[value]
  1551:0116 BB1101         MOV    BX,0111
  1551:0119 B90500         MOV    CX,0005
  1551:011C EB0E           JMP    @C0001
┌─DGROUP:@C0002:
│ 1551:011E 33D2           XOR    DX,DX
│ 1551:0120 F7360401       DIV    Word Ptr [ten]
│ 1551:0124 0017           ADD    [BX],DL
│ 1551:0126 0BC0           OR     AX,AX
│ 1551:0128 7406           JZ     @C0003
│ 1551:012A 4B             DEC    BX
│ 1551:012B 49             DEC    CX
│ DGROUP:@C0001:
│ 1551:012C 0BC9           OR     CX,CX
└─1551:012E 75EE           JNZ    @C0002
  DGROUP:@C0003:
  1551:0130 BA0601         MOV    DX,0106
  1551:0133 B409           MOV    AH,09
  1551:0135 CD21           INT    21
  1551:0137 CD20           INT    20

如果小木偶想觀察 0ABCDH 轉換後的十進位數，能否依照個位數、十位數、百位數……逐一從記憶體位址 0111 處開始往低位址填入，那麼最好的中斷點就是位址 0126 處。因為上一條指令就是把除以 10 後的餘數，填入記憶體裏。另外，小木偶也想在迴圈執行完後，資料尚未印在螢光幕前，觀察結果是否正確，所以指定兩個中斷點：

  -bp 126 "r;d 100 l20" [Enter] →設置第 0 號中斷點，且中斷後執行「r」與「d」兩個指令
  -bp @c0003 [Enter] →設置第 1 號中斷點，在迴圈外  
  -bl [Enter] →列出所有中斷點
  0 e 1551:0126 [DGROUP:@C0002+08 (0126)]  "R;D 100 L20"
  1 e 1551:0130 [DGROUP:@C0003] 
  -g [Enter] →開始執行，但並不會執行到程式結束才停止
  AX=112E  BX=0111  CX=0005  DX=0001  SP=FFFE  BP=0000  SI=0000  DI=0000 →到第 0 號中斷點就暫停執行
  DS=1551  ES=1551  SS=1551  CS=1551  IP=0126   NV UP EI PL NZ NA PO NC  →，並印出暫存器資料
  1551:0126 0BC0           OR     AX,AX                         ;BR0 →第 0 號中斷點
  1551:0100  EB 11 CD AB 0A 00 30 41-42 43 44 48 3D 30 30 30  k.M+..0ABCDH=000→及記憶體位址 0100
  1551:0110  30 31 24 A1 02 01 BB 11-01 B9 05 00 EB 0E 33 D2  01$!..;..9..k.3R→至011F的內容
                 ⤷0111 處的「31」就是 0ABCDH 除以十的餘數轉換成 ASCII 字元

執行到 0126 的第 0 號中斷點就停下來了，並自動執行「R」與「D」指令，印出暫存器及 answer 字串。到現在為止已經把個位數算出來了，接下來再試試看十位數，如下：

  -g [Enter]
  AX=01B7  BX=0110  CX=0004  DX=0008  SP=FFFE  BP=0000  SI=0000  DI=0000
  DS=1551  ES=1551  SS=1551  CS=1551  IP=0126   NV UP EI PL NZ NA PO NC
  1551:0126 0BC0           OR     AX,AX                         ;BR0 →一樣到第 0 號中斷點就暫停執行，並印出資料
  1551:0100  EB 11 CD AB 0A 00 30 41-42 43 44 48 3D 30 30 30  k.M+..0ABCDH=000
  1551:0110  38 31 24 A1 02 01 BB 11-01 B9 05 00 EB 0E 33 D2  81$!..;..9..k.3R
              ⤷0110 處的「38」就是 0ABCDH 除以一百的餘數轉換成 ASCII 字元

已經檢查過個位數和十位數了，相信迴圈應該沒有問題了，可以清除迴圈內的中斷點，待會再執行時就不會在迴圈內中斷了，請看下面的操作：

  -bc 0 [Enter] →清除第 0 號中斷點
  -g [Enter]
  AX=0000  BX=010D  CX=0001  DX=0004  SP=FFFE  BP=0000  SI=0000  DI=0000
  DS=1551  ES=1551  SS=1551  CS=1551  IP=0130   NV UP EI PL ZR NA PE NC
  DGROUP:@C0003:
  1551:0130 BA0601         MOV    DX,0106                       ;BR1
  -d 100 l20 [Enter]
  1551:0100  EB 11 CD AB 0A 00 30 41-42 43 44 48 3D 34 33 39  k.M+..0ABCDH=439
  1551:0110  38 31 24 A1 02 01 BB 11-01 B9 05 00 EB 0E 33 D2  81$!..;..9..k.3R
  -g [Enter]
  0ABCDH=43981→正確的印出結果
  Program terminated normally (0)
  -q [Enter]

註一：解決 DIV 溢位

有兩種情形會使得 DIV 發生溢位：①除數為零，②被除數太大而除數太小以致於讓商無法存入累加器中。要防止第一種溢位的情形很簡單，只要在執行 DIV 之前檢查運算元是否為零即可，程式如下：

        cmp     bx,0    ;檢查除數是否為零
        jz      zero    ;若為零，跳過DIV指令
        div     bx      ;若不為零，進行DIV指令
        ....    ....
zero:                   ;此處為處理除數為零的程式

要防止第二種溢位的情形，可以使用兩次除法，以 16 位元的除法為例，第一次先計算高字組，第二次再去計算低字組。這種方法好像是以前我們在小學學的直式除法 ( 也叫長除法 )，例如要計算 58÷3，我們會用右圖的方法計算，最後商為 19，餘數為 1。

我們也可以把 DIV 指令想成直式除法，把 32 位元的被除數，DX 想成是 5，AX 想成是 8。我們先做高字組的除法，所得的商 ( 圖中的 Q1 ) 即為最後商的高字組，而餘數 ( 圖中的 R1 ) 為第二次除法的被除數之高字組，第二次除法的被除數低字組則是原先的低字組，由圖上看就是原來的 AX。

第二次除法所得的商是最後商的低字組，所得的餘數是最後的餘數。此副程式原始碼如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
;-------------------------------------------------------------------------------
;改良式除法，division，能儘量避免除法溢位
;輸入：DX:AX－被除數
;　　　CX－除數
;輸出：DX:AX－商
;　　　CX－餘數
division        PROC
        LOCAL   temp:WORD       ;暫時存放原先被除數的低字組
        LOCAL   quotient:WORD   ;暫時存放商的高字組
        mov     temp,ax         ;保存原先被除數的低字組
        mov     ax,dx
        sub     dx,dx
        div     cx              ;第一次除法的餘數為第二次除法的高字組
        mov     quotient,ax     ;第一次除法後的商為最後商的高字組，先保存起來
        mov     ax,temp         ;取回原先被除數的低字組當做第二次除法的低字組
        div     cx
        mov     cx,dx           ;第二次除法的餘數就是最後的餘數
        mov     dx,quotient
        ret
division        ENDP
;-------------------------------------------------------------------------------

小木偶覺得，這個副程式很有用，能處理很大數的除法，也不必擔心除法溢位的問題。但要注意的是，這個改良式除法副程式，並沒有檢查除數是零的過程，因此呼叫前要先檢查除數是否為零。