要說明的是上面這張圖是將 stellar_blade.bmp 改存成 JPG 檔以節省網頁空間，檔案剩下 90692 位元組，幾乎變成原來的八分之一。在電腦上的圖片大致分成兩種，向量圖與點陣圖。向量圖是指像 AutoCAD 所存的 *.DWG 檔，或是像從前網際網路流行的 Flash，它們的圖片主要是以線、圓……等基本幾何圖形構成，例如畫一張人臉，只需一個橢圓當輪廓、兩個小圓當眼睛、一個三角形當鼻子、一個橢圓當嘴，然後各塗上適當顏色，而描述圓或橢圓只需要少數的幾個點或半徑即可，所以畫出一幅向量圖必須經過一些計算，著色，當圖形複雜時就會比較慢。向量圖的優點是檔案較小，因為只要存下少量的關鍵資料就可以了；此外就是，放大縮小都不會失真。
但是要存一張人物照或風景等照片，就沒有辦法用簡單的幾何圖形表示，這些就是點陣圖。一般可以把點陣圖看成是由許多點由左而右、由上而下一個點一個點（此處的點，一般稱為像素，見第七章）堆砌而成，雖然有些點陣圖不是這樣排列，但此處小木偶只是提一提這個觀念而已。而每一像素由不同的顏色表現出來，所以就可以顯出一幅圖片，例如副檔名為 BMP 的圖片（Bitmap 的縮寫，也稱為「位元圖」，檔案體積很大）。但是因為這樣的圖片檔案太大了，所以產生各式各樣的壓縮方式，而造成多種副檔名，如 GIF、JPG、PNG 等等。
這一章的主角是位元圖，也就是副檔名為 BMP 的圖片檔，它是沒有經過壓縮的點陣圖，也是 Windows 直接支援的。在這一章裏小木偶要介紹三個例子來說明如何將 BMP 圖片檔顯示在視窗的工作區內。要顯示的是 stellar_blade.bmp 檔，尺寸為 640×360，佔據 691254 位元組，圖片的樣子如下：要說明的是上面這張圖是將 stellar_blade.bmp 改存成 JPG 檔以節省網頁空間，檔案剩下 90692 位元組，幾乎變成原來的八分之一。
第一個例子是把 stellar_blade.bmp 製作成資源，第二、第三個例子在命令提示字元中輸入 stellar_blade.bmp 顯示 BMP 圖片檔；如果改用其他 BMP 圖片檔，也可以顯示該 BMP 圖片檔。第三個例子則利用 BitBlt 的特性，在顯示位元圖時對邊框稍做修飾。
先介紹第一個例子，VIEWBMP1 在視窗中顯示位元圖的原理及步驟，同時也介紹資源描述檔中的 BITMAP 區塊與這個例子會使用到的 Win64 API。
把 BMP 檔案顯示在視窗內，有許多種方法，VIEWBMP1 採用一種簡單的方法。在第八章曾提過，若要在工作區內顯示文字、圖片等資料，必須對該視窗工作區的裝置內容進行操作。將位元圖顯示於工作區也是如此，但稍有一點不一樣，步驟如下：
上面的步驟，可以用下圖說明：
可能你會有這樣的疑問：直接呼叫 SelectObject 將位元圖選入工作區裝置內容不就完成了嗎？為何要這樣麻煩呢？
大致上的原因有三個，第一是為了效率、第二是避免顯示過程中的閃爍與不穩定、第三是為了靈活性。使用記憶體裝置內容時，可以先在記憶體裝置內容中準備好要顯示在工作區的資料，然後一次將整個資料傳輸到視窗工作區的裝置內容，這比直接在視窗工作區的裝置內容中，逐一操作或繪製圖像更有效率。另外在不同操作或繪製時，可能需花費一些時間處理，如果 CPU 來不及處理便會造成閃爍、不穩定的現象，這也是為何會採用在記憶體裝置內容處理好再傳輸至視窗工作區的裝置內容。
我們可以在資源描述檔中，使用 BITMAP 來定義位元圖，其語法如下：
位元圖名稱 BITMAP 位元圖檔案名稱
位元圖名稱與位元圖檔案名稱都與前一章的 ICON 的規定一樣，請參考前一章。
CreateCompatibleDC 能在記憶體中建立與指定裝置內容相容的裝置內容，其原型如下：
invoke CreateCompatibleDC,\
hdc ; handle to DC
CreateCompatibleDC 只有一個參數，hdc，它是現有的裝置內容，CreateCompatibleDC 會建立與 hdc 相容的裝置內容。如果 hdc 為零，那麼 CreateCompatibleDC 會建立與應用程式螢幕相容的裝置內容。這種裝置內容是儲存在記憶體內，故也稱為記憶體裝置內容（memory device context），當記憶體裝置內容建立後，Windows 作業系統會以預設值設定記憶體裝置內容，例如前景和背景顏色設為黑色和白色、畫筆為黑色實線、畫刷為白色……等等。記憶體裝置內容可以像普通裝置內容一樣使用，例如設定屬性、獲取當前屬性、選擇畫筆……等等，甚至也能在它上面繪製文字或圖形。
如果 CreateCompatibleDC 執行成功，回傳值是記憶體裝置內容的代碼；如果執行失敗，回傳值為零。如果不再使用記憶體裝置內容，應呼叫 DeleteDC 將其銷毀。
DeleteDC 用於銷毀裝置內容，它只有一個參數，hdc，就是要銷毀的裝置內容代碼。DeleteDC 原型為：
invoke DeleteDC,\
hdc ; handle to DC
如果 DeleteDC 執行成功，回傳值是一；如果執行失敗，回傳值為零。此外要注意的是，呼叫 GetDC 得到的裝置內容，不再使用時，必須呼叫 ReleaseDC 將其釋放，不可呼叫 DeleteDC 銷毀它。
AdjustWindowRect 會根據所需的工作區的矩形大小計算所需的視窗大小，然後可以將計算後的視窗大小傳遞給 CreateWindowEx 來建立視窗。AdjustWindowRect 的原型是：
invoke AdjustWindowRect,\
lpRect,\ ; pointer to client-rectangle structure
dwStyle,\ ; window styles
bMenu ; menu-present flag
這三個參數的意義如下：
如果 AdjustWindowRect 執行成功，回傳值為一且 lpRect 所指位址上的 RECT 結構體會變成視窗左上角及右下角座標；如果 AdjustWindowRect 執行失敗，回傳值為零。
LoadBitmap 能從執行檔中的資源內載入指定的位元圖，其原型如下：
invoke LoadBitmap,\
hInstance,\ ; handle of application instance
lpBitmapName ; address of bitmap resource name
hInstance 是模組代碼，一般是呼叫 GetModuleHandle 得到。lpBitmapName 是位元圖資源的名稱，這個名稱是以零為結尾的字串，同時此名稱須與資源描述檔的位元圖名稱相同。另外，lpBitmapName 也可以是小於 65535 的正整數，代表位元圖的識別碼，如果是這樣的情況，那麼在資源描述檔中，BITMAP 前面的位元圖名稱也要使用相同的數值，作為識別碼。
如果 LoadBitmap 執行成功，回傳值是位元圖代碼；如果執行失敗，回傳值為零。用 LoadBitmap 載入的位元圖，不再使用之後要呼叫 DeleteObject 銷毀。
BitBlt 是把某個設備內容（稱為來源裝置內容）中的一塊矩形區域的數位資料傳輸到另一個設備內容（稱為目的裝置內容）之中，這些數位資料通常是圖案、文字等顏色組成的資料。BitBlt 的原型是：
invoke BitBlt,\
hdcDest,\ ; handle to destination DC
nXDest,\ ; x-coord of destination upper-left corner
nYDest,\ ; y-coord of destination upper-left corner
nWidth,\ ; width of destination rectangle
nHeight,\ ; height of destination rectangle
hdcSrc,\ ; handle to source DC
nXSrc,\ ; x-coordinate of source upper-left corner
nYSrc,\ ; y-coordinate of source upper-left corner
dwRop ; raster operation code
BitBlt 其實是「bit block transfer」的意思，其參數說明如下：
BitBlt 會在來源裝置內容（亦即 hdcSrc）中，把座標為（nXSrc, nYSrc）當做矩形的左上角座標，且該矩形寬為 nWidth、高為 nHeight，然後將該矩形範圍內的資料傳輸到目的裝置內容（亦即 hdcDest）中，左上角座標為（nXDest, nYDest）、與前述相同大小的矩形。
在傳輸過程中，BitBlt 也可以進行一些運算操作，BitBlt 最後一個參數是 dwRop，是 DWORD 長的正整數，它決定了當資料由來源裝置內容傳輸到目的裝置內容時，進行的操作。dwRop 的操作對象有三種：①來源裝置內容中指定的矩形範圍內的資料、②目的裝置內容指定矩形範圍內原本的資料以及③畫刷，但並不是每一種操作都會用得到這三種，有時只有一種，有時兩種或三種，有時甚至不需要，例如 BLACKNESS 就不需要。
其實操作方式也可看成是運算，有複製、或、且、互斥或、非五種，經過這些操作之後，再存入目的裝置內容指定矩形範圍內，因此在目的裝置內容中所指定矩形範圍內的圖案會發生變化。下表是常用的 dwRop，可以查閱 MSDN 得到更多資料。表中最後一欄的 S 代表來源裝置內容中指定的矩形範圍內的資料、D 代表目的裝置內容指定矩形範圍內的資料、B 代表畫刷。而操作後的結果會寫入 D。
| dwRop | 數值 | 說明 | 結果 |
| BLACKNESS | 42H | 使目的矩形填滿黑色 | 0 |
| WHITENESS | 0FF0062H | 使目的矩形填滿白色 | 1 |
| SRCCOPY | 0CC0020H | 將來源矩形的資料複製到目的矩形 | S |
| NOTSRCCOPY | 330008H | 來源矩形作非運算之後填入目的矩形 | not S |
| MERGECOPY | 0C000CAH | 來源矩形與目的裝置內容的畫刷作且運算後填入目的矩形 | S and B |
| SRCPAINT | 0EE0086H | 來源矩形與目的矩形作且運算後填入目的矩形 | S or D |
| SRCINVERT | 660046H | 來源矩形與目的矩形作互斥或運算後填入目的矩形 | S xor D |
如果 BitBlt 執行成功，回傳值是一；如果執行失敗，回傳值為零。VIEWBMP3 說明利用 BitBlt 的 dwRop 參數的例子。
SetBkMode 設定所指定的設備內容背景混合模式，背景混合模式用於文字、交錯畫刷（hatched brushes）和非實線的畫筆。SetBkMode 的原型是：
invoke SetBkMode,\
hdc,\ ; handle to DC
iBkMode ; background mode
hdc 是要設定設備內容的代碼，iBkMode 是要設定的模式。iBkMode 是想要設定的背景模式，有兩種選擇：①TRANSPARENT、②OPAQUE。前者是透明的，意思保持後面的背景圖案不變；後者是以當前背景色塗滿。如果 SetBkMode 執行成功，回傳值為原先的背景模式；如果執行失敗，回傳值為零。
GetObject 能獲得指定的圖形物件（graphics object）資料，此處的圖形物件可以是位元圖、畫筆、調色板、畫刷、字形。GetObject 的原型是：
invoke GetObject,\
hgdiobj,\ ; handle to graphics object
cbBuffer,\ ; size of buffer for object information
lpvObject ; buffer for object information
這三個參數的意義如下：
GetObject 能夠獲得許多種圖形物件的資料，不同種的圖形物件有不同的資料，這些資料會被存放於 lpvObject 所指的位址，此位址實際上是不同的結構體。例如假設要獲得位元圖的資料，那麼 hgdiobj 為位元圖代碼，lpvObject 為 BITMAP 結構體；假設要獲得畫筆的資料，那麼 hgdiobj 為畫筆代碼，lpvObject 為 LOGPEN 結構體……。
如果不確定第二、第三個參數，也可以使 lpvObject 為零，呼叫 GetObject 之後，回傳值就是 lpvObject 所指的位址需要的記憶體大小。然後可以再呼叫 GetObject，第二次呼叫時，第二個參數就是第一次呼叫的回傳值，並且在第三個參數指定的位址準備足夠大的記憶體空間（也就是回傳值大小），就能獲得 hgdiobj 物件的資料了。
如果 GetObject 執行失敗，回傳值為零。如果 lpvObject 不為零而且 GetObject 執行成功，那麼 lpvObject 會填上正確的資料且回傳值是所填資料有多少位元組；如果 lpvObject 為零而且 GetObject 執行成功，那麼回傳值是所填資料需要多少位元組存放。
如果呼叫 GetObject 時第一個參數是位元圖代碼，那麼得到的位元圖資料會存在 BITMAP 結構體中，底下是 BITMAP 結構體的欄位：
BITMAP STRUCT bmType LONG ? ;位元圖類型，必須是0 bmWidth LONG ? ;位元圖寬度，必須是正數 bmHeight LONG ? ;位元圖高度，必須是正數 bmWidthBytes LONG ? ;每一列占用多少個位元組 mPlanes WORD ? ;顏色面個數 mBitsPixel WORD ? ;每個像素需要多少位元 DWORD ? ;空的雙字組 mBits LPVOID ? ;位元圖資料的指標 BITMAP ENDS
首先要說明的是，如果你使用 WinInc 包含檔，那麼 BITMAP 是定義在 wingdi.inc 檔案內，但這個定義是錯的，少了上面以紫紅色標示的那一行，這一行的目的是讓以後的欄位都對齊 32 位元邊界。也就是說使以後的欄位起始位址的個位數不是 0 就是 8。如果使用的是 MASM64 SDK，那麼 BITMAP 是定義在 win64.inc 檔案內，這個定義是正確的。
底下說明 BITMAP 結構體中各欄位的意義：
| mBitsPixel | 每個像素有多少位元 | 顏色數 |
| 1 | 1 | 2 |
| 4 | 4 | 16 |
| 8 | 8 | 256 |
| 24 | 24 | 16777216 |
假設某個 BMP 圖片是真彩圖片，而第零列第零行的像素是黑色，第零列第一行的像素是白色，那麼 mBits 所指位址的記憶體內就是三個位元組的零，接下來的三個位元組都是 0FFh。這就是所謂的像素資料，這些像素資料構成一幅圖片。如果某個位元圖是 256 色，第零列第零行是黑色，同列第一行是白色，那麼 mBits 所指位址的記憶體是一個位元組的零，接著是一個位元組的 0FFh。因為不同顏色，資料類型不同，所以 mBits 的資料類型是 VOID。
VIEWBMP1 會由資源中載入 stellar_blade 位元圖，而後顯示於視窗工作區內。VIEWBMP1 會使用四個檔案：VIEWBMP1.ASM、VIEWBMP1.RC、eye.ico、stellar_blade.bmp，可以在這裏下載。底下是資源描述檔，VIEWBMP1.RC 的內容：
1 2 |
VIEWICO ICON eye.ico stellar_blade BITMAP stellar_blade.bmp |
底下是原始程式 VIEWBMP1.ASM 的內容：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88
89 90 91 92
93 94 95 96
97 98 99 100
101 102 103 104
105 106 107 108
109 110 |
;將BMP圖檔製作成BITMAP資源，然後以LoadBitmap載入顯示於螢幕上
OPTION CASEMAP:NONE
OPTION WIN64:7
INCLUDE WINDOWS.INC
INCLUDELIB GDI32.LIB
INCLUDELIB KERNEL32.LIB
INCLUDELIB USER32.LIB
;*****************************************************************************************
.CONST
szClassName DB "VIEWBMP1",0
szIconName DB "VIEWICO",0
szAppName DB "EVE - 劍星的女主角",0
szBmpName DB "EVE",0
;*****************************************************************************************
.DATA
hInstance DQ ? ;模組代碼
hwnd HWND ? ;視窗代碼
hBitmap HBITMAP ? ;位元圖代碼
bitmap BITMAP <> ;位元圖的資料
rcClient RECT <0,0,?> ;工作區矩形範圍
;*****************************************************************************************
.CODE
;-----------------------------------------------------------------------------------------
WndProc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL ps:PAINTSTRUCT,hdcMem:HDC
.switch uMsg
.case WM_PAINT
invoke BeginPaint,hWnd,ADDR ps
invoke CreateCompatibleDC,ps.hdc
mov hdcMem,rax
;把stellar_blade.bmp圖案繪製於記憶體裝置內容中
invoke SelectObject,hdcMem,hBitmap
;把szAppName字串繪製於記憶體裝置內容中
invoke SetBkMode,hdcMem,TRANSPARENT
invoke DrawText,hdcMem,OFFSET szAppName,-1,OFFSET rcClient,\
DT_SINGLELINE or DT_CENTER or DT_VCENTER
;把stellar_blade.bmp與szAppName字串的內容傳輸至視窗工作區裝置內容
invoke BitBlt,ps.hdc,0,0,bitmap.bmWidth,bitmap.bmHeight,hdcMem,0,0,SRCCOPY
invoke DeleteDC,hdcMem
invoke EndPaint,hWnd,ADDR ps
.case WM_DESTROY
invoke DeleteObject,hBitmap
invoke PostQuitMessage,0
.default
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endsw
xor rax,rax
ret
WndProc ENDP
;-----------------------------------------------------------------------------------------
main PROC
LOCAL wc:WNDCLASSEX,msg:MSG,rect:RECT
invoke GetModuleHandle,0
mov hInstance,rax
mov wc.cbSize,SIZEOF WNDCLASSEX
mov wc.style,CS_HREDRAW or CS_VREDRAW
lea rdx,WndProc
mov wc.lpfnWndProc,rdx
mov wc.cbClsExtra,0
mov wc.cbWndExtra,0
mov wc.hInstance,rax
invoke LoadIcon,hInstance,OFFSET szIconName
mov wc.hIcon,rax
mov wc.hIconSm,rax
invoke LoadCursor,NULL,IDC_ARROW
mov wc.hCursor,rax
mov wc.hbrBackground,COLOR_WINDOW+1
mov wc.lpszMenuName,0
lea rdx,szClassName
mov wc.lpszClassName,rdx
invoke RegisterClassEx,ADDR wc
;載入位元圖，以獲得位元圖的寬度與高度
invoke LoadBitmap,hInstance,OFFSET szBmpName
mov hBitmap,rax
invoke GetObject,hBitmap,SIZEOF BITMAP,OFFSET bitmap
mov r10d,bitmap.bmWidth ;R10D＝位元圖寬度
mov r11d,bitmap.bmHeight ;R11D＝位元圖高度
mov rcClient.right,r10d
mov rcClient.bottom,r11d
;計算能容納整張位元圖的視窗需要最小寬度與高度
mov rect.left,0
mov rect.top,0
mov rect.right,r10d
mov rect.bottom,r11d
invoke AdjustWindowRect,ADDR rect,WS_CAPTION or WS_SYSMENU,0
mov r10d,rect.right
mov r11d,rect.bottom
sub r10d,rect.left ;R10D＝計算完成後的視窗寬度
sub r11d,rect.top ;R11D＝計算完成後的視窗高度
;建立工作區恰好能容納整張位元圖的視窗
invoke CreateWindowEx,0,ADDR szClassName,ADDR szAppName,WS_CAPTION or\
WS_SYSMENU,50,50,r10d,r11d,0,0,hInstance,0
mov hwnd,rax
invoke ShowWindow,hwnd,SW_SHOWNORMAL
invoke UpdateWindow,hwnd
.while TRUE
invoke GetMessage,ADDR msg,0,0,0
.break .if rax==0
invoke TranslateMessage,ADDR msg
invoke DispatchMessage,ADDR msg
.endw
invoke ExitProcess,0
main ENDP
;*****************************************************************************************
END main |
組譯方式如下：
Microsoft Windows [版本 6.1.7601] Copyright (c) 2009 Microsoft Corporation. All rights reserved. C:\Users\wanker>uasm [Enter] →執行 UASM.BAT 批次檔，省了許多打字輸入，見第 11 章 UASM.BAT C:\Users\wanker>SET INCLUDE=C:\UASM\Include C:\Users\wanker>SET LIB=C:\UASM\lib64 C:\Users\wanker>SET PATH=C:\UASM;C:\UASM\bin64;C:\Windows\system32;C:\Windows;C: \Windows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\Program Fi les (x86)\UltraEdit-32 C:\Users\wanker>E: E:\>CD E:\HOMEPAGE\SOURCE\WIN64 LINK=/SUBSYSTEM:WINDOWS /DEBUG E:\HomePage\SOURCE\Win64>cd VIEWBMP [Enter] →切換至 VIEWBMP 子目錄 E:\HomePage\SOURCE\Win64\VIEWBMP>uasm64 -win64 viewbmp1.asm [Enter] UASM v2.56, Oct 27 2022, Masm-compatible assembler. Portions Copyright (c) 1992-2002 Sybase, Inc. All Rights Reserved. Source code is available under the Sybase Open Watcom Public License. VIEWBMP1.ASM: 110 lines, 3 passes, 138 ms, 0 warnings, 0 errors E:\HomePage\SOURCE\Win64\VIEWBMP>rc viewbmp1.rc [Enter] Microsoft (R) Windows (R) Resource Compiler Version 10.0.10011.16384 Copyright (C) Microsoft Corporation. All rights reserved. E:\HomePage\SOURCE\Win64\VIEWBMP>link viewbmp1.obj viewbmp1.res [Enter] Microsoft (R) Incremental Linker Version 14.25.28614.0 Copyright (C) Microsoft Corporation. All rights reserved. /SUBSYSTEM:WINDOWS /DEBUG E:\HomePage\SOURCE\Win64\VIEWBMP>
VIEWBMP1.ASM 中第 97 行呼叫 CreateWindowEx 時，第七、八個參數，nWidth、nHeight，指的是視窗大小，但是視窗四周有邊框，上面有標題欄，有時還有功能表，中間才是工作區，所以工作區的大小比視窗小。如果要使工作區恰好能容納整張位元圖，可以呼叫 AdjustWindowRect 來調整視窗大小。
不過 AdjustWindowRect 的第一個參數是工作區的大小，是資料類型為 RECT 結構體，其名稱為 rect 的區域變數（定義在第 57 行），並非以寬度和高度表示。所以得到位元圖的大小之後，把 rect 的四個欄位 left、top、right、bottom 分別填入適當的數值，left、top 設為零，right 設為位元圖的寬，bottom 為位元圖的高（見第 86∼90 行）。
呼叫 AdjustWindowRect 成功之後，計算所得的視窗大小存於 rect 變數之中，所以視窗的寬度等於 rect.right－rect.left，高度等於 rect.bottom－rect.top，在 VIEWBMP1.ASM 中相減之後的差值分別存於 R10D、R11D 暫存器裏面。然後以它們為參數呼叫 CreateWindowEx，見第 91∼98 行。
獲得位元圖的各項資料，一般是呼叫 GetObject，傳入的參數是位元圖代碼及資料類型為 BITMAP 的結構體。如果 GetObject 成功執行後，BITMAP 結構體內會填入該位元圖的各項資料。至於如何能由 BMP 圖片檔得到位元圖代碼？有兩種方法：①先將 BMP 圖片檔製作成資源，接著用 LoadBitmap 載入。②直接呼叫 LoadImage 載入 BMP 圖片檔。VIEWBMP1 使用的是前一種方法，見第 77∼80 行。第二、三個例子使用第二種方法。
上面兩件工作（獲得位元圖的大小、調整視窗大小）本應該放在 WM_CREATE 訊息中處理，但這時候視窗已經建立，雖然可以呼叫 Win64 API 改變視窗大小，但何必這麼麻煩？在呼叫 CreateWindowEx 時，就指定能顯示整張圖片的視窗寬度與高度不就好了嗎？因此這兩件事情才放在 main 裏處理。
毫無疑問，顯示 BMP 圖片必須在處理 WM_PAINT 時發生。見第 30∼40 行，這些步驟在本章一開始時，就已經說過了，主要就是依序呼叫 CreateCompatibleDC→SelectObject→BitBlt→DeleteDC。但為了證明記憶體裝置內容也能繪製文字，所以第 36 行，呼叫 DrawText 把 szAppName 字串繪製於記憶體裝置內容，然後呼叫 BitBlt 時，也能將這個字串傳輸至視窗工作區內而顯現出來。
第 35 行呼叫 SetBkMode 的原因是讓字串的背景變得透明，否則背景為白色，較不美觀。
VIEWBMP1 已解說完畢，剩餘沒說明的，前面已經提過，不再贅述。
本章第二個例子，VIEWBMP2 可以在命令提示字元中，輸入下面指令：
viewbmp2 filename
使用者在命令提示之後，輸入 VIEWBMP2 之後是一個或多個空白，然後是 filename，這 filename 就是 BMP 圖片檔的檔案名稱，可以包含磁碟機名、路徑名。然後再按下「ENTER」鍵，就能出現一個視窗，其工作區就是該 BMP 圖片檔的圖片。例如底下的例子，可以顯示 stellar_blade.bmp 圖片檔：
從上面可以得知，VIEWBMP2 必須要取得「命令列字串」，所謂命令列字串指的是在命令提示字元內使用者輸入的所有字元，但結尾不含 carriage return 字元（carriage return 是按下「ENTER」鍵生成的字元），而以零取代。例如上圖的例子，以紅色框框住的是輸入的指令，命令列字串便是「"viewbmp2 stellar_blade.bmp",0」，換句話說，使用者怎樣輸入，命令列字串就長得怎麼樣，就只是結尾是零。而程式名稱之後，或者說指令之後的「stellar_blade.bmp」，一般稱為參數或選項。那麼要如何取得命令列字串呢？可以呼叫 GetCommandLine 完成。
當然，VIEWBMP2 不限定只能觀看 stellar_blade.bmp 圖片檔，只要是位元圖，都能觀看。例如底下的例子是觀看 D: 磁碟機的圖片檔，「D:\PICTURE\97f1logu00.bmp」：
E:\HomePage\SOURCE\Win64\VIEWBMP>viewbmp2 d:\PICTURE\97f1logu00.bmp
GetCommandLine 可以獲得命令提示列上的字串。它沒有參數，所以呼叫方式可以直接使用 x86 指令，CALL，畢竟不論是 UASM 的 INVOKE 假指令還是 MASM64 SDK 的 invoke 巨集，都是為了將參數存入暫存器或堆疊的，既然 GetCommandLine 沒有參數，就可以直接使用 CALL 指令，當然要使用 invoke 也不是不行。底下是 GetCommandLine 的原型：
call GetCommandLine
GetCommandLine 的回傳值是命令列字串的位址。
除了得到命令列字串之外，VIEWBMP2 還要能分析命令列字元，以萃取出 BMP 圖片檔名稱。小木偶孤陋寡聞，不知道是否有 Win64 API 可以完成這件事情，但是可以用 x86 CPU 指令完成。在這之前，還得先獲得字串長度，這可以呼叫 lstrlen。
這四個指令很類似，先說明 SCASB，如果能瞭解它，另外三個就很容易瞭解了。
SCASB 是 scan string byte 的意思，翻成中文就是以位元組方式掃描字串，更進一步來說就是在某個字串中掃描，看看是否有指定的位元組。語法如下：
SCASB
指定的位元組必須是放在 AL 暫存器裏，被掃描字串的位址放在 RDI，每掃描一次會讓 RDI 指向下一個位址。如果像上式那樣，僅僅是 SCASB 指令，那就只掃描一次，其實就是把 AL 和 RDI 所指位址的記憶體內容比較，並使 RDI 指向下一個位址。比較結果如果相同，零值旗標設為一，否則為零。
所謂的下一個位址是依據方向旗標決定的，如果方向旗標為 UP，那麼 RDI 增加一；若方向旗標為 DN，RDI 減少一。如何設置方向旗標為 UP 或 DN，請參考第三章x86 指令：CLD 與 STD 一節。
不過，SCASB 通常會搭配 REPNE 或 REPE 使用。REPNE 是 repeat while not equal 的意思，意即不相等時重複；REPE 是 repeat while equal 的意思，意即相等時重複。假如寫成「REPNE SCASB」或「REPE SCASB」，這樣就能重複掃描。RDI 為要掃描的字串位址，RCX 為重複次數，每掃描一次，RCX 會減一，RDI 會根據方向旗標自動指向下一個位址。語法如下：
REPNE SCASB REPE SCASB
REPNE SCASB 的意思是如果不同就重複掃描；反過來說，如果相同就停止掃描。更進一步來說是指，當 AL 之內容與 RDI 所指位址上的內容不相等，就重複再掃描一次，當然 RDI 會指向下一位址同時 RCX 減一。這種過程會一直重複，直到找到與 AL 相同的位元組或是 RCX 減至零才停止。如果找到相同的位元組而停止，那麼會使零值旗標變為 ZR，同時 RDI 會指向找到相同位元組的下一位址。如果是 RCX 減至零都沒找著相同的，那麼會使零值旗標變為 NZ。
所以結論就是，REPNE SCASB 常用於在一字串中搜尋某個字元，如果找著了，零值旗標設為 ZR，但 RDI 並非指向所找到字元的位址，而是下一位址。如果找不著，零值旗標設為 NZ，且 RCX 為零。
REPE SCASB 的意思是如果相同就重複掃描；反過來說，如果不同就停止掃描。更進一步來說是指，當 AL 之內容與 RDI 所指位址上的內容相等，就重複再掃描一次，當然 RDI 會指向下一位址同時 RCX 減一。這種過程會一直重複，直到找到與 AL 不同的位元組或是 RCX 減至零才停止。如果找到不同的位元組而停止，那麼會使零值旗標變為 NZ，同時 RDI 會指向找到不同位元組的下一位址。如果是 RCX 減至零都沒找著不同的，那麼會使零值旗標變為 ZR。
所以結論就是，REPE SCASB 常用於在一字串（此字串的前面數個字元都是相同的）中搜尋首次出現不同的字元，如果找著了不同字元，零值旗標設為 NZ，RDI 指向首個不同字元的下一位址。如果都沒找著不同字元，零值旗標設為 ZR，且 RCX 為零。
最後要說的是，REPE 與 REPZ 是一樣的，REPNE 與 REPNZ 是一樣的。在組合語言裏，比較兩數相同是採用減法，只是不將結果寫入暫存器內，僅改變零值旗標。因此如果兩數相同，相減之後為零，零值旗標會設為 ZR，所以相同跟零值是一樣的。
在 VIEWBMP2.EXE 中，獲得命令列字串位址之後，分析它就知道，命令列字串前面幾個字元是 VIEWBMP2，而後是空白，有可能是一個空白或多個空白，然後才是要顯示在視窗內的 BMP 圖片檔的檔名。所以小木偶的想法是使 EDI 指向命令列字串位址，然後用 REPNE SCASB 搜尋空白字元。找到空白字元之後，為了怕使用者輸入多個空白字元，就使用 REPE SCASB 搜尋首個不是空白字元。程式碼如下：
;get_1st副程式用來搜尋命令列字串中第一個參數的位址 ;輸入：pszCmdLine－命令列字串的位址 ;輸出：RAX－若找到第一個參數，RAX＝第一個參數位址 ; 若沒找參數，RAX＝0 get_1st PROC USES rdi pszCmdLine:QWORD invoke lstrlen,pszCmdLine mov rdi,pszCmdLine mov rcx,rax ;RCX＝命令列字串長度 cld mov al," " ;AL＝空白字元 repne scasb ;在EDI所指的位址中搜尋空白字元 jnz n_find ;若沒找到，跳躍至n_find:處 repe scasb ;若找到空白，繼續搜尋非空白，若能找到非空白這就是第一個參數 jz n_find dec rdi mov rax,rdi ;若找到第一個參數，RAX＝第一個參數位址 jmp exit n_find: xor rax,rax ;沒找到參數 exit: ret get_1st ENDP
與 SCASB 指令類似的 x86 指令還有 SCASW、SCASD、SCASQ，它們與 SCASB 的差別只在於一次掃描的資料長度，SCASB 一次掃描一個位元組，所以 RDI 每次增減一。SCASW 一次掃描一個字組，所以 RDI 每次增減二；SCASD 一次掃描一個雙字組，所以 RDI 每次增減四；SCASQ 一次掃描一個四字組，所以 RDI 每次增減八。它們也可以與 REPE、REPNE 搭配，重複次數均存放於 RCX。
LoadImage 能夠由檔案或資源中載入圖示、游標、動態游標、位元圖等不同形式的圖片檔。其原型為：
invoke LoadImage,\
hinst,\ ; handle of the instance that contains the image
lpszName,\ ; name or identifier of image
uType,\ ; type of image
cxDesired,\ ; desired width
cyDesired,\ ; desired height
fuLoad ; load flags
下面是各參數的說明：
| fuLoad | 數值 | 說明 |
| LR_DEFAULTCOLOR | 0 | 系統預設值，見 cxDesired、cyDesired 的說明。 |
| LR_CREATEDIBSECTION | 2000H | 當 uType 為 IMAGE_BITMAP 時，LoadImage 傳回 DIB 位元圖，而不是 DDB 位元圖。這對於載入 DIB 位元圖很有幫助。 |
| LR_DEFAULTSIZE | 40H | 見 cxDesired、cyDesired 的說明。 |
| LR_LOADFROMFILE | 10H | 由檔案載入位元圖、圖示、游標，lpszName 為對應的檔案名稱。 |
| LR_LOADMAP3DCOLORS | 1000H | 如果載入圖片的顏色超過 256 色，就不要使用此選項。此選項是為了突出 3D 視覺，而調整調色盤中顏色，如下： 深灰色，RGB(128,128,128) 變為 COLOR_3DSHADOW； 灰色，RGB(192,192,192) 變為 COLOR_3DFACE； 淺灰色，RGB(223,223,223) 變為 COLOR_3DLIGHT。 |
| LR_MONOCHROME | 1 | 以黑、白方式載入圖片。 |
| LR_SHARED | 8000H | 如果多次呼叫 LoadImage 載入相同圖片資源，如果 fuLoad 有使用 LR_SHARED，則直接使用原先的圖片代碼。如果沒設定 LR_SHARED，則會重新載入且傳回不同的代碼。使用此旗標時，系統會在不再需要資源時銷毀資源。LR_SHARED 不可用於具有非標準大小的圖片、載入之後可能會變更的圖片，或是從檔案載入的圖片。 |
用 LoadImage 載入的位元圖，不再使用之後要呼叫 DeleteObject 銷毀；載入的游標，要呼叫 DestroyCursor 銷毀；載入的圖示，要呼叫 DestroyIcon 銷毀。如果 LoadImage 執行成功，回傳值為圖形物件的代碼；如果執行失敗，回傳值為零。
VIEWBMP2 需要 VIEWBMP2.ASM、VIEWBMP2.RC、eye.ico 三個檔案，完整的內容可以在這裏下載。底下是 VIEWBMP2.ASM 的部分內容：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 ⁝
97 98 99 100
101 102 103 104
105 106 107 108
109 110 111 112
113 114 115 116
117 118 119 120
121 122 123 124
125 126 127 128
129 130 131 132
133 134 135 136
137 138 139 140
141 142 143 144 |
;於命令提示字元中輸入「VIEWBMP2 filename」，其中的filename是BMT圖片檔，就能顯示於螢幕上
OPTION CASEMAP:NONE
OPTION WIN64:7
INCLUDE WINDOWS.INC
INCLUDELIB GDI32.LIB
INCLUDELIB KERNEL32.LIB
INCLUDELIB USER32.LIB
;*****************************************************************************************
.CONST
szClassName DB "VIEWBMP2",0
szIconName DB "VIEWICO",0
szAppName DB "VIEW BMP2",0
sNotFindBmp DB "錯誤的BMP圖檔，或無法開啟BMP圖檔"
;*****************************************************************************************
.DATA
hInstance DQ ? ;模組代碼
hwnd HWND ? ;視窗代碼
hBitmap HBITMAP ? ;位元圖代碼
bitmap BITMAP <> ;位元圖的資料
rcClient RECT <0,0,?> ;工作區矩形範圍
pszFileName LPSTR ? ;命令列中使用者輸入的BMP檔名位址
;*****************************************************************************************
.CODE
;-----------------------------------------------------------------------------------------
;get_1st副程式用來搜尋命令列字串中第一個參數的位址
;輸入：pszCmdLine－命令列字串的位址
;輸出：RAX－若找到第一個參數，RAX＝第一個參數位址
; 若沒找參數，RAX＝0
get_1st PROC USES rdi pszCmdLine:QWORD
invoke lstrlen,pszCmdLine
mov rdi,pszCmdLine
mov rcx,rax ;RCX＝命令列字串長
cld
mov al," " ;AL＝空白字元
repne scasb ;在EDI所指的位址中搜尋空白字元
jnz n_find ;若沒找到，跳躍至n_find:處
repe scasb ;若找到空白，繼續搜尋非空白，若能找到非空白這就是第一個參數
jz n_find
dec rdi
mov rax,rdi ;若找到第一個參數，RAX＝第一個參數位址
jmp exit
n_find: xor rax,rax ;沒找到參數
exit: ret
get_1st ENDP
;-----------------------------------------------------------------------------------------
WndProc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL ps:PAINTSTRUCT,hdcMem:HDC
.switch uMsg
.case WM_PAINT
invoke BeginPaint,hWnd,ADDR ps
invoke CreateCompatibleDC,ps.hdc
mov hdcMem,rax
;把使用者輸入的BMP圖片檔繪製於記憶體裝置內容中
invoke SelectObject,hdcMem,hBitmap
;把BMP圖片檔名稱繪製於記憶體裝置內容中
invoke SetBkMode,hdcMem,TRANSPARENT
invoke DrawText,hdcMem,pszFileName,-1,OFFSET rcClient,\
DT_SINGLELINE or DT_CENTER or DT_VCENTER
;把BMP圖片檔與BMP圖片檔名稱傳輸至視窗工作區裝置內容
invoke BitBlt,ps.hdc,0,0,bitmap.bmWidth,bitmap.bmHeight,hdcMem,0,0,SRCCOPY
invoke DeleteDC,hdcMem
invoke EndPaint,hWnd,ADDR ps
.case WM_DESTROY
invoke DeleteObject,hBitmap
invoke PostQuitMessage,0
.default
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endsw
xor rax,rax
ret
WndProc ENDP
;-----------------------------------------------------------------------------------------
main PROC
LOCAL wc:WNDCLASSEX,msg:MSG,rect:RECT,cbOutput:QWORD
⁝
mov wc.lpszClassName,rdx
invoke RegisterClassEx,ADDR wc
;獲得命令列字串，並從中獲取參數，此參數應該是 BMP 圖片檔的名稱
call GetCommandLine
invoke get_1st,rax ;獲得第一個參數的位址
or rax,rax ;若RAX＝0，獲得參數失敗
jz fail
mov pszFileName,rax ;若RAX不為零，RAX＝第一個參數位址
;載入位元圖，以獲得位元圖的寬度與高度
invoke LoadImage,0,rax,IMAGE_BITMAP,0,0,LR_LOADFROMFILE
or rax,rax
jz fail
mov hBitmap,rax
invoke GetObject,hBitmap,SIZEOF BITMAP,OFFSET bitmap
mov r10d,bitmap.bmWidth ;R10D＝位元圖寬度
mov r11d,bitmap.bmHeight ;R11D＝位元圖高度
mov rcClient.right,r10d
mov rcClient.bottom,r11d
;計算能容納整張位元圖的視窗需要最小寬度與高度
mov rect.left,0
mov rect.top,0
mov rect.right,r10d
mov rect.bottom,r11d
invoke AdjustWindowRect,ADDR rect,WS_CAPTION or WS_SYSMENU,0
mov r10d,rect.right
mov r11d,rect.bottom
sub r10d,rect.left ;R10D＝計算完成後的視窗寬度
sub r11d,rect.top ;R11D＝計算完成後的視窗高度
;建立工作區恰好能容納整張位元圖的視窗
invoke CreateWindowEx,0,ADDR szClassName,ADDR szAppName,WS_CAPTION or\
WS_SYSMENU,50,50,r10d,r11d,0,0,hInstance,0
mov hwnd,rax
invoke ShowWindow,hwnd,SW_SHOWNORMAL
invoke UpdateWindow,hwnd
.while TRUE
invoke GetMessage,ADDR msg,0,0,0
.break .if rax==0
invoke TranslateMessage,ADDR msg
invoke DispatchMessage,ADDR msg
.endw
exit: invoke ExitProcess,0
;如果使用者沒輸入參數或載入BMP圖片檔錯誤，於命令提示字元印出錯誤訊息，然後退出程式
fail: invoke GetStdHandle,STD_OUTPUT_HANDLE
invoke WriteConsole,rax,OFFSET sNotFindBmp,SIZEOF sNotFindBmp,ADDR cbOutput,0
jmp exit
main ENDP
;*****************************************************************************************
END main |
組譯、連結 VIEWBMP2 的方法與前面不太一樣，進入命令提示字元之後，過程如下，黃色字是要輸入的指令：
Microsoft Windows [版本 6.1.7601] Copyright (c) 2009 Microsoft Corporation. All rights reserved. C:\Users\wanker>set include=c:\uasm\include [Enter] C:\Users\wanker>set lib=c:\uasm\lib64 [Enter] C:\Users\wanker>e: [Enter] E:\>cd e:\HomePage\SOURCE\Win64\VIEWBMP [Enter] e:\HomePage\SOURCE\Win64\VIEWBMP>set path=c:\uasm;c:\uasm\bin64;%path% [Enter] e:\HomePage\SOURCE\Win64\VIEWBMP>uasm64 -win64 viewbmp2.asm [Enter] UASM v2.56, Oct 27 2022, Masm-compatible assembler. Portions Copyright (c) 1992-2002 Sybase, Inc. All Rights Reserved. Source code is available under the Sybase Open Watcom Public License. VIEWBMP2.ASM: 144 lines, 3 passes, 161 ms, 0 warnings, 0 errors e:\HomePage\SOURCE\Win64\VIEWBMP>rc viewbmp2.rc [Enter] Microsoft (R) Windows (R) Resource Compiler Version 10.0.10011.16384 Copyright (C) Microsoft Corporation. All rights reserved. e:\HomePage\SOURCE\Win64\VIEWBMP>link /subsystem:console viewbmp2.obj viewbmp2.res [Enter] →連結 Microsoft (R) Incremental Linker Version 14.25.28614.0 Copyright (C) Microsoft Corporation. All rights reserved. e:\HomePage\SOURCE\Win64\VIEWBMP>
注意到上面最後一個步驟，連結。必須使用 LINK.EXE 的「/subsystem:console」選項（大小寫不拘），這是因為如果使用者沒輸入參數或者載入BMP圖片檔錯誤，VIEWBMP2 會在命令提示字元中顯示錯誤訊息。假如沒有前述的「/subsystem:console」選項，就無法取得標準輸出裝置，無法將錯誤訊息顯示於命令提示字元中。
VIEWBMP2 與 VIEWBMP1 差不多，主要不同的地方有：
①：第 99∼104 行，呼叫 GetCommandLine 取得命令列字串，並呼叫 get_1st 由其中擷取出 BMP 圖片檔名稱，然後將其位址存入 pszFileName 變數裏。考慮到使用者有可能輸入錯誤，所以呼叫 get_1st 完之後必須檢查是否有發生錯誤。
②：第 105∼108 行，呼叫 LoadImage 而不是呼叫 LoadBitmap，因為只有前者能讀取 BMP 圖片檔，而後者只能載入資源中的位元圖。當然，VIEWBMP2 呼叫 LoadImage 時輸入的 BMP 檔名是使用者輸入的，為以防輸入錯誤而當掉，所以也要檢查 LoadImage 是否真的能正常載入，如果有錯誤，就得處理。
③：第 138∼141 行，不論是 get_1st 還是 LoadImage 產生的錯誤，都會來到此處處理。處理方式很簡單，就只是印出錯誤訊息，並終止 VIEWBMP2。
④：第 58∼59 行，不再印出「EVE - 劍星的女主角」，而是印出 BMP 圖片檔的檔名。
其他的地方都與 VIEWBMP1 相同，就不多說了。接下來看本章最後一個例子。
本章的第三個例子是 VIEWBMP3，它跟 VIEWBMP2 類似，差別在於利用 BitBlt 的 dwRop 以及 Polygon 的特性做出相框效果。例如使用者在命令提示字元中輸入「viewbmp3 stellar_blade.bmp」，結果出現下面視窗：
可以看見原來 stellar_blade.bmp 的邊緣已經被白色的框框取代，這就是小木偶所謂的相框效果。依慣例先介紹 VIEWBMP3 會用到的 x86 指令與 Win64 API。
這四個指令很類似，先介紹 STOSB，瞭解了之後，其他三個就很容易了。
STOSB 的用法是：
STOSB
STOSB 是 store string byte，翻成中文是把資料存入記憶體內；更仔細地說，是把 AL 內的資料存入 RDI 所指的記憶體內，同時依據方向旗標使 RDI 增或減一。如果方向旗標已設定，也就是方向旗標之值為一，那麼 RDI 減一；如果方向旗標已清除，也就是方向旗標之值為零，那麼 RDI 增一。附帶一提，RCX 之值不會改變。
STOSB 可以搭配 REP 指令使 STOSB 重複執行多次，重複次數放在 RCX，如下面的程式：
REP STOSB
這時 CPU 會先檢查 RCX 是否為零，如果為零，那麼 CPU 什麼都沒做直接跳至下一道指令；如果不為零，每執行一次，RCX 就會減一並依據方向旗標使 RDI 增減一直至 RCX 變為零為止，至於 RDI 是增還是減跟前述一樣就不多說了。這樣的指令會使一塊長度為 RCX 個位元組的記憶體內容，都變得跟 AL 相同，通常用於要清除一塊記憶體的時候。
看到 STOSW、STOSD、STOSQ 的最後一個字母，就應該可以猜得出來，這三個指令依次是把 AX、EAX、RAX 之值，存入 RDI 所指的位址，然後根據方向旗標使 RDI 增或減二、四、八。同樣這三個指令，也能搭配 REP 指令使用，使之重複讓累加器存入記憶體中，重複次數存於 RCX 中，這時候 CPU 會先檢查 RCX 是否為零，跟 REP STOSB 一樣，就不再贅述。
Polygon 是用於繪製多邊形，以當前畫筆畫出邊線，以當前畫刷填滿內部。Polygon 的原型是：
invoke Polygon,\
hdc,\ ; handle to DC
lpPoints,\ ; polygon vertices
nCount ; count of polygon vertices
Polygon 的各參數說明如下：
Polygon 會依據 lpPoints 所指的位址找到由多邊形頂點所組成的陣列，然後由陣列中的第零個元素開始，以當前畫筆畫畫出到第一個元素的線段，再畫出到第二個元素的線段……直至最後一個元素為止，Polygon 還能自動把最後一個元素與第零個元素連起來，使其成封閉多邊形，最後再以當前畫刷將其內部填滿。
Polygon 並不會使用當前像素，也不會改變當前像素。如果陣列中的元素比 nCount 多，那麼多出來的會被忽略掉。如果 Polygon 執行成功，回傳值為一；如果執行失敗，回傳值為零。
底下的例子是以兩個像素寬的黃色畫筆，及紅色畫刷畫出來的，程式碼如下，但其中畫筆與畫刷的程式碼沒列出來，所得結果如下面左圖。圖中的座標實際上不會標示出來，這裏只是為了幫讀者瞭解才這樣做。
array POINT <50,0>,<0,87>,<50,174>,<150,174>,<200,87>,<150,0> invoke Polygon,hdc,OFFSET array,6
如果不小心把第一個元素與第二個元素互換了，程式碼如下，結果變成上面右圖。
array POINT <50,0>,<50,174>,<0,87>,<150,174>,<200,87>,<150,0> invoke Polygon,hdc,OFFSET array,6
其實製作相框效果並不難，關鍵是利用邏輯運算之一的「或運算」，就是 OR 運算。OR 運算有兩個特性：①任何數值與零進行 OR 運算，結果還是原數值；②任何數值與等位元數的 1 的進行 OR 運算，結果為等位元數的 1。①很容易理解，例如 36H（36H 等於十進位的 54） 與 0 進行 OR 運算，36H 換成二進位是 0011 0110，見下面圖左，然後每一位元對相同位置的位元作 OR 運算，得到的還是 0011 0110，也就是 36H。
②36H 換算成二進位只需一個位元組表示，也就是需要八個位元表示。所謂等位元數的一，意思是說 36H 與這八個位元都是一的二進位數作 OR 運算。此二進位數換算成十進位就是 255，十六進位是 0FFH，見上圖右邊。36H 和 0FFH 進行 OR 運算，結果是 0FFH。
瞭解了 OR 這兩個特性之後，還得知道 BMP 圖片檔中的顏色是以光的三原色，也就是紅、綠、藍表示。假如某個 BMP 圖片檔是真彩的位元圖，那麼一個像素需要三個位元組表示，這三個位元組位址由低而高分別代表紅、綠、藍。假設某個像素是黑色，那麼此像素上螢光幕並不發出任何光線，因此這三個位元組均為 0；假設某個像素是白色，代表螢光幕上該像素發出等量的紅、綠、藍三色光，這三個位元組都是 0FFH。而一幅真彩的位元圖，就是由各種顏色的許多像素構成。
由前述說明可以推想，這些不同數值的像素與零進行 OR 運算，結果還是該像素的顏色；若與 0FFH 作 OR 運算，所得為 0FFH，也就是白色。所以要達到八邊形相框的效果，就在視窗工作區的裝置內容呼叫 Polygon 就能畫出八邊形，而且內部為黑色，外部是白色。內部用黑色，可以先建立黑色畫刷，再以 SelectObject 選擇此畫刷。而八邊形外部為白色，這更容易，因為當視窗建立時，預設值的工作區裝置內容就是白色，所以什麼都不必做，八邊形外部就是白色的。
VIEWBMP3 需要三個檔案：VIEWBMP3.ASM、VIEWBMP3.RC、eye.ico，可以到這裏下載，這裏僅列出 VIEWBMP3.ASM 中重要的部分。
VIEWBMP3.ASM 的第 11 行，宣告了 wdt 為相框邊框的寬度，如果以後要修改相框邊框寬度，就只需要修改此值即可。第 25 行定義了 aryPt 陣列，內有八個資料類型為 POINT 的元素，代表了八邊形的八個頂點。而其中的第零、第一個元素只與相框邊框寬度有關，因此可以直接寫出來；但其他六個元素，與 BMP 圖片的寬度、高度有關，必須由計算得到。計算工作由副程式 set_pt 負責。
下圖是第 102 行執行「invoke Polygon,ps.hdc,OFFSET aryPt,8」的結果，但這圖案並不顯示在工作區上，這是因為接下來的幾行指令會呼叫 BitBlt 將工作區的裝置內容覆寫。現在來看看 set_pt 如何計算出 Polygon 所需的頂點座標。第 31∼34 行，設定 R10D、R11D 為 BMP 圖片的寬度與高度，也設定了 RDI 為第二個頂點座標的位址。第 34 行的 TYPE 是計算資料類型的長度，見第三章，所以 TYPE POINT 的結果是 8。前面提過，第零、第一個元素已經在第 25 行定義過了，所以從第二個元素開始，這就是「2*(TYPE POINT)」的來由。
接下來的第 35∼71 行就是計算六個頂點的 X 座標及 Y 座標，都是先把 EAX 當做基準，計算完後以 STOSD 指令將 EAX 存入 aryPt 陣列適當的位址。這裏利用 STOSD 的特性，每次存入後 EDI 會自動加四而指向下一個位址。
1 2
⁝ 10 11 12 ⁝ 24
25 26 27 28 29 30
31 32 33 34 35 36
37 38 39 40 41 42
43 44 45 46 47 48
49 50 51 52 53 54
55 56 57 58 59 60
61 62 63 64 65 66
67 68 69 70 71 72
73 ⁝ 95 96 97 98
99 100 101 102 103 104
105 106 107 108 109 110
111 112 113 114 115
116 ⁝ 192 193 |
;於命令提示字元中輸入「VIEWBMP2 filename」，其中的filename是BMT圖片檔，就能顯示於螢幕上，
;且具有相框效果
⁝
wdt EQU 20 ;相框寬度為20像素
;*****************************************************************************************
⁝
hBrush HBRUSH ? ;黑色畫刷代碼
aryPt POINT <wdt,2*wdt>,<2*wdt,wdt>,4 DUP(<?>),<2*wdt,?>,<wdt,?>
;*****************************************************************************************
.CODE
;-----------------------------------------------------------------------------------------
;設定八邊形相框的頂點座標，第零個以及第一個元素已經直接定義好了，故從第二個元素開始
set_pt PROC USES rdi
lea rdi,aryPt
mov r10d,bitmap.bmWidth
mov r11d,bitmap.bmHeight
 add rdi,2*(TYPE POINT)
