Ch 05　印出暫存器的數值

小木偶打算在本章裏，說明如何印出 16 位元長的十六進位數值，這個數值恰好是一個暫存器的長度。因此在本章裏，小木偶打算把 BX 裏面的數值印在螢光幕上。藉由這個程式，可以讓讀者更了解組合語言是如何由最基礎的工作開始，慢慢的往上增加，最後成就偉大的工作。

PRINTBX.ASM 程式

假如 BX 內之數值為 4162H，要把 BX 之值印在螢光幕上，並不像其他中階或高階語言那樣，只要用指令「PRINT BX」即可，也不能像底下那樣：

        MOV     BX,4162H        ;ASCII 碼的 41H 代表「A」，62H 代表「b」
        MOV     STRING,BX       ;把 BX 存入 STRING 字串
        MOV     AH,9
        MOV     DX,OFFSET STRING;取得 STRING 的位址
        INT     21H

因為這樣印出來的是 BH、BL 所代表的 ASCII 字元，「bA……」，並不是十六進位數值，4142 ( 註一 )。那麼要如何做呢？


原理

其實也不難，很好理解。如果 BX 內的數值是 4162H，要印出來，顯然是要分四次印，因此勢必要用到迴圈。第一次印「4」這個字元、第二次印「1」這個字元……，檢查這些阿拉伯數字 ( 也就是這些字元 ) 的 ASCII 編碼，4 的 ASCII 碼是 34H、1 的 ASCII 碼是 31H、……。這些阿拉伯數字的 ASCII 碼在 30H∼39H 之間。

根據第一章的服務程式，以第一次印出來的「4」這個字元為例，要印出這個字元，必須用底下程式：

        MOV     DL,34H
        MOV     AH,2
        INT     21H

第二次要印出來的字元是「1」，就得在 DL 裏存放 31H。很明顯 DL 暫存器裏的十六進位的個位數是來自原來 BX 暫存器裏的四個位數的數值，DL 裏十六進位的十位數是自行加上去的，應該是以 30H 為基準往上加的結果。那麼有沒有辦法一次只取出 BX 暫存器裏的四個位數中的一個，而且由最高位數開始呢？答案是……有的！要用到兩個 x86 指令：ROL 與 AND。


x86 指令：ROL 與 ROR

和其他程式語言相比，組合語言最擅長的就是位元運算，ROL 與 AND 都會牽涉到位元運算。

ROL 是向左旋轉數個位元的指令 ( rotate left )，其語法是

ROL     運算元,1        式(1)
ROL     運算元,CL       式(2)
ROL     運算元,立即值    式(3)

ROL 指令會把運算元裏面的每個位元向左旋轉，這裏的運算元可以是暫存器，也可以是記憶體變數，那什麼是旋轉呢？還是舉個例子說明。如下圖，BX 為 4162H，換成二進位是「0100 0001 0110 0010」，向左旋轉一個位元的意思是第 15 位元的 0 由下方旋轉移到第 0 位元，原來第 0 位元的 0 向左移到第 1 位元，原來第 1 位元的 1 向左移到第 2 位元，其餘依此類推，最後變成「1000 0010 1100 0100」，就變成十六進位的 82C4H。

ROL 指令還會影響進位旗標 ( 進位旗標稱為 carry flag，簡稱 CF )。當向左旋轉一位元時，第十五位元除了旋轉至第 0 位元之外，也會同時複製到進位旗標；如果是向左旋轉多個位元時，就是最後一次旋轉的第 15 位元複製到進位旗標。因此當 BX 為 4162H 時，執行「ROL BX,1」時，進位旗標為 0。如果 BX 為 4162H，執行「ROL BX,2」時，就會設定進位旗標 ( 亦即進位旗標會變成 1 )。

