第二十六章　通用對話盒：開啟舊檔（一）

Windows 作業系統提供一些已經設計好的對話盒可供程式設計師直接使用，稱為通用對話盒（common dialog boxes），它不需要像前幾章的對話盒，要先在在資源描述檔中用 DIALOG 或 DIALOGEX 區塊定義，然後用資源編譯器編譯，所得到的資源檔再用連結器與目的檔連結；通用對話盒只需呼叫下表中的 Win64 API 即可產生，當然在呼叫這些 Win64 API 之前必須將參數設定好，而這些參數都是複雜的結構體。常見的通用對話盒有下面幾種：

通用對話盒要呼叫的 API要使用結構體
設定顏色ChooseColorCHOOSECOLOR
搜尋FindTextFINDREPLACE
取代ReplaceTextFINDREPLACE
設定字型ChooseFontCHOOSEFONT
開啟舊檔GetOpenFileNameOPENFILENAME
另存新檔GetSaveFileNameOPENFILENAME
版面設定PageSetupDlgPAGESETUPDLG
選擇目錄SHBrowseForFolderBROWSEINFO

例如要產生「開啟舊檔」通用對話盒，需先設定好 OPENFILENAME 結構體的個欄位，然後呼叫 GetOpenFileName API。雖然通用對話盒的種類很多，但這一章只著重在「開啟舊檔」通用對話盒。

開啟舊檔通用對話盒

顧名思義，開啟舊檔通用對話盒是用於取得檔案名稱的對話盒。根據在 OPENFILENAME 中不同的設定，它的執行畫面有多種不同的樣子，但是主要可分為兩類：舊風格（old-style，亦翻譯成舊樣式）與總管風格（explorer-style，也翻譯成總管樣式、探險者樣式等）。下圖是在 Windows 7 作業系統產生的開
啟舊檔對話盒，兩者都是呼叫 GetOpenFileName 產
生的，圖一是舊風格，圖二是總管風格。使用者可以用滑鼠左鍵在檔案列表中選擇檔案，見上面兩圖中滑鼠游標選定的「97f1logu00.bmp」檔案，該檔案的名稱會出現在「檔名（N）：」或「檔案名稱（N）：」之後的編輯框內（紅色框），然後按下「確定」或「開啟」按鈕，就能獲得所選擇的檔案名稱，在應用程式裏面可以作為後續處理的資料，很方便而且易於使用。底下介紹 GetOpenFileName API。

GetOpenFileName API

GetOpenFileName 的原型如下：

invoke  GetOpenFileName,\
        lpofn           ; address of structure with initialization data

它只有一個參數，OPENFILENAME 結構體的位址。呼叫 GetOpenFileName 之前，須設定好此結構體的欄位，GetOpenFileName 由此結構體獲得所需資料，並把另外一些資料藉由此結構體，傳回給應用程式，供其使用。

如果使用者有選定某個檔案，且按下「確定」或「開啟」按鈕，回傳值為非零，且 OPENFILENAME 的 lpstrFile 欄位所指位址上存有包含磁碟機名稱、路徑名的完整檔案名稱。如果使用者按下「取消」按鈕或按下右上角的關閉按鈕，回傳值為零，可呼叫 CommDlgExtendedError 獲得進一步的錯誤訊息。

OPENFILENAME 結構體

OPENFILENAME 結構體僅用於呼叫 GetOpenFileName 與 GetSaveFileName 兩個 Win64 API 的參數，前者會彈出「開啟舊檔」對話盒，後者會彈出「另存新檔」對話盒。在 WinInc 的 COMMDLG.INC 含入檔中，OPENFILENAME 的定義有錯，必須要有對齊值，在 STRUCT 之後必須加上對齊值 8，就如同底下 OPENFILENAME 所定義的樣子：

OPENFILENAME        STRUCT    8
  lStructSize       DWORD     ?  ;① OPENFILENAME結構體長度
  hwndOwner         HWND      ?  ;② 擁有此對話盒的視窗代碼
  hInstance         HINSTANCE ?  ;③ 模組代碼
  lpstrFilter       LPWSTR    ?  ;④ 篩選字串位址
  lpstrCustomFilter LPWSTR    ?  ;⑤ 自行定義的篩選字串位址
  nMaxCustFilter    DWORD     ?  ;⑥ lpstrCustomFilter所指緩衝區大小
  nFilterIndex      DWORD     ?  ;⑦ 預設的篩選字串
  lpstrFile         LPWSTR    ?  ;⑧ 存放完整檔名的緩衝區位址
  nMaxFile          DWORD     ?  ;⑨ lpstrFile所指緩衝區大小
  lpstrFileTitle    LPWSTR    ?  ;⑩ 檔名位址
  nMaxFileTitle     DWORD     ?  ;⑪ lpstrFileTitle所指緩衝區大小
  lpstrInitialDir   LPWSTR    ?  ;⑫ 初始目錄位址
  lpstrTitle        LPWSTR    ?  ;⑬ 標題欄字串的位址
  Flags             DWORD     ?  ;⑭ 旗標
  nFileOffset       WORD      ?  ;⑮ 檔名在完整檔名的第幾個字元
  nFileExtension    WORD      ?  ;⑯ 副檔名在完整檔名的第幾個字元
  lpstrDefExt       LPWSTR    ?  ;⑰ 預設副檔名位址
  lCustData         LPARAM    ?  ;⑱ 傳給攔截函式自行定義的資料
  lpfnHook          QWORD     ?  ;⑲ 攔截函式位址
  lpTemplateName    LPWSTR    ?  ;⑳ 對話盒面板名稱的位址
 IF (_WIN32_WINNT GE 500h)       ;㉑ Windows版本NT 5.0及其以後版本才有的欄位
  pvReserved        DWORD     ?  ;㉒ 保留的欄位，應設為0
  dwReserved        DWORD     ?  ;㉓ 保留的欄位，應設為0
  FlagsEx           DWORD     ?  ;㉔ 擴充的旗標
 ENDIF
OPENFILENAME        ENDS

OPENFILENAME 結構體的欄位很多，底下簡略介紹：

