第24章　淺談機械碼

在第一章時曾提到過機械碼（machine code），那時候說過機械碼是一連串的十六進位數值，換算成二進位，就是一連串的「0」與「1」，就成為 CPU 能看得懂，也知道如何執行的指令與資料。例如 CPU 看到「00」就知道這是「ADD」指令，看到「10H」就知道是「ADC」指令。「00」、「10H」是機械碼；「ADD」、「ADC」是 x86 指令，亦可稱助記憶碼（mnemonic code）。

最近看見老羅的繽紛天地，有介紹機械碼的一種說法，很有創意。以下節自老羅的繽紛天地：

在開始回答什麼是 OpCode 之前，請讓我先來提幾個小問題。

  1. 計算機只認識 0 和 1 嗎？
  2. 如果上面的回答是「是」，那麼我們平時寫的程序源代碼是 0 和 1 嗎？
  3. 如果上面的回答是「不是」，那麼計算機是怎麼「知道」我們的程序的意思的？

按順序作答，依次是：

  1. 是。
  2. 不是。
  3. ？？？

最後一個問題的答案是……？我們來舉個例子……

老羅所舉的例子是「NOP」指令，其機械碼是「90H」。就跟小木偶舉「ADD」、「ADC」指令，其機械碼是「00」、「10H」一樣的原理。

對人類而言，助記憶碼較易理解，機械碼則難以理解。這也就是我們用組合語言撰寫好原始程式之後，還要交由組譯器將其「翻譯」成機械碼。還記得嗎？把用組合語言撰寫好的原始程式轉換成機械碼的過程稱為組譯，反過來的過程則稱為反組譯，如下圖。這一章將要談 x86 指令和機械碼的關係。

x86 CPU 家族自民國 67 年（西元 1978 年）發展至今，經歷過許多次改革。較為重大的是從 16 位元到 32 位元階段，多了保護模式與虛擬 86 模式；從 32 位元到 64 位元，又新增了長模式（long mode）。因為微軟與英特爾無法放棄既有的龐大客戶，所以雖然經過多次變革，都會遵守向下相容（downward compatibility，又稱回溯相容或向後相容，英文是 backward compatibility）的原則。

向下相容的意思是較晚開發的 CPU 能執行較舊的 CPU 所有功能，但新增了一些功能或改進一些缺點。同時有時候又有商業考量，這樣就造成 x86 CPU 越來越複雜。對於初學者，也越來越難以理解，造成學習上的困難。在這裡，小木偶先介紹 x86 CPU 的開山老祖，8086/8088 等十六位元 CPU 的機械碼，然後介紹三十二位元 CPU 的機械碼，最後介紹六十四位元 CPU 的機械碼。

十六位元 CPU 的機械碼

雖然 x86 家族中，十六位元 CPU 有 8086/8088 以及 80286 三種，但 80286 還具有十六位元的保護模式指令，但現已淘汰且不再使用，所以此處僅介紹 8086/8088 CPU 的機械碼。

一道 8086/8088 指令，轉換成機械碼之後，機械碼的長度並不固定，最少一個位元組，最多有六個位元組。8086/8088 CPU 機械碼的格式如下圖： 第一個位元組稱為 BYTE1，位於最低位址；第二個位元組稱為 BYTE2，位於比 BYTE1 高一個位元組的位址上；其餘位元組依次往高位址存放。這六個位元組，只有 BYTE1 是必定存在的，其餘則是依據 BYTE1 決定是否有必要，因此 BYTE2∼BYTE6 可有可無。

操作碼（OpCode）

大部分的文獻把 BYTE1 稱為「OpCode」，是 operation code 的縮寫，一般翻譯為「操作碼」，或「運算碼」。它決定了 CPU 要執行哪一種指令，例如 OpCode 在 00H∼05H 之間，都是 ADD 指令；假如 OpCode 是 06H，就是 PUSH 指令。OpCode 的第零、第一位元視 OpCode 不同，有時候有特殊意義，有時則沒有。如果有的話，其意義是：

1.第零位元：稱 W 位元，表示運算元寬度。若為 0，表示八位元；若為 1，表示 16 位元。

2.第一位元：稱 D 位元，表示資料向哪個方向存入，更準確的說，D 位元是用來表示 BYTE2 的 Reg 是來源運算元還是目的運算元。若 D＝0，表示 Reg 是來源運算元；D＝1，表示 Reg 是目的運算元。

OpCode 的完整列表，應該查閱英特爾的資料，Intel® Architecture Software Developer Manual 的第二卷 Volume 2:Instruction Set Reference，在其後面的 Appendix A OpCode Map 有完整的資料。這份文獻包含了從 8086/8088 到最新的 x86－64 指令。但是這本太複雜了，另外還有一本英特爾發行的電子書 9800722-03_The_8086_Family_Users_Manual_Oct79.pdf，也有詳盡的資料，而且僅介紹 8086/8088 CPU。此外，在小木偶的網頁 DOS 組合語言附錄七也列出「8086/8088 OpCode Map」表格。

ModR/M 位元組

BYTE2 也稱為 ModR/M 位元組，可分為三個欄位：①第 6∼7 位元是 Mod，決定定址模式（addressing mode）。②第 3∼5 位元是 Reg，指定了暫存器。③第 0∼2 位元：是 R/M（register/memory），與 Mod 相互搭配決定定址模式中的暫存器。R/M 與 Mod 之間的關係及意義如下表：

8086/8088 Mod 與 R/M 的關係
R/MMod＝00Mod＝01 Mod＝10Mod＝11
W＝1W＝0
000[BX+SI][BX+SI+D8][BX+SI+D16]AXAL
001[BX+DI][BX+DI+D8][BX+DI+D16]CXCL
010[BP+SI][BP+SI+D8][BP+SI+D16]DXDL
011[BP+DI][BP+DI+D8][BP+DI+D16]BXBL
100[SI][SI+D8][SI+D16]SPAH
101[DI][DI+D8][DI+D16]BPCH
110記憶體位址[BP+D8][BP+D16]SIDH
111[BX][BX+D8][BX+D16]DIBH

少數情形下，OpCode 會延伸到 ModR/M，這種情形發生在 OpCode 是 80H∼83H、0D0H∼0D3H、0F6H、0F7H、0FEH、0FFH 的時候。ModR/M 原本是三個欄位：Mod、Reg，R/M 所組成，當操作碼延伸到 ModR/M 時，Reg 欄位就變成操作碼延伸的地方，其餘兩個欄位仍不變。

假如 OpCode 延伸到 ModR/M 位元組，那麼在附錄七的「8086/8088 OpCode MAP」表格中，會標示成「GRP?」（? 表示數字）。這時候要知道真正的指令，還必須查閱附錄七的「8086/8088 OpCode Extensions」。

ModR/M 位元組中三個欄位已介紹完兩個，只剩 Reg 欄位，其數值與意義，如下表：

Reg 所代表的暫存器
Reg000001010011100101110111
八位元暫存器ALCLDLBLAHCHDHBH
十六位元暫存器AXCXDXBXSPBPSIDI
三十二位元暫存器EAXECXEDXEBXESPEBPESIEDI

雖然尚未提到三十二位元的 CPU，但是為了節省篇幅，所以上表也列出三十位元的暫存器。

偏移位址：BYTE3、BYTE4

BYTE3 與 BYTE4 代表偏移位址，就是上表中的 D8 或 D16，依據 OpCode 及 ModR/M 決定需要 D8 還是 D16，甚至全省略。D8 與 D16 是有號數，也就是說它們可以是正數，也可以是負數。如果是正數表示往高位址方向定址；如果是負數表示往低位址方向定址。

D8 代表八位元的偏移位址，其範圍在－128∼127之間，在 BYTE2 之後還會有 BYTE3 而省略 BYTE4；D16 代表十六位元的偏移位址，其範圍在－32768∼32767之間，在 BYTE2 之後還會有 BYTE3、BYTE4。

立即值：BYTE5、BYTE6

BYTE5、BYTE6 代表立即值（immediate value，可視為常數），依據 OpCode 及 ModR/M 決定是否需要立即值，如果不需要，那麼 BYTE5、BYTE6 就會被省略；如果需要立即值，也依據 OpCode 決定需要八位元還是十六位元的立即值，如果是八位元那就會省略 BYTE6，如果是十六位元那 BYTE5、BYTE6 都存在。

前置碼（Prefix Byte）

雖然真正讓指令執行的機械碼就只是上面提到的從操作碼到立即值，但有時候某些指令會在機械碼之前，加上該指令需要的「修飾」動作，例如某些指令可以加上重複的修飾，使其重複動作。這樣的修飾指令稱為前置碼，到了 32 位元時，正式把前置碼納入到機械碼之中。前置碼是放在 BYTE1 之前，也就是比 BYTE1 更低位址的一個位元組。8086/8088 指令中，前置碼可分為三種：

①：第一種是重複指令，又分成兩類：⑴REP、REPE、REPZ 的機械碼都是 0F3H，這三個指令都是一樣的。
　　　　　　　　　　　　　　　⑵REPNE、REPNZ 的機械碼都是 0F2H，這兩個指令都是一樣的。
這兩類指令多用於處理字串，常與 MOVSB、STOSB……等指令搭配，因此 0F2H、0F3H 被當作是前置碼。

②：第二種是凌越區段（見第十三章），其格式如右圖，兩個 R 位元的意義如下表：

　　　　　
RR 位元前置位元組區段暫存器
0026HES
012EHCS
1036HSS
113EHDS

③：第三種是 LOCK 指令，其機械碼是 0F0H。

由這三類得知，如果機械碼起始的位元組是以下七個：0F3H、0F2H、26H、2EH、36H、3EH、0F0H 的其中之一的話，那麼就表示此機械碼有前置碼，必須比對上面三種情形，找出前置碼的意義。一道指令的機械碼有可能超過一個前置碼，如果這樣的話，順序並不重要，都能正常執行。

例子

機械碼與 8086/8088 指令的關係，已經介紹完了，底下來看看幾個例子。