向左旋轉有兩個特性：①如果運算元是 8 位元的暫存器，旋轉 4 個位元，那麼就會讓較高的四個位元與較低的四個位元互換。例如 AL 為 1AH，執行「ROL AL,4」後，AL 變成 0A1H。②如果運算元是 16 位元的暫存器，旋轉 4 個位元後，會把最高的四個位元移到最低的四個位元，次高的四個位元變成最高的四個位元，例如 AX 為 4162H，執行「ROL AX,4」就會變成 1624H。第二個特性就是 PRINTBX.ASM 要用到的。

8086/8088 執行 ROL 指令時，只能旋轉一個位元，亦即只能用式子 (1)；如果要旋轉多個位元，也不是不可以，但要用式子 (2)，在執行 ROL 之前，先把要旋轉的位元個數存入 CL 暫存器裏。80286 及其以後的 CPU 要旋轉多個位元，可直接寫在運算元之後，如式子 (3)，立即值就是旋轉的位元數。

ROR 是 rotate right 的意思，除了旋轉方向向右之外，其餘的特性都與 ROL 都一樣。


x86 指令：AND

AND 指令的語法是

AND     目的運算元,來源運算元

這個指令是將目的運算元與來源運算元做 AND 運算，再將結果存入目的運算元。AND 翻譯成「且」的意思，這種運算是只有當兩個條件都成立時才為真。

例如你放學回家，媽媽說：「要寫完今天的作業並且預習完明日的功課才能玩電腦。」意思就是如果你「今日作業」和「預習明日功課」只要有一項沒做完，就不能「玩電腦」，只有當兩項都做好了才可以玩電腦。

在電腦中，「1」表示真或成立的意思，「0」表示偽或不成立的意思。所以，只有當兩個數都為一，做 AND 運算時，其結果才為一，只要運算的兩數有一個為零，結果就為零。AND 運算表如下：

0 AND 0＝0
0 AND 1＝0
1 AND 0＝0
1 AND 1＝1

AND 指令中的目的運算元可以是暫存器或記憶體變數，來源運算元可以是常數、暫存器或記憶體變數，但是來源運算元與目的運算元不可同為記憶體變數。來源運算元與目的運算元的長度必須一致，做 AND 運算時，相對應的位元互相運算，亦即來源運算元的第 0 位元與目的運算元第 0 位元做 AND 運算、來源運算元的第 1 位元與目的運算元第 1 位元做 AND 運算……其餘依此類推。

舉個例子說明。如右圖的 DL 暫存器之值為 24H，執行「AND DL,0FH」時，把每個位元對齊後，每個位元做 AND 運算後，結果如最下面黃字所示。值得一提的是，0FH 這個數值，較高的四個位元均為 0，因此不管 DL 較高的四個位元是什麼，與其做 AND 運算後均為 0；而較低的四個位元均為一，也不管 DL 較低的四個位元是什麼，其數值保持不變。

像上面這樣，把一個整數的某些位元清除 ( 清除的意思是變為 0 )，而保留其他位元的過程稱為「遮罩」( mask )，方法很簡單，先設定一數讓要遮罩的位元都設為零，然後和原整數做 AND 運算就可以了。


PRINTBX.ASM 的原始程式

講解完用 ROL 與 AND 兩個指令可以把 BX 裏面的十六進位數值的四個位數依序拆解開來，底下小木偶就列出原始程式來，以饗讀者：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
.MODEL          TINY                    ;組譯並連結成PRINTBX.COM
.386                                    ;使用386指令集，可以用「ROL BX,4」
;*******************************************************************************
.CODE
ORG             100h
;-------------------------------------------------------------------------------
start:          jmp     begin
value           DW      4162h           ;要在螢光幕上印出來的十六進位數
begin:          mov     bx,value        ;把此數存入BX
                mov     cx,4            ;BX內有四個位數，所以要印四次
                mov     ah,2            ;DOS服務程式，AH＝2，印出字元