①、lStructSize：OPENFILENAME 結構體長度，以位元組為單位。Windows API 會隨著作業系統版本升級而添加新的欄位而增加新的功能，但又要相容舊有的應用程式。藉由 lStructSize，Windows 可以判斷應用程式使用哪個版本，而達到相容的目的。
②、hwndOwner：擁有此對話盒的視窗之視窗代碼，如果沒有視窗擁有此對話盒，可將此欄位設為 0。
③、hInstance：有三種情形，與在 Flags 欄位中，OFN_ENABLETEMPLATEE 與 OFN_ENABLETEMPLATEHANDL 兩旗有關，這兩個旗標須擇一設定，或是都不設定：
⑴、如果 Flags 中設定了 OFN_ENABLETEMPLATE，那麼 hInstance 是模組代碼，且此模組代碼含有 lpTemplateName 所指位址的對話盒面板。
⑵、如果 Flags 中設定了 OFN_ENABLETEMPLATEHANDLE，hInstance 是包含對話盒面板的記憶體物件代碼。
⑶、如果 Flags 不含 OFN_ENABLETEMPLATEHANDLE，也不含 OFN_ENABLETEMPLATE，系統會忽略 hInstance。
④、lpstrFilter：篩選字串的位址，可以包含一組或一組以上的篩選字串，每組篩選字串都是由一對以零結尾的字串組成；最後一組篩選字串後面，要以兩個零表示結束。篩選字串由一對字串組成：
⑴、第一個字串為顯示字串（display string），用於顯示在「檔案類型」的下拉式方塊控制項內（例如，在圖一或圖二的「位元圖(*.bmp)」，藍色框）。
⑵、第二個字串為篩選形式字串（filter pattern），指定篩選規則，符合篩選規則的檔案會列在對話盒中的清單盒控制項內（list box control，在圖一或圖二的紫色框）。篩選規則通常是指定某一種類型的檔案，而檔案類型由副檔名決定。例如副檔名是「.BMP」就代表位元圖，「.TXT」代表純文字檔，所以篩選形式字串就像「"*.BMP",0」或「"*.TXT",0」的樣子。（此處副檔名的大小寫不拘，視為相同。「*」代表萬用字元，表示任意字元，同時可以是一個任意字元、也可以是兩個、三個……，也就是說 9.bmp、95can05.bmp 都符合 *.BMP 篩選規則）
底下來看幾個例子。假如在開啟舊檔對話盒要挑選某個位元圖檔案，那麼應該在對話盒的檔案列表中列出所有位元圖檔案，所以篩選字串只有一組，如下： 
"位元圖",0,"*.BMP",0,0
假如要在開啟舊檔對話盒要挑選位元圖或者另一種常見的壓縮圖片檔「.JPG」，那麼篩選字串就有兩組。而 JPG 檔的副檔名可以是「.JPG」也可以是「.JPEG」，像這樣一個顯示字串搭配多個篩選形式字串時，可以用分號（;）來分隔它們，如下： 
"位元圖",0,".BMP",0
"壓縮圖檔",0,"*.JPG;*.JPEG",0,0
篩選形式字串也可以由有效的檔名字元和萬用字元「*」組成，但不可使用空格。例如底下的例子只會在清單盒控制項內顯示以「9」開頭的 BMP 檔案： 
"檔名為 9 起頭的位元圖",0,"9*.BMP",0,0
在下拉式方塊控制項顯示的顯示字串順序，是按照 lpstrFilter 中指定的順序。如果 lpstrFilter 為 NULL，則對話盒不會顯示任何顯示字串，而清單盒控制項會顯示初始目錄內的所有檔案。
⑤、lpstrCustomFilter：自行定義的篩選字串位址，包含一對顯示字串與篩選形式字串，中間以零隔開，最後以兩個零為結尾。應用程式首次建立對話盒時，如果指定 lpstrCustomFilter 為顯示字串位址，且顯示字串並非空字串，那麼當使用者選取檔案時，對話盒會將目前的篩選形式複製到篩選形式字串中。在下次建立對話盒時，系統會使用 lpstrCustomFilter 指定的篩選字串。如果 nFilterIndex 為零，對話盒會使用自訂篩選。
如果 lpstrCustomFilter 不是零，必須指定 nMaxCustFilter 的值為 lpstrCustomFilter 緩衝區的大小，以字元為單位；如果是零，對話盒就不會保留使用者自行定義的篩選字串。
⑥、nMaxCustFilter：lpstrCustomFilter 所指的緩衝區大小，以字元為單位，至少需 40 字元。如果 lpstrCustomFilter 為零，或所指位址的第一個字元為零，系統會忽略 nMaxCustFilter。
⑦、nFilterIndex：nFilterIndex 的數值可以是 1、2……到 lpstrFilter 內有多少組篩選字串，也就是篩選的索引。這索引值所代表的顯示字串會顯示於下拉清單型複合框或檔案類型控制項旁的編輯框內。例如在 lpstrFilter 所指位址是 
"組合語言",0,"*.ASM",0
"超文本標記語言",0,"*.HTML;*.HTM",0
"C語言",0,"*.C",0,0
而 nFilterIndex 設為 1，那麼畫面如右圖三。
⑧、lpstrFile：存放完整檔名的緩衝區位址。呼叫 GetOpenFileName 或 GetSaveFileName，使用者挑選好檔案並成功返回時，此緩衝區會存放完整檔名，完整檔名包含磁碟機名稱、路徑名、主檔名及副檔名。此緩衝區亦可存放初始檔名，作法是在呼叫前，把以零結尾的檔案名稱填入此緩衝區即可；如果不須初始檔名，緩衝區第一個字元必須是零。初始檔名會顯示在「檔名」或「檔案名稱」右邊的複合框內。
如果已設定 OFN_ALLOWMULTISELECT 旗標，且使用者挑選多個檔案，GetOpenFileName 或 GetSaveFileName Win64 API 返回時，緩衝區會包含目前的路徑名，後面接著使用者選定的所有檔名（僅包含主檔名及副檔名）。對於總管風格的對話盒，路徑名與檔名之間以 0 隔開，檔名與檔名之間也以 0 隔開，最後一個檔名之後有兩個 0，表示結束。對於舊風格的對話盒，路徑名與檔名、檔名與檔名之間，以空白當分隔符號，而具有空白字元的檔名會以短檔名（即 DOS 的檔名格式，8 個位元組的主檔名加上 3 個位元組的副檔名，就是所謂的 8.3 格式）表示。假如有設定 OFN_ALLOWMULTISELECT，但使用者僅選定一個檔案，那路徑名與檔名之間不會有 0 或空白分隔符號。
如果緩衝區太小，回傳值為零，呼叫 CommDlgExtendedError 會傳回 FNERR_BUFFERTOOSMALL。在此情況下，lpstrFile 緩衝區的第一個字組是所需的大小，以字元為單位。
⑨、nMaxFile：lpstrFile 所指之緩衝區大小，以字元為單位。緩衝區必須夠大，才能儲存路徑和檔案名稱，包括終止的 Null 字元。如果緩衝區太小而無法包含檔案資訊，GetOpenFileName 和 GetSaveFileName 會傳回零。緩衝區長度至少應為 256 個字元。
⑩、lpstrFileTitle：檔名位址。當呼叫 GetOpenFileName 或 GetSaveFileName，使用者由對話盒中選定好檔案並成功返回時，系統會把該檔案的檔名存於此欄位所指位址的緩衝區內，此檔名不含路徑，僅包含主檔名與副檔名。如果不需要這項資料，也可以把此欄設為零。
⑪、nMaxFileTitle：lpstrFileTitle 所指緩衝區大小，單位為字元。如果 lpstrFileTitle 設為零，系統會忽略此欄位。
⑫、lpstrInitialDir：初始目錄位址，此位址指向以零結尾的目錄名稱，這個目錄可以是絕對路徑或相對路徑。當產生「開啟舊檔」或「另存新檔」對話盒時，對話盒中的清單盒控制項（在圖一或圖二的紫色框）或圖三的「資料夾」就是 lpstrInitialDir 所指的目錄。話雖如此，但實際上為了操作便利性，lpstrInitialDir 會依據不同作業系統而對初始目錄的設定有不同的策略：
⑴、Windows 3.x 與 Windows NT 3.x：
⒜、如果 lpstrInitialDir 已指定目錄，初始目錄即為 lpstrInitialDir 所指的目錄。
⒝、如果 lpstrInitialDir 為零，而 lpstrFile 所指字串包含路徑，那麼初始目錄為 lpstrFile 所指的路徑。
⒞、如果都不符合上述條件，初始目錄為當前目錄（即應用程式所在目錄）。
⑵、Windows 98/Me：
⒜、如果 lpstrInitialDir 已指定目錄，初始目錄即為 lpstrInitialDir 所指的目錄。
⒝、如果 lpstrInitialDir 為零，而 lpstrFile 所指字串包含路徑，那麼初始目錄為 lpstrFile 所指的路徑。
⒞、如果 lpstrInitialDir 為零，而 lpstrFile 所指字串不包含路徑，但是當前目錄含有符合 lpstrFilter 所指定篩選形式的檔案，那麼初始目錄為當前目錄。
⒟、否則初始目錄為「我的文件夾」，即「C:\My Documents\」。
⑶、Windows XP/2000：
⒜、如果 lpstrFile 所指定字串包含路徑，那麼初始目錄即為該路徑。
⒝、如果 lpstrFile 所指定字串不含路徑，初始目錄即為 lpstrInitialDir 所指的目錄。
⒞、如果 lpstrInitialDir 為零，而應用程式之前曾使用過「開啟舊檔」或「另存新檔」對話盒，那麼初始目錄是最近使用的目錄。然而，如果應用程式長時間未執行，該目錄會被捨棄。
⒟、如果 lpstrInitialDir 為零，且應用程式之前未曾使用過「開啟舊檔」或「另存新檔」對話盒，但是當前目錄包含符合 lpstrFilter 所指定篩選形式的檔案，那麼初始目錄為當前目錄。
⒠、承上⒟的條件，當前目錄沒有符合 lpstrFilter 所指定篩選形式的檔案，初始目錄為使用者的「我的文件」資料夾（C:\Documents and Settings\使用者名稱\My Documents\）。
⒡、承上⒠的條件，使用者的「我的文件」資料夾不存在或無法存取時，或者都不符合上述所有條件，初始目錄為桌面資料夾（C:\Documents and Settings\使用者名稱\Desktop\）。
⑷、Windows 7：
⒜、如果 lpstrInitialDir 的值與應用程式首次使用「開啟舊檔」或「另存新檔」對話盒時所傳入的 lpstrInitialDir 值相同，則初始目錄是使用者最近選擇的路徑。
⒝、如果不相等且 lpstrFile 包含路徑，那麼初始目錄為 lpstrFile 所包含的路徑。
⒞、如果 lpstrFile 不包含路徑，且 lpstrInitialDir 已指定路徑，那麼初始目錄為 lpstrInitialDir 所指定路徑。
⒟、如果 lpstrInitialDir 為零，並且當前目錄含有符合 lpstrFilter 所指定篩選形式的檔案，那麼初始目錄為當前目錄。
⒠、如果當前目錄不含符合 lpstrFilter 所指定篩選形式的檔案，那麼初始目錄為當前使用者的「我的文件」資料夾（C:\Users\使用者名稱\Documents\）。
⒡、如果上述條件均不滿足，初始目錄為使用者的桌面資料夾（C:\Users\使用者名稱\Desktop\）。
這兒有必要說明⒜的意思，舉個例子可能會更好，假設以下情境：
㈠、如果有個應用程式從未執行過，當它第一次執行時產生「開啟舊檔」或「另存新檔」對話盒時，假設 lpstrInitialDir 為「D:\ASM\」且 lpstrFile 為零。因為是第一次開啟對話盒不做⒜的比較，而且 lpstrFile 沒有路徑，所以依據⒞，初始目錄為「D:\ASM\」，對話盒上的初始目錄是「D:\ASM\」。
㈡、假設使用者更換目錄為「D:\ASM\WIN64\」，並挑選了其中的「PRIME.ASM」檔案，按「確定」按鈕離開對話盒。系統會記住這個改變後的目錄。
㈢、下次再開啟「開啟舊檔」或「另存新檔」對話盒時，假設 lpstrInitialDir 仍為「D:\ASM\」，因為與第一次傳入的 lpstrInitialDir 相同，所以系統會忽略「D:\ASM\」，而把初始目錄設為上次使用者選擇的「D:\ASM\WIN64\」，這就是⒜的作用。這種策略很符合人們在職場上的工作。當人們修改某個檔案，該檔案在修改過程中通常放在同一目錄裏，而且也需要經過多次修改，讓使用者只須第一次選擇該目錄，以後不必再重新選擇，比較方便。
㈣、假如下次開啟對話盒時，lpstrInitialDir 變為「D:\ASM\WIN32\」，那麼系統會以「D:\ASM\WIN32\」作為初始目錄，而不管上次選擇的是哪個目錄。
⑬、lpstrTitle：標題欄字串的位址。如果 lpstrTitle 為零，表示使用預設的標題欄。預設的標題欄字串會隨 Windows 版本不同而不同。例如，呼叫 GetOpenFileName 時，Windows 7 及其以前的是「開啟舊檔」，而 Windows 10 是「開啟」；如果呼叫 GetSaveFileName，Windows 7、Windows 10 都是「另存新檔」。
⑭、Flags，旗標，用來初始化對話盒或是改變對話和外觀等，常用到的數值如下表，也可以用「OR」運算子連接數個旗標：
Flags說明
OFN_READONLY
1		使「唯讀」複選框在對話盒一開始建立時，為選中狀態。
OFN_OVERWRITEPROMPT
2		OFN_OVERWRITEPROMPT 只有在呼叫 GetSaveFileName 有效。當使用者選擇已存在的檔案時，系統會警告該檔案已存在，是否要取代？如果回答「是」，另存新檔對話盒被銷毀回到原應用程式；如果回答「否」，返回另存新檔對話盒讓使用者繼續選擇。
OFN_HIDEREADONLY
4		不顯示「唯讀」複選框。
OFN_NOCHANGEDIR
8		如果使用者在呼叫 GetSaveFileName 彈出的通用對話盒中，搜尋檔案時變更工作目錄，返回時會將目錄還原為呼叫前的工作目錄。但此旗標對 GetOpenFileName 無效。
OFN_SHOWHELP
10h		顯示說明按鈕。當使用者按下該按鈕後，攔截程式收到 WM_NOTIFY 訊息，此訊息中會含有 CDN_HELP 通知碼，攔截函式需處理此通知碼（見 WM_NOTIFY）。因此必須在 Flags 設定 OFN_ENABLEHOOK，並且在 lpfnHook 欄位設定攔截函式位址。
OFN_ENABLEHOOK
20h		此旗標啟用 lpfnHook 欄位。
OFN_ENABLETEMPLATE
40h		此旗標啟用 lpTemplateName 欄位。
OFN_ENABLETEMPLATEHANDLE
80h
OFN_NOVALIDATE
100h		預設情形下，使用者在編輯框內輸入的檔名含不合法字元，按下「開啟」按鈕後系統會提出警告，並返回通用對話盒讓使用者繼續選擇。但設定 OFN_NOVALIDATE 後，系統不驗證檔案名稱，允許使用者於編輯框輸入無效檔名。
OFN_ALLOWMULTISELECT
200h		允許使用者挑選多個檔案。若 Flags 含 OFN_ALLOWMULTISELECT 與 OPN_EXPLORER，那麼使用「總管風格」；若只含 OFN_ALLOWMULTISELECT 但不含 OPN_EXPLORER，那麼會使用「舊風格」。
OFN_EXTENSIONDIFFERENT
400h		當使用者輸入的副檔名與 lpstrDefExt 所指定的副檔名不同，那麼當 GetOpenFileName 或 GetSaveFileName 返回時，系統會在 Flags 設定 OFN_EXTENSIONDIFFERENT 旗標，應用程式可檢查是否含此旗標而做後續處理。如果 lpstrDefExt 為零，那麼就不使用此旗標。
OFN_FILEMUSTEXIST
1000h		設定 OFN_FILEMUSTEXIST 後，使用者如果在編輯框輸入不存在的檔案並按下開啟按鈕，系統會彈出一對話盒警告找不到該檔案，並返回通用對話盒內繼續讓使用者選擇。
OFN_CREATEPROMPT
2000h		當使用者輸入不存在的檔案時，此旗標會導致對話盒提示使用者是否建立檔案。如果使用者選擇建立檔案，對話方盒會關閉，GetOpenFileName 或 GetSaveFileName 會傳回輸入的檔名供應用程式進行後續處理；否則，返回對話盒方塊。如果此旗標同時還搭配 OFN_ALLOWMULTISELECT，那麼系統只傳回第一個檔案名稱。
OFN_SHAREAWARE
4000h		指定如果 OpenFile 函式的呼叫因為網路共用違規而失敗，則會忽略錯誤，而且對話盒會傳回選取的檔案名。如果未設定此旗標，對話盒會在使用者指定的檔案名發生網路共用違規時通知您的攔截程式。如果您設定 OFN_EXPLORER 旗標，對話盒會將 CDN_SHAREVIOLATION 訊息傳送至攔截程式。如果您未設定 OFN_EXPLORER，對話方塊會將 SHAREVISTRING 已註冊的訊息傳送至攔截函式。
OFN_NOREADONLYRETURN
8000h		傳回的檔案未選取「唯讀」複選框，而且不在受寫入保護的目錄中。
OFN_NOTESTFILECREATE
10000h		如果應用程式將檔案儲存在 create-nonmodify 共用網路上，則應該指定此旗標；此時，程式庫不會檢查寫入保護、完整磁片、開啟的磁片磁碟機門或網路保護。
OFN_NONETWORKBUTTON
20000h		不顯示「網路」按鈕。但總管風格左側「位置列」（原文是「places bar」，也翻譯成「常用位置列」）中的網路，仍會顯示。
OFN_NOLONGNAMES
40000h		對於舊風格的對話盒，此旗標會使用短檔名格式（8.3 格式）。總管風格對話盒會忽略此旗標，一律顯示長檔名。
OFN_EXPLORER
80000h		使對話盒採「總管風格」（Explorer-style）顯示其畫面如圖二。這是預定的旗標，也就是不管有沒有在 Flags 中指定 OPN_EXPLORER 都會採用這種風格。
另一種稱為舊風格（old-style），如圖四。Flags 不含 OPN_EXPLORER，但含有 OFN_ALLOWMULTISELECT，就會使用舊風格。有關舊風格，還有更多資訊請參閱註一。
OFN_NODEREFERENCELINKS
100000h		指示對話盒傳回所選捷徑（.LNK）的路徑和檔案名檔案；如果未指定此值，傳回的是捷徑是真實檔案的路徑和檔案名。
OFN_LONGNAMES
200000h		此旗標讓舊風格對話盒使用長檔名；若未設此旗標，或設置 OFN_ALLOWMULTISELECT 旗標，舊風格對話盒會使含有空格的檔案名採用短檔案名（8.3 格式）。總管風格對話盒會忽略此旗標，並一律顯示長檔名。
OFN_ENABLEINCLUDENOTIFY
400000h		當使用者開啟資料夾時，會導致對話盒將 CDN_INCLUDEITEM 通知碼傳送至攔截程式。對話盒會針對新開啟的資料夾中的每個項目傳送通知碼，藉由這通知碼，應用程式可以控制對話盒在清單盒控制項中顯示哪些項目。
OFN_ENABLESIZING
800000h		設定 OFN_ENABLESIZING 後能夠使用滑鼠或鍵盤來調整對話盒大小。但是具有「總管風格」的開啟舊檔或另存新檔對話盒允許調整對話盒大小，而不論是否設定了此旗標。只有在自行撰寫的掛鉤函式或自訂範本時，才需要此旗標。舊風格對話盒不允許調整大小，不論是否設定了此旗標。
OFN_FORCESHOWHIDDEN
10000000		強制顯示系統檔案和隱藏檔案，從而覆蓋使用者設定的「顯示或不顯示隱藏文件」選項。然而，不會顯示同時為系統和隱藏屬性的檔案。
⑮、nFileOffset：使用者選定好檔案之後，系統會把檔名位於 lpstrFile 的第幾個字元填入此欄位，由零開始計數。例如 lpstrFile 所指位址的完整檔名是「"E:\TST\MYCODE.ASM",0」，那麼 nFileOffset 為 7。如果使用者選擇了多個檔案，那麼 nFileOffset 指的是第一個檔案的檔名位於第幾個字元。
⑯、nFileExtension：使用者選定好檔案之後，系統會把副檔名位於 lpstrFile 的第幾個字元填入此欄位，由零開始計數。例如 lpstrFile 所指位址的完整檔名是「"E:\TST\MYCODE.ASM",0」，那麼 nFileExtension 為 14。如果使用者選擇了多個檔案，那麼系統不使用 nFileExtension。
⑰、lpstrDefExt：預設副檔名的位址，如果副檔名超過三個字元，那麼僅前面三個字元有效。副檔名前不須加上「.」，系統會自行添加；如果副檔名前有「.」，那麼系統會把「.」扣除，而取扣除「.」之後的前三個字元為副檔名。
⑴、如果 lpstrDefExt 已設好預設副檔名位址，使用者於通用對話盒的編輯框輸入檔案名稱，有底下兩種情形：
⒜、使用者沒輸入副檔名，那麼系統會把檔案名稱視為主檔名，並自動在後面加上 lpstrDefExt 位址上的副檔名。
⒝、使用者有輸入副檔名但與 lpstrDefExt 所指定的不同，那麼 lpstrFile 所指的位址存入的是使用者輸入的檔名，且會於 Flags 欄位設定 OFN_EXTENSIONDIFFERENT。
⑵、如果 lpstrDefExt 設為零，使用者於通用對話盒的編輯框輸入沒有副檔名的檔案名稱，那麼在 lpstrFile 所指的檔名就只有主檔名，系統不會自動於後加上副檔名。
⑱、lCustData：應用程式自行定義的資料，可藉由 WM_INITDIALOG 訊息傳給攔截程式，攔截函式收到 WM_INITDIALOG 訊息，其中 lParam 會有 OPENFILENAME 結構體的位址，從這兒可以得到 lCustData 中自行定義的資料。
⑲、lpfnHook：攔截函式位址，只有在 Flags 欄位包含 OFN_ENABLEHOOK 旗標，lpfnHook 才有效。攔截函式可使「開啟舊檔」或「另存新檔」對話盒處理控制項的輸入，或添加額外的功能。見攔截函式一節。
⑳、lpTemplateName：對話盒面板名稱的位址，或對話盒面板識別碼，不論是哪一種都是在 hInstance 欄位所指定模組代碼中的資源內。只有在 Flags 欄位包含 OFN_ENABLETEMPLATE 旗標，lpTemplateName 才有效。如果 Flags 同時設定 OFN_EXPLORER，系統會使用此欄位所指定的對話盒面板來建立對話盒，所建立的對話盒是開啟舊檔或另存新檔對話盒的子對話盒，詳細情形見下一章。如果未設定 OFN_EXPLORER，系統也使用此欄位所指定的對話盒面板來建立對話盒，但卻是取代舊風格的對話盒。
㉑、_WIN32_WINNT GE 500h：_WIN32_WINNT GE 500h 並非 OPENFILENAME 的欄位，而是條件組譯判斷式，它的意義是如果 _WIN32_WINNT（_WIN32_WINNT 是 Windows 版本）大於或等於 500h，才組譯 IF 和 ENDIF 之間的程式碼。Windows 版本很複雜，可參閱註二。Windows 版本為 NT 5.00 的是 Windows 2000，也就是在 Windows 2000 及其更新的版本才支援底下㉒∼㉔三個欄位。
㉒、pvReserved：保留，應設為 0。
㉓、dwReserved：保留，應設為 0。
㉔、FlagsEx：用於初始化對話盒的擴充旗標，可以是零或 OFN_EX_NOPLACESBAR（OFN_EX_NOPLACESBAR 等於 1）。如果把 FlagsEx 設為 OFN_EX_NOPLACESBAR，那麼不顯示對話盒左邊的「位置列」，但只有在 Windows XP 及更早的作業系統上開發的應用程式有效。

