第二十九章　通用控制項：標籤控制項

什麼是通用控制項（Common Controls）？

在 Windows 1.0 的時代，系統中就已經使用按鈕、編輯框、複合框等控制項（稱為標準控制項或使用者控制項），來加強使用者界面，讓電腦的使用不再是冷冰冰的機器，增進了不少親和力。到了 Windows 95 時，這些標準控制項仍保留繼續使用，在第二十∼二十二章，小木偶已簡單介紹過了。

除了這些使用較頻繁的標準控制項之外，還有另外一類是在 Windows 95 之後，才加入的控制項，稱為通用控制項，包含 animation、header、list-view、month calendar、progress bar、status bar、syslink、tab、tooltip、trackbar、tree-view、up-down 等控制項。處理這些控制項的 API 都包含在 COMCTL32.DLL 裏，其版本是 4.00 版，隨著 Windows 95/NT 4.0 原版光碟販售。

隨時間流逝，每發佈新版本的 IE 或新版本的 Windows ，COMCTL32.DLL 也隨之更新，每次更新有時也會新增一些通用控制項。經過歷年來逐漸增加，到 Windows XP 時已經增為約 23 個通用控制項了（參考賴榮樞先生的 Windows XP 程式設計概論），版本為 6.00 版。

即使這些通用控制項之間的外觀與功用相差十萬八千里，但從程式設計師的眼光看來，通用控制項和標準控制項一樣，都是子視窗，只是不同的控制項有特殊的風格（style）、訊息（message）與通知碼（notification）。下圖一是常見的通用控制項：

載入通用控制項

由於通用控制項的數量太多，假如系統一啟動，就把所有的通用控制項載入並註冊，是很浪費資源的，所以微軟並沒有這樣做。這意味著，要使用它們之前，必須先確定是否已經載入記憶體。程式可以呼叫 InitCommonControls 或 InitCommonControlsEx，它們的原型是：

call    InitCommonControls

invoke  InitCommonControlsEx,\
        lpInitCtrls     ; pointer to INITCOMMONCONTROLSEX

InitCommonControls 沒有參數，因此只要執行了 InitCommonControls 就會把所有的通用控制項載入。InitCommonControlsEx 有一個參數，此參數是位址指標，指向稱為 INITCOMMONCONTROLSEX 結構體的位址，其欄位如下：

INITCOMMONCONTROLSEX    STRUC
  dwSize                DWORD   ?
  dwICC                 DWORD   ?
INITCOMMONCONTROLSEX    ENDS

dwSize 是 INITCOMMONCONTROLSEX 結構體的大小，單位是位元組；必須在呼叫 InitCommonControlsEx 之前就填入適當的大小，系統藉此分辨版本。dwICC 是指要初始化的通用控制項，其值可以是下表中最右欄的其中之一：

表一：常見的通用控制項
控制項視窗類別說明dwICC
動畫控制項
animation		SysAnimate32 動畫控制項可顯示 AVI。AVI 是一系列位元圖畫面，類似電影。但動畫控制項只能顯示不包含音訊的 AVIICC_ANIMATE_CLASS
80h
標題欄控制項
header		SysHeader32標題欄通常位於資料上方，區分不同類型的資料。它可以是其他控制項的子視窗，例如清單盒控制項ICC_LISTVIEW_CLASSES
1
清單檢視控制項
list-view		SysListView32清單檢視用於顯示同類項目的子視窗，而且提供多種顯示方式，它比清單盒控制項更有彈性ICC_LISTVIEW_CLASSES
1
月曆控制項
month calendar		SysMonthCal32月曆控制項提供類似月曆的介面，供使用者簡單明白地輸入或選取日期ICC_DATE_CLASSES
100h
進度列控制項
progress bar		msctls_progress32進度列是應用程式用來顯示冗長作業的進度，讓使用者知道電腦還在處理，並非當機ICC_PROGRESS_CLASS
20h
狀態列控制項
status bar		msctls_statusbar32狀態列是通常位於父視窗底部的水平子視窗，應用程式可以在狀態列上顯示各種狀態資訊ICC_BAR_CLASSES
4
超連結控制項
syslink		SysLink超連結控制項可在視窗中內嵌超文字連結，讓使用者快速獲取相關資料ICC_LINK_CLASS
8000h
標籤控制項
tab		SysTabControl32標籤控制項類似筆記本的分隔頁或檔案櫃中的標籤，藉由標籤控制項，使用者可以快速切換到另一個對話盒ICC_TAB_CLASSES
8
工具提示控制項
tooltip		Tooltips_class32當使用者將滑鼠指標停在某些區域時，有時會彈出一個小小的矩形方塊，提示使用者某些資訊ICC_BAR_CLASSES
4
滑動軸控制項
trackbar		msctls_trackbar32滑動軸上通常有滑桿及刻度，使用者可以把滑鼠移到滑桿上按住左鍵不放，將滑桿移到適當刻度上，以對電腦下達指令ICC_BAR_CLASSES
4
樹狀檢視控制項
tree-view		SysTreeView32樹狀檢視通常用於顯示具有階層性質的資料，例如磁碟上的檔案和目錄ICC_TREEVIEW_CLASSES
2
上下控制項
up-down		msctls_updown32上下控制項是一對箭頭按鈕，分別指向上及向下，使用者可以用滑鼠左鍵點選它們，以遞增或遞減某種數值ICC_UPDOWN_CLASS
10h

另外，dwICC 也可以是 ICC_STANDARD_CLASSES、ICC_WIN95_CLASSES 兩種，前者是載入固有的標準控制項，包含靜態控制項、編輯框、按鈕、清單盒、下拉式方塊控制項、捲動軸控制項。後者可以一次就載入動畫、標題欄、快捷鍵、清單檢視、進度列、狀態列、標籤、工具提示、工具列、滑動軸、樹狀檢視和上下控制項，而不需分別載入。

InitCommonControlsEx 具有累積性。意思是如果第一次呼叫 InitCommonControlsEx 時，dwICC 參數是 ICC_ANIMATE_CLASS，第二次卻是 ICC_PROGRESS_CLASS，最後系統會載入動畫控制項與進度列控制項，不會消除先載入的動畫控制項。另外上表中，有些 dwICC 參數值會載入兩個或兩個以上的通用控制項，例如 ICC_TAB_CLASSES 會載入標籤與工具提示兩種控制項。

表一未列出來的工具列容器控制項（Rebar Controls）、日期時間挑選控制項（Date And Time Picker）、IP 控制項（IP Address Control）、換頁控制項（Pager Controls）、擴展複合框這五個通用控制項（Combo BoxEx Controls），必須由 InitCommonControlsEx 載入，而無法由 InitCommonControls 載入。

因為通用控制項種類很多，本章僅介紹一個通用控制項，標籤控制項，而且用一個例子來說明如何建立標籤控制項。

標籤控制項

標籤控制項各部名稱

標籤控制項依需求，分成數個標籤項目（或簡稱項目，item），每個標籤項目使分為兩部分：標籤（tab）與顯示區域（display area）。一般而言，標籤位於上方，顯示文字標題，這些文字也叫標籤文字；如有需求也能於標籤內顯示圖像。顯示區域通常位於標籤底下，而且不論有多少個標籤，顯示區域只有一個，它是所有標籤共用的。標籤控制項的工作區，包含了標籤、顯示區域，以及標籤右方的空白。

本章要介紹的例子稱為 HMS2S（HMS 是時、分、秒的意思），意思是此程式會把使用者輸入的時、分、秒轉換為總共多少秒，這是第一個功能；也能把使用者輸入的秒數，轉換成幾時幾分幾秒，此為第二個功能；第三個功能是說明。這三個功能恰好是標籤控制項的三個項目。見圖二：圖二中的「時分秒→秒」、「秒→時分秒」、「說明」都是標籤文字，而它們分別與前面圖像所圍住的矩形區域稱為標籤，在 HMS2S 中有三個標籤，以紫色框框住。系統以索引值代表這些標籤，索引值是以零開始，每往右一個標籤就增加一。例如「時分秒→秒」標籤文字與左邊的紫框黃字的 H 圖像合起來，是索引值為零的標籤；「秒→時分秒」與左邊的紫框黃字的 S 圖像合起來，是索引值為一的標籤……。標籤底下，用藍色框圍住的區域是顯示區域。

使用者用滑鼠左鍵點擊標籤，就能在這三個功能中切換，而顯示區域也會隨之切換成與其對應所需的畫面，這些畫面其實是標籤控制項的子對話盒。稍後再詳述。

建立標籤控制項