next:           rol     bx,4            ;旋轉四個位元，即十六進位的一個位數
                mov     dl,bl           ;保存BX，用DL運算
                and     dl,0fh          ;遮罩DL內較高的四個位元
                add     dl,"0"          ;使DL之值變成阿拉伯數字的ASCII碼
                cmp     dl,"9"          ;檢查是否為英文字母
                jbe     print_it        ;如果不是，就跳到print_it
                add     dl,7            ;如果是，加上7，使DL變成A∼F
print_it:       int     21h             ;印出字元
                loop    next            ;是否已印出四個位數了，若否，跳到next
                int     20h             ;若是，結束
;*******************************************************************************
END             start

把 PRINTBX.ASM 組譯連結的方式很簡單，開啟「Microsoft Virtual PC」，執行其中的「MS-DOS 6.20」虛擬機器，然後輸入下面的指令：

C:\>e: [Enter]

E:\>cd dos\printbx [Enter]

E:\DOS\PRINTBX>ml printbx.asm [Enter]
Microsoft (R) Macro Assembler Version 6.11
Copyright (C) Microsoft Corp 1981-1993.  All rights reserved.

 Assembling: printbx.asm

Microsoft (R) Segmented Executable Linker  Version 5.31.009 Jul 13 1992
Copyright (C) Microsoft Corp 1984-1992.  All rights reserved.

Object Modules [.obj]: printbx.obj/t 
Run File [printbx.com]: "printbx.com"
List File [nul.map]: NUL
Libraries [.lib]: 
Definitions File [nul.def]:

E:\DOS\PRINTBX>

看到上面的 PRINTBX.ASM，從第十一行到二十行就是印出 BX 內的四位數的十六進位數值，底下一一解釋新指令。


.386 假指令

「.386」假指令是用來指示 ML.EXE 在編製程式碼的時候，使用 80386 指令集編製。在第零章「80286、IBM PC/AT 與 MS－DOS 3.0」一節中曾指出，x86 CPU 有向下相容的特性，新一代的 CPU 中新增一些指令同時又能執行前一代 CPU 的所有指令。截至目前 ( 民國 110 年 )，英特爾出品的 CPU 也歷經許多代了，因此才會有這個假指令。如果不指定哪一代 CPU 的話，ML.EXE 預設指令集是「.8086」，也就是 8086/8088 CPU 的指令集。

前面提過，8086/8088 的向左旋轉指令，每次只能旋轉一個位元。但是現在的電腦所配備的 CPU 早就是 Core i3/5/7/9 ( 比 .586 還要更新的 CPU ) 了，當然應該用更好的指令集。為了能夠使用「ROL BX,4」這種一次可以旋轉四個位元的指令，小木偶使用「.386」假指令，指定能使用 80386 指令集。

底下一系列的假指令，提供讀者參考。類似的假指令有「.286」、「.386」、「.486」、「.586」以及「.286P」、「.386P」、「.486P」、「.586P」，後面四個假指令讓程式能使用特殊的指令，這些特殊的指令大多用於保護模式的特權階級指令。另外還有設定浮點運算器指令集的，包含「.8087」、「.287」、「.387」，一般而言，如果原始程式已指定某個 CPU 的指令集，ML.EXE 會自行搭配與之配合的浮點運算器指令集。例如指定「.286」，ML.EXE 會自動指定「.287」，但也可以自行指定其他浮點運算器指令集。還有「.8086」、「.186」等假指令

注意！「.MODEL」與「.386」的先後次序很重要。如果「.MODEL」在前，「.386」在後，那麼會使用十六位元的區段，這是在 DOS 系統中的程式使用的方式；如果「.386」在前，「.MODEL」在後，那麼會使用三十二位元的區段，這是在 Windows 系統中的程式使用的方式。

DEBUG 無法認識全部「.286」的指令集，像「ROL BX,4」就無法正常顯示。我們實驗看看：