WM_NOTIFY 訊息

第二十章提過的標準控制項能發出 WM_COMMAND 訊息，但有些控制項不發出 WM_COMMAND 訊息，而是發出 WM_NOTIFY 訊息，例如通用控制項（common controls）以及在開啟舊檔或另存新檔通用對話盒中的「說明」按鈕就是如此。

WM_NOTIFY 訊息的 wParam 是發出 WM_NOTIFY 訊息的控制項識別碼（identifier），識別碼並不一定是唯一的，所以應用程式應該使用 NMHDR 結構體中的 hwndFrom 或 idFrom 欄位來識別控制項。

WM_NOTIFY 訊息的 lParam 是一個結構體的位址，不同控制項在 lParam 所指位址上的結構體不同，例如清單檢視控制項（list view）的結構體是 NMLISTVIEW，開啟舊檔或另存新檔通用對話盒中的「說明」按鈕的結構體是 OFNOTIFY。OFNOTIFY 的各個欄位如下：（注意！OFNOTIFY 結構體有對齊值 QWORD，WinInc 在 COMMDLG.INC 中遺漏對齊值必須更正才能正確執行）

OFNOTIFY    STRUCT  QWORD
  hdr       NMHDR   <>  ;NMHDR 結構體
  lpOFN     DQWORD  ?   ;OPENFILENAME 結構體位址
  pszFile   LPSTR   ?   ;檔案名稱位址