凡控制項都是子視窗，所以標籤控制項也不例外，它是另一個視窗的子視窗，姑且稱「另一個視窗」為主視窗。假如主視窗為一般視窗，通常是在呼叫 CreateWindowsEx 建立主視窗之後，再呼叫 CreateWindowsEx 建立標籤控制項，而且後者需指定視窗類別為「SysTabControl32」。

假如主視窗是對話盒，那麼可以在資源描述檔中定義「DIALOG」區塊，於此區塊中用「CONTROL」描述標籤控制項，最重要的是指定視窗類別為「SysTabControl32」；然後於組合語言原始程式中呼叫 DialogBoxParam 同時建立主對話盒以及標籤控制項。

不論哪一種情形，在這之前，都必須呼叫 InitCommonControls 或 InitCommonControlsEx，載入與標籤控制項相關的資料，以初始化標籤控制項。此外，在建立標籤控制項時，依需求可以指定不同的風格，有關標籤控制項的風格，可以查詢這兒。

建立標籤項目

當標籤控制項建立完成之後，接下來可以建立標籤項目。建立標籤項目的方法是呼叫 SendMessage，而第二個參數，訊息識別碼，必須是 TCM_SETIMAGELIST 訊息，程式碼如下：

invoke  SendMessage,hTab,TCM_INSERTITEM,iItem,pItem

其中 hTab 是標籤控制項代碼，此標籤控制項內會新添加標籤項目。iItem 是標籤項目索引，由零開始；假如新添加的項目索引並不是最後一個，其後還有項目，那麼新添加的項目會插入其中，原來被插入的與後面的都會往後退一號。例如原來標籤控制項有五個標籤項目，其索引值為 0、1、2、3、4。如果執行「invoke SendMessage,hTab,TCM_INSERTITEM,3,ADDR tci」，那麼原來索引值為 3、4 的項目會變為 4、5；原來 0、1、2 的項目仍不變；新添加的項目索引值為 3。

pItem 是 TCITEM 結構體的位址。如果成功建立新的項目，回傳值為新項目的索引；否則回傳值為－1。在這些參數裏，最重要的是如何設定 TCITEM 結構體的欄位。

除了對標籤控制項發出的 TCM_INSERTITEM 訊息會用到 TCITEM 之外，還有 TCM_GETITEM 或 TCM_SETITEM 訊息，也會用到 TCITEM。後兩則訊息分別是取得標籤項目的資料，以及設定標籤項目的資料。TCITEM 也稱為 TC_ITEM，其欄位如下：（注意！在 WinInc 中 TCITEM 的定義有誤，必須在 STRUCT 之後的對齊選項加上「8」才對）

TCITEM        STRUCT 8
  mask_       DWORD  ?  ;指定哪個欄位有效的旗標
  dwState     DWORD  ?  ;狀態
  dwStateMask DWORD  ?  ;遮罩不處理的狀態
  pszText     LPSTR  ?  ;字串位址
  cchTextMax  DWORD  ?  ;字串長度
  iImage      DWORD  ?  ;圖像索引
  lParam      LPARAM ?  ;應用程式自行定義的資料
TCITEM        ENDS

底下說明 TCITEM 個欄位的意義：

①、mask_：在 MSDN 文件中第一個欄位本是 mask，但與組合語言的運算子 mask 發生衝突（在 MASM 中，mask 用於處理紀錄，RECORD，內的運算），故 WinInc 將其改成 mask_，它可以是下表中各旗標的組合，它指定了 TCITEM 中哪些欄位有效。
旗標數值說明
TCIF_IMAGE2iImage 欄位有效
TCIF_PARAM8lParam 欄位有效
TCIF_RTLREADING4顯示 pszText 所指的字串時，其方向與父視窗文字反向
TCIF_STATE10hdwState 欄位有效
TCIF_TEXT1pszText 欄位有效
②、dwState：取得或設定標籤控制項的項目狀態時，mask_ 需包含 TCIF_STATE 旗標，再以 TCM_GETITEM 或 TCM_SETITEM 為參數呼叫 SendMessage。如果是前者，呼叫完成後此欄位會存有標籤項目的狀態；如果是後者，需在呼叫前設好 dwState，才能設定好標籤項目狀態。TCM_INSERTITEM 訊息會忽略此欄位，因為新建標籤項目時，不能同時設定狀態。
③、dwStateMask：遮罩位元，意思是指定那些位元會變更，而其他位元代表的狀態不變。只有位元為一，才會改變。TCM_INSERTITEM 訊息會忽略此欄位。
④、pszText：以零為結尾的字串位址，此字串為標籤文字。如果是呼叫 TCM_GETITEM 取得標籤文字時，那麼此位址為緩衝區位址，而這緩衝區用於接收標籤文字的字串。
⑤、cchTextMax：此欄位僅在取得標籤文字時有效，用於指定緩衝區大小，以字元為單位。
⑥、iImage：指定使用哪一個圖像，此欄位是在圖像列表（image list）中的索引值。
⑦、lParam：應用程式自行定義的資料，例如相對應的子對話盒代碼，可以在使用者切換項目時，於視窗函式中收到而顯現相對應的子對話盒。

標籤控制項的標籤狀態很少，有底下幾種，除了廢棄不用的 TCIS_HIDDEN，剩下兩種，每種狀態都用一個位元表示：

狀態數值說明
TCIS_BUTTONPRESSED1標籤呈現按鈕被按下的狀態，只有 TCS_BOTTOM 才有此狀態
TCIS_HIGHLIGHTED2標籤處於高亮度狀態
TCIS_HIDDEN1標籤處於隱藏狀態，但已廢棄不用

假如要設定第二個標籤為高亮度狀態，用以下程式碼設定：

        mov     tci.mask_,TCIF_STATE
        mov     tci.dwState,TCIS_HIGHLIGHTED
        invoke  SendMessage,hTab,TCM_SETITEM,2,ADDR tci

假設此標籤控制項有 TCS_BOTTOM 風格，而第二個標籤恰好處於按鈕被按下的狀態。執行上面程式時，tci.dwState 為 2，換算為二進位是 0000 0010，第一個位元為一表示設定高亮度，第零位元為零表示設定標籤按鈕鬆開。原本只是要讓第二個標籤以高亮度顯示，結果不僅達成了，還讓原本是處於按下狀態的標籤變成鬆開狀態，這就多此一舉而且不符合原來的目的。TCITEM 設置 dwStateMask 欄位，就是為了解決此問題。dwStateMask 的目是為了遮罩某些位元，不使其改變，要改變的位元將其設為一，不改變的位元設為零。所以正確程式如下：

        mov     tci.mask_,TCIF_STATE
        mov     tci.dwState,TCIS_HIGHLIGHTED
        mov     tci.dwStateMask,TCIS_HIGHLIGHTED
        invoke  SendMessage,hTab,TCM_SETITEM,2,ADDR tci

像 HMS2S 有三個項目，就得呼叫三次 SendMessage，每次都對標籤控制項發出 TCM_INSERTITEM 訊息，但 iItem 不同，TCITEM 內的 pszText 也指向不同的字串位址。底下的程式碼會在標籤控制項中建立一個索引值為零、名稱為「時分秒→秒」的標籤項目：

.DATA
tci     TCITEM  <>
szHms2s DB      "時分秒→秒",0
        ⁝
        mov     tci.mask_,TCIF_TEXT
        lea     r10,szHms2s
        mov     tci.pszText,r10
        INVOKE  SendMessage,hTab,TCM_INSERTITEM,0,ADDR tci

圖像列表

圖像列表（image list，也翻譯成圖像清單）是一種用來存儲和管理多個小圖像的物件，而這些小圖像通常用於標籤控制項、清單檢視等控制項。儲存在圖像列表內的小圖像，大小必須一致（例如都是 16×16 或都是 32×32 像素），儲存在圖像列表的圖像可以是位元圖（副檔名是 BMP）、圖示（副檔名是 ICO）或游標（副檔名是 CUR）。

建立圖像列表需呼叫 ImageList_Create，剛建立好的圖像列表內並無任何圖像，必須呼叫 ImageList_Add 或 ImageList_ReplaceIcon 才能在圖像列表中添加圖像，前者新增位元圖，後者新增圖示或游標。每新增一張圖像，系統會賦予圖像一個索引值，由零開始然後是 1、2、3……。索引值代表這張圖像，如果控制項要使用圖像列表中的圖像時，就以索引值表示。如果不再需要圖像列表，需呼叫 ImageList_Destroy 將其銷毀。

如果要在標籤項目的文字左邊顯示圖像，其步驟為：①呼叫 ImageList_Create 建立圖像列表、②在圖像列表中添加圖像、③以 TCM_SETIMAGELIST 為參數呼叫 SendMessage，設定與標籤控制項相關聯的圖像列表、④以 TCM_INSERTITEM 為參數呼叫 SendMessage，在這之前要設定 TCITEM 的 iImage 欄位、⑤不再需要圖像列表時銷毀它。