E:\DOS\PRINTBX>debug printbx.com [Enter]
-u [Enter]
10B8:0100 EB02          JMP	0104
10B8:0102 62            DB	62
10B8:0103 41            INC	CX
10B8:0104 8B1E0201      MOV	BX,[0102]
10B8:0108 B90400        MOV	CX,0004
10B8:010B B402          MOV	AH,02
10B8:010D C1            DB	C1 →此處本應該是「ROL BX,4」但 DEBUG 不認得 80286 所有指令，所以反組譯錯誤
10B8:010E C3            RET
10B8:010F 048A          ADD	AL,8A
10B8:0111 D380E20F      ROL	WORD PTR [BX+SI+0FE2],CL
10B8:0115 80C230        ADD	DL,30
10B8:0118 80FA39        CMP	DL,39
10B8:011B 7E03          JLE	0120
10B8:011D 80C207        ADD	DL,07
-q [Enter]

E:\DOS\PRINTBX>

可以用另一個除錯器代替，小木偶推薦的是隨 MASM 4.0 附的符號除錯器，SYMDEB.EXE，如果您按照小木偶第零章及附錄一的方式安裝，SYMDEB.EXE 已經在「C:\TOOLS\」子目錄裏了。SYMDEB 的使用方法和 DEBUG 類似，但功能更為強大，我們試試看：

E:\DOS\PRINTBX>c:\tools\symdeb printbx.com [Enter]
Microsoft (R) Symbolic Debug Utility  Version 4.00
Copyright (C) Microsoft Corp 1984, 1985.  All rights reserved.

Processor is [80286]
-u 104 [Enter]
1405:0104 8B1E0201       MOV	BX,[0102]
1405:0108 B90400         MOV	CX,0004
1405:010B B402           MOV	AH,02
1405:010D C1C304         ROL	BX,04 →反組譯正確
1405:0110 8AD3           MOV	DL,BL
1405:0112 80E20F         AND	DL,0F
1405:0115 80C230         ADD	DL,30                         ;'0'
1405:0118 80FA39         CMP	DL,39                         ;'9'
-q [Enter]

E:\DOS\PRINTBX>


記憶體變數

PRINTBX.ASM 的第八行，「value DW 4162h」，value 是變數名稱，這裏的變數是儲存在記憶體中的某一個位址，不是儲存在暫存器裏，所以也叫記憶體變數；當然你也可以把暫存器當成變數，叫暫存器變數，但以後小木偶把記憶體變數稱為變數，暫存器變數就叫暫存器。在組合語言中，宣告一個變數採用的方法如下：

變數名  DW      數值

在組合語言裏，用變數名稱代替位址，例如在 PRINTBX 裏，value 就是位址 0102，你可以看見上面用 SYMDEB 反組譯的結果 ( 以紅字表示 )。如要把 value 之值移入 BX，組譯後會變成「MOV BX,[0102]」。這裏有個觀念特別重要，以中括號把位址括起來，代表此位址內的數值。因此，「[0102]」代表的是位址 0102 的數值，亦即 [0102]＝4162。( 請參閱註二 )

定義變數時，如果不知道數值是多少，也可以用「?」代替。例如

unknow  DW      ?

DW 是定義十六位元的變數，十六位元長稱為「字組」，數值只能在 0∼65535 之間，DW 也可以寫成 WORD，例如

unknow  WORD   ?

變數名稱的第一個字必須以英文字母、底線、@、?、$ 等為開頭，其後還可以用阿拉伯數字，當然英文、底線、@ 仍然可以使用。對 ML.EXE 6.11 版來說，變數名稱最多只能到 247 個字元，已經非常足夠了。另外變數名稱不能和假指令或是 x86/x87 指令集重複。

如果你確定某個變數不會超過 255 的話，可以用 DB 或 BYTE 定義八位元的變數，範圍從 0 到 255，其語法為：

變數名  DB      數值
變數名  BYTE    數值

除了 DB、DW 外，還有好幾種資料類型，其數值範圍不同，列在下表：