OFNOTIFY    ENDS

底下說明 OFNOTIFY 的各欄位：

①、hdr：hdr 是一個稱為 NMHDR 的結構體。不論 WM_NOTIFY 訊息是由哪一種控制項發出，其 lParam 所指的結構體雖不同，但是不論是哪一種結構體，其第一個欄位必定是一個稱為 NMHDR 的結構體。NMHDR 結構體的各欄位如下（NMHDR 是 notification message header 的意思）：
NMHDR       STRUCT
  hwndFrom  HWND    ?   ;發出 WM_NOTIFY 訊息的控制項代碼
  idFrom    DWORD   ?   ;發出 WM_NOTIFY 訊息的控制項識別碼
  code      DWORD   ?   ;通知碼
NMHDR       ENDS
在 NMHDR 欄位中的 code，稱為通知碼，系統會把使用者的操作方法通知給對話盒函式，不同的控制項有不同的操作方法，所以有不同的通知碼。例如當使用者按下開啟舊檔或另存新檔通用對話盒中的「說明」按鈕時，code 欄位就是 CDN_HELP。
雖然不同的控制項會發出不同的通知碼，但是底下的八種通知碼是每一種通用控制項都會發出的：
通知碼說明
NM_CLICK使用者在通用控制項按下鬆開滑鼠左鍵
NM_DBLCLK使用者在通用控制項連續兩次按下鬆開滑鼠左鍵
NM_RCLICK使用者在通用控制項按下鬆開滑鼠右鍵
NM_RDBLCLK使用者在通用控制項連續兩次按下鬆開滑鼠右鍵
NM_RETURN使用者在通用控制項擁有輸入焦點時，按下鍵盤上的「Enter」鍵
NM_SETFOCUS通用控制項獲得輸入焦點
NM_KILLFOCUS通用控制項失去輸入焦點
NM_OUTOFMEMORY沒有足夠的記憶體操作通用控制項
當使用者操作開啟舊檔或另存新檔時，它們也會以攜帶著不同的通知碼發送給攔截函式，這些通知碼見下一章。
②、lpOFN：lpOFN 是 OPENFILENAME 結構體位址，此結構體就是呼叫 GetOpenFileName 或 GetSaveFileName 時的參數。
③、pszFile：檔名位址，此檔名是發生網路共用違規的檔名。此欄位只有適用於 CDN_SHAREVIOLATION 通知碼。