例子一：「00 00」

  1. 首先 00 不是那七個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 00，查附錄七的「8086/8088 OpCode Map」，得知 00 的指令是「ADD Eb,Gb」。
    1. 查閱附錄七「8086/8088 Argument Addressing Codes」，得知 E 的意思是此運算元可能是通用暫存器，也可能是記憶體；G 的意思是 ModR/M 的 Reg 代表通用暫存器。
    2. 查閱附錄七「8086/8088 Argument Operand Codes」，得知 b 代表位元組（byte）。
    綜合上面步驟 i、ii，得知 Eb 表示長度為一個位元組的記憶體或暫存器（一個位元組其實就是八位元）。同理，Gb 是長度為一個位元組的通用暫存器，而此暫存器是哪一個則必須查閱「Reg 所代表的暫存器」。
    因此，「ADD Eb,Gb」的意思是把某個一個位元組長的記憶體或暫存器（Eb）之值，加上 Reg 所代表長度一個位元組的暫存器（Gb）之值，再寫入該記憶體或暫存器裏面。
  3. ModR/M 為 00，換算成二進位是 0000 0000，故 Mod 為 00，Reg 為 000，R/M 為 000。
    1. 由 Reg 等於 000，查閱「Reg 所代表的暫存器」得知 000 可能代表 EAX、AX 或 AL，因為由步驟 2 得知是八位元，或由 W 位元為零也可知暫存器是八位元，故 Reg 代表「AL」，也就是說「Gb」代表「AL」。
    2. 以 Mod 為 00 以及 R/M 為 000 搭配，查閱「8086/8088 Mod 與 R/M 的關係」，得到 Ev 為「[BX+SI]」，此為記憶體並非暫存器。
  4. 綜合第 2、3 步驟，得知「00 00」反組譯後是「ADD [BX+SI],AL」。

例子二：「05 77H 2AH」

  1. 首先 05 不是那七個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 05，查附錄七的「8086/8088 OpCode Map」，得知 05 的指令是「ADD AX,Iv」。其中的 I 是立即值（immediate value，見附錄七8086/8088 Argument Addressing Codes），v 代表字組（見附錄七8086/8088 Argument Operand Codes）。到此得知，05 是把 AX 之值加上某個長為一字組的常數。
  3. 此立即值就是後面的 77H 2AH，但因為 x86 家族的電腦，其資料儲存都是以小序端方式存於記憶體中，故立即值為「2A77H」。
  4. 綜合第 2∼3 步驟，得知「05 77H 2AH」反組譯後是「ADD AX,2A77H」。

例子三：「0EH」

  1. 首先 0EH 不是那七個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 0EH，查附錄七的「8086/8088 OpCode Map」，得知 0EH 的指令是「PUSH CS」。到此就結束了。

例子四：「89H 0D8H」

  1. 首先 89H 不是那七個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 89H，查附錄七的「8086/8088 OpCode Map」，得知 89H 的指令是「MOV Ev,Gv」（Ev、Gv 的意義可以看前三個例子，或是查閱附錄七的「8086/8088 Argument Addressing Codes」以及「8086/8088 Argument Operand Codes」）。到此得知，89H 是把 Reg 所代表長一個字組的暫存器（Gv）之值，移到某個暫存器或記憶體（Ev）裏面。
  3. ModR/M 為 0D8H，換算成二進位是 1101 1000，故 Mod 為 11，Reg 為 011，R/M 為 000。
    1. 由 Reg 等於 011，查閱「Reg 所代表的暫存器」得知 011 可能代表 EBX、BX 或 BL，因為由上一步驟得知是字組，或由 W 位元為一也可知暫存器長度是字組，故選擇「BX」。
    2. 以 Mod 為 11 以及 R/M 為 000 搭配，查閱「8086/8088 Mod 與 R/M 的關係」，得到 Ev 為「AX」而非記憶體位址。
  4. 由 OpCode 的 D 位元（第一個位元）為零得知，Reg 為來源運算元，也就是 BX 為來源運算元。或是由 Gv 所代表的 Reg 是 BX，且由 89H 的指令是「MOV Ev,Gv」，也可知道 BX 是來源運算元。
  5. 綜合第 2、3 ii、4 步驟得知「89H 0D8H」反組譯後是「MOV AX,BX」。

例子五：「80H 07 2AH」

  1. 首先 80H 不是那七個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 80H，查附錄七的「8086/8088 OpCode Map」，得知 80H 的指令是「GRP1 Eb,Ib」。
  3. 因為查到了 GRP?，故 ModR/M 的 Reg 是 OpCode 的延伸。ModR/M 為 07，換算成二進位是 0000 0111，故 Mod 為 00，OpCode 的延伸為 000，R/M 為 111。
  4. 以 OpCode 延伸至 ModR/M 的第 3∼5 位元，000，以及 GRP1 查閱附錄七的「8086/8088 OpCode Extensions」得知 GRP1 代表「ADD」。
  5. 由步驟 2、4 得知 80H 07 代表「ADD Eb,Ib」，接下來查出 Eb、Ib 的意義：
    1. 查閱附錄七「8086/8088 Argument Addressing Codes」，得知 E 的意思是此運算元可能是通用暫存器，也可能是記憶體；I 的意思是常數。
    2. 查閱附錄七「8086/8088 Argument Operand Codes」，得知 b 代表位元組。
    綜合上面步驟 i、ii，得知「ADD Eb,Ib」是把某個八位元的記憶體或暫存器加上某個常數。
  6. 此常數 Ib 就是接在 ModR/M 位元組之後的 2AH。
  7. 以 Mod 為 00 以及 R/M 為 111 搭配，查閱「8086/8088 Mod 與 R/M 的關係」，得到 Eb 是「[BX]」。
  8. 綜合步驟 5∼7，得到「80H 07 2AH」反組譯後是「ADD BYTE PTR [BX],2AH」。（加上「BYTE PTR」的原因是因為，「[BX]」、2AH 這兩個運算元都無法看出其長度是字組還是位元組。）

例子六：「2EH 8BH 56H 0F0H」

  1. 首先 2EH 是七個前置碼中的一個，查閱前置碼，得知 2EH 代表凌越區段，「CS:」。
  2. 第一個操作碼 8BH，查附錄七的「8086/8088 OpCode Map」，得知 8BH 的指令是「MOV Gv,Ev」。到此得知 8BH 是把某個長度為字組的記憶體或暫存器（Ev）之值存入 Reg 所代表的暫存器（Gv）裏面。
  3. ModR/M 為 056H，換算成二進位是 0101 0110，故 Mod 為 01，Reg 為 010，R/M 為 110。
    1. 由 Reg 等於 010，查閱「Reg 所代表的暫存器」得知 010 可能代表 EDX、DX 或 DL，因為由上一步驟得知長度是字組，或由 W 位元為 1，也可知暫存器長度是字組，故 Gv 是「DX」。
    2. 以 Mod 為 01 以及 R/M 為 110 搭配，查閱「8086/8088 Mod 與 R/M 的關係」，得到 Ev 為「[BP+D8]」，此為記憶體並非暫存器。
    3. 由步驟 ii，得到的「[BP+D8]」，其中的 D8 為八位元的偏移位址，即 ModR/M 後面接著的 0F0H。但是 0F0H 為負值，其實就是－10H，因此 D8 就是－10H。
  4. 綜合所有步驟得知，「2EH 8BH 56H 0F0H」反組譯後是「MOV DX,CS:[BP－10H]」。

機械碼還出現在哪裡？答案是列表檔

一般而言，機械碼不常使用，最常出現的地方是除錯程式，像 DEBUG、SYMDEB 都一定會用到。除此之外，還會出現在哪裡呢？還有就是列表檔。

列表檔是在組譯原始程式時，指定「/Fl」或「-Fl」選項後，由 ML.EXE 根據原始程式製造出來的檔案。列表檔的副檔名是「LST」，是純文字檔，可以用一般文書處理軟體，例如 UltraEdit32、記事本等軟體開啟。

口說無憑，實際製作一份列表檔來試試。以第十一章的 HELLOW1.ASM 為例子，在進入 MS－DOS 虛擬機器時，輸入下面黃色字的指令：

C:\>e: [Enter]

E:\>cd dos\exe [Enter]

E:\DOS\EXE>ml /Fl hellow1.asm [Enter] →加上「/Fl」選項，以製造列表檔
Microsoft (R) Macro Assembler Version 6.11
Copyright (C) Microsoft Corp 1981-1993.  All rights reserved.

 Assembling: hellow1.asm

Microsoft (R) Segmented Executable Linker  Version 5.31.009 Jul 13 1992
Copyright (C) Microsoft Corp 1984-1992.  All rights reserved.

Object Modules [.obj]: hellow1.obj
Run File [ascii2.com]: "hellow1.exe"
List File [nul.map]: NUL
Libraries [.lib]: 
Definitions File [nul.def]:

E:\DOS\EXE>

組譯過程中輸入「/Fl」，可以命令 ML.EXE 製作出列表檔來。要製作列表檔，須注意底下的事：

  1. 輸入「-Fl」也有一樣的效果。事實上，ML.EXE 的所有選項起頭，可用「/」或「-」，效果一樣。
  2. ML.EXE 的選項有大小寫之分，所以不可以寫成「/fl」或「/FL」。
  3. 「/Fl」之後可以不指定列表檔檔名，也可以指定列表檔的檔名。

原始程式與列表檔的差別

原始程式（副檔名是 ASM）與列表檔（副檔名是 LST）都是純文字檔，那麼有何區別？我們把已製作好 HELLOW1.ASM 與 HELLOW1.LST 列成下表相互比較，就知道有何不同了：

HELLOW1.ASMHELLOW1.LST




.Model  SMALL,C
.386
.STACK
;***************************************
.DATA
msg     DB      "Hellow, World.$"
;***************************************
.CODE
        .STARTUP
        mov     dx,OFFSET msg
        mov     ah,9
        int     21h
        .EXIT   0
;***************************************
END
 