標籤控制項顯示區域內的子對話盒

前面提過，標籤控制項是主視窗的子視窗。而在標籤控制項內，位於顯示區域的地方，通常也會有許多控制項供使用者使用。這些控制項如何產生呢？事實上這些控制項都包含在對話盒內，而這個對話盒是標籤控制項的子視窗。這種關係可以想像成祖孫三代：主視窗→標籤控制項→子對話盒。因為每個標籤項目功能不同，子對話盒的內容也會不同，所以一個標籤項目需搭配一個子對話盒。

像本章的例子，見圖二的 HMS2S，主視窗是標題欄為「時分秒與秒的轉換」的視窗，標籤控制項是它的子視窗。而標籤控制項有三個標籤項目，各自有一個子對話盒，所以有三個子對話盒。第一個標籤是「時分秒→秒」，其子對話盒對應前述的第一個功能是將時分秒轉換成秒，例如 2 時 0 分 0 秒變成 7200 秒；第二個標籤是「秒→時分秒」，對應第二個功能是將秒轉換成時分秒，例如 86400 秒變成 24 時 0 分 0 秒；第三個標籤是說明，對應第三個功能，說明。

子對話盒是標籤控制項的子視窗，而且是在標籤控制項所在的矩形範圍內，要遵守下面幾項規則：

⑴、子對話盒可以在資源描述檔中以 DIALOG 或 DIALOGEX 區塊定義，但必須加上 WS_CHILD 風格，而且不可有 WS_POPUP 風格，也不可以有標題欄（也就是不能有 CAPTION 選項）。
⑵、使用者可以在不關閉子對話盒的情況下，就切換到另一個標籤項目的子對話盒，所以這些子對話盒都是屬於不強制回應對話盒，必須呼叫 CreateDialogParam 建立。
⑶、計算子對話盒尺寸或標籤控制項尺寸，可分為兩種情形：（子對話盒的尺寸可以和顯示區域一樣大，稍微小一、兩個像素）
⒜、以顯示區域為準，也就是已知顯示區域尺寸，去計算標籤控制項尺寸。
⒝、但大部分的情形是以標籤控制項為準，也就是已知標籤控制項尺寸，去計算顯示區域尺寸。
⑷、使用者切換標籤時，應用程式需在視窗函式中處理 TCN_SELCHANGE 通知碼，並呼叫 ShowWindow 決定顯示哪個子對話盒，不顯示哪個子對話盒。

上述的第⑴、⑵並不難，不特別詳述。底下說明第⑶點，這與標籤控制項的 TCM_ADJUSTRECT 訊息有關。TCM_ADJUSTRECT 訊息是藉由呼叫 SendMessage 發送給標籤控制項的，其過程如下：

invoke  SendMessage,hTab,TCM_ADJUSTRECT,fLarger,pRect

hTab 是標籤控制項的代碼。fLarger 是布林值，不是零就是一，它代表著底下兩種情形：

⒜、如果 fLarge 為一，代表是在已知顯示區域的尺寸，去計算標籤控制項的尺寸。在呼叫 SendMessage 之前，pRect 是 RECT 結構體位址，該結構體內存有顯示區域左上角及右下角座標。當 TCM_ADJUSTRECT 計算完成後，該結構體會變為標籤控制項的左上角及右下角座標。
⒝、如果 fLarge 為零，代表是在已知標籤控制項的尺寸，去計算顯示區域的尺寸。在呼叫 SendMessage 之前，pRect 是已存有標籤控制項左上角及右下角座標的 RECT 結構體位址。當 TCM_ADJUSTRECT 計算完成後，該結構體會變為顯示區域的左上角及右下角座標。

本章的例子，HMS2S 是採用⒝方式。先呼叫 GetClientRect 得到標籤控制項左上角及右下角座標存於 RECT 結構體內，這兩個座標圍住的矩形，包含項目名稱與顯示區域，其實就是標籤控制項的工作區。在以 TCM_ADJUSTRECT 為參數呼叫 SendMessage 的同時，把 fLarger 設成零、pRect 設為由 GetClientRect 得到的 RECT 結構體位址。完成呼叫後，前述 RECT 結構體內就是顯示區域左上角及右下角座標，也就是子對話盒所在的矩形區域。

HMS2S 有三個標籤項目，所以也有三個子對話盒與之對應。而這三個子對話盒的位置與尺寸都相同，其所在的矩形與大小，就是在以 TCM_ADJUSTRECT 為參數呼叫 SendMessage 時，得到的矩形，也恰好是顯示區域所在範圍。

在介紹規則⑷之前，得先了解 WM_NOTIFY 與通知碼的關係。

WM_NOTIFY 訊息

當使用者以滑鼠左鍵點擊標籤或其他通用控制項時，系統會對主視窗的視窗函式發出 WM_NOTIFY 訊息。此訊息的 wParam 是發出 WM_NOTIFY 訊息的控制項識別碼（identifier）。識別碼並不一定是唯一的，所以應用程式應該使用 lParam 所指位址上的 NMHDR 結構體內的 hwndFrom 欄位來識別控制項，該欄位是發出 WM_NOTIFY 的控制項之代碼。

事實上，lParam 所指位址上的結構體名稱，會隨通用控制項而不同，但這些結構體的第一個欄位必定是稱為 NMHDR 的結構體。底下是 NMHDR 結構體的各欄位：

NMHDR       STRUCT
  hwndFrom  HWND    ?   ;發出 WM_NOTIFY 訊息的控制項代碼
  idFrom    DWORD   ?   ;發出 WM_NOTIFY 訊息的控制項識別碼
  code      DWORD   ?   ;通知碼
NMHDR       ENDS

NMHDR 前兩個欄位已在上述結構體欄位的註解（灰色字）說明了，不再贅述。code 稱為通知碼（notification code），不同的控制項會發出不同的通知碼，但是底下的八種通知碼是每一種通用控制項都會發出的：

通知碼數值說明
NM_CLICK－2使用者在通用控制項按下滑鼠左鍵後很快鬆開
NM_DBLCLK－3使用者在通用控制項連續兩次快速按下滑鼠左鍵後又很快鬆開
NM_RCLICK－5使用者在通用控制項按下滑鼠右鍵後很快鬆開
NM_RDBLCLK－6使用者在通用控制項連續兩次快速按下滑鼠右鍵後又很快鬆開
NM_RETURN－4使用者在通用控制項有輸入焦點時，按下鍵盤上的「Enter」鍵
NM_SETFOCUS－7通用控制項獲得輸入焦點
NM_KILLFOCUS－8通用控制項失去輸入焦點
NM_OUTOFMEMORY－1沒有足夠的記憶體操作通用控制項

因為 NMHDR 結構體是由系統經由 WM_NOTIFY 訊息的 lParam 參數指定的，並非由應用程式自行定義的，要存取 NMHDR 結構體的欄位就會比較麻煩。通常會用 ASSUME 假指令宣告某個 64 位元的暫存器對應此結構體起始位址，再將此暫存器之值設為 lParam，這樣該暫存器就是結構體的起始位址，然後就能由一般存取結構體的方式存取各欄位。

如果不須再存取該結構體，須取消此暫存器對應的結構體的宣告。例如底下的例子是以 R11 指向 NMHDR 結構體的起始位址，假如要存取 NMHDR 中的 code 或其他欄位也不困難，見下面第三列，過程如下：

        ASSUME  r11:PTR NMHDR
        mov     r11,lParam
        mov     eax,[r11].code
         ⁝
        ASSUME  r11:NOTHING

一般而言，通用控制項的通知碼常為負值，例如 NM_CLICK 之值為－2，換算為雙字組的十六進位是 0FFFFFFFEh。有關於負數的表示方法，可參閱第九章。

切換標籤項目

當使用者以滑鼠左鍵點擊標籤項目時，系統會對視窗函式發出 WM_NOTIFY 訊息，而其通知碼是 TCN_SELCHANGE。在 lParam 所指位址上是 NMHDR 結構體，在此結構體內的 code 欄位就是通知碼，TCN_SELCHANGE。

視窗函式檢測到此通知碼之後，應對使原來顯示的子對話盒變為不顯示，而是顯示使用者所挑選標籤項目對應的子對話盒。詳細過程見後面。

HMS2S 原始程式

底下是 HMS2S.EXE.MANIFEST 的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
  <assemblyIdentity
    type="win32"
    name="AtHome.Wanker.HMS2S"
    version="1.0.0.0"
    processorArchitecture="amd64"
  />
  <dependency>
    <dependentAssembly>
      <assemblyIdentity
        type="win32"
        name="Microsoft.Windows.Common-Controls"
        version="6.0.0.0"
        processorArchitecture="amd64"
        publicKeyToken="6595b64144ccf1df"
        language="*"
      />
    </dependentAssembly>
  </dependency>
