小木偶打算在本章裏，說明如何由鍵盤輸入長一個字組的十六進位數值，然後把它存在一個變數裏。一個字組長度是十六位元，所以這個數最大是 0FFFFH，相當於十進位的 65535。
小木偶用 DOS 服務程式，AH＝01/INT 21H，輸入字元。當使用者輸入一個鍵時，所按下鍵的 ASCII 碼會存於 AL 裏。例如，在鍵盤上的「Caps Lock」燈未亮時，按下「A」鍵，AL 裏的數值是 61H，這是英文字母「a」的 ASCII 碼。如果使用者按下 Shift 不放，再按「A」鍵，那 AL 裏的數值是 41H，這是英文字母的「A」的 ASCII 碼。
十六進位數值是以 0∼9 及 A∼F 表示，因此得到鍵盤上的 ASCII 碼後，首先要檢查的是使用者所按下的字元是否在 30H∼39H 或 41H∼46H 或 61H∼66H 之間。這三個區間所代表的字元，依序是 0∼9、A∼F 以及 a∼f，如果不是這些字元，表示使用者輸入錯誤，印出錯誤訊息後離開程式。
如果輸入正確的字元，就得處理這些字元，使它變成一位數字。先說說大家比較清楚的十進位數值。隨便舉個十進位數，例如 9988 好了，我們都知道這兩個 9 所代表的意義不同，分別是 9000 與 900；兩個 8 也不同，分別是 80 與 8。那答案很明顯了 9988＝9×103＋9×102＋8×101＋8×100，這是十進位，每個位數都要再乘上 10 的冪方。
同樣的道理，十六進位的每個位數，也要乘上 16 的冪方。小木偶的想法是當使用者輸入正確的字元後，要先把在 30H∼39H 的阿拉伯數字變成 0H∼9H 的一個位數，或是把 41H∼46H 的大寫英文字母變成 0AH∼0FH 的一個位數，把 61H∼66H 的小寫英文字母變成 0AH∼0FH 的一個位數。
小木偶設定一個變數，用來儲存最後輸入的十六進位數值。一開始先讓這個變數設為 0，當使用者輸入第一個位數時，例如使用者按下「A」鍵，先用前一段的方法把輸入的字元變成 0AH，然後再把剛剛所講的變數乘以 10H，因為此變數為零，所以乘積還是零，再把新處理過的那一個位數加到變數裏，這樣該變數就變成 0AH 了。第二次，假如使用者按下「9」鍵，那麼處理這個按鍵後應該變成 09H，再把變數乘以 10H，該變數就變成 0A0H，再加上 9，該變數就變成 0A9H 了。
依此類推，每次使用者按下一鍵，就會使該變數乘以 10H，再加上處理過的按鍵數值 ( 不管使用者按哪一個鍵，這個數值在 0∼0FH 範圍內 )。這樣連續四次，就能在變數裏取得使用者輸入的十六進位數值了。
底下來說說會用到的 x86 指令。
SHL 指令的語法如下：
SHL 目的運算元,1 式(1) SHL 目的運算元,CL 式(2) SHL 目的運算元,立即值 式(3)
SHL 指令是「shift logical left」的意思，是指目的運算元內的每個位元向左移位數個位元，如果只移一個位元，就用式 (1)；如果一次要移好幾個位元，用式 (2)，把要移位的位元數事先存入 CL 裏面。8086/8088 CPU 只能用這兩種方法，80286 及更高階的 CPU 可以用式 (3)，要移位的位元數直接以立即值表示。底下舉個例子說明。
右圖是說明 AX 暫存器裏的每個位元向左移一位的情形。AX 暫存器有十六位元，最高位元是第 15 位元，最低位元是第 0 位元。當執行「SHL AX,1」指令時，第 15 位元會被移至旗標暫存器 ( carry flag，簡稱 CF ) 裏，然後第 14 位元移至第 15 位元，其餘依此類推……第零位元移至第一位元，而第零位元則填入 0 ( 右圖中，以粉紅色的 0 表示 )。SHL 和 SAL ( shift arithmetic left ) 的機械碼一模一樣的，所以是相同的指令，它們不是旋轉，和 ROL 不同。
SHL 有一項特性，非常好用，那就是可以當做乘以 2 的冪方。例如「SHL AX,1」相當於把 AX 乘以 2，「SHL AX,2」相當於乘以 22，「SHL AX,2」相當於乘以 23……以此類推。還是以十進位數值來比喻好了，12 向左移移位，不就變 120，相當於乘以 10；向左移兩位，就變成 1200，相當於成 102。
SHR 是邏輯右移 ( shift logical right ) 的意思，亦即把目的運算元中的每個位元，向右移數個位元。只有移位方向向右以及相當於除以 2 的冪方，這兩點與 SHL 不同，其他特性都一樣，包含最高位元會補上 0。
但是 SAR ( shift arithmetic right，算術右移 ) 卻與 SHR 不同，SAR 指令在移位的時候，最高位元保持原來的值。例如 AL 為「1000 1100」，執行「SAR AL,1」後，AL 變成「1100 0110」，且進位旗標被清除。如果 AL 為「1000 1100」，執行「SAR AL,2」後，AL 變為「1110 0011」，進位旗標被清除。
SHL、SAL、SHR、SAR 四指令執行後，會影響多個旗標，包含進位旗標、同位旗標、零值旗標、符號旗標、溢位旗標五個旗標。
SUB 指令是有號數的減法運算指令，語法是
SUB 目的運算元,來源運算元
SUB 指令會把目的運算元減掉來源運算元之後，再把差存入目的運算元裏面，因此，目的運算元之值會改變，來源運算元之值不變。目的運算元可以是暫存器或變數，來源運算元可以是暫存器、變數或立即值。但目的運算元與來源運算元不可同時為變數，且兩者長度要相同。
SUB 指令會影響許多旗標，包含進位旗標、同位旗標、輔助進位旗標、零值旗標、符號旗標、溢位旗標六個旗標。
底下就是 INPUT1.ASM，它能讓使用者輸入一個字組長度的十六進位數，然後把它存於記憶體裏。
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 |
;由鍵盤輸入一個字組長的十六進位數，然後存入value變數裏。
.MODEL TINY
.386
;*******************************************************************************
.CODE
ORG 100h
;-------------------------------------------------------------------------------
start: jmp begin
value DW ?
error_message DB 0dh,0ah,"Please input 0~9 or A~F.$"
begin: mov cx,4 ;一個字組的十六進位數有四位
mov value,0 ;使value歸零
next: mov ah,1 ;DOS服務程式，鍵盤輸入字元
int 21h ;AL＝輸入字元的ASCII碼
cmp al,"0" ;檢查AL是否在30H∼39H之間
jb illegal ;若AL比30H小，使用者輸入不正確的字元
cmp al,"9" ;若AL在30H∼39H之間，跳到arabic_number處
jbe arabic_number
cmp al,"A" ;檢查AL是否在"A"∼"F"之間
jb illegal ;若AL比"A"小，使用者輸入不正確的字元
cmp al,"F" ;若AL在"A"∼"F"之間，跳到uppercase處
jbe uppercase
cmp al,"a" ;檢查AL是否在"a"∼"f"之間
jb illegal ;若AL比"a"小，使用者輸入不正確的字元
cmp al,"f" ;若AL在"A"∼"F"之間，跳到lowercase處
jbe lowercase
illegal: mov ah,9
mov dx,OFFSET error_message
int 21h ;使用者輸入不合法的字元
jmp quit ;印出錯誤訊息之後離開程式
arabic_number: sub al,"0" ;使阿拉伯數字在0H∼9H之間
jmp shift
uppercase: sub al,37h ;使大寫英文字母在0AH∼0FH之間
jmp shift
lowercase: sub al,57h ;使小寫英文字母在0AH∼0FH之間
shift: shl value,4 ;value＝value×10H
cbw ;使AH變為0
add value,ax ;value＝value＋AX
loop next
quit: int 20h
;*******************************************************************************
END start |
組譯及連結方式跟以前一樣，在「MS-DOS 6.20」虛擬機器中，先切換子目錄為「E:\DOS\INPUT」後，再輸入「ml input1.asm」即可。底下小木偶解說原始程式的第 14∼29 行，這段程式處理使用者所按下的鍵是否為合法的十六進位字元，如果不是就跳到 illegal 標記，印出錯誤訊息後離開程式；如果是，就要依據使用者輸入的是阿拉伯數字，還是大寫英文字母，還是小寫英文字母去計算，使按鍵所代表的字元落在 0∼0FH 之間。
查 ASCII 表，就可以知道，阿拉伯數字、大寫英文字母、小寫英文字母並沒有連著排列，如下表，用帶有底色的區塊表示：
| 字元 | ASCII 碼 | 字元 | ASCII 碼 | 字元 | ASCII 碼 | 字元 | ASCII 碼 | 字元 | ASCII 碼 |
| 0 | 30H | 3CH | 48H | 54H | 60H | ||||
| 1 | 31H | 3DH | 49H | 55H | a | 61H | |||
| 2 | 32H | 3EH | 4AH | 56H | b | 62H | |||
| 3 | 33H | 3FH | 4BH | 57H | c | 63H | |||
| 4 | 34H | 40H | 4CH | 58H | d | 64H | |||
| 5 | 35H | A | 41H | 4DH | 59H | e | 65H | ||
| 6 | 36H | B | 42H | 4EH | 5AH | f | 66H | ||
| 7 | 37H | C | 43H | 4FH | 5BH | 67H | |||
| 8 | 38H | D | 44H | 50H | 5CH | 68H | |||
| 9 | 39H | E | 45H | 51H | 5DH | 69H | |||
| 3AH | F | 46H | 52H | 5EH | 6AH | ||||
| 3BH | 47H | 53H | 5FH | 6BH |
小木偶的做法是最先檢查是否為阿拉伯數字，阿拉伯數字的 ASCII 碼在 30H∼39H 之間，因此小於 30H 的就不是阿拉伯數字，也不是英文字母，表示使用者輸入的不是十六進位該有的符號，就跳到處理不合法字元處，也就是 illegal 處。通過大於或等於 30H 檢查後，再檢查有沒有超過 39H，如果沒有表示為阿拉伯數字，到 arabic_number 處，讓 AL 減去 30H，就能使 30H∼39H 的 ASCII 碼變成 0H∼9H 的數值，存於 AL 裏面。
如果超過 39H，那麼可能是英文字母。但大寫英文字母從 41H 開始，所以檢查是否小於 41H，如果小於表示使用者輸入錯誤，就跳到 illegal 處。如果大於或等於 41H，再檢查是否超過 46H，如果沒有表示為 A∼F 之間。假如使用者按下的是「A」鍵，AL 會傳回 41H ( 十進位的 65 )，我們應該要把它變成十六進位的 0AH ( 十進位的 10 )，所以要減去 55 ( 十進位的 37H )。這就是第 39 行，為什麼要減去 37H 的原因。
其餘的就是檢查是否為小寫的英文字母，「a」∼「f」，過程就不重複了。
接下來的是第 43∼45 行，這三行程式，就是讓原先的變數，value，乘以 10H，再加上 AL 裏面的數。AL 的數是根據使用者按下的按鍵處理後得到的。這段前面已經提過了，也不再重複。但有個指令，CBW 值得一提，不過在講 CBW 之前，先要知道什麼是有號數，請看註一。
CBW 是「convert byte to word」的意思，它是改變資料類型的指令，其語法是
CBW
表面上 CBW 沒有運算元，但其實是有個隱藏的運算元，那就是 AX 暫存器。CBW 會把存於 AL 的數值，變成存於 AX。亦即，把位元組的資料類型，以有號數的方式變成字組的資料類型。
若 AL 的第 7 位元為 0，執行完 CBW 後，AH 內所有位元都變為 0；若 AL 的第 7 位元為 1，執行完後，AH 內所有位元變為 1。也就是說，CBW 會把 AL 內的符號，延伸到 AH 內。這樣就能把 AL 中的有號數，擴充至 AX。
例如下圖 AX 為 0FF65H，AL 為 65H，第七位元是零。當執行 CBW 後，AL 上的第七位元擴充到 AH 暫存器，使 AH 上的每個位元都變成 0。
另外有兩個指令，CWD、CDQ，和 CBW 很類似。CWD 是「convert word to double word」的意思，它把 AX 看成有號數，將其第 15 位元的符號擴充至 DX，亦即把 AX 擴充至 DX:AX。CDQ 是「convert double word to quad word」把 EAX 看成有號數，將其第 31 位元的符號擴充至 EDX，亦即把 EAX 擴充成 EDX:EAX。
在 INPUT1.ASM 的第 44 行，使用者輸入字元的 ASCII 碼，已經被第 36∼42 行的程式調整過要，使其範圍落在 0∼9H 之間，並存於 AL 裏。第 43 行，以使原先的變數乘以 10H 了，接下來要把 AL 加到變數裏。但因為變數是十六位元長，AL 是八位元長，長度並不相等，因此要把 AH 變成零。而我們能夠確定，AL 必為正數，因其範圍必在 0∼9H 之間，故用 CBW 指令。當然，使用「MOV AH,0」也是可以的。
微軟西元 1992 年發售的 MASM 6.x 版，新增了許多加強假指令，包含了類似高階程式語言的條件控制流程指令 ( conditional control flow )。這些指令包含了底下幾種，然後，小木偶會利用底下的條件控制流程改寫 INPUT1.ASM。
最簡單的情形是︰
.IF 判斷式
程式一
.ELSE
程式二
.ENDIF
上面的寫法，應該很容易了解。當判斷式為「真」時執行程式一裏的指令；為「偽」時就執行程式二裏的指令。假如為「偽」時不用執行任何指令，則 .ELSE 以及程式二可以刪除，就變成底下的樣子：
.IF 判斷式
程式片段
.ENDIF
底下我們看一個例子，來說明組譯器是如何把這些假指令轉換成機械碼的。例如，下面左邊的例子是「如果 AX 等於 BX，就在螢幕上印出大寫的英文字母 A；否則印出位址 200H 的字串」( 這裏的等於，必須用「==」)：
.IF AX==BX
MOV DL,"A"
MOV AH,2
INT 21H
.ELSE
MOV DX,200H
MOV AH,9
INT 21H
.ENDIF
INC CX | 10B8:0100 3BC3 CMP AX,BX 10B8:0102 7508 JNZ 010C 10B8:0104 B241 MOV DL,41 10B8:0106 B402 MOV AH,02 10B8:0108 CD21 INT 21 10B8:010A EB07 JMP 0113 10B8:010C BA0002 MOV DX,0200 10B8:010F B409 MOV AH,09 10B8:0111 CD21 INT 21 10B8:0113 41 INC CX |
經過組譯後的結果在上面右半邊。你可以看到，「.IF/ELSE/ENDIF」仍然是用 CMP、JNZ、JMP 這些 x86 指令來作邏輯判斷及跳躍。因此這些指令的限制 ( 例如 JNZ 跳躍距離只能在－128∼127 之間 ) ，也就是「.IF/ELSE/ENDIF」的限制。雖然如此，使用這些假指令，可以讓程式流程變得清楚明白，方便於閱讀修改。因此，如果您使用 MASM 6.x 版本的話，建議可以儘量用這種假指令。
因為「.IF/.ESLEIF/.ELSE/.ENDIF」是由組譯器將之「翻譯」成 80x86 指令集的某一些指令，再將之相互搭配，所以「.IF/.ESLEIF/.ELSE/.ENDIF」只是假指令。
判斷式也叫條件 ( condition )，其模樣大致可分為四種︰
①：可以是數值關係式，其形式為：
運算元1 比較運算子 運算元2
運算元1 可以為暫存器或變數，運算元2 可以是暫存器、變數或立即值，但不能同時為變數，這是因為在 x86 指令裏，可以有「CMP AX,BX」，但沒有比較兩個變數的指令。例如上面的例子，「.IF AX==BX」中，「AX==BX」就是判斷式，AX、BX 是兩個運算元，而「==」是比較運算子。常用的比較運算子，見下表：
| 比較運算子 | 意義 | 比較運算子 | 意義 | 比較運算子 | 意義 |
| == | 等於 | != | 不等於 | > | 大於 |
| < | 小於 | >= | 大於或等於 | <= | 小於或等於 |
②：可以是數值關係式之間，再做複雜的邏輯運算。例如兩個數值關係式都為真時才執行某些指令。可用的邏輯運算子如下表：
| 邏輯運算子 | 意義 | 邏輯運算子 | 意義 | 邏輯運算子 | 意義 |
| && | 且 | || | 或 | ! | 非 |
例如底下的例子是，如果 AL<100 且 AL>50 ( 其實就是 AL 在 50∼100 之間 )，就使 BX 加上 200H。
.IF (al<100)&&(al>50)
MOV BX,200H
.ENDIF
③：判斷式也可以僅僅是一個運算元，此運算元可以是暫存器、變數、數值。使用這種情況時是指當運算元非零時，會被認為是「真」；為零時，被認為是「偽」。例如底下的例子是「如果 AL 不為零，就使 BX 加 100H」：
.IF AL
ADD BX,100H
.ENDIF
④：運算元也可以是旗標的狀態，可以用的旗標狀態如下表：
| 旗標 | 意義 | 旗標 | 意義 | 旗標 | 意義 |
| ZERO? | 零值旗標設定時為真 | CARRY? | 進位旗標設定時為真 | OVERFLOW? | 溢位旗標設定時為真 |
| SIGN? | 符號旗標設定時為真 | PARITY? | 同位旗標設定時為真 |
例如底下的例子是「當 AL 等於 BL，或 CY 時，就讓 CX 變為零」：
.IF (AL==BL)||CARRY?
MOV CX,0
.ENDIF
在內定情形下，ML.EXE 都會把在判斷式中的暫存器當成無號數，以無號數判斷其大小。如果要使暫存器當成有號數來判斷時，可以在前面加上「SBYTE PTR」、「SWORD PTR」、「SDWORD PTR」強迫使其變成有號數。很明顯的，「SBYTE PTR」、「SWORD PTR」、「SDWORD PTR」這些資料類型之前冠以「S」，這「S」表示符號 ( sign ) 之意。下面的例子，請讀者試試看，判斷最後 DX 是多少？
MOV AL,0FFH
MOV BL,1
MOV DX,0
.IF SBYTE PTR AL>BL
MOV DX,1
.ENDIF
因為在比較時，程式以「SBYTE PTR」表明 AL 與 BL 要當成有號數比較。AL 之值為 0FFH 是有號數的 －1；BL 為 1，不論有號數還是無號數都是 1。因此 AL 小於 BL，故不會執行「 .IF」與「.ENDIF」之間的指令，所以 DX 為 0。
上面的程式，如果把「SBYTE PTR」拿掉，執行完後，DX 是 1。
上面所提到的最多只有兩種分支情形，亦即「若……就執行程式一，否則執行程式二」。但是「.IF/.ELSE/.ENDIF」還可以擴充成更多的分支，如底下的程式：
.IF 判斷式一
程式一
.ELSEIF 判斷式二
程式二
.ELSEIF 判斷式三
程式三
.ELSE
程式四
.ENDIF
這種多個分支流程是，假如判斷式一為真，則執行程式一的指令；假如判斷式二為真，則執行程式二的指令；假如判斷式三為真，則執行程式三的指令……，假如都不是上面的情形，則執行 .ELSE 之後的程式。換句話說，「.IF/.ESLEIF/.ELSE/.ENDIF」的用法很有彈性，您可以依需要，省卻「.ELSEIF」或省卻「.ELSE」，也可以視情況增加「.ELSEIF」條件分支，不過不論那一種情形，「.IF」 和「.ENDIF」必定是成對搭配在一起，好像一對夫妻一樣，並且要放在條件控制流程的最前面與最後面。
底下的例子，AX 已存有水溶液的 pH 值，如果 AX 為七，水溶液呈現中性；小於七，水溶液呈現酸性；大於七，水溶液呈現鹼性：
ACID DB "The solution is acid.$"
BASE DB "The solution is base.$"
NEUTRAL DB "The solution is neutral.$"
⁝
.IF AX<7
mov dx,OFFSET ACID
.IF AX==7
mov dx,OFFSET NEUTRAL
.IF AX>7
mov dx,OFFSET BASE
.ENDIF
mov ah,9
int 21h
MASM 6.x 的高階條件控制流程指令，除了「.IF/.ESLEIF/.ELSE/.ENDIF」外，還有「.WHILE/.ENDW」與「.REPEAT/.UNTIL」。
先來看看「.WHILE/.ENDW」的語法︰
.WHILE 判斷式
程式
.ENDW
「.WHILE/.ENDW」迴圈的執行過程如下︰當程式執行到 .WHILE 時，會檢查判斷式是否為真，假如為真，則執行 .WHILE 與 .ENDW 之間的程式，直到遇到 .ENDW 時，再回到開頭 .WHILE 處檢查判斷式是否為真，若為真時，再度執行 .WHILE 與 .ENDW 之間的程式，一直到判斷式為假時，才跳到 .ENDW 下一行程式執行。所以看起來，「.WHILE/.ENDW」就像是 C/C＋＋ 的 WHILE {} 迴圈一樣。
再來看看「.REPEAT/.UNTIL」的語法︰
.REPEAT
程式
.UNTIL 判斷式
「.REPEAT/.UNTIL」迴圈的執行過程如下：當程式執行到 .REPEAT 時，會先執行 .REPEAT 和 .UNTIL 之間的程式，然後檢查 .UNTIL 之後的判斷式，若判斷式為真，則離開迴圈，判斷式為偽，則回到 .REPAET 處執行 .REPEAT 和 .UNTIL 之間的程式，然後再一直重複。也就是說，這段程式碼會一直重複在 .REPEAT 到 .UNTIL 之間的程式，直到判斷式為真時跳出迴圈。這一對假指令和 C/C＋＋ 的 DO 迴圈一樣。
「.REPEAT/.UNTIL」與「.WHILE/.ENDW」很像，但稍有不同。「.REPEAT/.UNTIL」會先執行其中的程式一次，然後再判斷 .UNIT 後的真偽，以決定是否重複再執行一次；而 .WHILE/.ENDW 則會先判斷 .WHILE 後的真偽，決定是否執行其內的程式，因此有可能不會執行其中的程式。
在「.WHILE/.ENDW」或「.REPEAT/.UNTIL」迴圈裏，除了讓判斷式判斷可退出迴圈外，如果有其他情形也要退出迴圈時，也可以加上「.BREAK .IF」假指令，強制退出迴圈，表示只有在 .IF 之後的條件為『真』時，才退出迴圈。例如底下的程式是讓使用者輸入一個字串並存於 string 字串變數裏，直到使用者按下 Enter 鍵為止︰
mov bx,OFFSET string
.WHILE 1
mov ah,1
int 21h
.BREAK .IF al==0dh
mov [bx],al
inc bx
.ENDW
「.CONTINUE .IF」則是在 .IF 之後的判斷式為真時，會跳到「.WHILE/.ENDW」或「.REPEAT/.UNTIL」迴圈開始處執行。例如下面是一個輸入數字字串的程式，當使用者不是按 0∼9 的阿拉伯數字時，會跳回迴圈起始處，繼續等待使用者輸入數字；如果使用者按下 Enter 鍵 ( ASCII 碼為 0DH ) 或 Esc 鍵 ( 掃描碼是 01 ) 時，跳出迴圈。
.REPEAT
mov ah,1
int 21h
.BREAK .IF (al==0dh)||(al==01)
.CONTINUE .IF (al<='0')||(al>='9')
stosb
.UNTIL ah==1
INPUT1.ASM 有許多地方要判斷所輸入的字元是否為十六進位數字的合法字元，不僅繁雜，也難以閱讀。小木偶以 MASM 6.x 新增的條件控制流程指令改寫 INPUT1.ASM，於是變成底下的程式，INPUT2.ASM：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 |
;由鍵盤輸入一個字組長的十六進位數，然後存入value變數裏。
.MODEL TINY
.386
;*******************************************************************************
.CODE
ORG 100h
;-------------------------------------------------------------------------------
start: jmp begin
value DW ?
error_message DB 0dh,0ah,"Please input 0~9 or A~F.$"
begin: mov cx,4 ;一個字組的十六進位數有四位
mov value,0 ;使value歸零
.WHILE cx
mov ah,1 ;DOS服務程式，鍵盤輸入字元
int 21h ;AL＝輸入字元的ASCII碼
.IF (al>="0")&&(al<="9")
sub al,"0"
.ELSEIF (al>="A")&&(al<="F")
sub al,37h
.ELSEIF (al>="a")&&(al<="f")
sub al,57h
.ELSE
mov ah,9
mov dx,OFFSET error_message
int 21h
.BREAK .IF 1
.ENDIF
shl value,4 ;value＝value×10H
cbw ;使AH變為0
add value,ax ;value＝value＋AX
dec cx
.ENDW
int 20h
;*******************************************************************************
END start |
比較 INPUT1.ASM 與 INPUT2.ASM，發現後者的原始碼短了很多，少了許多標記，在判斷使用者是否輸入正確的十六進位字元，也簡潔扼要許多，並且容易閱讀，這是「結構化」優點；但是缺點則是可執行檔較大，卻大不了多少。因此近代程式設計，大多希望程式設計師能設計出結構化的程式來。
DEC 指令的用法是：
DEC 運算元
DEC 指令是使其後所接的運算元減一，這裡可以做為運算元的有變數或暫存器。根據 DEC 運算後的結果，受影響的旗標有溢位旗標、符號旗標、零值旗標、輔助進位旗標及同位旗標，進位旗標不受影響。
無號數就是沒有正、負號的數，一般我們把它看成是正數，要定義一個位元組長度、一個字組長度、一個雙字組長度、一個四字組的無號數，用「DB」、「DW」、「DD」、「DQ」，也可以用「BYTE」、「WORD」、「DWORD」、「QWORD」。如下面的用法，都是定義無號數。
變數 DB 數值 變數 DW 數值 變數 DD 數值 變數 DQ 數值
有號數是指帶有正號或負號的數，以最高位元表示正、負號。最高位元為零，表示此數為正數；最高位元為一，表示此數是負數。以一個位元組長度的數來說，第七位元為 1，就代表負數；為零，就代表正數。
有了這觀念以後，那 －1 怎麼表示呢？以一位元組長度的有號數來說，可能有人以為 1，用二進位表示是「0000 0001」；－1 是負數，因此第七位元為 1，所以－1 是「1000 0001」。但這種想法是錯的，因為 －1 比零還要小一，或者反過來說，－1 加一等於零。「1000 0001」加一後變成「1000 0010」，照剛才的邏輯，這是 －2，顯然這樣的想法是錯誤的。
那怎樣才對呢？應該這樣，「1111 1111」加一變成「0001 0000 0000」，雖然超過了一個位元組的範圍，如果僅看一個位元組，那麼就剛好是零。在電腦科學上，我們規定了加、減法中，目的運算元和來源運算元長度相同。基於以上理由，一個位元組寬度時，－1 以二進位表示為「1111 1111」。同理，一個字組寬度時，－1 為「1111 1111 1111 1111」。
我們可以把有號數中的正、負數想想成以零為界線，如下圖紅色的數字就是有號數。向右為有號數的正數，每經一格分別是 1、2、3……127；向左為有號數的負數，分別是 －1、－2、－3……－128。最後分別終止在正數最大的 127 和負數最小的 －128。
上圖也表示了同一個十六進位的數值，可以解釋為有號數也可以看成無號數，這完全要看程式如何解釋以及如何定義變數。例如「0FFH」可以代表無號數的 255 ( 十進位 )，也可以是有號數 －1 ( 十進位 )。這完全要看當初在定義變數時如何定義的。定義無號數用「DB」或「BYTE」；定義有號數用「SBYTE」，這裏的「S」顯然是 signed 的意思。
x db 0ffh ;x＝255
y sbyte 0ffh ;y＝－1
z sbyte ?
… …… ……
mov z,81h ;z＝－127
上面的程式碼裏，把 z 定義為有號數，故「mov z,81h」其實就是讓 z 變成 －127。x 和 y 兩變數都是「0FFH」，但是 x 要把它想成是無號數，255； y 卻是有號數 －1。你也可以把「y sbyte 0ffh」寫成「y sbyte -1」。
儘管如此，定義無號數用「DB」或「BYTE」，有號數用「SBYTE」，卻不是強制規定的。因此你還是可以用像「x DB -1」、「y SBYTE 255」這樣的指令，這些都能通過組譯。我想這大概是因為存入的數值，最後都變成十六進位數值，而且都是 0FFH，沒有差別，但是還是要小心使用。
定義其他長度的有號數與無號數，也都和位元組類似，小木偶整理成下表：
| 種類 | 假指令 | 名稱 | 長度 ( 位元組 ) | 所能表示的整數範圍 |
| 無號數 | DB、BYTE | 位元組 | 1 | 0∼255 |
| DW、WORD | 字組 | 2 | 0∼65,535 | |
| DD、DWORD | 雙字組 | 4 | 0∼4,294,967,295 | |
| DQ、QWORD | 四字組 | 8 | 0∼18,446,744,073,709,551,615 | |
| 有號數 | SBYTE | 位元組 | 1 | －128∼127 |
| SWORD | 字組 | 2 | －32,768∼32,767 | |
| SDWORD | 雙字組 | 4 | －2,147,483,648∼2,147,483,647 |
SHL ( shift logical left ) 與 SAL ( shift arithmetic left ) 是一樣的指令，其語法如下：
SHL 目的運算元,1 式(1) SHL 目的運算元,CL 式(2) SHL 目的運算元,立即值 式(3)
SHL 指令是的意思，是指目的運算元內的每個位元向左移位數個位元，如果只移一個位元，就用式 (1)；如果一次要移好幾個位元，用式 (2)，把要移位的位元數事先存入 CL 裏面。8086/8088 CPU 只能用這兩種方法，較高階的 CPU 可以用式 (3)，要移位的位元數直接以立即值表示。
由最高位向左移出的資料會消失不見，只有最後一次移出的位元會存入進位旗標裏。由最低位元向左移入的位元，都會填上零，亦即把零移入最低位元。
SHL 有一項特性，非常好用，那就是可以當做乘以 2 的冪方。例如「SHL AX,1」相當於把 AX 乘以 2，「SHL AX,2」相當於乘以 22，「SHL AX,2」相當於乘以 23……以此類推。
SHR 是邏輯右移 ( shift logical right ) 的意思，亦即把目的運算元中的每個位元，向右移數個位元。只有移位方向向右以及相當於除以 2 的冪方，這兩點與 SHL 不同，其他特性都一樣，包含最高位元會補上 0。
SAR 是算術右移 ( shift arithmetic right ) 的意思，亦即把目的運算元中的每個位元，向右移數個位元。SAR 指令在每次移位的時候，最高位元保持原來的值。如果 AL 為「1000 1100」，執行「SAR AL,2」後，AL 變為「1110 0011」，進位旗標被清除。
SUB 指令是有號數減法運算指令，語法是
SUB 目的運算元,來源運算元
SUB 指令會把目的運算元減掉來源運算元之後，再把差存入目的運算元裏面，因此，目的運算元之值會改變，來源運算元之值不變。目的運算元可以是暫存器或變數，來源運算元可以是暫存器、變數或立即值。但目的運算元與來源運算元不可同時為變數，且兩者長度要相同。
SUB 指令會影響許多旗標，包含進位旗標、同位旗標、輔助進位旗標、零值旗標、符號旗標、溢位旗標六個旗標。
CBW ( convert byte to word ) 指令會把 AL 中的有號數，擴充至 AX。若 AL 的第七位元為一，則 AX 的第 8∼15 位元均變為一；若 AL 的第七位元為零，則 AX 的第 8∼15 位元均變為零。
CWD ( convert word to double word ) 指令會把 AX 中的有號數，擴充至 DX:AX。若 AX 的第十五位元為一，則 DX 所有位元均變為一；若 AX 的第十五位元為零，則 DX 所有位元均變為零。
CDQ ( convert double word to quad word ) 指令會把 EAX 中的有號數，擴充至 EDX:EAX。若 EAX 的第三十一位元為一，則 EDX 所有位元均變為一；若 EAX 的第三十一位元為零，則 EDX 的所有位元均變為零。
CBW、CWD、CDQ 均不影響旗標。
無號數就是沒有正、負號的數，一般我們把它看成是正數，要定義一個位元組長度、一個字組長度、一個雙字組長度、一個四字組的無號數，用「DB」、「DW」、「DD」、「DQ」，也可以用「BYTE」、「WORD」、「DWORD」、「QWORD」。
有號數是指帶有正號或負號的數，以最高位元表示正、負號。最高位元為零，表示此數為正數；最高位元為一，表示此數是負數。以一個位元組長度的數來說，第七位元為 1，就代表負數；為零，就代表正數。要定義一個位元組、一個字組、一個雙字組的有號數，可以分別用「SBYTE」、「SWORD」、「SDWORD」；但是沒有「SQWORD」。
這是 MASM 6.x 新增的條件控制流程指令，其語法是：
.IF 判斷式一
程式一
.ELSEIF 判斷式二
程式二
.ELSEIF 判斷式三
程式三
.ELSE
程式四
.ENDIF
這種多個分支流程是，假如判斷式一為真，則執行程式一的指令；假如判斷式二為真，則執行程式二的指令；假如判斷式三為真，則執行程式三的指令……，假如都不是上面的情形，則執行 .ELSE 之後的程式。換句話說，「.IF/.ESLEIF/.ELSE/.ENDIF」的用法很有彈性，您可以依需要，省卻「.ELSEIF」或省卻「.ELSE」，也可以視情況增加「.ELSEIF」條件分支，不過不論那一種情形，「.IF」 和「.ENDIF」必定是成對搭配在一起，好像一對夫妻一樣，並且要放在條件控制流程的最前面與最後面。
.WHILE/.ENDW 的語法︰
.WHILE 判斷式
程式
.ENDW
.WHILE/.ENDW 迴圈的執行過程如下︰當程式執行到 .WHILE 時，會檢查判斷式是否為真，假如為真，則執行 .WHILE 與 .ENDW 之間的程式，直到遇到 .ENDW 時，再回到開頭 .WHILE 處檢查判斷式是否為真，若為真時，再度執行 .WHILE 與 .ENDW 之間的程式。一直到判斷式為假時，才跳到 .ENDW 下一行程式執行。
.REPEAT/.UNTIL 的語法︰
.REPEAT
程式
.UNTIL 判斷式
.REPEAT/.UNTIL 迴圈的執行過程如下：當程式執行到 .REPEAT 時，會先執行 .REPEAT 和 .UNTIL 之間的程式，然後檢查 .UNTIL 之後的判斷式，若判斷式為真，則離開迴圈，判斷式為偽，則回到 .REPAET 處執行 .REPEAT 和 .UNTIL 之間的程式，然後再一直重複。也就是說，這段程式碼會一直重複在 .REPEAT 到 .UNTIL 之間的程式，直到判斷式為真時跳出迴圈。
.CONTINUE .IF 的語法如下：
.CONTINUE .IF 判斷式
.CONTINUE .IF 用於 .WHILE/.ENDW 或 .REPEAT/.UNTIL 之內，當判斷式為真時，可以跳至迴圈的最前面。
.BREAK .IF 的語法如下：
.BREAK .IF 判斷式
.BREAK .IF 與 .CONTINUE .IF 很相像，都用於 .WHILE/.ENDW 或 .REPEAT/.UNTIL 之內，當判斷式為真時，可以強制退出迴圈，而不是回到迴圈的一開頭。
例如底下的程式是「當使用者按下阿拉伯數字時，將它存入 DX 所指的位址儲存起來；如果不是阿拉伯數字，就跳出迴圈」：
mov bx,200h
.WHILE 1
mov ah,1
int 21h
.BREAK .IF (al<"0")||(al>"9")
mov [bx],al
inc bx
.ENDW
int 20h