微軟所開發的 DOS 作業系統中，最為常見的可執行檔有兩種，其副檔名分別是 COM 與 EXE。前幾章所介紹的是 COM ( 是 command 的意思 )，當它儲存在磁碟片時的內容和載入到記憶體的內容是一模一樣；如果不用特殊的方式製作，程式碼與資料在同一區段內，故檔案大小無法超過 64KB；因此只能製作小型程式，這大大的限制 COM 可執行檔的功能。
而這一章要介紹的是 EXE 可執行檔，EXE 是英文 execute 的意思。EXE 檔的程式碼及資料放在不同區段，故大小可以超過 64KB。當它儲存在磁碟片時，除了程式碼及資料外，還添加了一個稱為檔案頭表 ( file header ) 的資料。而作業系統載入 EXE 可執行檔時，會根據檔案頭表所記載的資料進行配置，然後才執行。依據檔案頭表的不同，EXE 檔有許多種格式：
本來在 DOS 作業系統下的原生程式 ( native program ) 是「MZ」格式，但是當微軟發展 Windows 1.x∼3.x 時，如果無法執行 MZ 格式的 EXE，便會失去許多商機，因此 Windows 1.x∼3.x 也能執行 DOS 的原生程式，這也是一種「向下相容」。而後到了 32 位元的時代，Windows 95∼10 也是如此，它們也都能執行 MZ 與 NE 格式的 EXE 檔。到了 64 位元的 Windows 時，還在使用 16 位元程式的人大概已經很少了，微軟決心拋棄舊包袱，才不支援 MZ 格式，但還是不敢不支援 PE 格式的執行檔。小木偶將這些 EXE 可執行檔，與支援的作業系統製作成下表：
| EXE 格式 | 支援的作業系統 |
| MZ | DOS、Windows 1.x∼3.x、32 位元的 Windows 95/98/Me/XP/Vista/7/8.x/10 |
| NE | Windows 1.x∼3.x、32 位元的 Windows 95/98/Me/XP/Vista/7/8.x/10 |
| PE | 32 位元及 64 位元的 Windows 95/98/Me/XP/Vista/7/8.x/10 |
| PE＋ | 64 位元的 Windows 95/98/Me/XP/Vista/7/8.x/10 |
有了上表及前一段所敘述的觀念就知道，MZ 格式的 EXE 可執行檔，能在 32 位元的 Windows 7 作業系統下執行，但不能在 64 位元的 Windows 7 作業系統下執行。而 PE＋ 格式的 EXE 可執行檔只能在 64 位元的 Windows 7 作業系統下執行，而不能在 32 位元的 Windows 7 作業系統下執行。
雖然 EXE 檔有許多不同的格式，但是在這裏小木偶僅介紹如何撰寫 MZ 格式的 EXE 可執行檔。MZ 格式的 EXE 可執行檔與 COM 可執行檔最大的不同，就是 EXE 有多個區段。
在 DOS 裏，區段 ( segment ) 是指一塊連續的記憶體，其大小最多只有 64KB，也就是 65536 個位元組。區段開始的位址並非任意的位址 ( 這裏的位址是指「實體位址」，不是「區段：偏移位址」詳細情形見第一章 )，只有能被 16 整除的位址才能是區段開始位址，以十六進位表示的話，就是實體位址最右邊那一位必須是「0」，這樣的位址稱為「節」( paragraphs )。
MZ 格式的 EXE 可執行檔至少包含三個區段，分別放著程式碼、資料與堆疊，因此在撰寫組合語言時，就要分別宣告這三個區段。宣告區段的方式有兩種：①簡易方式與②完整方式。先說第一種。以簡易方式宣告區段時，只要寫出一些假指令，組譯器會自動使用預設的區段名稱及屬性，除了方便之外，簡易的區段宣告能搭配微軟發售的高階語言編譯器，因此很容易與之產生的目的檔聯結。( 見註一 )
在第四章時，宣告程式碼區段與資料區段，分別用 .CODE 與 .DATA 假指令；而堆疊區段則使用 .STACK 假指令。這三個假指令語法如下：
.CODE 【區段名稱】 .DATA .STACK 【堆疊大小】
宣告程式碼區段用 .CODE 假指令，後面接著的區段名稱可以省略，如果省略，在 TINY、SMALL、COMPACT、FLAT 記憶體模式時，程式碼區段的內定名稱是「_TEXT」；如果是 MEDIUM、LARGE、HUGE 模式時，內定的名稱是「區段名稱_TEXT」。
定義資料區段用 .DATA 假指令，不論記憶體模式為何，其名稱都是「_DATA」。
定義堆疊區段用 .STACK 假指令，後面可以接堆疊大小，其單位是位元組，如果省略的話，內定值是 1024 位元組。對大部分的程式而言，1024 個位元組的堆疊已經足夠了。不論記憶體模式為何，堆疊區段的名稱都是「STACK」。堆疊的位址會受到「.MODEL」的影響，有關「.MODEL」的設定請參考第四章。主要的是堆疊有兩種性質：NEARSTACK 與 FARSTACK，前者表示堆疊區段與資料區段在同一區段；後者表示堆疊區段與資料區段在不同區段內。
定義好了程式碼、資料、堆疊三個區段之後，還要把區段暫存器分別指向這三個區段的位址，也就是要設定 CS、DS、SS 三個區段暫存器之值。把 CS 暫存器之值設為程式碼區段的位址，是由 DOS 系統來分配的不用我們煩惱，我們要擔心的是 DS、SS 之值須由程式設定，最簡單的方法是使用 .STARTUP 假指令即可。
雖然說一個區段最多可達 64KB 的大小，但對於大多數小型程式而言，都無法達到，尤其是堆疊區段。如果資料區段大小與堆疊區段大小加起來不超過 64KB，那麼假使把它們放在同一個區段，也就是 DS 與 SS 相同，同時小心的讓 SP 不會覆蓋掉到真正存放資料的地方 ( 還記得堆疊區段是由高位址向低位址使用 )，那麼我們就能用 DS:BX 直接存取堆疊，反過來也可以用 SS:SP 直接存取資料。像這樣的資料區段和堆疊區段，可視為一個群組，稱為區段群組 ( DGROUP )。
而 .STARTUP 就是為了達到這個目的又能簡化程式設計師的工作。底下小木偶就舉下面的 hellow1.asm 為例子來說明 .STARTUP 如何辦到的：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 |
.MODEL SMALL,C
.386
.STACK
;*******************************************************************************
.DATA
msg DB "Hellow, World.$"
;*******************************************************************************
.CODE
.STARTUP
mov dx,OFFSET msg
mov ah,9
int 21h
.EXIT 0
;*******************************************************************************
END |
用「ml hellow1.asm」組譯並連結成功後，用「symdeb hellow1.exe」載入，觀看一開始暫存器的初始值及反組譯的結果是：
E:\DOS\EXE>symdeb hellow1.exe [Enter] Microsoft (R) Symbolic Debug Utility Version 4.00 Copyright (C) Microsoft Corp 1984, 1985. All rights reserved. Processor is [80286] -r [Enter] AX=0000 BX=0000 CX=002B DX=0000 SP=0400 BP=0000 SI=0000 DI=0000 DS=1543 ES=1543 SS=1556 CS=1553 IP=0000 NV UP EI PL NZ NA PO NC 1553:0000 B85415 MOV AX,1554 -u 0 1a [Enter] 1553:0000 B85415 MOV AX,1554 1553:0003 8ED8 MOV DS,AX 1553:0005 8CD3 MOV BX,SS 1553:0007 2BD8 SUB BX,AX 1553:0009 C1E304 SHL BX,04 1553:000C 8ED0 MOV SS,AX 1553:000E 03E3 ADD SP,BX 1553:0010 BA0C00 MOV DX,000C 1553:0013 B409 MOV AH,09 1553:0015 CD21 INT 21 1553:0017 B8004C MOV AX,4C00 1553:001A CD21 INT 21 -
對照原始程式，上面藍字的程式就是 .STARTUP 作用後添加的結果。第一行是把 1554H 移入 AX，這 1554H 其實就是資料區段的位址，這是由 DOS 以及 EXE 的檔案頭表共同決定的，並不是我們所能控制的。堆疊的位址通常比資料區段高，因此 SS 的值則是由資料區段的大小決定。像 hellow1.exe 的資料區段前面 12 個 ( 其程式碼可以由程式碼區段 1553:0010 處得知 ) 位元組沒使用，真正的資料有 15 個位元組 ( 即 msg 字串大小 )，因此資料區段實際上有 27 個位元組。還記得前面說過每個區段起始的實體位址必須是 16 的整數倍，27 除以 16 是 1 餘 11，因此要用兩個節來容納。所以 SS 之值比 AX 多 2，故一開始，SS 為 1556H。
再看橙色字的 SP 值為 400H，換算成十進位是 1024，亦即 .STACK 的預設值。綜合以上所說，如果現在要把 SS 設成和 DS 一樣，同時又不能把覆寫原來的資料，因此 SP 必須再多加一些。那麼要加上多少呢？答案很明顯，就是資料區段的大小，同時又要符合一個區段必須由「節」的位址開始，顯然就是 20H 了。
瞭解了這個過程，.STARTUP 所做的事情就很簡單了，首先把 DS 設定資料區段所在位址 ( 其程式碼在程式碼區段的 1553:0000∼1553:0003 )，接下來的兩行算出資料區段佔了多少節，然後 1553:0009 處把節乘以 16 得到佔了多少位元組，藍字的最後兩行就是設定好新的 SS:SP。
如果程式使用 .STARTUP 來簡化初始程式，那麼在原始程式結尾的 END 假指令可以不必指定程式的進入點，即使寫出來也會被組譯器忽略。理由很簡單，既然已經指定 .STARTUP，就表示程式的進入點就在這兒了。
觀察原始程式第 13 行，這是一個新的假指令「.EXIT 0」，它的語法其實是
.EXIT value
value 稱為結束碼 ( exit code )，是一個位元組大小的數值，亦即 value 的範圍必須在 0∼255 之間，DOS 的批次檔 ( batch file ) 可以利用這個退出碼進行處理工作。再對照原始碼及反組譯結果，會發現 .EXIT 會添加額外的程式碼，「MOV AX,4C00」與「INT 21H」，很明顯這是一個 DOS 服務程式，其功能是結束程式，將控制權反還給 DOS 作業系統。
結束程式，把控制權還給 DOS 輸入：AH＝4C AL＝退出碼 執行：INT 21
或許有人會問，為何不像以前製作 COM 檔時，使用「INT 20H」來結束程式呢？原因是因為在 EXE 檔執行時，通常會改變 DS，也就是說 DS 已經不是原來 DOS 交給程式的數值了，所以 EXE 檔不用「INT 20H」結束程式。那麼，COM 檔是否可以用 AH＝4CH/INT 21H 結束程式呢？答案是可以的，你可以自行試試。
上面的程式架構，可以說是所有小型程式的範本，因此小木偶特別寫在下面：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16 |
.MODEL SMALL,C
.386
.STACK
;*******************************************************************************
.DATA
;存放資料的地方
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
;存放副程式的地方
;-------------------------------------------------------------------------------
.STARTUP
;存放程式碼的地方
.EXIT value
;*******************************************************************************
END |
用完整的方式宣告區段時，必須使用一對 SEGMENT/ENDS 假指令，它的語法是：
name SEGMENT [[align]] [[READONLY]] [[combine]] [[use]] [['class']]
statements
name ENDS
statements 是在 SEGMENT 與 ENDS 之間的程式碼或資料，這些程式碼或資料就是該區段的內容。
name 是區段名稱，可自由設定但不可以是暫存器名稱、指令名稱等等組譯器保留字。在原始程式中，同名稱的區段即使分開來寫，中間隔著其他區段，連結器還是會把它們合併成同一個區段。如果你的程式是由許多模組組成的大程式，不同模組內如果有相同名稱的區段也會被連結器合併成在同一區段內，除非 combine 設為 PRIVATE，就不會合併同名稱的區段。
align 是排列形式，是指區段起始位址的規則，可以是下面幾種形式：
READONLY 是讓組譯器將此區段設為唯讀區段，意思在這區段的資料只能讀取不能寫入。組譯器會檢查原始碼內的程式有沒有將資料寫入這個區段內，如果有就發生錯誤。這在設計保護模式的程式和設計有關 ROM 的程式時很有用。READONLY 可以省略，表示此區段可讀可寫。
combine 是指合併形式，是指示連結器如何處理不同模組的區段，可以是下面幾種情形：
use 是設定區段內的偏移位址以及預設的運算元是 16 位元或 32 位元。在說明 use 之前，應該要先知道，MASM 6.11 不僅能撰寫 DOS 程式，也能撰寫 32 位元的 Windwos 程式。前者是 16 位元的作業系統，用 16 位元長度表示偏移位址，因此最大只能是 64KB，這也就是一個區段最大的長度了；後者是 32 位元作業系統，用 32 位元表示偏移位址，最大可達 4GB。
那麼組譯器如何判別要組譯成 16 位元的程式還是 32 位元？這要看原始碼一開始 .MODEL 和 .386 或 .486 的順序了。如果是 .MODEL 在前，組譯器會製作 16 位元的 DOS 程式；反之則製作 32 位元的 Windows 程式。
儘管如此，我們還是可以製作一個程式中有些區段是 16 位元的，有些是 32 位元的，兩種不同位元位址的混合程式，這種情形大多用於作業系統。這時候就要用 use 來決定哪些區段是 16 位元，哪些是 32 位元，因此 use 有兩種選項：USE16 與 USE32，很明顯前者是 16 位元的位址，後者是 32 位元的位址。
有些 x86 指令會假定預設區段，例如 PUSH、POP 是假定在 SS 所指的區段內存取資料，MOV 指令則是假定在 DS 所指的區段內存取資料。因此，還要有個假指令來告訴組譯器，哪個區段對應哪個暫存器，這個指令就是 ASSUME。通常是在程式碼區段宣告之後，就要有一條 ASSUME 假指令，說明區段與區段暫存器的對應關係。ASSUME 的語法是：
ASSUME segregister:seglocation [[,segregister:seglocation]]
其中 segregister 是區段暫存器，seglocation 是區段名稱。
ASSUME 指示將暫存器與區段之間的關係告訴組譯器，讓組譯器知道如何組譯，其實並沒有把區段位址填入區段暫存器內。因此，在原始程式一開始的地方，還要加上幾條 x86 指令讓 DS 指向資料區段的位址。這些指令如下：
mov ax,資料區段名稱
mov ds,ax
完整程式如下：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28 |
.MODEL SMALL,C
.386
;*******************************************************************************
mystack SEGMENT PARA STACK 'stack'
DB 1024 DUP (?)
mystack ENDS
;*******************************************************************************
mydata SEGMENT PARA PUBLIC 'data'
msg DB "Hellow, World.$"
mydata ENDS
;*******************************************************************************
mycode SEGMENT PARA PUBLIC 'code'
assume cs:mycode,ds:mydata
;-------------------------------------------------------------------------------
main PROC
mov ax,mydata
mov ds,ax
mov dx,OFFSET msg
mov ah,9
int 21h
mov ax,4c00h
int 21h
main ENDP
;-------------------------------------------------------------------------------
mycode ENDS
;*******************************************************************************
END main |
把上面原始程式存成 hellow2.asm，然後進入「Virtual PC」的「MS-DOS 6.20」，下達「ml hellow2.asm」組譯即可正常執行，執行時也是在螢幕上印出「Hellow, World!」就結束程式。
這個程式第 4∼6 行，設定堆疊區段大小為 1KB ( 即 1024 個位元組 )，堆疊區段的名稱為 mydstack，而合併形式為「STACK」，合併形式為「STACK」就會被組譯器視為堆疊區段。注意到 SEGMENT 與 ENDS 成對出現，不只堆疊區段如此，資料區段、程式碼區段也是如此。
第 8∼10 行為資料區段，名稱為「mydata」，在後面第 13 行可以見到 ASSUME 把資料區段與 DS、程式碼區段與 CS 對應起來，也可以把這一行分成兩行：
ASSUME cs:mycode ASSUME ds:mydata
第 16 行取得 mydata 的區段位址並存於 AX 裏，第 17 行把 DS 之值設為 AX。可能會有人問，為何不簡單用一行「mov ds,mydata」就好了，這是因為在 x86 的 MOV 指令不能把常數存入區段暫存器的指令，只能把通用暫存器存入區段暫存器裏，故只能用這樣間接的方法。
其他的程式碼應該不須多做解釋了。
模組 ( module ) 可以想像成是執行某件特定工作的程式。當要開發某個大型軟體時，常常會將它分成數個小程式，交給不同的程式設計師，分別同時撰寫，最後只需再以主程式將各個小程式連結起來，就能製作成一個完整的程式。這些小程式就能看成是模組，而這樣設計軟體的方式稱為模組化。
像微軟的文書處理軟體，「WORD」，本身除了處理文字之外，還會多了額外的功能，例如方程式、圖片等功能，就應該是由不同的單位設計而成的。