資料類型宣告方式名稱長度　( 位元組 )無號整數範圍
　　　字元DB 或 BYTE位元組10∼255
無號短整數DW 或 WORD字組20∼65535
　無號整數DD 或 DWORD雙字組40∼4294967295
無號長整數DQ 或 QWORD四字組80∼18446744073709551615


x86 指令：ADD

ADD 是加法指令，語法是

ADD     目的運算元,來源運算元

ADD 會把目的運算元與來源運算元相加，並把和存入目的運算元裏面。因此，目的運算元之值會改變，來源運算元之值不變。目的運算元可以是暫存器或記憶體變數，來源運算元可以是暫存器、記憶體變數或立即值，但是目的運算元與來源運算元位元數須一致，且不可同時為記憶體變數。例如底下的例子：

value   DW      ?
        ……    ……
        ADD     AX,BX
        ADD     AX,value
        ADD     AX,9
        ADD     avlue,CX

上面的指令都是正確的。

回到 PRINTBX 原始程式中，第十五行是「ADD DL,"0"」，組譯器會把一對「"」或一對「'」內的字元，轉換成 ASCII 碼，也就是說這一行會自動變成「MOV DL,30H」，因為字元「0」的 ASCII 碼是 30H。


x86 指令：JBE

接下來要說明的是第十六、十七行：

        cmp     dl,"9"          ;檢查是否為英文字母
        jbe     print_it        ;如果不是，就跳到print_it

這兩行是檢查 DL 是否超過 39H ( 阿拉伯數字 9 的 ASCII 碼是 39H )，如果沒超過就跳到 print_it 處繼續執行；如果超過就執行「JBE print_it」下一行指令。為什麼要檢查 DL 有沒有超過 39H 呢？這是因為十六進位數值是以 0∼9 與 A∼F 表示，但是在 ASCII 編碼中，阿拉伯數字後面並不是英文字母，英文字母 A 的 ASCII 碼是 41H，與 39H 隔了七個字元。所以如果 DL 超過 39H，表示此位數必須以 A∼F 表示，需要再加上 7。

JBE 指令的一般用法是

CMP     目的運算元,來源運算元
JBE     標記

JBE 通常在 CMP 指令之後，表示目的運算元低於或等於來源運算元 ( 低於就是小於的意思，在組合語言中，低於用在無號數的比較 )，就跳躍至標記處執行。JBE 其實是「jump short if below or equal」的意思，也可以用 JNA，兩者是一樣的意思。JNA 是「jump short if not above」，亦即不高於就跳躍。不管是 JBE 或 JNA 都只能是短程跳躍，並且 CPU 會將目的運算元與來源運算元當做無號數來比較。要解釋無號數是什麼，並不容易，因此以後再說，現在可以把無號數當成正數，但兩者並不完全相同。有關無號數的比較，還有許多相關且常見的指令，請閱讀註三。

在執行 JBE 時，CPU 會檢查旗標暫存器。當零值旗標處於設定狀態，或進位旗標處於設定狀態，就發生跳躍。前一個條件很容易理解，當零值旗標設定時，表示運算結果為零，亦即目的運算元等於來源運算元，即發生跳躍。那麼進位旗標呢？底下小木偶要說明的是進位旗標的意義。


進位旗標 ( Carry Flag )

進位旗標簡稱 CF，當 CPU 做運算時，如果發生進位或借位時，進位旗標被設為 1；反之設為 0。底下的例子顯示了兩數相加以及相減，進位旗標的狀態。在每次執行 DEBUG 的「T」指令後，所列出來暫存器之值的第二行後面，就是旗標暫存器之值，其中 NC 代表進位旗標為 0，CY 代表進位旗標為 1：