</assembly>

底下是 HMS2S.RC 的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
#include "RESOURCE.H"
#define RT_MANIFEST 24
#define IDD_MAIN  1000
#define IDD_HMS2S 1001
#define IDD_S2HMS 1002
#define IDD_HELP  1003
#define IDT_TC    1004
#define IDB_EXIT  1005
#define IDE_HR1   1006
#define IDE_MN1   1007
#define IDE_SC1   1008
#define IDS_S1    1009
#define IDE_S2    1010
#define IDS_HMS   1011
#define ICON_MAIN 1012
#define ICON_HMS  1013
#define ICON_S    1014
#define ICON_HELP 1015

IDD_MAIN   DIALOG 300,200,220,100
FONT 8,"MS Sans Serif"
STYLE WS_VISIBLE|WS_OVERLAPPEDWINDOW
CAPTION "時分秒與秒的轉換"
BEGIN
  CONTROL    "",IDT_TC,"SysTabControl32",WS_CHILD|WS_VISIBLE,2,2,216,80
  PUSHBUTTON "離開",IDB_EXIT,162,84,56,14
END

IDD_HMS2S  DIALOG 10,10,156,42
FONT 8,"MS Sans Serif"
STYLE WS_CHILD
BEGIN
  EDITTEXT    IDE_HR1, 21, 9,27,12,ES_NUMBER
  LTEXT    "時",2100,  51,11,12,10
  EDITTEXT    IDE_MN1, 63, 9,27,12,ES_NUMBER
  LTEXT    "分",2101,  93,11,12,10
  EDITTEXT    IDE_SC1,105, 9,27,12,ES_NUMBER
  LTEXT    "秒",2102, 135,11,12,10
  LTEXT    "＝？秒",IDS_S1,12,27,60,12
END

IDD_S2HMS  DIALOG 10,10,156,42
FONT 8,"MS Sans Serif"
STYLE WS_CHILD
BEGIN
  EDITTEXT      IDE_S2, 21, 9, 54,12,ES_NUMBER
  LTEXT    "秒",2103,   77,11, 12,10
  LTEXT    "＝？時？分？秒",IDS_HMS,12,27,150,12
END

IDD_HELP   DIALOG 0,0,192,76
FONT 8,"MS Sans Serif"
STYLE WS_CHILD
BEGIN
  LTEXT "HMS2S能把時分秒換算為秒，也能反過來運算。",2104,10,20,180,24,
END

1       RT_MANIFEST MOVEABLE PURE "HMS2S.EXE.MANIFEST"

ICON_MAIN ICON  clock.ico
ICON_HMS  ICON  hms2s.ico
ICON_S    ICON  s2hms.ico
ICON_HELP ICON  help.ico

底下是 HMS2S.ASM 的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
OPTION CASEMAP:NONE
OPTION WIN64:7

IDD_MAIN  EQU   1000 ;主要對話盒識別碼
IDD_HMS2S EQU   1001 ;時分秒→秒對話盒識別碼
IDD_S2HMS EQU   1002 ;秒→時分秒對話盒識別碼
IDD_HELP  EQU   1003 ;說明對話盒識別碼
IDT_TC    EQU   1004 ;標籤控制項識別碼
IDB_EXIT  EQU   1005 ;離開按鈕識別碼
IDE_HR1   EQU   1006 ;輸入小時的編輯框識別碼
IDE_MN1   EQU   1007 ;輸入分的編輯框識別碼
IDE_SC1   EQU   1008 ;輸入秒的編輯框識別碼
IDS_S1    EQU   1009 ;輸出秒的靜態控制項識別碼
IDE_S2    EQU   1010 ;輸入秒的編輯框識別碼
IDS_HMS   EQU   1011 ;輸出多少時多少分多少秒的靜態控制項識別碼
ICON_MAIN EQU   1012 ;主要對話盒圖示
ICON_HMS  EQU   1013 ;時分秒→秒標籤的圖示
ICON_S    EQU   1014 ;秒→時分秒標籤的圖示
ICON_HELP EQU   1015 ;說明標籤的圖示

UNICODE   EQU   1

INCLUDE     WINDOWS.INC
INCLUDE     COMMCTRL.INC
INCLUDE     MYFIX.INC
INCLUDELIB  KERNEL32.LIB
INCLUDELIB  USER32.LIB
INCLUDELIB  COMCTL32.LIB
;*******************************************************************************
.CONST
iccex    INITCOMMONCONTROLSEX <SIZEOF INITCOMMONCONTROLSEX,ICC_TAB_CLASSES>
sz1st    DW 6642h,5206h,79d2h,2192h,79d2h,0 ;時分秒→秒
sz2nd    DW 79d2h,2192h,6642h,5206h,79d2h,0 ;秒→時分秒
sz3rd    DW 8aaah,660eh,0         ;說明
szFmtSec DW 0ff1dh,37,64h,79d2h,0 ;＝%d秒
szFmtHms DW 79d2h,0ff1dh,37,64h,6642h,37,64h,5206h,37,64h,79d2h,0 ;秒＝%d時%d分%d秒
n3600    DD 3600
sixty    DD 60
;*******************************************************************************
.DATA
hInst   DQ  ? ;模組代碼
hImgLst DQ  ? ;圖像列表代碼
hTab    DQ  ? ;標籤控制項代碼
SelItem DQ  2 ;顯示hSubDlg陣列中哪個子對話盒，預設值是2，亦即顯示IDD_HELP子對話盒
hSubDlg DQ  3 DUP (?) ;依序是IDD_HMS2S、IDD_S2HMS、IDD_HELP子對話盒代碼
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
HlpProc PROC    hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
        xor     rax,rax
        ret
HlpProc ENDP
;-------------------------------------------------------------------------------
S2HProc PROC    hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL   buffer[20h]:WORD
.if uMsg==WM_COMMAND
        mov     rax,r8  ;R8W＝識別碼
        shr     rax,16  ;AX＝通知碼
  .if ax==EN_CHANGE
    .if r8w==IDE_S2
      ;把編輯框的秒數，轉換成多少時多少分多少秒
        invoke  GetDlgItemInt,hDlg,IDE_S2,0,0
        xor     edx,edx
        div     n3600
        mov     r8d,eax
        mov     eax,edx
        xor     rdx,rdx
        div     sixty
        mov     r10d,edx
        invoke  wsprintf,ADDR buffer,OFFSET szFmtHms,r8d,eax,r10d
        invoke  SetDlgItemText,hDlg,IDS_HMS,ADDR buffer
    .endif
  .endif

.else
        xor     rax,rax
        ret
.endif
        mov     rax,1
        ret
S2HProc ENDP
;-------------------------------------------------------------------------------
H2SProc PROC    hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL   minute:QWORD,second:QWORD,buffer[20h]:WORD
.if uMsg==WM_COMMAND
        mov     rax,r8  ;R8W＝識別碼
        shr     rax,16  ;AX＝通知碼
  .if ax==EN_CHANGE
    .if (r8w==IDE_HR1)||(r8w==IDE_MN1)||(r8w==IDE_SC1)
      ;把IDE_HR1、IDE_MN1、IDE_SC1三個編輯框內代表時、分、秒的數值，變成秒數
        mov     second,RV(GetDlgItemInt,hDlg,IDE_SC1,0,0)
        mov     minute,RV(GetDlgItemInt,hDlg,IDE_MN1,0,0)
        invoke  GetDlgItemInt,hDlg,IDE_HR1,0,0
        mul     n3600
        mov     r8,rax
        mov     rax,minute
        add     r8,second
        mul     sixty
        add     r8d,eax
        invoke  wsprintf,ADDR buffer,OFFSET szFmtSec,r8d
        invoke  SetDlgItemText,hDlg,IDS_S1,ADDR buffer
    .endif
  .endif

.else
        xor     rax,rax
        ret
.endif
        mov     rax,1
        ret
H2SProc ENDP
;-------------------------------------------------------------------------------
DlgProc PROC    hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL   tci:TCITEM,cxDlgInTab:DWORD,cyDlgInTab:DWORD,rcTab:RECT
.if uMsg==WM_COMMAND
        mov     rax,r8  ;R8W＝識別碼
        shr     rax,16  ;AX＝通知碼
  .if (ax==BN_CLICKED)&&(r8w==IDB_EXIT)
        jmp     exit
  .endif