因為 OFNOTIFY 結構體是由系統經由 WM_NOTIFY 訊息的 lParam 參數指定的，並非由應用程式自行定義的，存取 OFNOTIFY 結構體就會比較麻煩。

通常會用 ASSUME 假指令宣告某個 64 位元的暫存器對應此結構體起始位址，再將此暫存器之值設為 lParam，這樣該暫存器就是結構體的起始位址，然後就能由一般存取結構體的方式存取各欄位。如果不須再存取該結構體，須取消此暫存器對應的結構體的宣告。例如底下的例子是以 R11 指向 OFNOTIFY 結構體的起始位址，假如要存取 NMHDR 中的 code 或其他欄位也不困難，見下面第三列，過程如下：

        ASSUME  r11:PTR OFNOTIFY
        mov     r11,lParam
        mov     eax,[r11].hdr.code
         ⁝
        ASSUME  r11:NOTHING

攔截函式（Hook Procedure）

攔截函式原文為 hook procedure，也翻譯成掛鉤函式，是一種應用程式定義的回呼函式，它能監視或處理系統發送到對話盒的訊息和事件，也用於自訂對話盒的行為。更詳細的說，攔截程式與 OPENFILENAME 結構體中，lpTemplateName 欄位所指定的子對話盒面板搭配後，可以在「開啟舊檔」或「另存新檔」對話盒添加新的控制項，以新增額外的功能。攔截函式的原型如下，跟視窗函式或對話盒函式一樣：

