因為 GetSystemMetrics 有 95 種引數值，無法在工作區中全部顯示出來。加上鉛垂捲動軸後，就能讓使用者自行操作，以觀察工作區沒顯示出來的內容。第七、八章談了如何建立具有基本功能的簡單視窗，這些功能包含能以滑鼠左鍵按住標題欄拖拉整個視窗、能以滑鼠按住視窗邊框放大或縮小視窗、在工作區繪製出文字……等功能，但如果在工作區顯示的資料太多，超出的部分就無法看到。這時候，可以在視窗中加上捲動軸（scroll bar，亦翻成捲動列、捲動條、滾動條），讓使用者可以向上下或左右移動，以看見更多資料。就好像我們用望遠鏡觀察遠方物體，雖然望遠鏡的鏡面很小，能看到的物體有限，但我們可以向上下或左右稍稍移動望遠鏡，就能觀察到原本看不見的物體。
捲動軸也是一樣，當我們操作視窗右邊的鉛垂捲動軸，假如按上方的捲動箭頭（scroll arrow），就好像把望遠鏡往上移動，可以看見較上方的物體；按下方的捲動箭頭，就好像把望遠鏡往下移動，可以看見較下方的物體；也可以直接拖曳捲動方塊（thumb），往上或下移動，就好像把望遠鏡往上或下移動至固定某處。
本章的範例顯示了一些有關系統的資料，如下圖，這些資料都是呼叫 GetSystemMetrics API 得到的，GetSystemMetrics 只有一個參數 nIndex，但是 nIndex 可以有 95 種引數值。這些引數都有名稱，而且以「SM_」為起頭，在「win64.inc」包含檔中宣告。例如下圖第一列的第一欄是 SM_MOUSEPRESENT，這是引數名稱，第二欄是引數值為 19 ( 事實上在 win64.inc 中已宣告「SM_MOUSEPRESENT equ 19」)，第三欄是引數的說明，第四欄是呼叫 GetSystemMetrics 的結果。有關 GetSystemMetrics 的用法請參考後面的說明。因為 GetSystemMetrics 有 95 種引數值，無法在工作區中全部顯示出來。加上鉛垂捲動軸後，就能讓使用者自行操作，以觀察工作區沒顯示出來的內容。
仔細觀察，就能發現鉛垂捲動軸可分為五個部分（上圖中以紫色字標示其名稱）：
上圖的視窗，只有鉛垂捲動軸。但大部分的視窗再底部還有一個水平捲動軸，同樣也包含上面的五個部分，功能也類似，只是把上下捲動改成往左右方向捲動。
想在視窗中建立捲動軸非常簡單，只需在呼叫 CreateWindowEx 時，在第三個參數中加上 WS_VSCROLL 就能建立鉛垂捲動軸，加上 WS_HSCROLL 就能建立水平捲動軸。當建立了捲動軸後，工作區的範圍就會變小了，這是因為工作區的範圍不包含捲動軸。下面的程式碼建立鉛垂捲動軸與水平捲動軸：
invoke CreateWindowEx,0,ADDR szClassName,ADDR szAppName,\
WS_OVERLAPPEDWINDOW or WS_VSCROLL or WS_HSCROLL,CW_USEDEFAULT,\
CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,0,0,hInstance,0
但是僅僅這樣，只是在視窗內顯示出捲動軸而已；如果要讓捲動軸發揮捲動功能，還必須倚賴額外的程式碼才行。
這些額外程式碼必須處理使用者操作鉛垂捲動軸產生的 WM_VSCROLL 訊息或是水平捲動軸產生 WM_HSCROLL 訊息。假如不加處理，那麼即使操作捲動箭頭、捲動方塊或捲動軌道，鬆開滑鼠後，捲動方塊還是會跳回原位置，工作區也不會發生捲動現象。這兩個訊息中的 wParam 參數中 0∼15 位元表示通知碼，這些通知碼均以「SB_」( 代表 scroll bar 之意 ) 起頭，表示使用者對捲動軸中的五個部分所做的操作，如下表所示，也可以參考本章一開始的圖中，藍字的說明：
| 通知碼 | 數值 | 說明 | 畫面動作 |
| SB_LINEUP | 0 | 使用者將滑鼠游標移至鉛垂捲動軸上端的箭頭後，按下滑鼠左鍵發出此通知碼 | 往上捲動一列 |
| SB_LINELEFT | 0 | 使用者將滑鼠游標移至水平捲動軸左端的箭頭後，按下滑鼠左鍵發出此通知碼 | 往左捲動一行 |
| SB_LINEDOWN | 1 | 使用者將滑鼠游標移至鉛垂捲動軸下端的箭頭後，按下滑鼠左鍵發出此通知碼 | 往下捲動一列 |
| SB_LINERIGHT | 1 | 使用者將滑鼠游標移至水平捲動軸右端的箭頭後，按下滑鼠左鍵發出此通知碼 | 往右捲動一行 |
| SB_PAGEUP | 2 | 使用者將滑鼠游標移至鉛垂捲動軸上邊的捲動軌道，按下滑鼠左鍵發出此通知碼 | 往上捲動一頁 |
| SB_PAGELEFT | 2 | 使用者將滑鼠游標移至水平捲動軸左邊的捲動軌道後，按下滑鼠左鍵發出此通知碼 | 往左捲動一頁 |
| SB_PAGEDOWN | 3 | 使用者將滑鼠游標移至鉛垂捲動軸下邊的捲動軌道，按下滑鼠左鍵發出此通知碼 | 往下捲動一頁 |
| SB_PAGERIGHT | 3 | 使用者將滑鼠游標移至水平捲動軸右邊的捲動軌道後，按下滑鼠左鍵發出此通知碼 | 往右捲動一頁 |
| SB_THUMBPOSITION | 4 | 使用者以滑鼠拖曳捲動方塊，鬆開滑鼠左鍵時，發出此通知碼。wParam 的 16∼31 位元為捲動方塊最後位置 | 移到捲動方塊的那一頁 |
| SB_THUMBTRACK | 5 | 使用者以滑鼠拖曳捲動方塊過程中，會不斷發出此通知碼。wParam 的 16∼31 位元為捲動方塊即時位置 | 移到捲動方塊的那一頁 |
| SB_ENDSCROLL | 8 | 使用者完成操作捲動軸，鬆開滑鼠左鍵時，發出此通知碼 | 移到捲動方塊的那一頁 |
由上表可得知，當使用者僅僅操作捲動軸一次，就會產生許多訊息。例如，使用者以滑鼠左鍵點擊鉛垂捲動軸上端的箭頭一次，當按下滑鼠左鍵時會發出通知碼為 SB_LINEUP 的 WM_VSCROLL 訊息，鬆開時會發出通知碼為 SB_ENDSCROLL 的 WM_VSCROLL 訊息。
再例如，當使用者拖曳鉛垂捲動軸上的捲動方塊。一開始，使用者把滑鼠游標移至捲動方塊上，按下滑鼠左鍵時會發出通知碼為 SB_THUMBTRACK 的 WM_VSCROLL 訊息；爾後在拖曳過程中，都不斷發出通知碼為 SB_THUMBTRACK 的 WM_VSCROLL 訊息，而其 wParam 的 16∼31 位元會隨著捲動方塊位置不同而變動；最後使用者鬆開滑鼠左鍵時，會發出 SB_THUMBPOSITION 的 WM_VSCROLL 訊息與 SB_ENDSCROLL 的 WM_VSCROLL 訊息。
當使用者拖曳捲動方塊時，在過程中會產生 SB_THUMBTRACK，結束時則產生 SB_THUMBPOSITION。視窗函式一般只處理這兩個通知碼中的其中一個，不管處理哪一個都各有優缺點：處理 SB_THUMBPOSITION 所需程式碼較為簡單，但使用者拖曳過程工作區不會變更；處理 SB_THUMBTRACK 工作區內容隨拖曳過程而改變，但電腦運算速度要夠快才行（現在，指民國 112 年，電腦的運算速度應該沒有問題）。
一般而言，視窗函式並不處理 SB_ENDSCROLL 通知碼，因為幾乎每個動作結束都會產生此通知碼，除非你想特別處理鬆開滑鼠時該做什麼動作。
除了 SB_THUMBPOSITION、SB_THUMBTRACK 之外，wParam 的 16∼31 位元之值都無意義，應該忽略。
在上面的描述中，有個關鍵的問題，那就是捲動方塊的位置與其所能移動的範圍。當捲動軸新建立時，系統內定其範圍在 0∼100 之間，而捲動方塊位置在 0 的地方。當然 Windows 提供一些 API 能獲取或設定對它們的資料。
GetScrollRange 用來獲得捲動方塊所能移動的範圍，其語法是：
invoke GetScrollRange,\
hWnd,\ ; handle of window with scroll bar
nBar,\ ; scroll bar flag
lpMinPos,\ ; address of variable that receives minimum position
lpMaxPos ; address of variable that receives maximum position
SetScrollRange 用來設定捲動方塊所能移動的範圍，其語法是：
invoke SetScrollRange,\
hWnd,\ ; handle of window with scroll bar
nBar,\ ; scroll bar flag
nMinPos,\ ; minimum scrolling position
nMaxPos,\ ; maximum scrolling position
bRedraw ; redraw flag
這兩個 API 的前兩個參數意義一樣，一併說明：
GetScrollRange 的第三、四個參數是 lpMinPos、lpMaxPos 分別是兩個長度為 32 位元的變數之位址。當呼叫 GetScrollRange 成功返回後，Windows 會把捲動方塊位置的最小與最大值存入這兩個變數中。
SetScrollRange 的第三、四個參數是 nMinPos、nMaxPos 是兩個長度為 32 位元的數值，可以是變數或常數，分別代表捲動方塊位置的最小與最大值。第五個參數，bRedraw 指定是否要重新繪製捲動軸，以反應捲動方塊改變位置，要重新繪製 bRedraw 設為一，不重繪設為零。
底下是呼叫 SetScrollRange 應注意的事項：①應用程式不應該在處理 WM_VSCROLL 或 WM_HSCROLL 訊息時，呼叫 SetScrollRange 改變捲動軸範圍。②如果使 SetScrollRange 的 nMinPos 大於 nMaxPos，會發生錯誤；如果 nMinPos 等於 nMaxPos，會使得捲動軸隱藏起來，雖然回傳值仍然表示成功執行，不過這並非隱藏捲動軸的好方法，若真有需要必須隱藏捲動軸，應該呼叫 ShowScrollBar。③nMaxPos 與 nMinPos 之差，必須在 MAXLONG ( MAXLONG 等於 2147483647，也就是 7FFF FFFFh ) 之內，否則會發生錯誤。④如果在呼叫 SetScrollRange 後，又呼叫了影響捲動方塊位置的 API，那麼應該將 bRedraw 設定為零以避免過多的重畫。
這兩個 API 的回傳值均一樣，當呼叫成功時回傳值為一，失敗時回傳值為零。
GetScrollPos 是用於取得捲動軸中捲動方塊的位置，如果呼叫成功，回傳值就是捲動方塊的位置；如果失敗，回傳值為零。它的語法是：
invoke GetScrollPos,\
hWnd,\ ; handle of window with scroll bar
nBar ; scroll bar flags
SetScrollPos 是用來設置捲動軸中捲動方塊的位置，其語法是：
invoke SetScrollPos,\
hWnd,\ ; handle of window with scroll bar
nBar,\ ; scroll bar flag
nPos,\ ; new position of scroll box
bRedraw ; redraw flag
這兩個 API 的前兩個參數意義一樣，都與 GetScrollRange 與 SetScrollRange 相同，可以參考前面，或者底下的說明：
SetScrollPos 的第三個參數，nPos 很明顯，就是要設置的捲動方塊新位置。最後一個參數，bRedraw 指定是否要重新繪製捲動軸，以反應捲動方塊改變位置，要重新繪製 bRedraw 設為一，不重繪設為零。如果 SetScrollPos 成功設置好新位置，回傳值為原先捲動方塊的位置，如果失敗回傳值為零。
最後很特別的是 WM_VSCROLL、WM_HSCROLL 中的 wParam 參數，表明了捲動方塊位置是十六位元，範圍在 0∼65535 之間。而 GetScrollRange、SetScrollRange、GetScrollPos、SetScrollPos 中的捲動方塊位置是三十二位元。實際上，Windows 能處理 32 位元的捲動位置，所以前述四個 API 是沒有問題的。如果是要依賴 WM_VSCROLL、WM_HSCROLL 取得捲動位置，要注意須先將設置捲動範圍在 0∼65535 之間。
底下小木偶實作一個程式，SYSMTR1.ASM，它能在工作區中顯示 95 筆的系統資料，每一筆資料單獨佔據一列，所以有 95 列。由於有這麼多列的資料，所以無法一次全都顯示出來，必須加上鉛垂捲動軸，才能觀察到所有的資料。也是為了單純起見，所以小木偶僅在 SYSMTR1 中加上鉛垂捲動軸。當你閱讀完本章且充分瞭解之後，要加入水平捲動軸也不是難事，可以自行試試。
GetSystemMetrics 可以得到系統的某種資料，例如螢幕寬度、高度等。它的語法是：
invoke GetSystemMetrics,\
nIndex ; system metric or configuration setting to retrieve
唯一的參數，nIndex，指定要獲得系統的哪一項資料，其實它是一些數值，共有 95 種。這些數值或可稱為引數值，它們大部分在 win64.inc 中宣告，分別以名稱代替這些引數值，而且均以「SM_」起頭（system metrics 之意）。凡是「SM_CX」起頭的都是某個東西的寬度，而「SM_CY」起頭的則是高度，單位都是像素（c 是 counter 之意，X、Y 本是橫座標與縱座標，這裡代表寬度與高度）。或許以後新的作業系統增加引數的種類，但小木偶在撰寫這一章時，查閱的是微軟網站上的資料，就只有 95 種，底下的表只列出幾種而已：
| nIndex（引數） | 引數值 | 說明 |
| SM_CXSCREEN | 0 | 螢幕寬度有多少像素 |
| SM_CYSCREEN | 1 | 螢幕高度有多少像素 |
| SM_MOUSEPRESENT | 19 | 如果配備滑鼠，回傳值為 1；反之為 0 |
| SM_SWAPBUTTON | 23 | 滑鼠左右鍵是否交換功能，如果交換，回傳值為 1；反之為 0 |
假如要在視窗的工作區中，像本章一開始的圖片那樣，把 GetSystemMetrics 的引數名稱、引數值、引數說明、回傳值等資料分成四欄顯示，那麼還要一些額外的資料，由於這些資料很多，因此另外儲存在 SYSMTR.INC 包含檔裡。此包含檔首先要有 95 種引數值，這 95 種引數值都是以「SM_」為開頭的常數，在 SYSMTR.INC 中為一個字組長度；第二是這些引數的名稱，它們都是大寫英文字母組成的字串，而且都以「SM_」為開頭，以零為結尾；第三是對這些引數的說明，也就是說名取得何種系統資料。每一筆資料都有這三部分，都放在程式的資料區段，.CONST，中。底下是 SYSMTR.INC 的一部分：
.CONST
n00 DW SM_CXSCREEN
DB "SM_CXSCREEN",0,"Primary display width",0
n01 DW SM_CYSCREEN
DB "SM_CYSCREEN",0,"Primary display height",0
n02 DW SM_CXVSCROLL
DB "SM_CXVSCROLL",0,"Vertical scroll bar width",0
n03 DW SM_CYHSCROLL
DB "SM_CYHSCROLL",0,"Horizontal scroll bar height",0
n04 DW SM_CYCAPTION
DB "SM_CYCAPTION",0,"Caption area height",0
⁝
因為每一筆資料長度均不固定，不容易存取，因此在 SYSMTR.INC 裡面，緊接著前述資料之後，是每一筆資料的起始位址，像底下的樣子：
aryPt DQ n00,n01,n02,n03,n04……n94
上面的 aryPt 是由每一筆資料的起始位址所組成的資料，其實就是陣列。有關陣列的用法，請參閱後面的說明。不過這裡並非真的一筆一筆的輸入「nXX,nYY……」，而是以底下的巨集程式寫出上面的陣列。畢竟，要寫 95 個元素太麻煩了！
aryPt LABEL QWORD
j=0
WHILE j LT LINES
IF @SizeStr(%j) EQ 1
temp TEXTEQU @CatStr(<n0>,%j) ;;若j<10，temp="n01"+j，因為j只有個位數
ELSE
temp TEXTEQU @CatStr(<n>,%j) ;;若j>=10，temp="n"+j，因為j為兩位數
ENDIF
DQ temp
j=j+1
ENDM
在工作區中印出文字，可以利用上一章介紹的 DrawText，但這一章小木偶打算介紹另一個 API，TextOut，來做這件事。TextOut 不須指定剪裁舉行，只需指定工作區中的某個座標為基準點，字串以此基準點印出來，比 DrawText 單純。TextOut 的用法是：
invoke TextOut,\
hdc,\ ; handle to DC
nXStart,\ ; x-coordinate of starting position
nYStart,\ ; y-coordinate of starting position
lpString,\ ; character string
cbString ; number of characters
hdc 毫無疑問是裝置內容代碼，繪製的文字將在此裝置內容中顯示；可以是呼叫 GetDC 或 BeginPaint 後的回傳值。nXStart、nYStart 分別是基準點的 X 座標與 Y 座標。lpString 是字串位址。cbSring 是字串長度，單位是字元個數。
SetTextAlign 是用來設置基準點如何使用。先看看它的語法：
invoke SetTextAlign,\
hdc,\ ;handle of device context
fMode ;text-alignment flag
很明顯，hdc 是裝置內容代碼。fMode 是文字排列方式，可以使用的排列方式有下面幾種：
| fMode | 說明 |
| TA_BASELINE | 文字的基準線（baseline，見 GetTextMetrics 的圖）位於基準點 |
| TA_BOTTOM | 文字下緣位於基準點 |
| TA_TOP | 文字上緣位於基準點 |
| TA_CENTER | 文字水平方向的中心點位於基準點 |
| TA_LEFT | 文字左緣位於基準點 |
| TA_RIGHT | 文字右緣位於基準點 |
| TA_NOUPDATECP | 當前位置不改變 |
| TA_UPDATECP | 以當前位置作為基準點，且當前位置會改變 |
當使用了 TA_UPDATECP 後，TextOut 就會忽略 nXStart、nYStart，而以當前位置為基準點；而執行完 TextOut 後，當前位置就會變成字串結尾的位置。當前位置一開始是在工作區左上角的座標，( 0, 0 )，的位置，可以經呼叫 MoveToEx、LineTo 等改變，或是使用 TA_UPDATECP 為參數呼叫 SetTextAlign 及 TextOut，也能改變當前位置。
如果成功執行完 SetTextAlign，回傳值是原來設定的文字排列方式；如果失敗，回傳值是 GDI_ERROR，可呼叫 GetLastError 得到更準確的錯誤原因。
例如右圖工作區中，以 SetTextAlign 與 TextOut 繪製的兩個字串：字串「左手指著月，右手取紅線」的基準點是 (10,10)，位於字串的左上角；而字串「賜予你和我如願的情緣。」的基準點是 (200,50)，位於字串的右下角。程式碼如下：
invoke SetTextAlign,hdc,TA_TOP or TA_LEFT
invoke TextOut,hdc,10,10,"左手指著月，右手取紅線",22
invoke SetTextAlign,hdc,TA_BOTTOM or TA_RIGHT
invoke TextOut,hdc,200,50,"賜予你和我如願的情緣。",22
言歸正傳。當 SYSMTR1 把各個 GetSysytemMetrics 的引數名稱、引數值、引數說明及回傳值分成四欄印在工作區內，很明顯，印出的第零列字串左上角座標是 ( 0, 0 )；第一列字串的左上角 X 座標為 0，Y 座標就應該是上一列的 Y 座標加上每一列文字的高度；第二列字串的左上角 X 座標還是 0，Y 座標是前一列的 Y 座標再加上每一列文字的高度……依此類推，便可知每列文字的左上角 X 座標均為 0，Y 座標為第幾列乘以每列文字的高度，這裡的第幾列是由零開始。
除此之外，每一欄的寬度與字元多寡及字元寬度有關。基於上面原因，必須取得字元高度及字元寬度。字元又可分為固定寬度的字元及可變寬度的字元，像中文字、「Courier New」、「Anonymous Pro」等屬於固定寬度字元，它的英文字母「I」與「M」等寬。像「Times New Roman」就屬於可變寬度字元，它的英文字母「I」的寬度比「M」窄很多。
那麼怎麼獲得字元的高度與寬度呢？很簡單，呼叫 GetTextMetrics 即可。GetTextMetrics 有兩個參數，呼叫方法如下：
invoke GetTextMetrics,\
hdc,\ ; handle of device context
lptm ; address of text metrics structure
先說第二個參數，lptm，是指向一個稱為 TEXTMETRIC 結構體的位址，這個結構體用來接收由 GetTextMetrics 傳回來有關文字的尺寸等資料。TEXTMETRIC 各欄位如下：
TEXTMETRIC STRUCT tmHeight SDWORD ? ; 字元高度，見右下圖 Height 的像素 tmAscent SDWORD ? ; 右下圖 Ascent 的像素 tmDescent SDWORD ? ; 右下圖 Descent 的像素 tmInternalLeading SDWORD ? ; 右下圖 InternalLeading 的像素 tmExternalLeading SDWORD ? ; 右下圖 ExternalLeading 的像素 tmAveCharWidth SDWORD ? ; 字元的平均寬度 tmMaxCharWidth SDWORD ? ; 字形中最寬字元的寬度 tmWeight SDWORD ?tmOverhang SDWORD ? tmDigitizedAspectX SDWORD ? tmDigitizedAspectY SDWORD ? tmFirstChar BYTE ? tmLastChar BYTE ? tmDefaultChar BYTE ? tmBreakChar BYTE ? tmItalic BYTE ? tmUnderlined BYTE ? tmStruckOut BYTE ? tmPitchAndFamily BYTE ? tmCharSet BYTE ? TEXTMETRIC ENDS
TEXTMETRIC 的成員太多，所以僅介紹 SYSMTR1 會用到的：
其中值得注意的是，如果是可變寬度的字形，大寫字母的寬度是字元平均寬度的 1.5 倍；如果是固定寬度的字形，大寫字母的寬度就是字元的平均寬度。
hdc 是裝置內容代碼。Windows 允許裝置內容中使用不同字形繪製文字，但 SYSMTR1 中只使用 Windows 內定的字形，也就是 SYSTEM_FONT，這種字形也用於標題欄、選單和對話盒中顯示字串。因為 SYSMTR1 沒有更換字形，所以可以在視窗一建立之時，在 WM_CREATE 中取得一列的高度。
當應用程式呼叫 CreateWindowEx 建立視窗時，作業系統就會對應用程式的視窗函式發出一則 WM_CREATE 訊息。WM_CREATE 訊息是視窗函式最早收到的訊息之一，處理此訊息時通常是做初始化的工作，例如在 SYSMTR1 程式中就是於處理此訊息時，呼叫 GetTextMetrics，求得字元寬度、每一列高度，進而計算出每一欄起始位置的 X 座標。
問題是 GetTextMetrics 的第一個參數就是裝置內容代碼，前面提過在 WM_PAINT 可以呼叫 BeginPaint 取得裝置內容代碼，那麼在 WM_CREATE 如何獲得裝置內容代碼呢？這也不難，可以呼叫 GetDC。GetDC 可以在處理不是 WM_PAINT 訊息中，獲得裝置內容代碼，當然在處理完相關作業後必須呼叫 ReleaseDC，釋放裝置內容以節約資源。
想要在處理非 WM_PAINT 訊息中獲得裝置內容代碼，可以呼叫 GetDC，它只有一個參數，就是要取得裝置內容的視窗代碼，回傳值就是裝置內容代碼，如果失敗回傳值為 0。GetDC 的原型是：
invoke GetDC,\
hWnd ; handle of window
invoke ReleaseDC,\
hWnd,\ ; handle of window
hDC ; handle of device context
ReleaseDC 則是釋放 hWnd 的裝置內容，如果成功回傳值為 1，失敗為 0。GetDC 與 ReleaseDC 必定成對存在，畢竟用完之後得釋放，以節約系統資源。
當使用者以滑鼠拖拉視窗邊框、按下視窗右上角的最小化或最大化按鈕、或是視窗從隱藏變為顯示……等操作，會涉及到改變視窗大小時，Windows 會對視窗函式發出 WM_SIZE 訊息。這時候 wParam 參數是下面幾個數值之一：
WM_SIZE 的 lParam 中，0∼15 位元是改變大小之後工作區的寬度，16∼31 位元則是其高度。
lstrlen 是 Windows API，它的語法是：
invoke lstrlen,\
lpString ; address of string to count
lstrlen 只有一個參數，以零結尾的字串位址。lstrlen 會利用此位址，來計算該位址上的字串長度，此長度即為回傳值，且不包含結尾的零，以字元為單位。
無號數與有號數中的號，指的是正負符號。在數學上，正數不需特別表示，負數只需在數值前加上負號，即「－」，就可以了。例如「3」是正數，「－3」是負數，兩者相加為零，且兩者與零都相差三，在數線上兩者與零的距離都相同，但 3 在右邊，－3 在左邊。那麼在電腦的記憶體中，如何表示負數呢？
在電腦中以最高位元表示符號，如果最高位元是零，表示正數；最高位元是一，表示負數。最高位元，也可稱為符號位元（sign bit）。右圖是以一個位元組（八個位元）為例，最高位元是第七位元，就是符號位元，以「S」表示。扣除符號位元還剩七個位元。假如符號位元是零，剩下的七個位元能表示 27 個數；假如符號位元是一，剩下的七個位元也能表示 27 個負數。換句話說，正數或負數的個數本該是一樣的。但是符號位元是零，剩下的七個位元也均為零，那麼這個數就是零；零不是正數也不是負數，這樣負數就比正數多一個。
假如把八個位元所能表示的數由零開始，一個一個接起來，變成下圖的圓環。首先看到零的位置，零的右邊是一、二、三……順時針繞一圈後到 FD、FE、FF，又回到零。
如果把零兩邊的兩數相加，亦即「01＋FF」，會得到「100」，假如結果只看八位元的結果，就只有「00」，最左邊的「1」是第八個位元，如右圖。同理，把零左右兩邊相距兩格的「02」與「FE」相加，且結果只看八個位元，也是零。這跟距離與零等距離的兩正數與負數相加，結果為零的原理一樣。這也就是為什麼把「FF」訂為「－1」、「FE」訂為「－2」……。
可能會有記憶裡很好的讀者問道，第一章提到二進位的「1111 1111」，相當於十六進位的「FF」，是十進位的「255」，現在怎麼又變成了「－1」了呢？原來記憶體中的數值完全由程式來解釋到底代表什麼，所以「FF」可以代表「255」，也可以是「－1」。更有甚者，例如十六位元的「A9B1」，當程式解釋為無號數時是「43441」，解釋為有號數時是「－22095」，甚至也可以解釋為萬國碼的文字，那是爪哇文「ꦱ」，如果解釋成 BIG5 碼則是中文的「店」。
JL 與 JLE、JG 與 JGE 的語法是
JL 標記 ;若小於則跳躍 JLE 標記 ;若小於或等於則跳躍 JG 標記 ;若大於則跳躍 JGE 標記 ;若大於或等於則跳躍
這四個指令通常與 CMP 指令搭配，用來比較有號數的大小，然後依據結果是否發生跳躍。以 JL 為例子，像下面的程式：
cmp al,22
jl ok
比較 AL 暫存器與常數 22，若 AL 小於 22，那麼就跳躍至 ok 標記處。要注意的是，JE/JLE 是否跳躍，是要把 AL 當成有號數來比較。如果要比較無號數，那麼必須用 JB。同樣的，JG 與 JGE 是將兩個運算元當做有號數來比較，若前者較大或等於，那麼才發生跳躍。
下面的兩個例子說明了有號數和無號數的比較。左右兩欄中的 AL 暫存器內之值均為「FF」，兩邊都是 AL 與 22 比較。先說比較的結果，左欄會發生跳躍至「ok」標記處，而右欄不發生跳躍。
| mov al,0ffh cmp al,22 j1 ok | mov al,0ffh cmp al,22 jb ok |
原因是左欄採用「JL」指令，必須把比較的兩個運算元都看成有號數來比較，AL 中的「FF」是「－1」，比 22 小，故發生跳躍。而右欄採用「JB」，必須把比較的兩個運算元都看成無號數，「FF」等於 255，比 22 大，故不發生跳躍。
最後整理如下表。表中的「G」是 greater 的意思，「L」是 less 的意思，「A」是 above 的意思，「B」是 below 的意思。
| 有號數 | JG（若大於，則跳躍） JGE（若大於或等於，則跳躍） | JL（若小於，則跳躍） JLE（若小於或等於，則跳躍） |
| 無號數 | JA（若高於，則跳躍） JAE（若高於或等於，則跳躍） | JB（若低於，則跳躍） JBE（若低於或等於，則跳躍） |
x86 指令的 MOV 指令，來源運算元與目的運算元的長度要相同，也就是說你無法把一個存於 16 位元暫存器內的數值，用 MOV 指令移到 32 位元的變數中，反之亦然。但用 MOVZX 與 MOVSX 可以把長度較短的來源運算元移到長度較長的目的運算元中，當然這兩個指令仍然無法把長度較長的來源運算元移到較短的目的運算元中，因為這樣會損失高位元中的資料。
使用 MOVZX 時會把長度較短的來源運算元移到較長的目的運算元中，而目的運算元多出來的所有位元均設為零，MOVZX 中的「Z」就是 zero 的意思。底下是 MOVZX 的語法：
MOVZX r16,r/m8 MOVZX r32,r/m8 MOVZX r64,r/m8 MOVZX r32,r/m16 MOVZX r64,r/m16
MOVZX 的目的運算元可以是 r16、r32、r64，分別代表 16 位元、32位元、64位元的暫存器。來源運算元可以是 r/m8、r/m16，分別是 8 位元、16 位元的暫存器或記憶體變數。例如底下的例子：
mov eax,11112222H
mov cl,88H
movzx eax,cl
結果 EAX 是 0000 0088H，EAX 中比 CL 多出來的 24 位元均設為零。
MOVSX 的語法與 MOVZX 的語法一樣，底下是 MOVSX 的語法：
MOVSX r16,r/m8 MOVSX r32,r/m8 MOVSX r64,r/m8 MOVSX r32,r/m16 MOVSX r64,r/m16
MOVSX 指令會把長度較短的來源運算元移到較長的目的運算元中，而目的運算元多出來的所有位元均設為來源運算元的最高位元。對有號數來說，來源運算元的最高位元，其實就是符號。若最高位元為零，表示正數；為一，表示負數。不論是正數還是負數，經過 MOVSX 移動資料到目的運算元之後，其值仍然相同，但位元數變多了，能夠運算的範圍也變大。例如底下的例子：
mov eax,11112222H
mov cl,88H
movsx eax,cl
EAX 最後會變成 0FFFF FF88H。CL 的最高位元為「1」，因此執行 MOVSX 之後，EAX 比 CL 多出來的部分全設為「1」。
要瞭解 TEST 指令，應先說明 AND 指令，因為它們幾乎一模一樣。AND 指令的語法是
AND 目的運算元,來源運算元
這個指令是將目的運算元與來源運算元做 AND 運算，再將結果存入目的運算元。AND 翻譯成「且」的意思，這種運算是只有當兩個條件都成立時才為真。
例如你放學回家，媽媽說：「要寫完今天的作業並且預習完明日的功課才能玩電腦。」意思就是如果你「今日作業」和「預習明日功課」只要有一項沒做完，就不能「玩電腦」，只有當兩項都做好了才可以玩電腦。
在電腦中，「1」表示真或成立的意思，「0」表示偽或不成立的意思。所以，只有當兩個數都為一，做 AND 運算時，其結果才為一，只要運算的兩數有一個為零，結果就為零。AND 運算的真值表如下：
0 AND 0＝0 0 AND 1＝0 1 AND 0＝0 1 AND 1＝1
AND 指令中的目的運算元可以是暫存器或記憶體變數，來源運算元可以是常數、暫存器或記憶體變數，但是來源運算元與目的運算元不可同為記憶體變數。來源運算元與目的運算元的長度必須一致，做 AND 運算時，相對應的位元互相運算，亦即來源運算元的第 0 位元與目的運算元第 0 位元做 AND 運算、來源運算元的第 1 位元與目的運算元第 1 位元做 AND 運算……其餘依此類推。
做完「且」運算之後，CPU 會清除進位旗標與溢位旗標，並根據運算結果改變符號旗標與零值旗標，而輔助旗標之值無意義。
舉個例子說明。如右圖的 DL 暫存器之值為 24H，執行「AND DL,0FH」時，把每個位元對齊後，每個位元做 AND 運算後，結果如最下面黃字所示。因為最後結果不是零，故 CPU 會清除零值旗標；最後結果的最高位是零，故 CPU 會清除符號旗標。
值得一提的是，0FH 這個數值，較高的四個位元均為 0，因此不管 DL 較高的四個位元是什麼，與其做 AND 運算後均為 0；而較低的四個位元均為一，也不管 DL 較低的四個位元是什麼，其數值保持不變。像上面這樣，把一個整數的某些位元清除 ( 清除的意思是變為 0 )，而保留其他位元的過程稱為「遮罩」( mask )，方法很簡單，先設定一數讓要遮罩的位元都設為零，然後和原整數做 AND 運算就可以了。
TEST 指令的語法是：
TEST 目的運算元,來源運算元
TEST 指令會使目的運算元與來源運算元做「且」運算，然後清除進位旗標與溢位旗標，並依據結果改變符號旗標與零值旗標，而輔助旗標之值無意義；但是，TEST 並不會將運算結果寫入目的運算元內，這是與 AND 指令不同的地方。可能會有人產生疑問，如果不保存運算結果，那麼，TEST 指令有甚麼用呢？底下舉兩個例子：①檢驗一數是正數還是負數 ( 見 DOS 組合語言第十四章 )、②檢驗一數是奇數還是偶數。
因為一數的最右邊那位數決定了此數是奇數還是偶數 ( 見第一章註三 )，不論是以二進位、十進位或十六進位表示，都是一樣。可以以 TEST 指令達到目的。例如要檢驗 AL 暫存器之值是奇數還是偶數，可以用底下的程式：
test al,1
jz even
odd: ⁝ ;AL為奇數
⁝
even: ⁝ ;AL為偶數
這六個 x86 指令都是將原來占用較少位元的資料擴充成較多位元的資料，也可以把它們視為能改變資料類型的指令。因為作用類似，所以在這裡一併介紹，這六個指令可分為兩類：①CBW、CWDE、CDQE 與 ②CWD、CDQ、CQO。先說 CBW 指令。
CBW 指令是「convert byte to word」的意思，意即將位元組的數值變成字組，其語法是
CBW
表面上 CBW 沒有運算元，但其實是有個隱藏的運算元，那就是 AX 暫存器。CBW 會把存於 AL 的數值，變成存於 AX。方法是把 AL 的符號位元複製到 AX 的第 8∼15 位元之中。在二進位數值中，最高位元是符號位元，若最高位元為 1，表示負數；若最高位元為 0，表示正數。
若 AL 的第 7 位元為 0，執行完 CBW 後，AH 內所有位元都變為 0；若 AL 的第 7 位元為 1，執行完後，AH 內所有位元變為 1。也就是說，CBW 會把 AL 內的符號，延伸到 AH 內。這樣就能把 AL 中的有號數，擴充至 AX。
例如下圖 AX 為 0FF65H，AL 為 65H，第七位元是零。當執行 CBW 後，AL 上的第七位元擴充到 AH 暫存器，使 AH 上的每個位元都變成 0。
CWDE 指令是「convert word to doubleword」的意思，把 AX 的第 15 位元複製到 EAX 的第 16∼31 位元。CDQE 指令「convert doubleword to quadword」的意思，它把 EAX 的第 31 位元複製到 RAX 的第 32∼63 位元。
CWD 指令雖然也是「convert word to doubleword」，但卻是把 AX 的第 15 位元複製到 DX 的所有位元內。同樣，CDQ 是把 EAX 的第 31 位元複製到 EDX 的所有位元內；CQO 是把 RAX 的第 63 位元複製到 RDX 的所有位元內。
最後整理成下表：
| 用途 | 指令 | 說明 | 指令 | 說明 |
| 位元組變字組 | CBW | AL 的符號位元→AX | ||
| 字組變雙字組 | CWDE | AX 的符號位元→EAX | CWD | AX 的符號位元→DX:AX |
| 雙字組變四字組 | CDQE | EAX 的符號位元→RAX | CDQ | EAX 的符號位元→EDX:EAX |
| 四字組變八字組 | CQO | RAX 的符號位元→RDX:RAX | ||
陣列 ( array ) 是許多資料類型相同的資料集合在一起所形成的一種資料結構。在組合語言裏，可以用任何已知的資料類型或是自行宣告的結構體定義一個陣列，在陣列中的每一筆資料都稱為元素 ( element )，每個元素都以「,」分隔。如果元素太多，一行寫不下，可以在一行最後一個元素之後加上「,」，然後換行。例如定義一個 10 以下質數所形成的 prime1 陣列，如下：
prime1 DB 2,3,5,7
prime2 DB 2,3,5,7,11,13,17,19,23,29,31,
37,41,43,47
love DB "I love my wife so much!"
prime2 也是一個陣列，由 15 個元素組成，每個元素的資料類型都是 BYTE，而且有換行。最後一個例子，雖然 love 是一個字串，但是它也符合由許多資料類型相同的資料形成的集合，此字串也可以看成是陣列。像 love 就是由 23 個元素，每個元素都是一個位元組形成的陣列。
再回到 SYSMTR1 程式，要顯示 GetSystemMetrics 的參數，nIndex，有 95 種可用的不同數值，各以長短不一的名稱表示；另外，這 95 種數值的說明，長度也不同，視為有 95 筆資料。要存取某一筆資料，並不容易。此處，小木偶以每一筆資料的起始位址集合起來，形成一個有 95 個元素，名為「aryPt」的陣列 ( ary 是 array 之意，Pt 是指標，pointer 的意思 )。像底下的樣子：
aryPt DQ n00,n01,n02,n03,n04……n94
在 64 位元的作業系統中，位址也是以 64 位元表示，64 位元相當於四字組 ( quard word )，因此上式以「DQ」定義此陣列。右圖是 aryPt 陣列在記憶體中的情形。每個黃色框代表一個四字組長的記憶體，存放著每一筆資料的位址，由第零筆資料的位址開始直到第 94 筆，也可以把每個黃色框看成存放著一個元素。四字組其實就是八個位元組，所以每個框框又再分成八等分，可由框框下緣看到。
在每個黃色框框下方，有磚紅色的箭頭指著每個元素的起始位址。假設第零個元素的起始位址是 x，那麼第一個元素的起始位址就是 x＋8，第二個元素的起始位址就是 x＋16……。因此要取得第 n 個元素 ( n 由零開始 ) 的位址並不難，就只需要計算 8×n 再加上 aryPt 起始位址即可，如下面的程式：
xor r10,r10 ;使R10變為0 lea r9,aryPt ;使R9變為aryPt的起始位址 mov r10d,n shl r10,3 ;R10＝8×n add r9,r10 ;R9＝aryPt陣列中，第n的元素的位址
執行過上面程式之後，R9 暫存器之數值，就是第 n 個元素的位址。此位址上就存有第 n 筆資料的起始位址。將這第 n 筆資料的起始位址讀取出來 ( 這種讀取記憶體資料的方式稱為間接定址 ) 之後，就可以存取第 n 筆資料的參數值、參數名稱及參數之說明。程式碼如下：
mov r11,[r9] ;R11＝第 n 筆資料的起始位址
movzx r10,WORD PTR [r11]
R11 暫存器就是第 n 筆資料的起始位址，可以用 R11 去存取這筆資料的參數值、參數名稱。像上面的 R10 就是第 n 筆資料的參數值。假如這樣還很難瞭解，那麼可以用 x64dbg 載入 SYSMTR1.EXE，在處理 WM_PAINT 訊息的程式中，有一道「lea r9,aryPt」指令，在此處設置中斷點，就能得到 aryPt 陣列的起始位址，並觀察之。
以 x64dbg 觀察 aryPt 陣列，假設它在記憶體位址 7FF606173263 處，也是第零個元素的位址 ( 下面資料的白色部分 )；紅色部分則是第二個元素的位址。如果你的 aryPt 陣列的起始位址與前面不同，那是很正常的。因為作業系統總是找到有足夠的記憶體可用，就會將程式載入至該記憶體內，而在此之前，執行多少程式以及各個程式所消耗的記憶體都會影響使用記憶體的多寡，所以 aryPt 陣列的起始位址應該會與下面的不同。
00007FF606173260 65 72 00 F0 20 17 06 F6 7F 00 00 14 21 17 06 F6 er.簸 ..繹....!..繹 00007FF606173270 7F 00 00 39 21 17 06 F6 7F 00 00 62 21 17 06 F6 ...9!..繹...b!..繹 00007FF606173280 7F 00 00 8E 21 17 06 F6 7F 00 00 B1 21 17 06 F6 ....!..繹...簣!..繹
再依據 aryPt 的起始位址，7FF6061720F0 ( 白色部分 )，可以用 x64dbg 觀察該位址的內容如下 ( 淡藍色的是第二筆資料 )：
00007FF6061720F0 00 00 53 4D 5F 43 58 53 43 52 45 45 4E 00 50 72 ..SM_CXSCREEN.Pr
00007FF606172100 69 6D 61 72 79 20 64 69 73 70 6C 61 79 20 77 69 imary display wi
00007FF606172110 64 74 68 00 01 00 53 4D 5F 43 59 53 43 52 45 45 dth...SM_CYSCREE
00007FF606172120 4E 00 50 72 69 6D 61 72 79 20 64 69 73 70 6C 61 N.Primary displa
00007FF606172130 79 20 68 65 69 67 68 74 00 02 00 53 4D 5F 43 58 y height...SM_CX
00007FF606172140 56 53 43 52 4F 4C 4C 00 56 65 72 74 69 63 61 6C VSCROLL.Vertical
00007FF606172150 20 73 63 72 6F 6C 6C 20 62 61 72 20 77 69 64 74 scroll bar widt
假設現在程式要印出第二筆資料，也就是要印出「SM_CXVSCROLL 2 Vertical scroll bar width……」，那麼首先要計算 aryPt 中第二個元素位址，計算此位址的程式碼如下：
xor r10,r10 ;使R10變為0 lea r9,aryPt ;使R9變為aryPt的起始位址，R9＝7FF606173263 mov r10d,i ;R10＝2，第2個元素 shl r10,3 ;R10＝16D＝10H，見第二章SHL指令 add r9,r10 ;R9＝aryPt陣列第2個元素的位址＝7FF606173273
第二步，經過上述程式，R9 內就是第二個元素的位址，讀取此位址中的數值，該數值就是第二筆資料的起始位址。程式碼如下：
mov r11,[r9] ;到R9所指位址7FF606173273，讀取該位址之值，存入R11，R11＝7FF606172139
第三步，依據第二筆資料的起始位址，可以讀取 GetSystemMetrics 的參數值、參數名稱、參數說明等資料，程式碼如下：
movzx r10,WORD PTR [r11] ;到R11所指位址7FF606172139，讀取該位址一個字組之值，R10＝0002
mov nIndex,r10d
add r11,2
mov pt1,r11 ;pt1＝R11＝nIndex名稱位址＝7FF60617213B
invoke lstrlen,r11
mov len1,rax ;len1＝nIndex名稱長度＝0C
inc rax
add rax,pt1
mov pt2,rax ;pt2＝RAX＝nIndex的說明字串＝7FF606172148
「.if/.elseif/.else/.endif」巨集是諸位先進所撰寫的，非 ML64 的保留字，故有區分大小寫 ( 亦即都必須照底下的大小寫來寫，否則會發生錯誤 )。它的語法有三種，先說最簡單的一種：
.if 判斷式
程式片段
.endif
上面這段程式碼是說，當判斷式為真時，執行程式片段內的程式碼；若判斷式為假，則跳至 .endif 之後的程式碼執行，而不執行程式片段內的程式碼。判斷式的寫法，跟「.while/.break .if/.endw」巨集的判斷式相同，請參閱第七章。
第二種語法是：
.if 判斷式
程式片段一
.else
程式片段二
.endif
上面的程式碼是說，當判斷式為真時，執行程式片段一裡面的程式碼，待執行完後跳至 .endif 之後的程式碼繼續執行；若判斷式為假，則執行程式片段二裡面的程式碼，執行完之後也跳至 .endif 之後的程式碼繼續執行。
第三種語法較為複雜：
.if 判斷式一
程式片段一
.elseif 判斷式二
程式片段二
.elseif 判斷式三
程式片段三
⁝
.else
程式片段
.endif
上面的程式碼是說，當判斷式一為真時，執行程式片段一裡面的程式碼，待執行完後跳至 .endif 之後的程式碼繼續執行；若判斷式一為假，且判斷式二為真，則執行程式片段二裡面的程式碼，執行完之後也跳至 .endif 之後的程式碼繼續執行；若判斷式一與判斷式二均為假，且判斷式三為真，則執行程式片段三裡面的程式碼，執行完之後也跳至 .endif 之後的程式碼繼續執行……；若以上判斷式均為假，就執行程式片段內的程式碼，執行完之後也跳至 .endif 之後的程式碼繼續執行。.else 與程式片段可以省略，如果省略，那麼所有判斷式為假時，就不會執行 .if 到 .endif 之間的任何程式片段，而是直接跳至 .endif 之後的程式執行。
SYSMTR1.ASM 與 SYSMTR.INC 檔案有點兒大，將其壓縮成 SYSMTR1.RAR，儲存於 MEGA 雲端裡。這裡，小木偶不打算將 SYSMTR1.ASM 完整列出來並解說，因為篇幅太大。而且前面說過，Windows 程式在註冊視窗類別、建立視窗、訊息迴圈等原理都一樣，用不著解釋。最需要解說的是處理 WM_CREATE、WM_SIZE、WM_VSCROLL、WM_PAINT 四則訊息的過程。
SYSMTR1.ASM 在處理 WM_CREATE 訊息時，呼叫 GetTextMetrics 以獲取字元的相關資料。不過 GetTextMetrics 的第一個參數就是裝置內容代碼，要在處理 WM_CREATE 訊息的過程中獲得裝置內容代碼，不能呼叫 BeginPaint，必須呼叫 GetDC，並且在使用完裝置代碼之後，呼叫 ReleaseDC 以釋放資源。
呼叫 GetTextMetrics 得到字元相關資料後，就可利用這些資料去計算三個重要的量：①一列的高度，存於 cyChar 變數中。②平均字元的寬度，存於 cxChar 變數中。③大寫字母的平均寬度，存於 cxCaps 變數中。
再根據平均字元的寬度、大寫字母的平均寬度，去計算 x1、x2、x3 三個常數。x1 是第二欄右緣的 X 座標，x2 是第三欄左緣的 X 座標，x3 是第四欄右緣的 X 座標，也是四個欄位的總寬度。在處理 WM_PAINT 訊息時，繪製由 GetSystemMetrics 得到的資料時，會用得著這三個常數，所以事先先計算好，保存在這些常數裡。下圖說明這三個常數。
由圖中可以知道，第一欄對齊左邊，X 座標均為 0，Y 座標每往下一列便增加 cyChar ( 淡藍色的三個座標 )。第二欄輸出的是數值，故對齊右邊，X 座標均相同 ( 就是 x1 )，Y 座標也是每往下一列便增加 cyChar ( 橙色的三個座標 )。第三欄是 GetSystemMetrics 參數的說明，對齊左邊，其左緣的 X 座標均為 x2，Y 座標也是每往下一列便增加 cyChar ( 黃色的座標 )。
x1 之值等於 MAXCHR_IDX×cxCaps+6×cxChar，這是因為 GetSystemMetrics 的參數名均為大寫字母，故用大寫字母的平均寬度 ( cxCaps ) 乘以 MAXCHR_IDX，MAXCHR_IDX 是參數名中字母最多的。後面的 6×cxChar 是再加上六個字元乘以字元的平均寬度，為何是六個字元呢？因為第一欄與第二欄之間用兩個空白作為間隔，還要再加上第二欄的數值最多是四位數，所以有六個字元。聰明的你，應該可以自行推導出 x2、x3，就不多說了。
底下是處理 WM_CREATE 訊息的程式碼：
|
122 123 124 125
126 127 128 129
130 131 132 133
134 135 136 137
138 139 140 141
142 143 144 145
146 147 148 149
150 151 152 153
154 155 156 157 158 |
.case WM_CREATE
invoke GetDC,hWnd
mov ps.hdc,rax
invoke GetTextMetrics,ps.hdc,ADDR tm
mov r10d,tm.tmAveCharWidth ;求得cyChar、cxChar、cxCaps
mov r9d,tm.tmHeight
mov cxChar,r10d ;cxChar＝tm.tmAveCharWidth＝字元平均寬度
add r9d,tm.tmExternalLeading;cyChar＝tm.tmHeight＋tm.tmExternalLeading
shl r10d,1 ; ＝字元高度，也是每一列的高度
mov cyChar,r9d
test tm.tmPitchAndFamily,1 ;若tm.tmPitchAndFamily的第零位元為0，表示
jz fixed_width ;固定寬度字元，cxCaps＝字元平均寬度
add r10d,cxChar ;若tm.tmPitchAndFamily的第零位元為1，表示
fixed_width: shr r10d,1 ;可變寬度字元，cxCaps＝字元平均寬度的1.5倍
mov cxCaps,r10d
;計算第一欄與第二欄以及兩欄之間的兩空格，共三項的總寬度，x1。
;x1＝MAXCHR_IDX×cxCaps+6×cxChar，x1為第二欄最右邊位置
mov rax,MAXCHR_IDX
mul r10d
mov r11d,cxChar
mov r9d,cxChar
mov x1,eax
shl r11d,2
shl r9d,1 ;R9D＝2×cxChar
add r11d,r9d ;R11D＝6×cxChar
add x1,r11d
;計算第三欄最左邊的位置，x2。x2＝x1＋2×cxChar
mov r8d,x1
add r8d,r9d
mov x2,r8d
;計算第四欄最右邊位置，x3。x3＝x2＋MAXCHR_NOTE×cxChar＋6×cxChar
mov rax,MAXCHR_NOTE
mov x3,r8d
mul cxChar
add x3,eax
add x3,r11d
invoke ReleaseDC,hWnd,ps.hdc |
本章篇幅已經太多了，有關 SYSMTR1.ASM 的說明，請見下一章。