.elseif uMsg==WM_NOTIFY
        ASSUME  r11:PTR NMHDR
        mov     r11,lParam
        mov     rax,[r11].hwndFrom      ;RAX＝發出WM_NOTIFY的控制項代碼
  .if rax==hTab
    .if [r11].code==TCN_SELCHANGE
        mov     rax,SelItem
        mova    rcx,hSubDlg[rax*8]
        invoke  ShowWindow,rcx,SW_HIDE
        invoke  SendMessage,hTab,TCM_GETCURSEL,0,0
        mov     SelItem,rax
        mova    rcx,hSubDlg[rax*8]
        invoke  ShowWindow,rcx,SW_SHOW
    .endif
  .endif
        ASSUME  r11:NOTHING

.elseif uMsg==WM_INITDIALOG
        invoke  SendMessage,hDlg,WM_SETICON,ICON_SMALL,RV(LoadIcon,hInst,ICON_MAIN)
      ;建立圖像列表，並於其內新增ICON_HMS、ICON_S、ICON_HELP三個圖示
        mov     hImgLst,RV(ImageList_Create,32,32,ILC_COLOR32 or ILC_MASK,3,0)
        invoke  ImageList_ReplaceIcon,hImgLst,-1,RV(LoadIcon,hInst,ICON_HMS)
        invoke  ImageList_ReplaceIcon,hImgLst,-1,RV(LoadIcon,hInst,ICON_S)
        invoke  ImageList_ReplaceIcon,hImgLst,-1,RV(LoadIcon,hInst,ICON_HELP)
      ;取得標籤控制項代碼，並設定與之相關聯的圖像列表
        mov     hTab,RV(GetDlgItem,hDlg,IDT_TC)
        invoke  SendMessage,rax,TCM_SETIMAGELIST,0,hImgLst
      ;在標籤控制項中插入三個項目，「時分秒→秒」、「秒→時分秒」、「說明」
        mov     tci.mask_,TCIF_TEXT or TCIF_IMAGE
        lea     r10,sz1st
        mov     tci.pszText,r10
        mov     tci.iImage,0
        INVOKE  SendMessage,hTab,TCM_INSERTITEM,0,ADDR tci
        lea     r10,sz2nd
        mov     tci.pszText,r10
        mov     tci.iImage,1
        INVOKE  SendMessage,hTab,TCM_INSERTITEM,1,ADDR tci
        lea     r10,sz3rd
        mov     tci.pszText,r10
        mov     tci.iImage,2
        INVOKE  SendMessage,hTab,TCM_INSERTITEM,2,ADDR tci
      ;計算標籤控制項顯示區域左上角的位置，記錄於rcTab，顯示區域的左上角在項目下方
        invoke  GetClientRect,hTab,ADDR rcTab
        INVOKE  SendMessage,hTab,TCM_ADJUSTRECT,FALSE,ADDR rcTab
      ;計算對話盒視窗的寬度與高度，存於cxDlgInTab、cyDlgInTab
        mov     ecx,rcTab.right
        mov     edx,rcTab.bottom
        sub     ecx,rcTab.left
        sub     edx,rcTab.top
        mov     cxDlgInTab,ecx  ;ECX＝標籤內對話盒的寬度
        mov     cyDlgInTab,edx  ;EDX＝標籤內對話盒的高度
      ;建立「時分秒→秒」、「秒→時分秒」、「說明」子對話盒，並使其移到適當位置
        mov     hSubDlg,RV(CreateDialogParam,hInst,IDD_HMS2S,hTab,OFFSET H2SProc,0)
        invoke  MoveWindow,rax,rcTab.left,rcTab.top,cxDlgInTab,cyDlgInTab,0
        mov     hSubDlg[8],RV(CreateDialogParam,hInst,IDD_S2HMS,hTab,OFFSET S2HProc,0)
        invoke  MoveWindow,rax,rcTab.left,rcTab.top,cxDlgInTab,cyDlgInTab,0
        mov     hSubDlg[16],RV(CreateDialogParam,hInst,IDD_HELP,hTab,OFFSET HlpProc,0)
        invoke  MoveWindow,rax,rcTab.left,rcTab.top,cxDlgInTab,cyDlgInTab,0
      ;把「說明」標籤設為被選定的，且顯示「說明」子對話盒
        invoke  SendMessage,hTab,TCM_SETCURSEL,2,0
        invoke  ShowWindow,hSubDlg[16],SW_SHOW

.elseif uMsg==WM_CLOSE
exit:   invoke  EndDialog,hDlg,0
        invoke  ImageList_Destroy,hImgLst

.else
        xor     rax,rax ;其他未處理的訊息返回 FALSE
        ret

.endif
        mov     rax,1   ;已處理的訊息，返回 TRUE
        ret
DlgProc ENDP
;-------------------------------------------------------------------------------
main    PROC
        invoke  InitCommonControlsEx,OFFSET iccex
        mov     hInst,RV(GetModuleHandle,0)
        invoke  DialogBoxParam,hInst,IDD_MAIN,0,OFFSET DlgProc,0
        invoke  ExitProcess,0
main    ENDP
;*******************************************************************************
END     main

把 HMS2S.EXE.MANIFEST、HMS2S.RC、HMS2S.ASM、clock.ico、hms2s.ico、s2hms.ico、help.ico、MYFIX.INC 八個檔案放在同一目錄，經 RC.EXE 編譯資源描述檔、UASM64.EXE 組譯組合語言原始碼、LINK.EXE 連結匯入程式庫、資源檔、目的檔之後，就能產生 HMS2S.EXE。這八個檔案中，前三個是原始程式，已於前面列出所有內容；第四∼七個檔案是圖示檔，可於此處下載，也可以自己製作；MYFIX.INC 可於此處下載，它用來修正 UASM64.EXE 組譯以 MOV 指令存取陣列的錯誤，見附錄二。

HMS2S 有三個標籤項目，分別對應三個子對話盒。在 HMS2S.ASM 中第 45 行，定義了 hSubDlg 陣列，來儲存這三個子對話盒的代碼。這三個子對話盒在 HMS2S.ASM 的第 174、176、178 三行建立，必須採用呼叫 CreateDialogParam 才能建立不強制回應對話盒；當然，呼叫 CreateDialogParam 的同時，也要指定對話盒面板以及對話盒函式。在這之前，第 163∼172 行已計算出子對話盒左上角所在座標，以及寬度與高度（所使用方法前面已敘述過了），所以可以在建立好子對話盒後，直接呼叫 MoveWindow 改變其尺寸並移至正確位置。

hSubDlg 陣列用於儲存三個子對話盒的代碼，底下來看看這個陣列如何儲存子對話盒代碼。

圖三是用 x64dbg 對 HMS2S.EXE 除錯時的畫面，標示㈮的是呼叫 CreateDialogParam 建立第一個子對話盒的程式碼。把滑鼠游標移到㈮的下兩行（也就是位址 0F51497h 處，標示㈭所在的藍色框內），按滑鼠左鍵點擊一次，再按鍵盤上的「F2」鍵，將中斷點設於此處。這樣執行到此處會中斷執行，就能看到 CreateDialogParam 的回傳值存於 RAX 暫存器內，它代表所建立的子對話盒代碼。同樣在標示㈬的藍色框內進行一樣的操作，設立另一個中斷點。按下 F9 鍵執行，就會於標示㈭中斷點處停止，最左邊標示 RIP，代表程式即將執行此行但尚未執行，也就是圖三的畫面。圖三紅色框的位址 0F55020h 是 RAX 要存入的位址，該位址也是 hSubDlg 陣列的位址，準確地說是 hSubDlg 陣列第零個元素的位址。如果你 x64dbg 的資料顯示區不是如此，可以把滑鼠游標移至標示㈫的藍色大框內，以滑鼠左鍵點擊一次，按下 Ctrl－G（先按住 Ctrl 鍵不放，再按一下 G 鍵），於彈出的對話盒內輸入「F55020」，按確認按鈕，就可以把資料區變成能看到 hSubDlg 所在的範圍。這時就能看到上面紫色框內的 RAX 數值 302C8h 已存入位址 0F55020h 處，變成「C8 02 03」。這是因為依照小端序排列，所以才形成這種樣子。

再按一次鍵盤上的 F9 鍵，會到標示㈬的中斷點停下來。這時，第二個子對話盒已經建立，其代碼為 702B6h（見圖四上面的深紅色框），也已存於 hSubDlg 陣列的第一個元素位址（0F55028h）處。因為視窗代碼需要八個位元組儲存（亦即四字組，QWORD），所以 hSubDlg 陣列長 24 個位元組。其中第零個元素以 hSubDlg[0] 或簡化為 hSubDlg 表示，第一個元素以 hSubDlg[8] 表示，第二個元素以 hSubDlg[16] 表示。在 HMS2S.ASM 第 174、176、178 行可以看到這樣的用法。