Microsoft (R) Macro Assembler Version 6.11                    10/12/23 21:47:27
hellow1.asm                                                     Page 1 - 1


                                .Model  SMALL,C
                                .386
                                .STACK
                                ;***************************************
 0000                           .DATA
 0000  48 65 6C 6C 6F 77        msg     DB      "Hellow, World.$"
       2C 20 57 6F 72 6C
       64 2E 24
                                ;***************************************
 0000                           .CODE
                                        .STARTUP
 0010  BA 0000 R                        mov     dx,OFFSET msg
 0013  B4 09                            mov     ah,9
 0015  CD 21                            int     21h
                                        .EXIT   0
                                ;***************************************
                                END
 
.Microsoft (R) Macro Assembler Version 6.11                    10/12/23 21:47:27
hellow1.asm                                                     Symbols 2 - 1




Segments and Groups:

                N a m e                 Size     Length   Align   Combine Class

DGROUP . . . . . . . . . . . . .        GROUP
_DATA  . . . . . . . . . . . . .        16 Bit   000F     Word    Public  'DATA'
STACK  . . . . . . . . . . . . .        16 Bit   0400     Para    Stack   'STACK'
_TEXT  . . . . . . . . . . . . .        16 Bit   001C     Word    Public  'CODE'


Symbols:

                N a m e                 Type     Value    Attr

@CodeSize  . . . . . . . . . . .        Number   0000h
@DataSize  . . . . . . . . . . .        Number   0000h
@Interface . . . . . . . . . . .        Number   0001h
@Model . . . . . . . . . . . . .        Number   0002h
@Startup . . . . . . . . . . . .        L Near   0000     _TEXT
@code  . . . . . . . . . . . . .        Text     _TEXT
@data  . . . . . . . . . . . . .        Text     DGROUP
@fardata?  . . . . . . . . . . .        Text     FAR_BSS
@fardata . . . . . . . . . . . .        Text     FAR_DATA
@stack . . . . . . . . . . . . .        Text     DGROUP
msg  . . . . . . . . . . . . . .        Byte     0000     _DATA

           0 Warnings
           0 Errors

上表的左半部是原始程式，HELLOW1.ASM，這是我們自己撰寫的，應該很熟悉。

上表右半部是列表檔。列表檔有兩頁：Page 1－1 與 Symbols 2-1。Page 1-1 可分成三欄。最左欄是位址，不論是資料區段或是程式碼區段都會列出每個字串、變數、每一道 x86 指令的位址。中間就是機械碼，資料區段內的資料轉換成十六進位數值、程式碼區段轉換成機械碼，此二者都是十六進位數值。最右欄是使用者撰寫的原始碼。

現在來試試看將第一行指令組譯成的機械碼反組譯。第一行指令的 OpCode 是 0BAH，查閱附錄七「8086/8088 OpCode Map」得知是「MOV DX,Iv」，亦即把十六位元的立即值存入 DX 內，而立即值就接在 0BAH 之後的 0000。我們可驗證看看，在 .DATA 中，msg 字串是否真的在位址 0000 處？

再看 Symbols 2－1，這一頁是 ML.EXE 根據原始程式所製作的統計資料，紀載了各個符號名稱。例如 HELLOW1.ASM 中使用了三個區段，它們分別是資料區段、堆疊區段、程式碼區段，在 SMALL 記憶體模式下，使用簡易方式定義區段時，仍然有各自的名稱，分別是 _DATA、STACK、_TEXT，也各自有其性質。

三十二位元 CPU 的機械碼

十六位元 CPU 的機械碼到此已經都敘述完畢，是不是很簡單呢？甚至想寫出類似 DEBUG 的反組譯器也並非不可能。

底下小木偶再接再厲，繼續說一說三十二位元 CPU 的機械碼。英特爾在製作三十二位元的 CPU 時，制定了一套規格，用來定義 32 位元的 CPU 有哪些指令，這套規格稱為 IA－32（Intel Architecture, 32-bit），包含從 80386、80486 到 Pentium 4、Pentium M，還有超微販售的 Am386DX 到 Athlon XP，甚至還有 Cyrix、VIA 販售的 CPU。總之 IA－32 CPU 包含了所有 x86 家族的 32 位元 CPU。

更有甚者，那就是 8086/8088/80286 這三個十六位元的 CPU 也被英特爾歸類為 IA－32 內，這大概是它們也具有最基本的 IA－32 指令集吧！？但這一節所說的 IA－32 CPU 專指三十二位元的 CPU，不包含 8086、8088、80286。

IA－32 的定址方式與 8086/8088 最大的不同在於八個通用暫存器都能拿來定址，並且新增了許多指令，因此英特爾將 IA－32 CPU 的機械碼格式重新定義了，但又必須與 8086/8088 相容。其格式如下圖： 由上圖中可以得知，IA－32 的機械碼分成六部分，每個部分用黃色框框住。上圖中機械碼的各部分只是代表順序，在一道指令的機械碼中，只有 OpCode 是必要的，其餘部分是需要而決定，如果是不需要的部分就會省略而跳過。例如大部分指令都沒有 Prefixes，那麼就從 OpCode 開始。此外，上圖的黃色框雖然都一樣大，但並不是代表它們所佔用的位元組都一樣多。其中只有 ModR/M 與 SIB 各佔一個位元組，其餘部分有時佔一個位元組，多時甚至佔四個位元組。

前置碼（Prefixes）

顧名思義，前置碼就是放在操作碼之前的程式碼。前置碼共有五種，在介紹「8086/8088 的機械碼」時，已經介紹過三種了，請按這裏閱讀。到了三十二位元的 CPU 時，新增了第四種和第五種，並修改第二種。此處只介紹不同於 8086/8088 的地方，然後在這一節的結尾做個小小的結論，因為 x86－64 CPU 的前置碼跟 IA－32 一樣。

新增的凌越區段前置碼

第二種前置碼是凌越區段，因為 IA－32 多了兩個區段暫存器，FS 與 GS，因此也多了 64H 和 65H 分別代表 FS: 和 GS: 的凌越區段前置碼。

運算元前置碼

第四種是 66H，稱為運算元前置碼，用來切換運算元長度，不過八位元長的運算元不受 66H 的影響。當區段是十六位元時，預設的運算元也是十六位元；如果出現了 66H 前置碼時，就會切換成三十二位元的運算元。反過來，當區段是三十二位元時，預設的運算元也是三十二位元；如果出現了 66H 前置碼時，就會切換成十六位元的運算元。

例如前一章的 MUL32_1.ASM 是 DOS 程式，是十六位元的程式，故其區段應為十六位元。以 DEBUG/SYMDEB 載入時，第一個指令在位址 0010 處，其機械碼是「66H 33H 0D2H」，出現運算元前置碼 66H，所以十六位元的暫存器會變三十二位元。讀者可以自行將「33H 0D2H」依照上面的方式反組譯，如果正確的話，所得結果為「XOR DX,DX」。但是如果最前面有運算元前置碼 66H 的話，就必須將運算元切換成三十二位元，因此「66H 33H 0D2H」反組譯結果為「XOR EDX,EDX」。

一般而言，DOS 程式的區段是十六位元，三十二位元的 Windows 其執行程式的區段是三十二位元。不過這樣的講法並不太精確，較精確的判斷方式是以「區段描述器」的第 54 位元來判斷。該位元稱為 D 位元，如果是一，表示該區段是三十二位元的區段；如果是零，表示該區段是十六位元的區段。

定址前置碼

第五種是 67H，稱為定址前置碼，用來切換定址模式。也就是說在十六位元區段中，假設有 67H 定址前置碼，就會切換成三十二位元的定址模式；反之，在三十二位元區段中，有 67H 定址前置碼，就會切換成十六位元的定址模式。但是並非像把「MOV AL,[BX]」變成「MOV AL,[EBX]」這樣簡單。這是因為，不論十六位元區段還是三十二位元區段，它們的定址模式都是依據 Mod 與 R/M 決定，而這兩種區段的 Mod 與 R/M 搭配所得的程式碼並不相同。

前置碼結論

到此前置碼已經介紹完畢，做個小小的結論。前置碼只有 26H、2EH、36H、3EH、64H、65H、66H、67H、0F0H、0F2H、0F3H 這十一個，並且並一定放在機械碼的最前面，其意義見下表：

32-Bit 前置碼
凌越區段26H、2EH、36H、3EH
64H、65H		ES:、CS:、SS:、DS:
FS:、GS:
運算元前置碼66H切換運算元長度
定址前置碼67H切換定址模式
鎖定匯流排0F0HLOCK
重複指令0F2H、0F3HREP、REPNZ

在這五種前置碼中，有些又有許多不同的意義，例如凌越區段又可分為 6 種不同的意義。但不論如何，同種類的前置碼都只用使用一個位元組，因為同種但不同意義的前置碼是互斥的，例如一道指令不可能同時從 ES 區段及 FS 區段讀取資料。不過，一道指令中可以出現多個不同種類的前置碼，這時候前置碼的順序可以任意安排。

例如在 DOS 程式中，如果原始程式有一行「MOV WORD PTR ES:[EBX],3344H」，不同組譯器組譯時，可能產生「67H 26H 0C7H 03 44H 33H」，也可能是「26H 67H 0C7H 03 44H 33H」，而 CPU 都能正確執行。這道指令用了兩個不同種類的前置碼，凌越區段與定址前置碼。

操作碼（OpCode）

機械碼的第二個部分稱為操作碼（operation code，縮寫為 OpCode），決定了 CPU 所要執行的指令。IA－32 的操作碼大多是一個位元組，但也有兩個位元組，最多三個位元組。要由操作碼查出所執行的指令，需要一張很大的表格，這張表格稱為「32-Bit OpCode Map」，在附錄七，請按這裏查閱。如果操作碼有兩個位元組，那麼第一個位元組通常是 0FH，也在附錄七，按這裏查閱。