函式名稱 PROC   hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
.if uMsg==訊息甲
   ⁝
.elseif uMsg==訊息乙
   ⁝
.else
        xor     rax,rax ;未經攔截函式處理過的訊息返回零
        ret
.endif
        mov     rax,1   ;已由攔截函式處理過的訊息返回一
        ret
函式名稱 ENDP

要建立攔截函式，必須在 OPENFILENAME 結構體的 Flags 欄位含有 OFN_ENABLEHOOK，並且在 lpfnHook 欄位所指定的攔截函式位址，缺一不可。

如果應用程式建立了總管風格的開啟舊檔或另存新檔通用對話盒，並且也提供了攔截程式，那麼系統會依據 OPENFILENAME 中 lpTemplateName 欄位所指定的對話盒面板，建立通用對話盒的子對話盒；而 lpfnHook 欄位所指定的攔截函式，就作為這個子對話盒的對話盒函式。假如應用程式只提供了攔截程式，但沒有指定對話盒面板，那麼系統會自行建立一個預設的子對話盒，而 lpfnHook 欄位所指定的攔截函式，就作為這個預設子對話盒的對話盒函式。

攔截函式的行為與對話盒函式一模一樣。對於應用程式感興趣的訊息加以處理，處理完畢把回傳值設為一返回系統，告知系統已處理過該訊息；對不感興趣的訊息，把回傳值設為零返回系統，告知系統並未處理該訊息，系統會負責處理。

例子：VIEWBMP4

第十五章介紹了 VIEWBMP2、VIEWBMP3，它們都是由命令提示字元輸入位元圖檔案名稱，然後再把位元圖顯示在工作區上，這並不符合現代人使用的習慣。這裏介紹的 VIEWBMP4，將改變這個流程。當 VIEWBMP4 執行後，使用者可以由主功能表選擇「檔案」→「開啟」（見下圖五），這時會彈出「開啟舊檔」通用對話盒（見下圖六）。使用者可於對話盒內挑選想觀看的位元圖，也可切換到別的目錄選擇其他目錄的位元圖，
按下「開啟舊檔」按鈕後，就能觀看位元圖了。

注意到上面圖六中的右下角有個「說明」按鈕，這是因為在呼叫 GetOpenFileName 時，其參數 OPENFILENAME 的 Flags 欄位含有 OFN_SHOWHELP 旗標。當使用者按下這個按鈕時，會產生一個視窗，說明此程式的功用。正因如此，所以必須有個攔截函式處理按下「說明」按鈕的訊息，這也造成 Flags 欄位需要有 OFN_ENABLEHOOK，同時 lpfnHook 欄位必須是攔截函式位址。

原始程式

底下是 VIEWBMP4.EXE.MANIFEST：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
  <assemblyIdentity
    type="win32"
    name="AtHome.Wanker.ViewBmp4"
    version="1.0.0.0"
    processorArchitecture="amd64"
  />
  <dependency>
    <dependentAssembly>
      <assemblyIdentity
        type="win32"
        name="Microsoft.Windows.Common-Controls"
        version="6.0.0.0"
        processorArchitecture="amd64"
        publicKeyToken="6595b64144ccf1df"
        language="*"
      />
    </dependentAssembly>
  </dependency>
</assembly>

底下是 VIEWBMP4.RC：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
#include "RESOURCE.H"
#define VBMENU   2000
#define IDM_OPEN 2001
#define IDM_QUIT 2002
#define IDM_HELP 2003
VBMENU  MENU
BEGIN
  POPUP "檔案"
    BEGIN
      MENUITEM "開啟",IDM_OPEN
      MENUITEM "離開",IDM_QUIT
    END
  MENUITEM "說明",IDM_HELP
END

#define RT_MANIFEST 24
1       RT_MANIFEST MOVEABLE PURE "VIEWBMP4.EXE.MANIFEST"

2004    ICON    EYE.ICO

底下是 VIEWBMP4.ASM：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
OPTION  CASEMAP:NONE
OPTION  WIN64:3
OPTION  LITERALS:ON

_WIN32_WINNT EQU 500h   ;使用Windows 2000及其以後的OPENFILENAME版本
UNICODE  EQU    1       ;使用UNICODE編碼字元
VBMENU   EQU    2000
IDM_OPEN EQU    2001
IDM_QUIT EQU    2002
IDM_HELP EQU    2003

INCLUDE         WINDOWS.INC
INCLUDELIB      GDI32.LIB
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB
INCLUDELIB      COMDLG32.LIB
;***************************************************************************************************
.CONST
szClass DW  "VIEWBMP",0
szTitle DW  89c0h,770bh,4f4dh,5143h,5716h,0             ;觀看位元圖
szRem   DW  89c0h,770bh,42h,4dh,50h,5716h,7247h,6a94h   ;觀看BMP圖片檔
        DW  7684h,7c21h,55aeh,7a0bh,5f0fh,3002h,0       ;的簡單程式。