C:>debug [Enter]
-a [Enter]
1096:0100 mov al,90 [Enter]
1096:0102 mov bl,80 [Enter]
1096:0104 mov cl,9 [Enter]
1096:0106 add al,bl [Enter]
1096:0108 sub al,cl [Enter]
1096:010A sub al,cl [Enter]
1096:010C [Enter]
-t[Enter]

AX=0090  BX=0000  CX=0000  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=0102   NV UP EI PL NZ NA PO NC
1096:0102 B380          MOV	BL,80
-t[Enter]

AX=0090  BX=0080  CX=0000  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=0104   NV UP EI PL NZ NA PO NC 
1096:0104 B109          MOV	CL,09
-t[Enter]

AX=0090  BX=0080  CX=0009  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=0106   NV UP EI PL NZ NA PO NC
1096:0106 00D8          ADD	AL,BL
-t[Enter]

AX=0010  BX=0080  CX=0009  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=0108   OV UP EI PL NZ NA PO CY
1096:0108 28C8          SUB	AL,CL 這是執行 ADD AL,BL 後的進位旗標，進位了⤶
-t[Enter]

AX=0007  BX=0080  CX=0009  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=010A   NV UP EI PL NZ AC PO NC
1096:010A 28C8          SUB	AL,CL 這是執行 SUB AL,CL 後的進位旗標，沒借位⤶
-t[Enter]

AX=00FE  BX=0080  CX=0009  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=010C   NV UP EI NG NZ AC PO CY
1096:010C C3            RET           這是執行 SUB AL,CL 後的進位旗標，借位了⤶
-

90h＋80h 應為 110h，從二位數變三位數發生進位，CPU 就會設定進位旗標 ( CY )。雖然後來 AL 為 1，但因為進位旗標為一，發生了進位，所以相加的結果並不是表面上 AL 的數值。接著是位址 0108 處的減法，運算前，AL 為 10，CL 為 9，以 AL 減去 CL 時，AL 大於 CL，夠減，不會發生借位，CPU 會清除進位旗標 ( NC )。接著是位址 0109 處的「SUB AL,CL」，這時候 AL 小於 CL 發生借位，CPU 會設定進位旗標 ( CY )。這三處均以藍字顯示。

在第三章裏曾提過，CMP 指令其實是作減法運算，只是不把所得的差儲存起來。因此執行完 CMP 指令，也會影響進位旗標。如果進位旗標被設定，表示發生借位，也就是目的運算元比較小，來源運算元較大。所以 JBE 指令的做法，就是檢查進位旗標，如果設定，就表示目的運算元小，發生跳躍。

我們實際上寫程式時，只需記得 JBE 是指小於或等於時，就發生跳躍。而不需要記得執行 JBE 時，是依據哪一種旗標狀態。小木偶會把這些原理寫出來，只是想告訴大家，JBE 或其他條件跳躍指令，都是依照旗標設定，才決定如何跳躍。


x86 指令：CLC 與 STC

CLC 與 STC 是用來清除進位旗標和設定進位旗標用的，其意為「clear carry flag」和「set carry flag」，都沒有運算元。


註一：小序端 ( Little-Endian ) 與大序端 ( Big-Endian )

雖然這個程式無法印出 BX 的數值來，只能印出 BH、BL 所代表的 ASCII 字元，並不符合我們的要求。但值得注意的是，印出來的字元是「bA……」，為何不是「Ab……」呢？這其中的道理還大有學問呢！

原來 IBM 個人電腦及其相容機種在記憶體上的安排是，較高位數存放於高位址的記憶體，而較低位數存放於低位址的記憶體，這種位元組排列的方式稱為「小端序」( little-endian )。例如十六進位的 1234H 佔用兩個位元組，1 是最高位數，寫在最左邊；4 是最低位數，寫在最右邊。但是，記憶體的安排是低位址在左邊，高位址在右邊。但是如果把 1234H 存入記憶體位址 0110 處時，需佔用兩個位元組，因此 0110 處存放 34H，0111 處存放 12H。