跟 8086/8088 一樣，有些指令的操作碼會延伸到 RegR/M 部分的第三∼五位元，這種操作碼通常會以第幾群的方式表現。也就是說在上述兩張表格中會標示「GRP??」，然後就要到附錄七的「32-Bit OpCode Extensions」查閱。

ModR/M 位元組

機械碼的第三個部分稱為 ModR/M 位元組，它決定了定址方式。跟 8086/8088 一樣，ModR/M 位元組拆成三部分，第零∼二位元稱為 R/M，第三∼五位元稱為 Reg，第六、七位元稱為 Mod。Mod 與 R/M 相互搭配決定了定址模式，這一部分與 8086/8088 大不相同。讀者可以自行將下表與「8086/8088 Mod 與 R/M 的關係表格」比較，就會發現，在使用哪一個暫存器、偏移位址大小、有無乘上倍率很不一樣。

Bit-32 Mod 與 R/M 的關係
R/MMod＝00Mod＝01 Mod＝10Mod＝11
W＝0W＝1
000[EAX][EAX+D8][EAX+D32]ALAX/EAX
001[ECX][ECX+D8][ECX+D32]CLCX/ECX
010[EDX][EDX+D8][EDX+D32]DLDX/EDX
011[EBX][EBX+D8][EBX+D32]BLBX/EBX
100SIB 定址SIB 定址SIB 定址AHSP/ESP
101[D32][EBP+D8][EBP+D32]CHBP/EBP
110[ESI][ESI+D8][ESI+D32]DHSI/ESI
111[EDI][EDI+D8][EDI+D32]BHDI/EDI

上表中，如果 Mod＝11 且 W＝1 時（W 位元是操作碼的第零個位元），得到的暫存器可能是 16 位元，也可能是 32 位元，那麼到底是哪一個呢？這時就要看所在區段預設的運算元大小，以及有沒有運算元前置碼了。在「三十二位元 CPU 的機械碼：運算元前置碼」中已經詳述過了，此處不再贅述。

上表中，當 R/M 為 100 時，有時會出現「SIB 定址」。這種情形發生時，ModR/M 位元組之後接著的就是 SIB 位元組。

SIB 位元組

SIB 位元組是 IA－32 新增的部分，在 8086/8088 並沒有這部分。SIB 完全是 IA－32 為了加強定址模式而新增的。SIB 是使用兩個通用暫存器，一個當作索引（index，SIB 中的 I 就是指 index），一個當作基底（base，SIB 中的 B 就是 base）使用，甚至可以讓索引再乘上一個 2 的冪次方作為倍率（scale，也就是 SIB 中的 S）；也可以只用一個通用暫存器，那麼這個通用暫存器可以看成索引或基底都無所謂。發生「SIB 定址」時，通常是存取陣列內的資料。

看上圖 IA－32 的機械碼格式，可以得知，SIB 位元組也拆成三部分，第零∼二位元稱為 Base，第三∼五位元稱為 Index，第六、七位元稱為 Scale。其中 Index 代表暫存器（可以想成是索引暫存器），Scale 代表倍率，此倍率乘在 Index 所代表的暫存器上，所形成的式子就稱為「索引倍率」。Index、Scale 所代表的意義如下表：

Index 所代表的暫存器
Index暫存器Index暫存器
000EAX100ESP
001ECX101EBP
010EDX110ESI
011EBX111EDI
Scale 所代表的倍率
Scale倍率
001
012
104
118

 
依據 Base 與 Mod 查閱下表，然後將「索引倍率」代入之後，就能查出 Mod、SIB 所代表的定址方式了。下表是 Base 與 Mod 相互配合，所得的關係表：

32-Bit Mod 與 Base 的關係
BaseMod＝00Mod＝01Mod＝10
000[EAX+索引倍率][EAX+D8+索引倍率][EAX+D32+索引倍率]
001[ECX+索引倍率][ECX+D8+索引倍率][ECX+D32+索引倍率]
010[EDX+索引倍率][EDX+D8+索引倍率][EDX+D32+索引倍率]
011[EBX+索引倍率][EBX+D8+索引倍率][EBX+D32+索引倍率]
100[ESP+索引倍率][ESP+D8+索引倍率][ESP+D32+索引倍率]
101[D32+索引倍率][EBP+D8+索引倍率][EBP+D32+索引倍率]
110[ESI+索引倍率][ESI+D8+索引倍率][ESI+D32+索引倍率]
111[EDI+索引倍率][EDI+D8+索引倍率][EDI+D32+索引倍率]

偏移位址與立即值

當解碼完操作碼、ModR/M、SIB 等三部分後，就能知道是否有其他運算元，如果有的話，運算元有多大，也就能知道後面的偏移位址（displacement）與立即值（immediate）。

例子

底下舉個例子來試試看人工反組譯。首先要先說明的是，底下的例子都是在三十二位元的區段內。

例子一：「85H 34H 9DH 3CH 20H 04 00」

  1. 首先 85H 不是那十一個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 85H，查附錄七的「32-Bit OpCode Map」，得知 85H 的指令是「TEST Ev,Gv」。
    1. 查閱附錄七「32-Bit Argument Addressing Codes」，得知 G 代表 Reg 是通用暫存器；E 代表此運算元可能是通用暫存器，也可能是記憶體。
    2. 查閱附錄七「32-Bit Argument Operand Codes」，得知 v 代表此運算元是字組或雙字組。
    因為是三十二位元區段，且沒有前置碼，所以預設的運算元是雙字組，故「TEST Ev,Gv」是把存於某個記憶體或暫存器（Ev）裏面的雙字組與某個暫存器（Gv）之值，進行 TEST 運算。
  3. ModR/M 為 34H，換算成二進位是 0011 0100，故 Mod 為 00，Reg 為 110，R/M 為 100。
    1. 由 Reg 等於 110，查閱「Reg 所代表的暫存器」得知 110 可能代表 ESI、SI 或 DH，從步驟 2 ii 得知運算元是雙字組，故 Gv 是「ESI」。
    2. 以 Mod 為 00 以及 R/M 為 100 搭配，查閱「32-Bit Mod 與 R/M 的關係」，得到「SIB 定址」。
  4. SIB 緊接著 ModR/M 之後，故 SIB 為 9DH，換算成二進位是 1001 1101，故 Scale 為 10，Index 為 011，Base 為 101。
    1. 依據 Scale 是 10，Index 是 011，分別查閱「Scale 所代表的倍率」及「Index 所代表的暫存器」得知 Scale 代表乘以 4，Index 代表 EBX，合起來「索引倍率」就是「EBX×4」。
    2. 以 Mod 為 00 以及 Base 為 101 查閱「32-bit Mod 與 Base 的關係」，得知為「[D32+索引倍率]」。
    3. D32 是指 32 位元的偏移位址，就是在 SIB 之後的 04203CH。
    由上面步驟 i∼iii，得知 Ev 是「[04203CH+EBX×4]」
  5. 由步驟 2、3 i、4 得知「85H 34H 9DH 3CH 20H 04 00」反組譯後是「TEST [04203CH+EBX×4],ESI」。

例子二：「81H 05 1CH 00 00 00 99H 20 00 0AH」

  1. 首先 81H 不是那十一個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 81H，查附錄七的「32-Bit OpCode Map」，得知 81H 的指令是「GRP1 Ev,Iv」。
  3. 因為查到 GRP?，故 ModR/M 的 Reg 是 OpCode 的延伸。ModR/M 為 05，換算成二進位是 0000 0101，故 Mod 為 00，OpCode 的延伸為 000，R/M 為 101。
  4. 以 OpCode 延伸至 ModR/M 的第 3∼5 位元，000，以及 GRP1 查閱附錄七的「32-Bit OpCode Extensions」得知 GRP1 代表「ADD」。
  5. 由步驟 2、4，得知 81H 05 代表「ADD Ev,Iv」，接下來查出 Ev、Iv 的意義：
    1. 查閱附錄七「32-Bit Argument Addressing Codes」，得知 E 代表此運算元可能是通用暫存器，也可能是記憶體；I 代表立即值，立即值可視為常數。
    2. 查閱附錄七「32-Bit Argument Operand Codes」，得知 v 代表此運算元是字組或雙字組。
    因為是三十二位元區段，且沒有前置碼，所以預設的運算元是雙字組，故「ADD Ev,Iv」是把存於某個記憶體或暫存器（Ev）裏面的雙字組再加上某個常數（Iv）。
  6. 由步驟 3，以 Mod 為 00 以及 R/M 為 101 搭配，查閱「32-Bit Mod 與 R/M 的關係」，得到 Ev 是「[D32]」。D32 代表三十二位元的偏移位址，也就是 SIB 後面接著，且依照小序端排列於記憶體中的 1CH 00 00 00。因此 Ev 就是「[0000001CH]」。
  7. 立即值是緊接著偏移位址後面的 99H 20 00 0AH，其數值為 0A002099H。故 Iv 是 0A002099H。
  8. 綜合第 4∼7 步驟，得到「81H 5 1CH 00 00 00 99H 20 00 0AH」反組譯後是「ADD DWORD PTR [0000001CH],0A002099H」（加上 DWORD PTR 是因為無法從這兩個運算元得知運算元長度）。