另外在 HMS2S.ASM 第 128∼134 也有類似的用法，這段程式是處理使用者用滑鼠左鍵點擊標籤時，切換不同子對話盒的過程。HMS2S.ASM 在第 44 行定義了預設值為 2 的 SelItem 變數，顧名思義，它代表使用者選擇了哪一個標籤項目。其範圍只能是在 0∼2 之間的整數：0 代表選擇「時分秒→秒」、1 代表選擇「秒→時分秒」、2 代表選擇「說明」。

當使用者選擇了某個標籤項目時，有兩步驟需要完成：①應使原有標籤項目對應的子對話盒不顯示、②顯示新選擇標籤項目對應的子對話盒。要完成第①步驟，程式碼如下：

        mov     rax,SelItem
        mova    rcx,hSubDlg[rax*8]
        invoke  ShowWindow,rcx,SW_HIDE

舉個例子來說，如果原先選擇的是「說明」，那麼 SelItem 等於 2，執行完上述第一行指令後，RAX 等於 2。第二行指令的 RAX*8 就等於 16，所以就可以想成是「mova rcx,hSubDlg[16]」。因為 UASM64.EXE 組譯類似「mov rcx,hSubDlg[rax*8]」的指令，也就是以 MOV 指令存取陣列中某個元素的數值時，會發生錯誤。因此小木偶撰寫了 mova 巨集，直接以機械碼代替 MOV 指令，就不會發生錯誤，詳情見附錄二。結論就是「mova rcx,hSubDlg[16]」其實就是「mov rcx,hSubDlg[rax*8]」，但能避免 UASM64.EXE 組譯錯誤，前提是要載入 MYFIX.INC。

上述程式最後一行並不難，呼叫 ShowWindow 讓原先的子對話盒不顯示。接下來是第②步。程式在第 131∼134 行，如下：

        invoke  SendMessage,hTab,TCM_GETCURSEL,0,0
        mov     SelItem,rax
        mova    rcx,hSubDlg[rax*8]
        invoke  ShowWindow,rcx,SW_SHOW

上述程式第一行是用來取得使用者選擇哪一個標籤項目，存入 SelItem 後，以巨集 mova 取出位於 hSubDlg 陣列內新選擇的子對話盒代碼，再呼叫 ShowWindow 顯示該子對話盒。

註解

底下是這一章用到的 Win64 API。

ImageList_Create API

ImageList_Create 用於建立圖像列表，它的原型是：

invoke  ImageList_Create,\
        cx,\            ; width of image
        cy,\            ; height of image
        flags,\         ; the type of image list
        cInitial,\      ; number of images that the image list initially
        cGrow           ; number of images by which the image list can grow

底下說明這些參數：

①、cx、cy：分別是圖像的寬度與高度，以像素為單位。在圖像列表中的每個圖像寬度都必須與其他一樣，高度也是如此。
②、flag：指定圖像列表的類型，可以是下表的數值：
flags數值說明
ILC_COLOR0使用預設值建立圖像列表，通常是 ILC_COLOR4，但如果使用舊的顯示裝置可能是 ILC_COLORDDB
ILC_COLOR44使用四位元顏色，即 16 色
ILC_COLOR88使用八位元顏色，即 256 色
ILC_COLOR1610h使用十六位元顏色，即 65536 色
ILC_COLOR2418h使用二十四位元顏色，即真彩
ILC_COLOR3220h使用二十四位元顏色，即真彩加上α通道
ILC_COLORDDB0FEh與裝置相關的位元圖
ILC_MASK1具有此旗標的圖像列表內，每張圖像都有兩張位元圖，一張是原圖，一張是作為遮罩的單色黑白圖，可使某一種顏色變得透明
ILC_MIRROR2000h在由右至左的系統中，圖像列表內的所有圖像都會被鏡像翻轉
ILC_ORIGINALSIZE10000h允許圖像列表接受比設定尺寸更小的圖像，而維持其原始尺寸
ILC_PERITEMMIRROR8000h當一次插入多個圖像時，允許單獨對每個圖像進行鏡像翻轉，而不是鏡像整個圖像串
③、cInitial：是圖像列表建立時，一開始的圖像數量。
④、cGrow：是指當圖像列表需要擴充時，系統自動地每次增加的圖像數量。

如果 ImageList_Create 成功建立圖像列表，那麼回傳值是圖像列表代碼；否則回傳值為零。如果不再需要圖像列表的話，應呼叫 ImageList_Destroy，將其銷毀。例如底下的例子是建立一開始能儲存 10 張 16×16 的圖像列表；如果不敷使用的話，系統會在每次需要擴充時自動每次擴充兩張：

invoke  ImageList_Create,16,16,ILC_COLOR16,10,2

ImageList_Destroy API

ImageList_Destroy 用於銷毀圖像列表，其原型為：

invoke  ImageList_Destroy,\
        himl            ; handle to the image list to destroy

ImageList_Destroy 只有一個參數，要銷毀的圖像列表代碼。如果成功銷毀，回傳值為一；否則為零。

ImageList_ReplaceIcon API

要在圖像列表中添加位元圖（Bitmap），是呼叫 ImageList_Add API，但是 ImageList_Add 並無法新增圖示或游標，因此只能用變通的方式。而 ImageList_ReplaceIcon 原來的功能是，用圖示或游標來取代圖像列表中的圖片。所以要新增圖示或游標，或是以圖示或游標取代原來在圖像列表內的圖片，都可以呼叫 ImageList_ReplaceIcon，其原型為：

invoke  ImageList_ReplaceIcon,\
        himl,\          ; handle to the image list
        i,\             ; index of the image to replace
        hicon           ; handle to the icon or cursor

這些參數的意義如下：

①、himl：要處理的圖像列表代碼。
②、i：要取代的圖像索引。如果 i 為－1，那麼此函式會把圖像添加在最後一個圖像之後。
③、hicon：圖示或游標代碼，它們會取代原有在圖像列表中的圖片。

如果執行成功，回傳值為圖像索引，否則為零。

CreateDialogParam API

CreateDialogParam 從資源中的對話盒面板建立不強制回應對話盒（modeless dialog boxes），其原型如下：

invoke  CreateDialogParam,\
        hInstance,\     ; handle to application instance
        lpTemplateName,\; identifies dialog box template
        hWndParent,\    ; handle to owner window
        lpDialogFunc,\  ; pointer to dialog box procedure
        dwInitParam     ; initialization value

各參數意義如下：

①、hInstance：包含對話盒面板的模組代碼。如果此參數為 0，則會使用目前的可執行檔。
②、lpTemplateName：以零結尾的字串，此字串代表對話盒面板名稱；也可以是 1∼65535 之間的正整數，此數值代表對話盒面板的識別碼。不論是哪一種，都需與資源描述檔中的對話盒面板配合。
③、hWndParent：視窗代碼，此視窗代碼表示擁有此對話盒。
④、lpDialogFunc：對話盒函式位址。
⑤、dwInitParam：當對話盒建立，但尚未顯示前，對話盒函式會收到 WM_INITDIALOG 訊息，其 lParam 參數就是 dwInitParam，應用程式可以用此數值進行初始化工作。

如果成功建立對話盒，回傳值是對話盒的視窗代碼；否則回傳值是零。CreateDialogParam 僅僅在記憶體內建立對話盒，但並不會把對話盒顯示於螢幕上；應用程式要呼叫 ShowWindow 來顯示對話盒。不再使用對話盒後，應用程式要呼叫 DestroyWindow 終結對話盒。

標籤控制項的風格

標籤控制項的風格如下：