因此讀取或寫入時，常常要顛倒過來思考。例如底下的程式片段：

C:\>debug [Enter]
-a [Enter]
1096:0100 mov bx,1234 [Enter]
1096:0103 mov [110],bx [Enter] →把 BX 存於記憶體 0110 處的一個字組裏
1096:0107  [Enter]
-d 110 l10 [Enter]
1096:0110  04 8B C6 F7 0A 0A D0 D3-48 DA 2B D0 34 00 85 10   ........H.+.4...
-t [Enter]

AX=0000  BX=1234  CX=0000  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=0103   NV UP EI PL NZ NA PO NC
1096:0103 891E1001      MOV	[0110],BX                          DS:0110=8B04

上面的兩個指令是在尚未把 BX 之內容 1234H 填入位址 0110 之前，位址 0110∼0111 處的字組紅字表示。底下下達「T」指令，執行把 BX 內之數值存入記憶體位址 0110 處：

-t [Enter]

AX=0000  BX=1234  CX=0000  DX=0000  SP=FFEE  BP=0000  SI=0000  DI=0000
DS=1096  ES=1096  SS=1096  CS=1096  IP=0107   NV UP EI PL NZ NA PO NC
1096:0107 47            INC	DI                                 
-d 110 l10 [Enter]
1096:0110  34 12 C6 F7 0A 0A D0 D3-48 DA 2B D0 34 00 85 10   4.......H.+.4...
-            ⤷110 處的「34 12」就是原先 BX 之值，1234H

上面程式會把 1234H 存入記憶體 0110 處的一個字組裏。在 DEBUG 用 Dump 指令觀察時，顯示的長度是一個位元組，一個字組要佔用兩個位元組。像上面 BX 裏的 1234H，12H 是較高位數，存於較高位址，0111 處；34H 是較低位數，存於較低位址，0110 處。因此在 DEBUG 裏看起來是顛倒的，初學者很容易搞混。

另外有些電腦上，是把較高位數存放於低位址的記憶體，而較低位數存放於高位址的記憶體，這種位元組排列的方式稱為「大端序」( big-endian )。


註二：一個模糊不清的地方

在組合語言裏，[位址] 代表該位址內的數值，例如本例裏的「MOV BX,[0102]」，並不是把 0102 放到 BX 裏，而是把記憶體位址 0102 的內容放到 BX 裏。因為 BX 是十六位元的暫存器，在記憶體位址 0102 處，16 位元的資料是 4162H，因此執行完這條指令後 BX 為 4162H。

前面幾章提過，變數名稱其實也是某個位址，像 printbx.asm 裏的 value，代表的就是 0102 這個位址。照理講，在原始碼中如果寫

        MOV     BX,value    ;第①式

應該是要把 value 代表的位址移入 BX 裏才對，也就是 BX 後來是 0102。如果要取得位址 0102 內的數值，應該要寫成

        MOV     BX,[value]  ;第②式

才對吧？的確如此，這裏常常讓人搞不清楚，因此有些組譯器要存取變數裏的內容，其語法要寫成類似第②式才行。不過 MASM 則仍採用第①式，這大概是為了配合高階語言的思路吧？


註三：常見的條件跳躍指令

除了本章介紹過的 JBE 指令外，還有另外三個指令和 JBE 類似，它們是 JA、JB、JAE。這四種指令。JA 是「jump short if above」的縮寫，意思是如果高於就跳躍。高於或低於的意思其實就是大於或小於，它們通常用在比較無號數的大小。JA 還需要搭配 CMP 使用，像下面的樣子：

        CMP     目的運算元,來源運算元
        JA      標記

上面兩行的程式是比較目的運算元和來源運算元，如果目的運算元高於來源運算元，那麼跳到標記處執行，否則執行「JA 標記」的下一行指令。例如底下的程式：

        MOV     CX,1
        MOV     AX,100
        CMP     AX,4
        JA      OK      ;因為 AX＞4，所以會跳到 OK: 處執行
        MOV     CX,0