例子三：「8BH 9CH 079H 10H 20H 33H 44H」

  1. 首先 8BH 不是那十一個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 8BH，查附錄七的「32-Bit OpCode Map」，得知 8BH 的指令是「MOV Gv,Ev」。
    1. 查閱附錄七「32-Bit Argument Addressing Codes」，得知 G 代表 Reg 是通用暫存器；E 代表此運算元可能是通用暫存器，也可能是記憶體。
    2. 查閱附錄七「32-Bit Argument Operand Codes」，得知 v 代表此運算元是字組或雙字組。
    因為是三十二位元區段，且沒有前置碼，所以預設的運算元是雙字組，故「MOV Gv,Ev」是把存於某個記憶體或暫存器（Ev）裏面的雙字組存入某個暫存器（Gv）裏。
  3. ModR/M 為 9CH，換算成二進位是 1001 1100，故 Mod 為 10，Reg 為 011，R/M 為 100。
  4. 由 Reg 等於 011，查閱「Reg 所代表的暫存器」得知 011 可能代表 EBX、BX 或 BL，因為是三十二位元（即雙字組），故代表 Reg 的 Gv，其實就是「EBX」。
  5. 以 Mod 為 10 以及 R/M 為 100 搭配，查閱「32-Bit Mod 與 R/M 的關係」表格，得知代表「SIB 定址」。
  6. SIB 位元組就是接著 ModR/M 之後的 079H。079H 換算成二進位是 0111 1001，Scale 是 01，Index 是 111，Base 是 001。
    1. 依據 Scale 是 01，Index 是 111，分別查閱「Scale 所代表的倍率」及「Index 所代表的暫存器」得知 Scale 代表乘以 2，Index 代表 EDI，合起來「索引倍率」就是「EDI×2」。
    2. 以 Mod 為 10 以及 Base 為 001 查閱「32-bit Mod 與 Base 的關係」，得知為「[ECX+D32+索引倍率]」。
    3. D32 是代表三十二位元的偏移位址，而此偏移位址就接在 SIB 之後的四個位元組，其值為 44332010H。
    綜合上面步驟 i∼iii，得知 Ev 就是「[ECX+EDI×2+44332010H]」。
  7. 結合步驟 2、4、6，得知「8BH 9CH 0B9H 10H 20H 33H 44H」反組譯後是「MOV EBX,[ECX+EDI×2+44332010H]。