szSure  DW  78bah,5b9ah,9000h,51fah,55ceh,0ff1fh,0      ;確定退出嗎？
szAsk   DW  8a62h,554fh,0         ;詢問
szNote  DW  8aaah,660eh,0         ;說明
szExt   DW  2ah,2eh,62h,6dh,70h,0 ;"*.bmp",0
;底下的篩選字串是「"位元圖(*.bmp)",0,"*.bmp",0,"所有檔案(*.*)",0,"*.*",0,0」
szFiltr DW  4f4dh,5143h,5716h,"(*.bmp)",0,"*.bmp",0,6240h,6709h,6a94h,6848h,"(*.*)",0,"*.*",0,0
;***************************************************************************************************
.DATA
hInst   DQ      ?
ofn     OPENFILENAME <>
szFile  DW  256 DUP (0) ;儲存自GetOpenFileName返回後的完整檔案名稱
;***************************************************************************************************
.CODE
;---------------------------------------------------------------------------------------------------
HookPrc PROC    hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
.if uMsg==WM_NOTIFY
        ASSUME  r11:PTR OFNOTIFY
        mov     r11,lParam
        mov     eax,[r11].hdr.code
  .if eax==CDN_HELP
    ;處理使用者按下「說明」按鈕
        invoke  MessageBox,hWnd,OFFSET szRem,OFFSET szNote,MB_OK or MB_ICONINFORMATION
  .endif
        ASSUME  r11:NOTHING
.else
        xor     rax,rax ;未處理的訊息，回傳值設為零
        ret
.endif
        mov     rax,1   ;已處理的訊息，回傳值設為一
        ret
HookPrc ENDP
;---------------------------------------------------------------------------------------------------
WndProc PROC    hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL   hBitmap:HBITMAP,rcClnt:RECT,bitmap:BITMAP,hDC:HDC,hdcMem:HDC
.if uMsg==WM_COMMAND
  .if r8w==IDM_OPEN
    ;建立開啟舊檔對話盒，供使用者選擇檔案
        mov     r11,hWnd
        mov     r10,hInst
        lea     r9,szFiltr
        lea     r8,szFile
        lea     rdx,szExt
        mov     ofn.lStructSize,SIZEOF ofn
        mov     ofn.hwndOwner,r11
        mov     ofn.hInstance,r10
        mov     ofn.lpstrFilter,r9
        mov     ofn.lpstrCustomFilter,0
        mov     ofn.nFilterIndex,1
        mov     ofn.lpstrFile,r8
        mov     ofn.nMaxFile,LENGTHOF szFile
        mov     ofn.lpstrFileTitle,0
        mov     ofn.nMaxFileTitle,0
        mov     ofn.lpstrInitialDir,0
        mov     ofn.lpstrTitle,0
        mov     ofn.Flags,OFN_SHOWHELP or OFN_EXPLORER or OFN_ENABLEHOOK or OFN_HIDEREADONLY
        mov     ofn.lpstrDefExt,rdx
        lea     r10,HookPrc
        mov     ofn.lCustData,0
        mov     ofn.lpfnHook,r10
        mov     ofn.lpTemplateName,0
        mov     ofn.pvReserved,0
        mov     ofn.dwReserved,0
        mov     ofn.FlagsEx,0
        invoke  GetOpenFileName,ADDR ofn
        mov     hBitmap,RV(LoadImage,hInst,ADDR szFile,IMAGE_BITMAP,0,0,LR_LOADFROMFILE)
    ;如果無法載入使用者選擇的位元圖，RAX會等於零，不做處理返回
        or      rax,rax
        jz      rtn
        invoke  GetObject,hBitmap,SIZEOF BITMAP,ADDR bitmap
        mov     r10d,bitmap.bmWidth     ;R10D＝位元圖寬度
        mov     r11d,bitmap.bmHeight    ;R11D＝位元圖高度
    ;計算能容納整張位元圖的視窗需要最小寬度與高度
        mov     rcClnt.left,0
        mov     rcClnt.top,0
        mov     rcClnt.right,r10d
        mov     rcClnt.bottom,r11d
        invoke  AdjustWindowRect,ADDR rcClnt,WS_CAPTION or WS_SYSMENU,0
        mov     r10d,rcClnt.right
        mov     r11d,rcClnt.bottom
        sub     r10d,rcClnt.left          ;R10D＝計算完成後的視窗寬度
        sub     r11d,rcClnt.top           ;R11D＝計算完成後的視窗高度
        invoke  MoveWindow,hWnd,50,50,r10d,r11d,0
    ;顯示使用者所選擇的位元圖
        mov     hDC,RV(GetDC,hWnd)
        mov     hdcMem,RV(CreateCompatibleDC,hDC)
        invoke  SelectObject,hdcMem,hBitmap
        invoke  BitBlt,hDC,0,0,bitmap.bmWidth,bitmap.bmHeight,hdcMem,0,0,SRCCOPY
        invoke  DeleteDC,hdcMem
        invoke  ReleaseDC,hWnd,hDC
  .elseif r8w==IDM_HELP
        invoke  MessageBox,hWnd,OFFSET szRem,OFFSET szNote,MB_OK or MB_ICONINFORMATION
  .elseif r8w==IDM_QUIT
        invoke  SendMessage,hWnd,WM_CLOSE,0,0
  .endif

.elseif uMsg==WM_DESTROY
        invoke  PostQuitMessage,0

.elseif uMsg==WM_CLOSE
close:  cmp     RV(MessageBox,0,ADDR szSure,ADDR szAsk,MB_YESNO or MB_ICONQUESTION),IDYES
        jne     rtn
        invoke  DestroyWindow,hWnd

.elseif uMsg==WM_DESTROY
        invoke  PostQuitMessage,0

.else
        invoke  DefWindowProc,hWnd,uMsg,wParam,lParam
        ret

.endif
rtn:    xor     eax,eax
        ret
WndProc ENDP
;---------------------------------------------------------------------------------------------------
main    PROC
        LOCAL   hwnd:HWND,msg:MSG,wc:WNDCLASSEX
        lea     rdx,WndProc
        mov     hInst,RV(GetModuleHandle,0)
        mov     wc.cbSize,SIZEOF WNDCLASSEX
        mov     wc.style,CS_HREDRAW or CS_VREDRAW
        mov     wc.lpfnWndProc,rdx
        mov     wc.cbClsExtra,0
        mov     wc.cbWndExtra,0
        mov     wc.hInstance,rax
        mov     wc.hIcon,RV(LoadIcon,hInst,2004)
        mov     wc.hIconSm,rax
        mov     wc.hCursor,RV(LoadCursor,NULL,IDC_ARROW)
        mov     wc.hbrBackground,COLOR_WINDOW+1
        mov     wc.lpszMenuName,VBMENU
        lea     rdx,szClass
        mov     wc.lpszClassName,rdx
        invoke  RegisterClassEx,ADDR wc
        mov     hwnd,RV(CreateWindowEx,0,ADDR szClass,OFFSET szTitle,WS_OVERLAPPEDWINDOW,\
                50,50,400,200,0,0,hInst,0)
        invoke  ShowWindow,hwnd,SW_SHOWNORMAL
        invoke  UpdateWindow,hwnd