OK:

因為 AX＞4，所以執行完「JA OK」後就直接跳躍到 OK: 處，因此不會執行「MOV CX,0」，故 CX 仍保持原值，1。

JB 是「jump short if below」的縮寫，意思是如果低於就跳躍。JAE 是「jump short if above or equal」的縮寫，意思是如果高於或等於就跳躍。

回顧


x86 指令：ADD

ADD 的語法是

ADD     目的運算元,來源運算元

ADD 指令會把目的運算元加上來源運算元之後，再把結果存入目的運算元。目的運算元可以是暫存器或記憶體變數，來源運算元可以是暫存器、記憶體變數或立即值。但目的運算元與來源運算元不可同時為記憶體變數，且兩者長度要相同。


x86 指令：AND

AND 的語法是

AND     目的運算元,來源運算元

ADD 指令會把目的運算元與來源運算元做「且」運算之後，再把結果存入目的運算元。目的運算元可以是暫存器或記憶體變數，來源運算元可以是暫存器、記憶體變數或立即值。但目的運算元與來源運算元不可同時為記憶體變數，且兩者長度要相同。

一般而言，AND 指令用迫在使運算元的某些位元變為零，但又要保留其他位元之值，這種過程稱為「遮罩」( mask )。


x86 指令：CLC 與 STC

CLC 與 STC 皆不需要運算元，分別是清除進位旗標和設定進位旗標。


x86 指令：JBE/JNA

JBE 一般要搭配 CMP 使用，方式如下：

CMP     目的運算元,來源運算元
JBE     標記

JBE 是在比較目的運算元與來源運算元之後，如果目的運算元小於或等於來源運算元，就使程式控制權跳躍到標記處。JBE 與 JNA 是一樣的指令，都只能往低位址跳躍 128 個位元組，或往高位址跳躍 128 個位元組。


x86 指令：ROL 與 ROR

ROL 與 ROR 的語法是

ROL     目的運算元,CL
ROL     目的運算元,立即值
ROR     目的運算元,CL
ROR     目的運算元,立即值

ROL ( rotate left ) 是使目的運算元向左旋轉數個位元的指令，目的運算元可以是暫存器或記憶體變數，旋轉幾個位元以 CL 或立即值表示。最後一次旋轉的最高位元，不僅會旋轉到最低位元去，還會複製到進位旗標裏。

ROR 是 rotate right 的意思，除了旋轉方向向右之外，其餘的特性都與 ROL 都一樣。


.386 假指令

.386 假指令用來指使 ML.EXE 採用 80386 CPU 的指令集編撰程式碼。ML.EXE 預設的指令集是 8086/8088，越高級的 CPU，指令擴增的越多。如果程式要用到更多、更強大的指令，就要自行定義「.386」、「.486」或「.586」這些假指令。

另外，DOS 是十六位元的作業系統，所以要撰寫在 DOS 系統下能執行的程式，必須編碼、定址成十六位元。這時必須「.MODEL」在前，「.386」在後才行；如果反過來，那麼會組譯成三十二位元的程式。


記憶體變數

記憶體變數其實就是變數，要定義一個變數，可以用底下的假指令：

變數名  DB      數值
變數名  DW      數值

前者是定義八位元的變數，範圍從 0 到 255；後者定義十六位元的變數，範圍從 0 到 65535。DB 或 DW 也可以分別用 BYTE 或 WORD 代替。

變數名  BYTE    數值
變數名  WORD    數值

表示。變數名稱的第一個字必須以英文字母、底線、@、?、$ 等為開頭，其後還可以用阿拉伯數字，當然英文、底線、@ 仍然可以使用。對 ML.EXE 6.11 版來說，變數名稱最多只能到 247 個字元，但已經非常足夠了。另外變數名稱不能和假指令或是 x86/x87 指令集重複。