風格數值說明
TCS_BOTTOM2此風格使標籤位於顯示區域的下面。
TCS_BUTTONS100h此風格將標籤顯示為按鈕的樣子，且顯示區域周圍沒有框線。具有此風格的標籤控制項，某個標籤有輸入焦點時並不一定處於被選取狀態，因為使用者可以用方向鍵變更輸入焦點，但不改變被選取的標籤。不具此風格時，輸入焦點與被選取的標籤是一致的。
TCS_FIXEDWIDTH400h所有標籤的寬度都相同，不能與 TCS_RIGHTJUSTIFY 搭配。
TCS_FLATBUTTONS8選取的標籤會顯現凹陷效果，而其他則無此效果。此風格只會影響具有 TCS_BUTTONS 風格的標籤控制項。
TCS_FOCUSNEVER8000h即使處於選取的標籤，也不會使標籤控制項獲得輸入焦點。
TCS_FOCUSONBUTTONDOWN1000h選取標籤項目，會使標籤控制項獲得輸入焦點。
TCS_FORCEICONLEFT10h圖示會對齊固定寬度標籤的左緣。此風格只能與 TCS_FIXEDWIDTH 搭配使用。
TCS_FORCELABELLEFT20h標籤文字會向左邊對齊。此風格只能與 TCS_FIXEDWIDTH 搭配使用。
TCS_HOTTRACK40h啟用標籤控制項的熱追蹤效果，亦即當滑鼠懸停在標籤名稱上時會自動高亮顯示。近期的 Windows 會自動啟用此項功能。
TCS_MULTILINE200h如果標籤太多一列顯示不完，且標籤控制項具有此風格時，標籤會以多列顯示；但如果標籤太多一列顯示不完，卻沒指定 TCS_MULTILINE，那麼僅顯示一列標籤，並於最右邊以箭頭表示還有其他標籤，使用者可以按箭頭，顯示其餘標籤。如果標籤很少能一列顯示完，即使有此風格，也僅僅顯示一列。
TCS_MULTISELECT4按住 Ctrl 鍵時可選取多個標籤，必須與 TCS_BUTTONS 搭配。
TCS_OWNERDRAWFIXED2000h擁有者繪製標籤控制項，也就是由應用程式，而不是系統，繪製標籤控制項。
TCS_RAGGEDRIGHT800h顯示多列標籤時，具有此風格的標籤控制項所顯示的標籤名稱寬度維持原貌，不會延伸至對齊控制項右緣或下緣（具有 TCS_VERTICAL 風格）。
TCS_RIGHT2標籤會以垂直方式顯示在標籤控制項右側，必須搭配 TCS_VERTICAL。
TCS_RIGHTJUSTIFY0顯示多列標籤時，具有此風格的標籤控制項所顯示的標籤寬度會由系統調整，使每列延伸至對齊控制項右緣；如果具有 TCS_VERTICAL，就對齊控制項下緣。此風格為預設，因此多列標籤，即使未指定此風格，也會對齊右緣或下緣，除非指定 TCS_RAGGEDRIGHT。
TCS_SCROLLOPPOSITE1當使用者選取多列標籤的其中一個時，預設情形，系統會將未緊鄰顯示區域的標籤移至僅靠顯示區域；假如指定此風格，系統不會移動選取的標籤，反而將在顯示區域與被選取標籤之間的所有標籤移至顯示區域對面處。
TCS_SINGLELINE0僅顯示一列標籤。此為預設風格，如果標籤太多無法移列顯示完，會於最右邊以箭頭表示；除非指定 TCS_MULTILINE，才會顯示多列。
TCS_TABS0預設的風格，顯示標準的標籤控制項，例如有框線，顯示區域背景與被選取的標籤名稱背景同色。如果指定了 TCS_BUTTONS，那麼顯示區域就沒有框線。
TCS_TOOLTIPS4000h標籤控制項具有相關的工具提示控制項。
TCS_VERTICAL80h鉛錘顯示標籤。預設的情形是，標籤在顯示區域左側，除非同時具有 TCS_RIGHT，那麼才會顯示在右側。

TCS_BOTTOM 與 TCS_RIGHT 數值相同，決定標籤在顯示區域的下方還是右方，得由是否有 TCS_VERTICAL 決定；若不具 TCS_VERTICAL，那麼就在下方，否則在右方。同理，TCS_TABS、TCS_SINGLELINE、TCS_RIGHTJUSTIFY 的數值都是零，它們都是預設值；與它們相對的是 TCS_BUTTON、TCS_MULTILINE、TCS_RAGGEDRIGHT，所以除非指定後面的三種風格，否則都採用預設值。

標籤控制項的通知碼

標籤控制項的通知碼是經由 WM_NOTIFY 訊息傳到視窗函式，藉以告知視窗函式或對話盒函式使用者進行了什麼操作，視窗函式或對話盒函式可以針對這事件加以處理。WM_NOTIFY 訊息中的 lParam 是 NMHDR 結構體位址，該結構體的 code 欄位就是通知碼。標籤控制項的通知碼有下面幾種：

通知碼數值說明
NM_RELEASEDCAPTURE－16滑鼠捕捉（mouse capture）是指一個控制項「捕捉」了滑鼠輸入，就算滑鼠游標移動到該控制項的區域之外，該控制項仍然會持續接收滑鼠訊息，例如滑鼠移動、按鍵釋放等訊息。當標籤控制項正在釋放滑鼠捕捉，會將 NM_RELEASEDCAPTURE 傳給父視窗的視窗函式。
TCN_FOCUSCHANGE－554具有 TCS_BUTTONS 風格的標籤控制項，因為按下 Tab 鍵或方向鍵使其得到或失去輸入焦點時，會將此通知碼傳送給父視窗的視窗函式。
TCN_GETOBJECT－553當使用者用滑鼠拖放物件，把物件移到具有 TCS_EX_REGISTERDROP 延伸風格的標籤控制項的標籤上面，會將此通知碼傳送給父視窗的視窗函式。視窗函式處理完後，必須傳回零。
TCN_KEYDOWN－550當使用者按下鍵盤上的某個按鍵，會將此通知碼傳送給父視窗的視窗函式。
TCN_SELCHANGE－551當使用者變更選取的標籤，但系統已處理完此事件，會將此通知碼傳送給父視窗的視窗函式。
TCN_SELCHANGING－552當使用者變更選取的標籤，但系統尚未處理此事件，會將此通知碼傳送給父視窗的視窗函式。

標籤控制項的通知碼皆為負值。像 TCN_KEYDOWN 之值為－550，換算為雙字組十六進位為 0FFFFFDDAh；TCN_SELCHANGE 之值為－551，換算為雙字組十六進位為 0FFFFFDD9h。上表中只有 TCN_GETOBJECT、TCN_SELCHANGING 要將回傳值傳給系統，其餘通知碼均不須將回傳值傳給系統。

當標籤控制項發出 TCN_GETOBJECT、TCN_KEYDOWN 通知碼時，WM_NOTIFY 訊息的 lParam 所指位址上並非 NMHDR 結構體，而是包含比 NMHDR 結構體更大的結構體。它們分別是 NMOBJECTNOTIFY 和 NMTCKEYDOWN，其欄位如下。但超過本章所要談論的範圍篇幅太大了，不再細說。

NMOBJECTNOTIFY    STRUCT
  hdr     NMHDR   <>
  iItem   DWORD	  ?
 ifdef __IID_DEFINED__
  piid    DWORD	  ?
 else 
  piid    DWORD	  ?
 endif 
  pObject DWORD	  ?
  hResult HRESULT ?
  dwFlags DWORD	  ?
NMOBJECTNOTIFY    ENDS
 
NMTCKEYDOWN      STRUCT 
  hdr     NMHDR  <>
  wVKey   WORD   ?  ;虛擬鍵碼
  flags   DWORD  ?  ;與WM_KEYDOWN的lParam意義相同
NMTCKEYDOWN      ENDS

當使用者把滑鼠游標移到未選取的標籤上面，再以滑鼠左鍵點擊該標籤，此刻系統尚未處理選取新標籤的切換工作時，就會發出 TCN_SELCHANGING。父視窗的視窗函式收到 TCN_SELCHANGING 通知碼後，應用程式可以決定是否讓系統繼續完成切換工作，還是要滿足某些條件才能切換：①如果視窗函式傳回 TRUE，則取消切換，就不會發送 TCN_SELCHANGE；②如果傳回 FALSE，則允許切換，待系統完成切換工作後，新選取的標籤已成為被選取狀態，才發出 TCN_SELCHANGE。如果視窗函式不處理 TCN_SELCHANGING，預設的結果是傳回 FALSE，也就是允許系統切換為新選取的標籤。假如使用者點擊當前已選取的標籤，也就是沒有變更選取標籤，那就不會發出 TCN_SELCHANGING，也不會發出 TCN_SELCHANGE。

標籤控制項的訊息

標籤控制項的訊息如下：