.while TRUE
        invoke  GetMessage,ADDR msg,0,0,0
.break .if rax==0
        invoke  TranslateMessage,ADDR msg
        invoke  DispatchMessage,ADDR msg
.endw
        invoke  ExitProcess,0
main    ENDP
;***************************************************************************************************
END      main

把 EYE.ICO、VIEWBMP4.EXE.MANIFEST、VIEWBMP4.RC、VIEWBMP4.ASM 四個檔案放在同一子目錄（例如「E:\HomePage\SOURCE\Win64\VIEWBMP\」），開啟「命令提示字元」，輸入下面指令製作 VIEWBMP4.EXE：

Microsoft Windows [版本 6.1.7601]
Copyright (c) 2009 Microsoft Corporation.  All rights reserved.

C:\Users\wanker>uasm [Enter] →執行 UASM.BAT 批次檔，設定組譯及連結環境，省了許多打字輸入

C:\Users\wanker>SET INCLUDE=C:\UASM\Include

C:\Users\wanker>SET LIB=C:\UASM\lib64

C:\Users\wanker>SET PATH=C:\UASM;C:\UASM\bin64;C:\Windows\system32;C:\Windows;C:
\Windows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\Program Fi
les (x86)\UltraEdit-32

C:\Users\wanker>E:

E:\>CD E:\HOMEPAGE\SOURCE\WIN64
LINK=/SUBSYSTEM:WINDOWS /DEBUG →到此 UASM.BAT 已執行完畢

E:\HomePage\SOURCE\Win64>cd VIEWBMP [Enter] →設定 VIEWBMP4.ASM 所在子目錄為當前目錄

E:\HomePage\SOURCE\Win64\VIEWBMP>uasm64 -win64 VIEWBMP4.ASM [Enter] →組譯
UASM v2.56, Oct 27 2022, Masm-compatible assembler.
Portions Copyright (c) 1992-2002 Sybase, Inc. All Rights Reserved.
Source code is available under the Sybase Open Watcom Public License.

VIEWBMP4.ASM: 169 lines, 3 passes, 121 ms, 0 warnings, 0 errors →沒有錯誤，成功組譯完成

E:\HomePage\SOURCE\Win64\VIEWBMP>rc VIEWBMP4.RC [Enter] →編譯資源描述檔
Microsoft (R) Windows (R) Resource Compiler Version 10.0.10011.16384
Copyright (C) Microsoft Corporation.  All rights reserved.
    →沒有訊息，代表編譯成功並生成 VIEWBMP4.RES 資源檔

E:\HomePage\SOURCE\Win64\VIEWBMP>link VIEWBMP4.OBJ VIEWBMP4.RES [Enter] →連結
Microsoft (R) Incremental Linker Version 14.25.28614.0
Copyright (C) Microsoft Corporation.  All rights reserved.

/SUBSYSTEM:WINDOWS /DEBUG →沒有訊息，代表 VIEWBMP4.EXE 成功製作好了

E:\HomePage\SOURCE\Win64\VIEWBMP>

如欲執行 VIEWBMP4.EXE，只須在命令提示字元輸入「VIEWBMP4」再按下「ENTER」鍵就可以見到執行畫面。VIEWBMP4 所需原理，在前面都已敘述過了，這裏就不多說了。

註解

註一：舊風格（Old-Style）與總管風格（Explorer-Style）

「舊風格」的對話盒首次出現於 Windows 3.1 時期的「開啟舊檔」與「另存新檔」對話盒，這種對話盒外觀如下圖： 到了 Windows 95 發表之後，才有了「總管風格」。在外觀上，這兩種風格最大的差別在於總管風格左側多了位置列（places bar，也翻譯成「常用位置列」，見圖二綠色框），除此之外總管風格還有許多能讓使用者更快速的選擇常用到的資料夾。（參考圖一及圖二）

除了外觀不同之外，處理這兩種風格的程式碼也不同，這大概是因為為了相容性。在 Windows 3.1 的時代還不支援長檔名，所以採用舊風格的對話盒，會呼叫為 Windows 3.1 所撰寫的程式碼。這兩種風格的對話盒還有許多不同之處，整理如下表：

功能舊風格總管風格
長檔案名支援不支援支援
是否可調整對話盒大小否是
多選檔案時檔名分隔符號空白空字元
自定義對話盒面板完全取代現有對話盒嵌入到現有對話盒

那麼系統如何決定對話盒使用舊風格還是總管風格？它由底下三點決定：

  1. 如果指定了 OFN_EXPLORER，則使用總管風格。
  2. 如果未指定 OFN_EXPLORER，但指定了 OFN_ENABLETEMPLATE、OFN_ENABLETEMPLATEHANDLE、OFN_ENABLEHOOK 或 OFN_ALLOWMULTISELECT 中的任一個旗標，則使用舊風格。
  3. 如果以上條件都不符合，則使用總管風格。

由以上看來，如果應用程式需要攔截函式或自訂對話盒面板，或需要挑選多個檔案時，同時又要使用總管風格，才需要設置 OFN_EXPLORER 旗標，否則 OFN_EXPLORER 旗標式可以省略的。

如果應用程式要使用舊風格，就得省略 OFN_EXPLORER，並提自訂對話盒面板或攔截函式；如果既要使用舊風格，又不提供自訂對話盒面板，那麼可以提供一個始終返回 FALSE 的攔截函式即可。

註二：Windows 的版本

自民國 74 年，微軟發表 Winodws 1.0 之後開啟 Windows 作業系統的黃金時代，而後隨著使用者增多與時代演進，微軟針對不同用戶進而發展出許多版本。如果不考慮行動裝置的 Windows CE，Windows 種類大致可分為三種：

①、16 位元：Windows 1.0、Windows 2.x、Windows 3.x。
②、Windows 95 核心的 Windows：
Windows 名稱959898 SEMe
Windows 95 核心版本4.00.9504.10.19984.10.22224.90.3000
③、NT 核心的 Windows：
Windows 名稱3.13.53.514.02000XPVista788.11011
NT 核心版本3.13.53.514.05.05.16.06.16.26.310.0.1904510.0.26100

由上表來看，在 Windows 2000 或之後的版本才支援 pvReserved、dwReserved、FlagsEx 這三個欄位；Windows 95/98/98SE/Me 都不支援。