例子四：「66H 0FH 0BAH 64H 18H 1CH 99H」

  1. 66H 是運算元前置碼，因為原先假設在三十二位元區段，所以切換運算元大小變為十六位元（十六位元合起來也稱為字組）。
  2. 第一個操作碼為 0FH，查附錄七的「32-Bit OpCode Map」，得知 0FH 代表「2-Byte Esc」，意思是操作碼有兩個位元組。
  3. 再以第二個操作碼，0BAH，查閱附錄七的「32-Bit OpCode Map Two-byte Opcode Map, Two-byte Opcode Map ( First Byte is 0FH )」得到「GRP8 Ev,Ib」。
  4. 因為查到 GRP?，故 ModR/M 的 Reg 是 OpCode 的延伸。ModR/M 是 64H，換算成二進位是 0110 0100，故 Mod 為 01，OpCode 的延伸是 100，R/M 為 100。
  5. 以 OpCode 延伸至 ModR/M 的第 3∼5 位元，100，以及 GRP8 查閱附錄七的「32-Bit OpCode Extensions」得知 GRP8 代表「BT」。
  6. 由步驟 3、5，得知「0FH 0BAH 64H」代表「BT Ev,Ib」，接下來查出 Ev、Ib 的意義：
    1. 查閱附錄七「32-Bit Argument Addressing Codes」，得知 E 代表此運算元可能是通用暫存器或記憶體；I 代表常數。
    2. 查閱附錄七「32-Bit Argument Operand Codes」，得知 v 代表此運算元是字組或雙字組、b 代表此運算元是位元組。
    由步驟 1 得知運算元大小是字組，故 Ev 代表此運算元是長度為字組的通用暫存器或記憶體；Ib 長度為位元組的常數。因此「BT Ev,Ib」是把某個記憶體或暫存器（Ev）裏面的字組，與長度為一個位元組的常數進行 BT 運算。
  7. 由步驟 4，以 Mod 為 01 以及 R/M 為 100 搭配，查閱「32-Bit Mod 與 R/M 的關係」表格，得知代表「SIB 定址」。
  8. SIB 位於 ModR/M 之後，故 SIB 為 18H，換算成二進位是 0001 1000，Scale 是 00，Index 是 011，Base 是 000。
    1. 依據 Scale 為 00、Index 為 011，分別查閱「Scale 所代表的倍率」及「Index 所代表的暫存器」得知 Scale 代表乘以 1，Index 代表 EBX，合起來索引倍率就是「EBX」。
    2. 以 Mod 為 01 以及 Base 為 000 查閱「32-bit Mod 與 Base 的關係」，得知為「[EAX+D8+索引倍率]」。
    3. D8 是代表八位元的偏移位址，而此偏移位址就是位於 SIB 之後的 1CH。
    上面步驟 i∼iii，得知 Ev 就是「[EAX+EBX+1CH」。
  9. Ib 位於偏移位址之後，故 Ib 就是 99H。
  10. 綜合步驟 6、8、9，得到「66H 0FH 0BAH 64H 18H 1CH 99H」反組譯後是「BT WORD PTR [EAX+EBX+1CH],99H」。

例子五：「85H 0CAH」

  1. 首先 85H 不是那十一個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 85H，查附錄七的「32-Bit OpCode Map」，得知 85H 的指令是「TEST Ev,Gv」。
    1. 查閱附錄七「32-Bit Argument Addressing Codes」，得知 E 代表此運算元可能是通用暫存器或記憶體；G 代表 Reg 是通用暫存器。
    2. 查閱附錄七「32-Bit Argument Operand Codes」，得知 v 代表此運算元是字組或雙字組。
    因為是三十二位元區段，所以預設是雙字組，故 Ev 代表此運算元是長度為雙字組的通用暫存器或記憶體；Gv 的意思是 Reg 所代表的是長度為雙字組的通用暫存器。「TEST Ev,Gv」就是使長度為雙字組的通用暫存器或記憶體（Ev）與長度為雙字組的通用暫存器（Gv）進行 TEST 運算。
  3. ModR/M 為 0CAH，換算成二進位是 1100 1010，故 Mod 為 11，Reg 為 001，R/M 為 010。
    1. 由 Reg 等於 001，查閱「Reg 所代表的暫存器」得知 001 可能代表 ECX、CX 或 CL，從步驟 2 得知運算元是雙字組，故 Gv 是「ECX」。
    2. 以 Mod 為 11 以及 R/M 為 010 搭配，查閱「32-Bit Mod 與 R/M 的關係」，得到可能代表 EDX、DX 或 DL，從步驟 2 得知運算元是雙字組，故 Ev 是「EDX」。
  4. 綜合步驟 2、3，「85H 0CAH」反組譯後是「TEST EDX,ECX」。

比較特別的是，在步驟 2 時，如果查閱不同資料時，有可能查到的是「TEST Gv,Ev」。事實上，「TEST Gv,Ev」與「TEST Ev,Gv」是一樣的指令，這是因為 TEST 指令僅僅讓兩個運算元進行 AND 運算然後改變旗標暫存器，但是並沒有將運算的結果覆寫目的運算元。也就是說 TEST 指令並不會改變目的運算元之值，所以目的運算元是 Gv 還是 Ev 就不重要了。

例子六：「41H」與「0FFH 0C1H」

例子六要反組譯兩道指令的機械碼：「41H」與「0FFH 0C1H」。為何要將這兩組機械碼擺在一起？等反組譯完之後就會明白了。現在先來做「41H」。

  1. 首先 41H 不是那十一個前置碼中的一個，所以此指令並無前置碼。
  2. 查附錄七的「32-Bit OpCode Map」，得知 41H 的指令是「INC eCX」。
  3. 查閱32-Bit Argument Operand Codes，得知 e 代表此運算元可能是十六位元的暫存器，亦可能是三十二位元的暫存器，因為在三十二位元區段，故預設為三十二位元，所以「41H」反組譯後得到「INC ECX」。

底下來看看如何反組譯「0FFH 0C1H」，步驟如下：

  1. 首先 0FFH 不是那十一個前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 0FFH，查附錄七的「32-Bit OpCode Map」，得知 0FFH 的指令是「GRP5 Ev」。到此可知目的運算元是存於某個記憶體位址或暫存器內的雙字組或字組。GRP5 代表 ModR/M 位元組的第 3∼5 位元並不是代表暫存器，而是 OpCode 的延伸。
  3. ModR/M 是 0C1H，換算成二進位是 1100 0001，故 Mod 為 11，OpCode 的延伸是 000，R/M 為 001。以 OpCode 延伸至 ModR/M 的第 3∼5 位元，000，以及 GRP5 查閱附錄七的「32-Bit OpCode Extensions」得知 GRP5 代表「INC」。再由步驟 3，得知指令為「INC Ev」。
  4. 以 Mod 為 11 以及 R/M 為 001 搭配，查閱「32-Bit Mod 與 R/M 的關係」表格，得到 Ev 是 CX/ECX 或 CL，且 W 位元為一、三十二位元區段預設運算元長度為三十二位元，故選擇 ECX。
  5. 綜合上面步驟，「0FFH 0C1H」反組譯後是「INC ECX」。

這兩組不同的機械碼，一個是「41H」，另一個是「0FFH 0C1H」經過反組譯之後，竟然都是「INC ECX」。由此可知，機械碼與 x86 指令，並非絕對的一對一關係。至少有可能是兩組不同的機械碼，對應到相同的 x86 指令。除此之外，到了發展 64 位元 CPU 的時代，也利用這個原理，將 40H∼4FH 的機械碼改成 REX 前置碼，不過這是下一節的主題了。

六十四位元的機械碼

這裏所講的六十四位元 CPU 指的是超微所提出來的 AMD64 架構的 CPU，而後由於市場的壓力，英特爾也接受這種架構並販售此架構的 CPU，最後普羅大眾就把這種架構稱為 x86－64，或簡稱為 x64。至今（民國 110 年，西元 2021 年左右），x64 仍是市面上主流的 CPU。它包含了超微的 Athlon 64/Athlon 64 FX 到 AMD Ryzen/AMD Epyc，以及英特爾的 Pentium 4 (Prescott)、Pentium D 到 Core i3/i5/i7。

x64 有許多種操作模式（見註一），這裏主要介紹六十四位元模式（64-bit mode）的機械碼，至於其他模式，在前面已經提過。在六十四位元模式下，x64 CPU 指令集與 IA－32 指令集最大的不同有：

  1. 通用暫存器由八個變為十六個，長度都是六十四位元，其名稱分別為 RAX、RBX、RCX、RDX、RBP、RSP、RSI、RDI、R8、R9、R10、R11、R12、R13、R14、R15。
  2. 這些暫存器，每一個又能再分出三十二位元、十六位元、八位元的暫存器。
  3. 能處理的運算元長度有位元組（八位元）、字組（十六位元）、雙字組（三十二位元）、四字組（六十四位元）。

為了表示這些新添的 64 位元暫存器及其再分出的暫存器，以及處理不同長度的運算元，x64 指令集多了 REX 前置碼。下圖是 x64 指令集的格式：

由上圖可以知道，x64 的機械碼可分為七部分，第一部分的名稱在 IA－32 中，原本稱為前置碼（prefixes），在 x64 改稱傳統前置碼（legacy prefixes）。第二個部分稱為 REX 前置碼（REX prefix，REX 的原文是 register extension），是新添的，其餘名稱不變。

傳統前置碼（Legacy Prefixes）

與 IA－32 相同，細節在前面已介紹過，也已整理出結論，可以按這裏查閱，此處不贅述。

REX 前置碼（REX prefix）

如果已經大致暸解 IA－32 的機械碼，那麼瞭解了 REX 前置碼之後，就幾乎也掌握住了 x64 機械碼。

在一道 x64 指令的機械碼中，REX 前置碼不是省略不出現，就是占用一個位元組。如果有出現 REX 前置碼的話，那麼這個位元組的第四∼第七位元的數值是固定的，依序是 0、0、1、0；而第零、一、二、三位元依需要而定，故不是定值，其名稱依序是 REX.B、REX.X、REX.R 以及 REX.W，見上圖。

由上敘述可得知，REX 前置碼的數值在 40H∼4FH 之間。但如果查附錄七的「32-Bit OpCode Map」，會發現在 40H∼4FH 已經有編碼了，其指令是 INC 或 DEC。原來 x64 編碼 OpCode 的設計者已經想過這個問題了，在三十二位元區段時，40H∼4FH 被當做 INC 或 DEC 指令；在六十四位元區段時，才是被當做是 REX 前置碼，而 INC 或 DEC 指令可由 0FEH、0FFH 與 ModR/M 第三∼五位元搭配照樣可以得到（見三十二位元 CPU 的機械碼例子六）。

REX.W

REX 前置碼的第三個位元稱為 REX.W，它負責控制運算元的大小。當 REX.W 為一時，運算元長度設為 64 位元；當 REX.W 為零時，運算元的長度為由運算元的預設長度以及運算元前置碼 66H 決定。詳細情形如下：

  1. 當 REX.W 為一時，運算元長度設為 64 位元。
  2. 當 REX.W 為零時，由運算元預設長度及運算元前置碼 66H 決定，有下面兩種情形：
    1. 如果運算元預設大小為 32 位元：
      • 沒有運算元前置碼 66H，運算元長度就是 32 位元。
      • 如果有運算元前置碼 66H 的話，運算元大小就會切換成 16 位元。
    2. 如果運算元預設大小為 16 位元：
      • 沒有運算元前置碼 66H，運算元長度就是 16 位元。
      • 如果有運算元前置碼 66H 的話，運算元大小就會切換成 32 位元。

運算元的預設長度會依據 x64 得操作模式決定，請參閱註一。

REX.R

REX.R 位元是 REX 前置碼的第二個位元，它與 ModR/M 中的 Reg 欄位合起來，共有四個位元，恰好可以代表 16 個暫存器，用以表示 x64 新增加的暫存器。換句話說，如果 REX.R 為零，Reg 欄位就代表舊有的暫存器；若 REX.R 為一，Reg 欄位就代表 R8∼R15 等新添的暫存器。

例如 REX.R 為 0，Reg 為 010 時，代表 DL、DX、EDX 或 RDX；若 REX.R 為 1，Reg 為 010 時，代表 R10B、R10W、R10D 或 R10 暫存器。當然還必須再搭配指示 REX.W 以及運算元前置碼，才能確實知道是哪個暫存器。

REX.R 位元與 Reg 欄位關係如下表：（下表同時也列出 REX.X 與 REX.B 的資料，因為這三者很相像，它們都是擴充暫存器而存在，差別在於擴充哪個欄位不同）

REX.R、REX.X、REX.B 與 Reg、Index、Base 欄位之關係
REX.R
/X/B		暫存器
長度		Reg、Index 或 Base 欄位
000001010011100101110111
0八位元ALCLDLBLAH/SPL CH/BPLDH/SILBH/DIL
十六位元AXCXDXBXSPBPSIDI
三十二位元EAXECXEDXEBXESPEBPESIEDI
六十四位元RAXRCXRDXRBXRSPRBPRSIRDI
1八位元R8BR9BR10BR11BR12BR13BR14BR15B
十六位元R8WR9WR10WR11WR12WR13WR14WR15W
三十二位元R8DR9DR10DR11DR12DR13DR14DR15D
六十四位元R8R9R10R11R12R13R14R15

在上表中，有四對八位元的暫存器，兩兩具有相同的編碼，那就是 AH/SPL、CH/BPL、DH/SIL、BH/DIL，那要怎麼區別呢？事實上，上面的表格有一點兒瑕疵必需說明，瞭解了這個說明之後，也就同時解決了剛剛的問題。上表中以紫色表示的暫存器是 IA－32 時代就已經有的暫存器，不需要加上 REX 前置碼就能表示，所以並沒有 REX.R 位元為零的問題。因此就能夠由有沒有 REX 前置碼來區別 AH/SPL，其餘三對也是如此。例如底下的例子：

機械碼     x86指令
------------------
FEC4      inc  ah
40FEC4    inc  spl

正因為如此，以下四個暫存器：AH、CH、DH、BH，不能與需要有 REX 前置碼才能表示的暫存器，例如 SPL、BPL、SIL、DIL、RAX、RBX……，同時出現在一道指令之中。例如底下的三道指令，都是錯誤的，都無法組譯成功：

        mov     ah,dil
        add     ch,sil
        movzx   rax,bh

REX.X 與 REX.B

REX.X 位元作用與 REX.R 位元的作用類似，REX.X 位元與 SIB 中的 Index 欄位合起來，共有四個位元，恰好可以代表十六個暫存器。REX.X 位元與 Index 欄位相互配合，所得的暫存器如上表。同理，REX.B 位元的作用也是延伸舊有的欄位，使得能夠表示十六個暫存器；差別在它可以延伸欄位有兩種：①SIB 中的 Base 欄位、②ModRM 中的 R/M 欄位。

操作碼（OpCode）

六十四位元模式下，機械碼的第三個部分是操作碼，它決定了 CPU 要執行的指令。在六十四位元模式下，操作碼最少使用一個位元組，最多三個位元組，如下表：

  1. 如果操作碼只有一個位元組，可查閱附錄七「64-Bit OpCode Map」，就能得知此操作碼代表什麼指令。
  2. 如果操作碼有兩個位元組，那麼第一個位元組必定是 0FH，可藉由第二個操作碼查閱附錄七「64-Bit OpCode Map, Two-byte Opcode Map ( First Byte is 0FH )」，查出是哪一個指令。
  3. 如果操作碼有三個位元組，那麼第一個位元組必定是 0FH，第二個操作碼不是 38H，就是 3AH，必是這兩者之一。這部分的操作碼所代表的指令，大多牽涉到多媒體或向量的計算。

跟 8086/8088、IA－32 一樣，有些操作碼會延伸到 ModR/M 中的第 3∼5 位元。如果是這種情形，在 OpCode Map 中會標示 GRP?，這時候依據 GRP? 與 ModR/M 中第 3∼5 位元之值，查閱附錄七「64-Bit OpCode Extensions」，才能知道是哪一個指令。

ModR/M 位元組

機械碼的第四個部分稱為 ModR/M 位元組，它決定了定址方式。跟 IA－32 一樣，ModR/M 位元組拆成三部分，第零∼二位元稱為 R/M，第三∼五位元稱為 Reg，第六、七位元稱為 Mod。Mod 與 R/M 相互搭配決定了定址模式。這一部分與三十二位元類似，但是為了要表示在六是四位元模式下，特有的 R8∼R15 暫存器，因此要考慮 REX 前置碼的 B 位元。請看下表：

64-Bit Mod 與 R/M 的關係
R/MMod＝00Mod＝01Mod＝10Mod＝11
REX.B
＝0		REX.B
＝1		REX.B
＝0		REX.B
＝1		 REX.B
＝0		REX.B
＝1		無REXREX.B＝0REX.B＝1
W＝0W＝0W＝1W＝0W＝1
000[RAX][R8][RAX+D8][R8+D8][RAX+D32][R8+D32]ALRAX/EAX/AXR8BR8/R8D/R8W
001[RCX][R9][RCX+D8][R9+D8][RCX+D32][R9+D32]CLRCX/ECX/CXR9BR9/R9D/R9W
010[RDX][R10][RDX+D8][R10+D8][RDX+D32][R10+D32]DLRDX/EDX/DXR10BR10/R10D/R10W
011[RBX][R11][RBX+D8][R11+D8][RBX+D32][R11+D32]BLRBX/EBX/BXR11BR11/R11D/R11W
100SIB 定址SIB 定址SIB 定址AHBPLRSP/ESP/SPR12BR12R/R12D/R12W
101[D32][D32][RBP+D8][R13+D8][RBP+D32][R13+D32]CHBPLRBP/EBP/BPR13BR13R/R13D/R13W
110[RSI][R14][RSI+D8][R14+D8][RSI+D32][R14+D32]DHSILRSI/ESI/SIR14BR14R/R14D/R14W
111[RDI][R15][RDI+D8][R15+D8][RDI+D32][R15+D32]BHDILRDI/EDI/DIR15BR15R/R15D/R15W

上表中，當 Mod＝11 且 W＝1 時，有 16 位元、32 位元、64 位元的暫存器，那麼到底要選哪一個呢？這時候必須看該預設的運算元大小，以及是否有出現 66H 前置碼決定，在前面已經敘述過，此處就不重複了。

SIB 位元組

64 位元模式的 SIB 跟 IA－32 的 SIB 類似，其中 Scale 欄位的意義完全一樣，請參閱 IA－32 的「Scale 所代表的倍率」；Index 欄位則做了擴充，必須與 REX.X 位元搭配，請參閱「REX.R、REX.X、REX.B 與 Reg、Index、Base 欄位之關係」。Base 也因為暫存器擴充成了十六個，必須與 REX.B 位元搭配，列表格如下。

64-Bit Mod 與 Base 的關係
BaseMod＝00Mod＝01Mod＝10
REX.B＝0REX.B＝1REX.B＝0REX.B＝1REX.B＝0REX.B＝1
000[RAX+索引倍率][R8+索引倍率][EAX+D8+索引倍率][R8+D8+索引倍率][EAX+D32+索引倍率][R8+D32+索引倍率]
001[RCX+索引倍率][R9+索引倍率][ECX+D8+索引倍率][R9+D8+索引倍率][ECX+D32+索引倍率][R9+D32+索引倍率]
010[RDX+索引倍率][R10+索引倍率][EDX+D8+索引倍率][R10+D8+索引倍率][EDX+D32+索引倍率][R10+D32+索引倍率]
011[RBX+索引倍率][R11+索引倍率][EBX+D8+索引倍率][R11+D8+索引倍率][EBX+D32+索引倍率][R11+D32+索引倍率]
100[RSP+索引倍率][R12+索引倍率][ESP+D8+索引倍率][R12+D8+索引倍率][ESP+D32+索引倍率][R12+D32+索引倍率]
101[D32+索引倍率][D32+索引倍率][EBP+D8+索引倍率][R13+D8+索引倍率][EBP+D32+索引倍率][R13+D32+索引倍率]
110[RSI+索引倍率][R14+索引倍率][ESI+D8+索引倍率][R14+D8+索引倍率][ESI+D32+索引倍率][R14+D32+索引倍率]
111[RDI+索引倍率][R15+索引倍率][EDI+D8+索引倍率][R15+D8+索引倍率][EDI+D32+索引倍率][R15+D32+索引倍率]

例子

底下的例子都是假設在 x64 CPU 的六十四位元模式下執行。

例子一：「0F7H 0D0H」、「66H 0F7H 0D0H」、「48H 0F7H 0D0H」

這三組機械碼用來說明 W 位元的作用。先看「0F7H 0D0H」。

  1. 首先 0F7H 不是那十一個傳統前置碼或 REX 前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 0F7H，查附錄七的「64-Bit OpCode Map」，得知 0F7H 的指令是「GRP3b Ev」。
  3. 因為查到了 GRP3b，故 ModR/M 的 Reg 是 OpCode 的延伸。ModR/M 為 0D0H，換算成二進位是 1101 0000，故 Mod 為 11，OpCode 的延伸為 010，R/M 為 000。
  4. 以 OpCode 延伸至 ModR/M 的第 3∼5 位元，010，以及 GRP3b 查閱附錄七的「64-Bit OpCode Extensions」得知 GRP3b 代表「NOT」。
  5. 由步驟 2、4 得知 0F7H 0D0H 代表「NOT Ev」，接下來查出 Ev 的意義：
    1. 查閱附錄七「64-Bit Argument Addressing Codes」，得知 E 代表此運算元可能是通用暫存器，也可能是記憶體。
    2. 再查閱附錄七「64-Bit Argument Operand Codes」，得知 v 代表字組、雙字組或四字組。
    因為是六十四位元模式，且沒有前置碼，所以預設的運算元是雙字組，故「NOT Ev」是把存於某個記憶體或暫存器（Ev）裏面的雙字組進行 NOT 運算。
  6. 由步驟 3，以 Mod 為 11 以及 R/M 為 000 搭配，查閱「64-Bit Mod 與 R/M 的關係」，且因為沒有 REX 前置碼，故把 REX.B 視為 0，於是 Ev 可能是 RAX、EAX、AX。因為六十四位於模式下，運算元預設長度是 32 位元，且沒有運算元前置碼 66H，故 Ev 是 EAX。
  7. 綜合步驟 5、6 得知，「0F7H 0D0H」反組譯後是「NOT EAX」。

再來看第二組機械碼，「66H 0F7H 0D0H」反組譯的過程。

  1. 首先 66H 是十一個傳統前置碼中的運算元前置碼，它會切換預設的運算元長度。
  2. 參考上面的例子，得知「0F7H 0D0H」反組譯之後是 NOT Ev，且 Ev 是 RAX、EAX、AX 中的其中一個。
  3. 因為只有當 REX.W 等於 1 時，運算元，Ev，才會是 64 位元的 RAX，但這個例子沒有 REX 前置碼，所以 Ev 不是 RAX。在六十四位於模式下，運算元預設長度是 32 位元，但因為有運算元前置碼 66H，必須將 Ev 切換成 16 位元，所以 Ev 是 AX。
  4. 由上面兩步驟，得知「66H 0F7H 0D0H」反組譯之後是「NOT AX」。

最後來看第三組機械碼「48H 0F7H 0D0H」反組譯的過程。

  1. 首先 48H 是 REX 前置碼，換算成二進位後是 0100 1000，得知 REX.W 為一，故運算元為 64 位元。
  2. 參考上面的「0F7H 0D0H」，得知反組譯之後是 NOT Ev，且 Ev 是 RAX、EAX、AX 中的其中一個。
  3. 由上面兩步驟，得知「48H 0F7H 0D0H」反組譯之後是「NOT RAX」。

例子二：「0FEH 0C1H」與「41H 0FEH 0C1H」

這兩組機械碼其實是用來說明 REX.B 位元的作用。先看「0FEH 0C1H」：

  1. 首先 0FEH 不是那十一個傳統前置碼或 REX 前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼 0FEH，查附錄七的「64-Bit OpCode Map」，得知 0FEH 的指令是「GRP4 Eb」。
  3. 因為查到了 GRP4，故 ModR/M 的 Reg 是 OpCode 的延伸。ModR/M 為 0C1H，換算成二進位是 1100 0001，故 Mod 為 11，OpCode 的延伸為 000，R/M 為 001。
  4. 以 OpCode 延伸至 ModR/M 的第 3∼5 位元，000，以及 GRP4 查閱附錄七的「64-Bit OpCode Extensions」得知 GRP4 代表「INC」。
  5. 由步驟 2、4 得知 0FEH 0C1H 代表「INC Eb」，接下來查出 Eb 的意義：
    1. 查閱附錄七「64-Bit Argument Addressing Codes」，得知 E 代表此運算元可能是通用暫存器，也可能是記憶體。
    2. 再查閱附錄七「64-Bit Argument Operand Codes」，得知 b 代表位元組。
    綜合上面步驟 i∼ii，得知「INC Eb」是使某個長度為一個位元組的記憶體或暫存器之值增加一。
  6. 由步驟 3，以 Mod 為 11 以及 R/M 為 001 搭配，查閱「64-Bit Mod 與 R/M 的關係」，且因為沒有 REX 前置碼，於是 Eb 就是 CL。
  7. 綜合步驟 5、6 得知，「0FEH 0C1H」反組譯後是「INC CL」。

再來看看「41H 0FEH 0C1H」反組譯的過程。

  1. 首先 41H 是 REX 前置碼，換算成二進位後是 0100 0001，得知 REX.B 為一。
  2. 參考上面的「0FEH 0C1H」例子，得知反組譯後是 INC Eb。
  3. 以 Mod 為 11 以及 R/M 為 001 搭配，查閱「64-Bit Mod 與 R/M 的關係」，且 REX.B 為一，所以得到 Eb 是 R9B。
  4. 由上面兩步驟，得知「41H 0FEH 0C1H」反組譯之後是「INC R9B」。

例子三：「4CH 69H 15H 20H 00 00 00 4AH 3BH 2CH 1DH」

這個機械碼很長，共 11 個位元組，但不必擔心，試試看就對了。

  1. 首先 4CH 是 REX 前置碼，換算成二進位後是 0100 1100，得知 REX.W 與 REX.R 均為一。因為 REX.W 為 1，運算元為 64 位元；因為 REX.R 為 1，ModR/M 的 Reg 欄位會與 REX.R 結合，會用到 R8∼R15 暫存器。
  2. 第一個操作碼是 69H，查附錄七的「64-Bit OpCode Map」，得知 69H 的指令是「IMUL Gv,Ev,Iz」。
    1. 查閱附錄七「64-Bit Argument Addressing Codes」，得知 G 代表 ModR/M 位元組中的 Reg 欄位是通用暫存器；E 代表此運算元可能是通用暫存器，也可能是記憶體；I 代表常數。
    2. 再查閱附錄七「64-Bit Argument Operand Codes」，得知 v 代表字組、雙字組或四字組，z 代表雙字組或字組。
  3. ModR/M 為 15H，換算成二進位是 0001 0101，故 Mod 為 00，Reg 為 010，R/M 為 101。
  4. 由 Reg 為 010 以及 REX.R 為 1，查閱「REX.R、REX.X、REX.B 與 Reg、Index、Base 欄位之關係」得知 Gv 可能是 R10W、R10D、R10；又知 REX.W 為 1，代表運算元是 64 位元。最後得到 Gv 代表 R10。
  5. 以 Mod 為 00 以及 R/M 為 101 搭配，查閱「64-Bit Mod 與 R/M 的關係」表格，得到 Ev 是「[D32]」，「[D32]」表示 32 位元的偏移位址，就是 ModR/M 之後的 00000020H，故 Ev 為「[20H]」。
  6. Iz 中的 z 可能是字組也可能是雙字組。根據附錄七「64-Bit Argument Operand Codes」的說明，當運算元是字組時，z 代表字組；當運算元是雙字組或四字組時，z 代表雙字組。因為 REX.W 為 1，表示運算元為四字組，所以 z 是雙字組。Iz 是雙字組的常數，就是 1D2C3B4AH。
  7. 綜合步驟 2、4∼6，得知「4CH 69H 15H 20H 00 00 00 4AH 3BH 2CH 1DH」反組譯後是「IUML R10,[20H],1D2C3B4AH」。

例子四：「4FH 8BH 0A4H 88H 3CH 00 00 00」

  1. 首先 4FH 是 REX 前置碼，換算成二進位後是 0100 1111，得知 REX.W、REX.R、REX.X、REX.B 均為一。
  2. 第一個操作碼是 8BH，查附錄七的「64-Bit OpCode Map」，得知 8BH 的指令是「MOV Gv,Ev」。
    1. 查閱附錄七「64-Bit Argument Addressing Codes」，得知 G 代表 ModR/M 位元組中的 Reg 欄位是通用暫存器，E 代表此運算元可能是通用暫存器，也可能是記憶體。
    2. 查閱附錄七「64-Bit Argument Operand Codes」，得知 v 代表字組、雙字組或四字組。
  3. 由步驟 1，REX.W 為 1，得知運算元是 64 位元，即四字組。再加上步驟 2，得知「4FH 8BH」反組譯後是「MOV Gv,Ev」，把一個四字組長的通用暫存器或記憶體內容（Ev），存入通用暫存器（Gv）中。
  4. ModR/M 為 0A4H，換算成二進位是 1010 0100，故 Mod 為 10，Reg 為 100，R/M 為 100。
  5. 由步驟 1，得知 REX.R 為 1；且由步驟 4，得知 Reg 為 100。以此二者為依據，查閱REX.R、REX.X、REX.B 與 Reg、Index、Base 欄位之關係，得知 Gv 是 R12。
  6. 由步驟 1，得知 REX.B 為 1，再由步驟 4，Mod 為 10，R/M 為 100，查閱64-Bit Mod 與 R/M 的關係，得知此為 SIB 定址，因此在 ModR/M 之後的 88H 是 SIB 位元組。
  7. SIB 位元組是 88H，換算成二進位是 1000 1000，故 Scale 為 10，Index 為 001，Base 為 000：
    1. Scale 為 10，查閱 Scale 所代表的倍率，得知倍率為 4。
    2. Index 為 001，且由步驟 1 知 REX.X 為 1，以此二者為依據，查閱REX.R、REX.X、REX.B 與 Reg、Index、Base 欄位之關係，得知索引為 R9。
    3. 由上面兩步驟，得知索引倍率是「R9*4」。
    4. Base 為 000 且由步驟 1 知 REX.B 為 1、步驟 4 知 Mod 為 10。以此三者，查閱64-Bit Mod 與 R/M 的關係，得知 Ev 為「[R8+D32+索引倍率]」。
    5. D32 為 32 位元的偏移位址，就是接在 SIB 之後的 0000003CH。
    綜合此步驟解析 SIB 後，得知 Ev 為「[R8+3CH+R9*4]」。
  8. 最後由步驟 3、5、7，得知「4FH 8BH 0A4H 88H 3CH 00 00 00」反組譯後為「MOV R12,[R8+3CH+R9*4]」

例子五：「96H」、「48H 96H」、「41H 96H」、「66H 41H 96H」、「66H 96H」

雖然這個例子要說明五組機械碼，但如果仔細觀察，就會發現這五組機械碼中，僅僅是傳統前置碼或REX 前置碼不同，而操作碼都是「96H」，因此可以猜想這五組應該是類似的指令。先來反組譯「96H」吧！

  1. 首先 96H 不是那十一個傳統前置碼或 REX 前置碼中的一個，所以此指令並無前置碼，從操作碼開始。
  2. 第一個操作碼是 96H，查附錄七的「64-Bit OpCode Map」，得知 96H 的指令是「XCHG rAX,rSI/r14」，亦即 rAX 與 rSI 或 r14 交換內容。
  3. 查閱附錄七「64-Bit Argument Addressing Codes」，得知 r 代表運算元是 16 位元、 32 位元或 64 位元的暫存器。
  4. 因為此機械碼沒有 REX 前置碼，故運算元為不需使用到 REX 前置碼的暫存器，亦即在 IA－32 中原本就有的暫存器，故 rSI/r14 應選 rSI。同時沒有運算元前置碼 66H，故使用預設的運算元大小。在六十四位元模式下，預設的運算元大小是三十二位元，故 rAX 為 EAX，rSI 為 ESI。
  5. 綜合步驟 2、4，得知「96H」反組譯後為「XCHG EAX,ESI」。

再來看第二組機械碼，「48H 96H」：

  1. 首先 48H 是 REX 前置碼，換算成二進位後是 0100 1000，得知 REX.W 為 1，所以運算元為 64 位元。
  2. 第一個操作碼是 96H，查附錄七的「64-Bit OpCode Map」，得知 96H 的指令是「XCHG rAX,rSI/r14」。
  3. 由步驟 1 知暫存器為 64 位元，故 rAX 是 RAX；rSI/r14 是 RSI 或 R14。因為 REX.B 為零，故選擇 RSI。
  4. 最後，「48H 96H」反組譯後為「XCHG RAX,RSI」。

來看第三組機械碼，「41H 96H」：

  1. 首先，41H 是 REX 前置碼，換算成二進位後是 0100 0001，得知 REX.B 為 1，意思是此運算元會在 R8∼R15。
  2. 因為沒有運算元前置碼 66H，故運算元大小為預設值；而六十四位元模式時，運算元大小預設值是 32 位元。也就是說運算元為 R8D∼R15D。
  3. 第一個操作碼是 96H，查附錄七的「64-Bit OpCode Map」，得知 96H 的指令是「XCHG rAX,rSI/r14」。
  4. 由上兩步驟，得知「41H 96H」反組譯後為「XCHG EAX,R14D」。

來看第四組機械碼，「66H 41H 96H」：

  1. 首先，66H 是運算元前置碼，切換運算元大小。六十四位元模式時，運算元大小預設值是 32 位元，切換後是 16 位元。
  2. 根據上面第三組機械碼，「41H 96H」反組譯後為「XCHG EAX,R14D」，如今變成 16 位元。因此「66H 41H 96H」反組譯後為「XCHG AX,R14W」。

最後來看第五組機械碼，「66H 96H」反組譯的步驟：

  1. 首先，66H 是運算元前置碼，切換運算元大小。沒有 REX 前置碼，故運算元大小不是 64 位元。
  2. 六十四位元模式時，運算元大小預設值是 32 位元，有 66H，故切換成 16 位元。
  3. 根據上面兩組的經驗，96H 代表「XCHG rAX,rSI/r14」，且沒有 REX.B，故選擇 rSI。
  4. 最後，「66H 96H」反組譯後得到「XCHG AX,SI」。

第五組也能這樣想，根據第四組「66H 41H 96H」反組譯後為「XCHG AX,R14W」，如今只是將 REX 前置碼拿掉，所以 REX.B 變為零，故把 R14W 改成 SI 就行了。

註一：x32－64 的工作模式

x64 兩種操作模式：①長模式（long mode）與②傳統模式（legacy mode），而每一種模式又可細分為數種子模式（sub-mode），有些複雜，如下面敘述：

①、長模式（long mode）被英特爾稱為「IA-32e 模式」（擴充版的 IA－32）。當使用者啟動電腦，六十四位元版的 Windows 7/8/10/11 等掌控電腦時，這時候 x－64 CPU 就在長模式之下。長模式又分為兩種子模式：

⑴、六十四位元模式（64-bit mode）：此模式使 64 位元作業系統能夠存取 64 位元線性位址，其預設位址大小為 64 位元，預設運算元大小為 32 位元。也就是說，當 64 位元版的 Windows 執行 64 位元的程式時，就是在此模式。
⑵、相容模式（Compatibility Mode）：相容模式允許大多數傳統 16 位元和 32 位元應用程式在 64 位元作業系統下運行，無需重新編譯。例如使用者在 64 位元版的 Windows 執行 32 位元的程式時，64 位元版的 Windows 就會讓此 32 位元程式的程式碼區段於此模式下執行。從應用程式的角度來看，相容模式看起來像是舊有的 x86 保護模式環境。然而，從作業系統的角度來看，位址轉換、中斷和異常處理以及系統資料結構則使用 64 位元長模式機制。

②、傳統模式又分為三種子模式：

⑴、保護模式（Protected Mode）：當使用者將電腦開關打開，如果啟動的是 32 位元版的 Windows 7/8/10/11 時，CPU 就於此模式下工作。保護模式支援記憶體分段、可選分頁和特權檢查。在保護模式運行的程式可以存取高達 4GB 的記憶體空間。
⑵、虛擬 8086 模式（Virtual 8086 Mode）：虛擬 8086 模式在保護模式下執行 16 位元程式。它使用簡單形式的記憶體分段、可選分頁和有限的保護檢查。在虛擬8086模式運行的程式可以存取 1MB 的記憶體空間。
⑶、真實模式（Real Mode）：當使用者將電腦開關打開，最初就是在此模式下，如果你啟動 MS－DOS，那麼 CPU 就處於此模式工作。於模式下，使用 Segment:Offset 的定址方式，最多可以存取 1MB 的記憶體空間。此模式不支援分頁或保護檢查，可將 x64 看成是速率很快的 8086/8088 CPU，其預設位址大小及預設運算元大小均為 16 位元。

x86－64 能執行的模式有點兒複雜，小木偶將上面的敘述整理成下表：

操作模式
（Operating Mode）		作業系統
（Operating System）		 位址預設
大小（bits）		運算元預設
大小（bits）
長模式
（Long Mode）		六十四位元模式
（64-Bit Mode）		 64 位元的作業系統，如 64
位元版的 Windows XP/7/8/
10/11		6432
相容模式
（Compatibility Mode）		32
1616
傳統模式
（Legacy Mode）		保護模式
（Protected Mode）		32 位元的作業系統，如
Windows 95/98/Me 或
32 位元版的 XP/7/8/10/11		 3232
1616
虛擬 8086 模式
（Virtual-8086 Mode）		1616
真實模式
（Real Mode）		16 位元的作業系統
，如 MS－DOS