;aryPt陣列的第二個元素
mov eax,r10d
sub eax,2*wdt
stosd
mov eax,wdt
stosd
;aryPt陣列的第三個元素
mov eax,r10d
sub eax,wdt
stosd
mov eax,2*wdt
stosd
;aryPt陣列的第四個元素
mov eax,r10d
sub eax,wdt
stosd
mov eax,r11d
sub eax,2*wdt
stosd
;aryPt陣列的第五個元素
mov eax,r10d
sub eax,2*wdt
stosd
mov eax,r11d
sub eax,wdt
stosd
;aryPt陣列的第六個元素
add rdi,4
mov eax,r11d
sub eax,wdt
stosd
;aryPt陣列的第七個元素
add rdi,4
mov eax,r11d
sub eax,2*wdt
stosd
ret
set_pt ENDP
;-----------------------------------------------------------------------------------------
⁝
WndProc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL ps:PAINTSTRUCT,hdcMem:HDC
.switch uMsg
.case WM_PAINT
invoke BeginPaint,hWnd,ADDR ps
;在工作區裝置內容上畫出內部是黑色八邊形、外部是白色的邊框
invoke SelectObject,ps.hdc,hBrush
invoke Polygon,ps.hdc,OFFSET aryPt,8
invoke CreateCompatibleDC,ps.hdc
mov hdcMem,rax
;把使用者輸入的BMP圖片檔繪製於記憶體裝置內容中
invoke SelectObject,hdcMem,hBitmap
;使工作區裝置內容與記憶體裝置內容進行OR運算後，寫入至工作區裝置內容
invoke BitBlt,ps.hdc,0,0,bitmap.bmWidth,bitmap.bmHeight,hdcMem,0,0,SRCPAINT
invoke DeleteDC,hdcMem
invoke EndPaint,hWnd,ADDR ps
.case WM_CREATE
invoke CreateSolidBrush,0 ;創建立黑色畫刷
mov hBrush,rax
call set_pt
⁝
;*****************************************************************************************
END main |
上面第 101∼102 行執行完後，在工作區的裝置內容裏的圖案，就像上圖一樣，一個內部為黑色的八邊形，八邊形外與視窗邊框之間為白色。接下來的第 103∼106 行，跟 VIEWBMP2 的過程一樣，建立記憶體裝置內容、選入 BMP 圖片檔。第 107∼108 行稍微不太一樣的是，呼叫 BitBlt 時，最後一個參數是 SRCPAINT，查閱前表得知是 S or D，此處的「或運算」讓八邊形內部是 BMP 圖片檔的圖案，外部是白色。