訊息說明wParamlParam回傳值
TCM_ADJUSTRECT
1328h		已知顯示區域大小，計算標籤控制項尺寸；或反過來。詳情見前面 若為一，表示已知顯示區域，計算控制項尺寸；否則為零RECT 結構體位址無
TCM_DELETEALLITEMS
1309h		刪除所有標籤項目不使用，應設為 0不使用，應設為 0若成功回傳值為一；否則為零
TCM_DELETEITEM
1308h		刪除某個標籤項目要刪除的項目索引不使用，應設為 0若成功回傳值為一；否則為零
TCM_DESELECTALL
1332h		將狀態為 TCIS_BUTTONPRESSED 的標籤設為未被選取若為零，所有標籤都設為未選取；若為一，除了目前選取的標籤之外，其餘都設為未選取不使用，應設為 0無
TCM_GETCURFOCUS
132Fh		取得具有輸入焦點的項目索引不使用，應設為 0不使用，應設為 0具有輸入焦點的項目索引
TCM_GETCURSEL
130Bh		取得被選取的項目索引不使用，應設為 0不使用，應設為 0被選取的項目索引
TCM_GETEXTENDEDSTYLE
1335h		取得延伸風格不使用，應設為 0不使用，應設為 0延伸風格
TCM_GETIMAGELIST
1302h		取得與標籤控制項相關的圖像列表不使用，應設為 0不使用，應設為 0圖像列表代碼
TCM_GETITEM
1305h 或 133Ch		取得標籤項目的資料。1305h 為 ANSI 版，133Ch 為寬字元版項目索引TCITEM 結構體位址若成功回傳值為一；否則為零
TCM_GETITEMCOUNT
1304h		取得標籤項目個數不使用，應設為 0不使用，應設為 0標籤項目個數
TCM_GETITEMRECT
130Ah		取得標籤的矩形範圍標籤項目索引RECT 結構體位址若成功回傳值為一；否則為零
TCM_GETROWCOUNT
132Ch		取得標籤共有幾列不使用，應設為 0不使用，應設為 0標籤列數
TCM_GETTOOLTIPS
132Dh		取得與標籤控制項相關的工具提示控制項不使用，應設為 0不使用，應設為 0工具提示代碼
TCM_GETUNICODEFORMAT
2006h		取得控制項是否使用萬國碼不使用，應設為 0不使用，應設為 0若為一表示使用萬國碼；否則使用 ANSI 字元
TCM_HIGHLIGHTITEM
1333h		設定某個標籤為高亮度顯示。但在 Comctl32.dll 6.0 版及其後版本沒有效果標籤項目索引設為一，使用高亮度；設為零，為正常狀態若成功回傳值為一；否則為零
TCM_HITTEST
130Dh		判斷某個工作區座標位於哪個標籤範圍內不使用，應設為 0TCHITTESTINFO 結構體的位址座標所在的標籤；若座標不在任何標籤內傳回－1
TCM_INSERTITEM
1307h 或 133Eh		在標籤控制項中插入新的標籤項目。1307h 為 ANSI 版，133Eh 為寬字元版新的標籤項目索引TCITEM 結構體位址若成功，回傳值為一；否則為－1
TCM_REMOVEIMAGE
132Ah		移除與標籤控制項相關聯的圖像列表中的某個圖像標籤項目索引不使用，應設為 0無
TCM_SETCURFOCUS
1330h		設定某個標籤項目具有輸入焦點要設為具有輸入焦點的標籤項目索引不使用，應設為 0無
TCM_SETCURSEL
130Ch		設定某個標籤為被選取的，若設定成功不會發送 TCN_SELCHANGING 或 TCN_SELCHANGE 通知碼要設為被選取的標籤項目索引不使用，應設為 0如果成功設定，回傳值為原先被選取的項目索引；如果失敗，回傳值為－1
TCM_SETEXTENDEDSTYLE
1334h		設定標籤控制項延伸風格某些位元的延伸風格不受影響延伸風格若設定成功，回傳值為原先的延伸風格；否則為－1
TCM_SETIMAGELIST
1303h		設定與標籤控制項相關聯的圖像列表不使用，應設為 0圖像列表代碼傳回原先圖像列表代碼；若沒有則傳回零
TCM_SETITEM
1306h 或 133Dh		設定標籤項目的資料。1305h 為 ANSI 版，133Ch 為寬字元版項目索引TCITEM 結構體位址若成功回傳值為一；否則為零
TCM_SETITEMEXTRA
130Eh		設定應用程式自行定義的資料位元組個數位元組個數不使用，應設為 0若成功回傳值為一；否則為零
TCM_SETITEMSIZE
1329h		設定標籤的寬度和高度（若所設定的寬度小於圖像列表中圖像的寬度，那麼會變為大於圖像寬度的最小值）不使用，應設為 00∼15 位元代表寬度，16∼31 位元代表高度，單位是像素原有的寬度（0∼15 位元）與高度（16∼31 位元）
TCM_SETMINTABWIDTH
1331h		設定每個標籤的最小寬度不使用，應設為 0最小寬度，單位是像素；如果設成－1表示使用預設值原先的最小寬度
TCM_SETPADDING
132Bh		設定標籤中每個圖示和標籤文字周圍的空白大小不使用，應設為 00∼15 位元代表水平方向的空白大小，16∼31 位元代表鉛錘方向空白大小，單位是像素無
TCM_SETTOOLTIPS
132Eh		設定與標籤控制項相關聯的工具提示工具提示代碼不使用，應設為 0無
TCM_SETUNICODEFORMAT
2005h		設定標籤控制項是否使用萬國碼一代表使用萬國碼，零代表使用 ANSI 字元不使用，應設為 0原先的字元編碼，一代表原來使用萬國碼，零代表原先使用 ANSI 字元

對標籤控制項送出 TCM_REMOVEIMAGE 時，刪除的是與其關聯圖像列表內的圖像。如果該圖像恰好是在某個標籤項目上的圖像，那麼該標籤項目上的圖像會消失，而其他標籤項目上的圖像不變；但這時圖像列表內，在刪除圖像之後的索引值已然改變，所以如果之後再把圖像設為標籤項目的圖像時，須採用新的索引值。

TCM_HITTEST 直譯是命中測試，意思是測試某一像素的座標是否在某個標籤名稱內，在顯現快捷功能表、拖放功能時會需要用到。雖然在微軟網站上說，這裏的座標是指螢幕座標，但實際測試結果是針對工作區左上角為原點的工作區座標。而像素的工作區座標是存放於 lParam 所指位址上的 TCHITTESTINFO 結構體，此結構體的各欄位如下：

TCHITTESTINFO   STRUCT
  pt    POINT   <>  ;要測試的工作區座標
  flags DWORD   ?   ;測試結果
TCHITTESTINFO   ENDS

pt 是要測試的工作區座標，flags 是測試後結果，可能的結果如下表：

flags數值說明
TCHT_NOWHERE1座標不在任何一個標籤名稱上
TCHT_ONITEMICON2座標位於標籤名稱的圖示上
TCHT_ONITEMLABEL4座標位於標籤名稱的文字上
TCHT_ONITEM6座標位於某個標籤名稱內，但不在圖示上，也不在文字上。如果是擁有者繪製的標籤控制項，只要座標位於標籤名稱中，不論是不是在圖示或文字上，flags 都會是這個值

對標籤控制項發出 TCM_SETITEMEXTRA 訊息，可以擴充應用程式自行定義的資料大小。原本預設值是 4 個位元組，存放於 TCITEM 的 lParam 欄位，但是如果不敷使用，可以利用 TCM_SETITEMEXTRA 訊息加以擴充。

在進行擴充之後，使用 TCM_INSERTITEM、TCM_GETITEM、TCM_SETITEM 訊息進行插入、獲得、設定標籤項目時，就無法使用 TCITEM 結構體了，必須自行定義新的結構體。而這個新的結構體的第一個欄位必須是 TCITEMHEADER 結構體，其餘欄位由應用程式定義，而且其餘欄位總共有多少位元組，必須與 TCM_SETITEMEXTRA 訊息的 wParam 指定的位元組數相符。底下是 TCITEMHEADER 與小木偶任意舉的例子，MY_TCITEM 結構體。在新的結構體裏，定義了兩個新的欄位資料：

TCITEMHEADER 結構體新的 MY_TCITEM 結構體
TCITEMHEADER    STRUCT  8
  mask_         DWORD   ?   ;指定哪個欄位有效的旗標
  lpReserved1   DWORD   ?   ;保留
  lpReserved2   DWORD   ?   ;保留
  pszText       LPSTR   ?   ;字串位址
  cchTextMax    DWORD   ?   ;字串長度
  iImage        DWORD   ?   ;圖像索引
TCITEMHEADER    ENDS
 
MY_TCITEM STRUCT        8
  tcihd   TCITEMHEADER  <>
  MyData  DWORD         ?           ;自行定義的資料
  MyName  DB            20h DUP (?) ;自行定義的資料
MY_TCITEM ENDS

TCM_SETITEMSIZE 與 TCM_SETMINTABWIDTH 不太相同。TCM_SETITEMSIZE 用於設定具有 TCS_FIXEDWIDTH 或 TCS_OWNERDRAWFIXED 風格的標籤控制項，所有標籤的尺寸都會變得相同，即使某些標籤文字不夠容納也一樣，超過的部分就無法看見；如果都不具這兩種風格的其中一種，那麼標籤寬度無法正常設定，但高度卻可以。TCM_SETMINTABWIDTH 則是不論是否有 TCS_FIXEDWIDTH 或 TCS_OWNERDRAWFIXED 風格，都會設定最小寬度，如果某個標籤文字太長，其寬度會隨之調整而能見其全貌。