上圖右側兩行，則簡述了資源描述檔。如果要在程式中加上選單、圖示等 UI 資源，那麼必須利用文書處理器編輯資源描述檔，資源描述檔的副檔名是 RC，待資源描述檔撰寫完成，以資源編譯器，例如 RC.EXE 編譯 RC 檔，製造出資源檔。資源檔副檔名是 RES，可以用連結器使其與目的檔、程式庫連結起來，製造出可執行檔，EXE 檔。這一章講述的是，如何在程式中改變圖示及游標。
Win64 程式可分為兩大類：①僅具有命令列介面（command-line interface，簡稱 CLI）的控制臺程式、②具有圖形使用者介面（Graphical User Interface，簡稱 GUI）的視窗程式。在第一至六章介紹的都屬於前者，第七章及其以後介紹的屬於後者。對使用者來說，使用圖形介面能讓操作更直覺、更親和。因此在 Windows 作業系統中，主要的程式都屬於具有圖形使用者介面的視窗程式。
具有圖形使用者介面的視窗程式，是由兩部分組成的：①程式碼與②UI 資源（UI 是 user interface 的縮寫）。此處的程式碼是指資料區段、程式碼區段、堆疊區段這些內容，非單單指 x86 指令的程式碼。而 UI 資源則是包含選單（menu）、圖示（icon）、游標（cursor）、位元圖（bitmap）、字型（font）、對話盒（dialog box）、版本資訊（version）……等等。這些資源都以圖形方式，顯示在程式視窗內，供使用者使用。
產生這些資源所使用的軟體不盡相同，所得副檔名也不一樣，例如圖示檔的副檔名是 *.ICO，游標檔的副檔名是 *.CUR，不一而足；也有些資源就是文字，例如選單、對話盒。不論如何，這些資源最後都必須放在一個稱為「資源描述檔」（resource-definition script file）的文字檔裏描述。資源描述檔的副檔名通常是 *.RC。資源描述檔再交由資源編譯器（RC.EXE）編譯成資源檔，資源檔的副檔名通常是 *.RES。最後再由連結器（LINK.EXE）把資源檔、目的檔以及程式庫連結在一起，產生可執行檔（*.EXE）。
下圖是用組合語言開發 Win64 程式的流程簡圖。左側兩行是在這一章之前已經使用過的流程，簡述其流程：我們用文書處理器，例如 UltraEdit32、記事本等軟體撰寫並編輯原始程式，待撰寫完畢存成 *.ASM 檔即為原始程式；然後用組譯器，也就是 ML64.EXE 或 UASM64.EXE 組譯，製造出目的檔；最後用連結器將目的檔與程式庫連結，造出可執行檔。上圖右側兩行，則簡述了資源描述檔。如果要在程式中加上選單、圖示等 UI 資源，那麼必須利用文書處理器編輯資源描述檔，資源描述檔的副檔名是 RC，待資源描述檔撰寫完成，以資源編譯器，例如 RC.EXE 編譯 RC 檔，製造出資源檔。資源檔副檔名是 RES，可以用連結器使其與目的檔、程式庫連結起來，製造出可執行檔，EXE 檔。
上圖中除了原始程式、資源描述檔是文字檔，可以用 UltraEdit32、記事本等文書處理器開啟或編輯；程式庫、目的檔、資源檔、圖示檔、游標檔、位元圖都是二進位檔，也就是不能用 UltraEdit32、記事本等文書處理器開啟或編輯的檔案（即使能開啟，也看不懂有什麼意義）。
底下就來說一說如何在資源描述檔中加入圖示檔及游標檔，並在程式中更換圖示及游標。
資源描述檔（resource-definition script file）的副檔名是 RC，是一種文字檔，裏面包含著各種 UI 資源。這些 UI 資源中，有些是二進位檔，必須以文字描述該二進位檔，例如圖示、游標；有些是文字，直接於資源描述檔中闡述即可，例如選單、對話盒。底下先看如何在資源描述檔中定義圖示及游標，以後幾章才說明其他的情形。
在資源描述檔裏添加圖示，可用關鍵字「ICON」，語法如下：
圖示名稱 ICON 圖示檔名稱
圖示名稱可以是字串，也可以是十六位元的無號數，不管是哪一種，都用來代替其後的圖示檔名稱。圖示檔名稱前後可以加上「"」，也可以不加；但如果圖示檔名稱中有空白，就必須加上「"」。圖示檔名稱也可以包含路徑，而其路徑中的兩個子目錄之間，可以用「\」或「/」做為分隔兩個子目錄名稱；但是像「\n」、「\t」會當成換行字元及水平定位字元，須注意。例如底下的例子：
2000 ICON SPLWND2.ICO /* 正確 */ SPLWND2 ICON "../THREAD/SPLWND2.ICO" /* 正確 */ SPLWND2 ICON "..\THREAD\SPLWND2.ICO" // 錯誤，因為「\T」會被當做水平定位字元
圖示名稱也可以是十六位元的無號數，十六位元的無號數必須是小於或等於 65535 的正整數，此無號數代表圖示的識別碼。例如上面的第一個例子。
要在資源描述檔裏添加游標，使用關鍵字「CURSOR」，語法如下：
游標名稱 CURSOR 游標檔名稱
游標名稱與游標檔名稱的規則，跟圖示相同，不再贅述，請參考上面 ICON 的說明。
資源描述檔有自己的關鍵字與語法，底下再介紹資源描述檔中常見的兩種關鍵字：①#define、②「/*」與「*/」、「//」。
由前面的例子，其實就能猜測，在資源描述檔中的註解有兩種：①以「/*」當做註解的開始，以「*/」為結尾，這種註解可以跨越很多行，適合用於較長的註解。②「//」，在這兩個字元之後的文字就是註解，最多只能一行。
這兩種註解的方式都是 C 語言的語法，這大概是微軟在撰寫 Windows 作業系統時，以 C 語言為主體，配以少量的組合語言。因此像 RC.EXE 這種工具程式，也遵守 C 語言的語法。
在資源描述檔中，如果要定義常數，可以用「#define」，定義某個常數之後，此常數作用範圍只能是這個資源描述檔。「#define」語法如下：
#define 常數名稱 數值
要注意的是「#define」必須用小寫字母，不能用大寫，例如「#DEFINE」就會發生錯誤。底下的例子，定義了常數 TEXT_CUR 為 5000：
#define TEXT_CUR 5000
在資源描述檔中，以「ICON」關鍵字添加圖示之後，只能在檔案總管中見到該程式以圖示代替。如果要在視窗標題欄的最左邊見到圖示，有兩種方法可以達到這個目的：第一種方法是在註冊視窗類別時，指定圖示；第二種方法是建立視窗之後，在處理 WM_CREATE 訊息時，呼叫 SendMessage 指定圖示。
第一種方法是在註冊視窗類別時，指定圖示，這種方法有三個步驟：
hIconSm 與 hIcon 可以是不同的圖示代碼，那就會在標題欄與工作列顯示不同的圖示；也可以是相同的圖示代碼，那麼在標題欄與工作列就會顯示同樣的圖示，這也是大部分程式的選擇。一般而言，hIconSm 圖示大小為 16×16，hIcon 則不一定，但這並不重要，因為 Windows 作業系統會在不同地方自動調整大小。
底下舉個例子說明。假設已經從網路上下載某個圖示檔，GIRL.ICO，那麼先把 GIRL.ICO、資源描述檔、原始程式都放在同一子目錄裏。在資源描述檔裏可以寫成下面的樣子：
ICONNAME ICON "GIRL.ICO"
或
#define ID_ICON 1200 ID_ICON ICON "GIRL.ICO"
前者使用字串，「ICONNAME」，代表圖示檔，後者是用識別碼，也就是數值，ID_ICON，來代表圖示檔（ID_ICON之值為 1200），兩者皆可。接下來先演示用字串代表圖示檔時，要如何在原始程式中使用圖示。在原始程式中，可以寫成下面的樣子：
.DATA
⁝
szIconName DB "ICONNAME",0
⁝
.CODE
⁝
invoke LoadIcon,hInstance,OFFSET szIconName
mov wc.hIcon,rax ;wc的資料類型是WNDCLASSEX，此步驟存入圖示代碼
mov wc.hIconSm,rax ;存入小圖示代碼
如果是用識別碼來代表圖示檔時，原始程式中，可以寫成下面的樣子：
ID_ICON EQU 1200
.CODE
⁝
invoke LoadIcon,hInstance,ID_ICON
mov wc.hIcon,rax ;wc的資料類型是WNDCLASSEX，此步驟存入圖示代碼
mov wc.hIconSm,rax ;存入小圖示代碼
第二種方法，可以在建立視窗之後改變圖示，通常是在處理 WM_CREATE 訊息時改變圖示。更進一步來說是有兩個步驟：先呼叫 LoadIcon 載入圖示，然後呼叫 SendMessage 把設定要圖示的訊息及圖示代碼傳給視窗。步驟一之前就用過了，不說明。第二個步驟是以第一個步驟的傳回的圖示代碼以及 WM_SETICON 為參數，呼叫 SendMessage 來設定圖示。先看看 SendMessage 的用法。
SendMessage 將某個訊息傳送給某個視窗的視窗函式，其實就是使系統呼叫該視窗的視窗函式，直到處理完此訊息才返回。SendMessage 的用法如下：
invoke SendMessage,\
hWnd,\ ; handle of destination window
Msg,\ ; message to send
wParam,\ ; first message parameter
lParam ; second message parameter
hWnd 是將要收到訊息的視窗之視窗代碼，如果 hWnd 為 HWND_BROADCAST 的話，那麼所有的頂級視窗都會收到訊息（頂級視窗是 top-level windows，是指由使用者或應用程式直接建立的視窗，而不是作為其他視窗的子視窗）。Msg 是即將要發送給 hWnd 的訊息之訊息識別碼。wParam 與 lParam 是該訊息的額外資料，與訊息種類有關。SendMessage 的回傳值與訊息識別碼有關。
假如要設定視窗的圖示，那麼可以使用下面的步驟：
WndProc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
⁝
.case WM_CREATE
invoke LoadIcon,hInstance,OFFSET szIconName
invoke SendMessage,hWnd,WM_SETICON,ICON_SMALL,rax
SendMessage 對自己，也就是 hWnd 發送 WM_SETICON 訊息，該訊息的意思就是 Windows 系統要設定 hWnd 的圖示。WM_SETICON 的 wParam 可以是 ICON_SMALL 或 ICON_BIG，前者代表設定標題欄左邊的圖示，後者代表設定執行後在工作列的圖示。WM_SETICON 的 lParam 是圖示代碼，是 LoadIcon 的回傳值。
SendMessage 的回傳值為視窗原先的圖示代碼，假如原先沒有圖示的話，就會傳回 0。一般而言，視窗函式不處理 WM_SETICON 訊息，而是交給 DefWindowProc 處理。
在程式中要改變滑鼠游標，跟改變圖示的方法一樣，都是在資料區定義與資源描述檔相同的游標名稱或游標識別碼，接下來也有兩種方法可以改變游標：第一種方法是在註冊視窗類別時，指定游標；第二種方法是呼叫 SetCursor 指定游標。
註冊視窗類別時可以呼叫 LoadCursor 取得游標代碼，在這之前我們都使用 Windows 系統內建的游標，例如 IDC_ARROW，然後把 WNDCLASSEX 的 hCursor 欄位指定為游標代碼即可。當然也可以使用使用者提供的游標，只需將 LoadCursor 的第二個參數改成使用者提供的游標名稱即可。因為方式與圖示一樣，就不再舉例說明。
先來說明牽涉到游標兩個 Win64 API：SetCursor 與 ShowCursor。
當註冊完視窗類別後，還是可以改變滑鼠游標，方法就是呼叫 SetCursor API。SetCursor 原型如下：
invoke SetCursor,\
hCursor ; handle of cursor
SetCursor 只有一個參數，hCursor，游標代碼，此游標代碼可能是 CreateCursor 所建立的，或是 LoadCursor、LoadImage 所載入的。如果此參數為 0，那麼游標就會消失。SetCursor 的回傳值是原本的游標代碼。
要使用 SetCursor 指定游標，必須在處理 WM_SETCURSOR 訊息中呼叫 SetCursor。原因是每當滑鼠移動時，系統會對視窗函式發出 WM_SETCURSOR 訊息，以重繪滑鼠游標。一般視窗函式不處理這則訊息，而是交由 DefWindowProc 處理，DefWindowProc 的處理方式是用視窗類別中，WNDCLASSEX 結構體的 hCursor 欄位所指定的游標繪製。
除非在註冊式窗類別時，將該欄位指定為零，否則只要一移動滑鼠，滑鼠游標便會恢復成該欄位指定的游標。但是如果視窗函式自行處理 WM_SETCURSOR 訊息時，就不會出現這種問題。
ShowCursor 用來顯示或隱藏滑鼠游標，只有一個參數，用法如下：
invoke ShowCursor,\
bShow ; cursor visibility flag
在 Windows 作業系統內部有個計數器，只有當此計數器大於零才會顯示滑鼠。當系統中安裝好滑鼠時，此計數器為 0；若未安裝滑鼠，計數器為－1。ShowCursor 的用途用來增減此計數器之值，當 bShow 為非零時，計數器之值加一；當 bShow 為 0 時，計數器減一。ShowCursor 的回傳值為增減後的計數器之值。
每當滑鼠移動且沒有滑鼠輸入動作時，系統就會對視窗函式發出 WM_SETCURSOR 訊息，以重繪滑鼠游標。WM_SETCURSOR 訊息的 wParam 是滑鼠游標所在的視窗代碼。
WM_SETCURSOR 訊息的 lParam 的 0∼15 位元是擊中測試（hit-test）結果，擊中測試是指滑鼠游標在位置不同，而有不同結果。例如滑鼠游標在工作區時，擊中測試是 HTCLIENT；在選單區域時，是 HTMENU；在最小化按鈕時，是 HTMINBUTTON；在最大化紐時，是 HTMAXBUTTON……等等。這些測試結果都是小於 65536 的正整數。lParam 的 16∼31 位元是滑鼠訊息，通常是 WM_MOUSEMOVE，但是如果滑鼠在選單區域，則此數值為零。
底下小木偶利用第十一章的 SPLWND_U.ASM，將其改寫，新的程式稱為 SPLWND2.ASM，它會改變圖示及滑鼠游標而不使用 Windows 所提供的。注意到標題欄左邊的圖示，跟 SPLWND_U 使用 Windows 系統中內建的圖示不同。除此之外，SPLWND2 的滑鼠游標在一般狀態時，為寶劍的樣子，見下圖左；當它移至字串上時，變成編輯狀態的樣子，見下圖右：
底下是 SPLWND2.ASM 的原始程式內容：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88
89 90 91 92
93 94 95 96
97 98 99 100
101 102 103 104
105 106 107 108
109 110 111 112
113 114 115 116
117 118 119 120
121 122 123 124 |
OPTION CASEMAP:NONE
OPTION WIN64:3
INCLUDE WINDOWS.INC
INCLUDELIB GDI32.LIB
INCLUDELIB KERNEL32.LIB
INCLUDELIB USER32.LIB
TEXT_CUR EQU 5000 ;游標在文字上的游標名稱
;***************************************************************************************************
.DATA
hInstance HINSTANCE ? ;模組代碼
hwnd HWND ? ;視窗代碼
wc WNDCLASSEX <>
msg MSG <>
ps PAINTSTRUCT <>
rect RECT <>
str_rect RECT <>
szCursorName LABEL BYTE
szIconName DB "SPLWND2",0 ;圖示名稱及一般情形下的游標名稱
szClassName DB "SimpleWndClass",0 ;視窗類別名稱
szAppName DB "簡單的視窗",0
sYouPress DB "你按下了 鍵。"
;***************************************************************************************************
.CODE
;---------------------------------------------------------------------------------------------------
WndProc PROC hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
.switch uMsg
.case WM_PAINT
invoke BeginPaint,hWnd,ADDR ps
invoke GetClientRect,hWnd,ADDR rect
;求得sYouPress字串所在矩形左上角座標(0,0)，與右下角座標(str_rect.right,str_rect.bottom)
;因此sYouPress字串的剪裁矩形寬為str_rect.right，高為str_rect.bottom
mov str_rect.left,0
mov str_rect.top,0
invoke DrawText,ps.hdc,ADDR sYouPress,SIZEOF sYouPress,ADDR str_rect,\
DT_CALCRECT or DT_SINGLELINE
;由工作區的寬與高，及sYouPress字串的剪裁矩形寬與高，可以計算sYouPress字串的剪裁矩形座標
;左上角X座標為(rect.right-str_rect.right)/2，Y座標為(rect.bottom-str_rect.bottom)/2
;右下角X座標為(rect.right-str_rect.right)/2+str_rect.right，Y座標為
;(rect.bottom-str_rect.bottom)/2+str_rect.bottom
mov r10d,rect.right
sub r10d,str_rect.right
shr r10d,1
mov str_rect.left,r10d
add str_rect.right,r10d
mov r11d,rect.bottom
sub r11d,str_rect.bottom
shr r11d,1
mov str_rect.top,r11d
add str_rect.bottom,r11d
invoke DrawText,ps.hdc,ADDR sYouPress,SIZEOF sYouPress,ADDR rect,\
DT_SINGLELINE or DT_CENTER or DT_VCENTER
invoke EndPaint,hWnd,ADDR ps
.case WM_MOUSEMOVE
movzx r10,r9w ;R10D＝滑鼠游標所在的X座標
shr r9,10h ;R9D＝滑鼠游標所在的Y座標
mov rdx,OFFSET szCursorName
;檢查滑鼠游標所在X座標是否在str_rect.left與str_rect.right之間，若否則跳躍至set_cr
cmp r10d,str_rect.left
jb set_cr
cmp r10d,str_rect.right
ja set_cr
;檢查滑鼠游標所在Y座標是否在str_rect.top與str_rect.bottom之間，若否則跳躍至set_cr
cmp r9d,str_rect.top
jb set_cr
cmp r9d,str_rect.bottom
ja set_cr
mov rdx,TEXT_CUR
set_cr: invoke LoadCursor,hInstance,rdx
invoke SetCursor,rax
invoke ShowCursor,TRUE ;也可以將這一行刪除
.case WM_CHAR
mov rax,wParam
mov [sYouPress+8],al
invoke InvalidateRect,hWnd,0,1
.case WM_DESTROY
invoke PostQuitMessage,0
.default
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endsw
xor rax,rax
ret
WndProc ENDP
;---------------------------------------------------------------------------------------------------
main PROC
invoke GetModuleHandle,0 ;取得模組代碼
mov hInstance,rax
mov wc.cbSize,SIZEOF WNDCLASSEX
mov wc.style,CS_HREDRAW or CS_VREDRAW
lea rdx,WndProc
mov wc.lpfnWndProc,rdx
mov wc.cbClsExtra,0
mov wc.cbWndExtra,0
mov wc.hInstance,rax
invoke LoadIcon,hInstance,OFFSET szIconName ;取得圖示代碼
mov wc.hIcon,rax ;存入圖示代碼
mov wc.hIconSm,rax ;存入小圖示代碼
invoke LoadCursor,hInstance,OFFSET szCursorName;取得游標代碼
mov wc.hCursor,rax ;存入游標代碼
mov wc.hbrBackground,COLOR_WINDOW+1
mov wc.lpszMenuName,0
lea rdx,szClassName
mov wc.lpszClassName,rdx
invoke RegisterClassEx,ADDR wc ;註冊視窗類別
invoke CreateWindowEx,0,ADDR szClassName,ADDR szAppName,WS_OVERLAPPEDWINDOW,\
CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,0,0,hInstance,0
mov hwnd,rax
invoke ShowWindow,hwnd,SW_SHOWNORMAL
invoke UpdateWindow,hwnd
.while TRUE
invoke GetMessage,ADDR msg,0,0,0
.break .if rax==0
invoke TranslateMessage,ADDR msg
invoke DispatchMessage,ADDR msg
.endw
invoke ExitProcess,0 ;程式結束
main ENDP
;***************************************************************************************************
END main |
底下是 SPLWND2.RC 的內容：
1 2 3 4
5 |
#define TEXT_CUR 5000
SPLWND2 ICON "SPLWND2.ICO"
SPLWND2 CURSOR "normal cursor.cur" /* 游標不在字串上的形狀，寶劍形狀的游標 */
TEXT_CUR CURSOR "text.cur" /* 游標在字串上的形狀，編輯狀態形狀的游標 */ |
圖示檔的來源大致有三，如下：
要注意的是，圖示檔與游標檔的寬與高相等，也就是正方形，且大多是 16×16、32×32、48×48、64×64……等大小，因此在轉換前，應以繪圖軟體將選定的圖片裁剪為正方形，Online-Convert 會自動依據你所選定的大小進行轉換。
游標檔的來源，與圖示檔類似，可以自行繪製或下載現成的，也可以由其他圖片轉換而來。
在 SPLWND2 所用到的圖示，SPLWND2.ICO，是小木偶由網路上下載後，經由 Online-Convert 網站轉換而來。見 SPLWND2.RC 第 3 行，以「SPLWND2」字串，代替 SPLWND2.ICO 圖示檔。
SPLWND2 所用的游標有兩個，「normal cursor.cur」與「text.cur」則是網路上直接下載的。前者是一般狀態下的滑鼠游標，是寶劍樣子的游標，以字串「SPLWND2」代替「normal cursor.cur」游標檔；後者是當滑鼠游標移至字串時，變成編輯狀態的游標，以識別碼 TEXT_CUR 代替「text.cur」游標檔。見 SPLWND2.RC 第 4∼5 行。而常數 TEXT_CUR 的定義在 SPLWND2.RC 第一行，將其定義為 5000。
把 SPLWND2.ASM、SPLWND2.RC、SPLWND2.ICO、「normal cursor.cur」與 text.cur 共五個檔案，都放在同一個子目錄中，例如「E:\HomePage\SOURCE\Win64\SPLWND」子目錄中，然後開啟「命令提示字元」，輸入下面黃色的指令：
Microsoft Windows [版本 6.1.7601] Copyright (c) 2009 Microsoft Corporation. All rights reserved. C:\Users\wanker>uasm [Enter] →執行 UASM.BAT 批次檔，省了許多打字輸入，見第 11 章 UASM.BAT C:\Users\wanker>SET INCLUDE=C:\UASM\Include C:\Users\wanker>SET LIB=C:\UASM\lib64 C:\Users\wanker>SET PATH=C:\UASM;C:\UASM\bin64;C:\Windows\system32;C:\Windows;C: \Windows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\Program Fi les (x86)\UltraEdit-32 C:\Users\wanker>E: E:\>CD E:\HOMEPAGE\SOURCE\WIN64 LINK=/SUBSYSTEM:WINDOWS /DEBUG E:\HomePage\SOURCE\Win64>cd SPLWND [Enter] →切換至 SPLWND 子目錄 E:\HomePage\SOURCE\Win64\SPLWND>uasm64 -win64 splwnd2.asm [Enter] →一如既往，組譯方式並無不同 UASM v2.56, Oct 27 2022, Masm-compatible assembler. Portions Copyright (c) 1992-2002 Sybase, Inc. All Rights Reserved. Source code is available under the Sybase Open Watcom Public License. SPLWND2.ASM: 124 lines, 3 passes, 645 ms, 0 warnings, 0 errors E:\HomePage\SOURCE\Win64\SPLWND>rc splwnd2.rc [Enter] →多了用 RC.EXE 編譯 SPLWND2.RC 資源描述檔 Microsoft (R) Windows (R) Resource Compiler Version 10.0.10011.16384 Copyright (C) Microsoft Corporation. All rights reserved. →無任何訊息，表示 RC.EXE 編譯成功 E:\HomePage\SOURCE\Win64\SPLWND>link splwnd2.obj splwnd2.res [Enter] →用 LINK.EXE 把目的檔與資源 Microsoft (R) Incremental Linker Version 14.25.28614.0 檔連結起來，製作出可執行檔 Copyright (C) Microsoft Corporation. All rights reserved. /SUBSYSTEM:WINDOWS /DEBUG E:\HomePage\SOURCE\Win64\SPLWND>
上述組譯、連結的過程中，幾乎與以前相同，差別在於兩處：①多了用 RC.EXE 編譯 SPLWND2.RC 資源描述檔、②連結時多加上 SPLWND2.RES 資源檔，連結時的目的檔與資源檔，誰先誰後都可以。完成上面步驟，就能產生 SPLWND2.EXE 可執行檔。可以在命令提示字元中，輸入 SPLWND2 執行它。
底下來解說 SPLWND2.ASM 程式所用到的原理。
為了要達到滑鼠游標移到字串上時，變更游標形狀，因此要監視包含住字串所在的最小矩形。如果滑鼠游標在這個矩形範圍內，就變成編輯狀態的游標，此游標檔名是「text.cur」，在 SPLWND2.ASM 與 SPLWND2.RC 中，皆以識別碼 TEXT_CUR（TEXT_CUR 之值為 5000）代替「text.cur」檔名。其程式碼大致如下：
TEXT_CUR EQU 05000
⁝
invoke LoadCursor,hInstance,TEXT_CUR
invoke SetCursor,rax
如果滑鼠游標不在這個矩形範圍內，就變成寶劍形狀的游標，此游標檔名是「normal cursor.cur」，在 SPLWND2.ASM 與 SPLWND2.RC 中，皆以字串「SPLWND2」代替游標檔名。其程式碼大致如下：
szCursorName DB "SPLWND2",0
⁝
invoke LoadCursor,hInstance,OFFSET szCursorName
invoke SetCursor,rax
包含住字串所在的最小矩形存放在 str_rect 變數之中，str_rect 的資料類型是 RECT 結構體，有四個欄位，見第八章。因此矩形左上角的 X 座標與 Y 座標分別是 str_rect.left、str_rect.top；而此矩形的右下角 X 座標與 Y 座標分別是 str_rect.right、str_rect.bottom。
滑鼠游標所在座標可由 WM_MOUSEMOVE 訊息的 lParam 中得到，不過 lParam 恰好是視窗函式的第四個參數，所以 lParam 之值就是 R9 暫存器之值。R9 的 0∼15 位元是滑鼠游標所在的 X 座標，16∼31 位元是 Y 座標。SPLWND2.ASM 的第 56∼57 行如下：
movzx r10,r9w ;R10D＝滑鼠游標所在的X座標 shr r9,10h ;R9D＝滑鼠游標所在的Y座標
其作用使得滑鼠游標所在的 X 座標與 Y 座標分別存於 R10D、R9D。
接下來檢查滑鼠游標所在的座標是否在包含住字串的最小矩形，方法是檢查 R10D 要在 str_rect.left 與 str_rect.right 之間，同時 R9D 也要在 str_rect.top 與 str_rect.bottom 之間，就表示滑鼠游標在包含住字串的最小矩形內，只要有一項不符合，就不在包含住字串的最小矩形內。
實際檢查時，先檢查 R10D 是否在 str_rect.left 與 str_rect.right 之間，若不在這兩數之間，表示滑鼠游標不在矩形內，跳躍至 set_cr: 標記處。假如滑鼠游標在這兩數之間，還要再檢查 R9D 是否在 str_rect.top 與 str_rect.bottom 之間，如果 R9D 不在這兩數之間，表示滑鼠游標不在矩形內，跳躍至 set_cr: 標記處。因此最後處理 WM_MOUSEMOVE 訊息的程式為：
.case WM_MOUSEMOVE
movzx r10,r9w ;R10D＝滑鼠游標所在的X座標
shr r9,10h ;R9D＝滑鼠游標所在的Y座標
mov rdx,OFFSET szCursorName
;檢查滑鼠游標所在X座標是否在str_rect.left與str_rect.right之間，若否則跳躍至set_cr
cmp r10d,str_rect.left
jb set_cr
cmp r10d,str_rect.right
ja set_cr
;檢查滑鼠游標所在Y座標是否在str_rect.top與str_rect.bottom之間，若否則跳躍至set_cr
cmp r9d,str_rect.top
jb set_cr
cmp r9d,str_rect.bottom
ja set_cr
mov rdx,TEXT_CUR
set_cr: invoke LoadCursor,hInstance,rdx
invoke SetCursor,rax
invoke ShowCursor,TRUE ;也可以將這一行刪除
上面這段程式，在檢查滑鼠游標是否在矩形範圍內之前，先假設滑鼠游標不在矩形範圍內，所以先讓 RDX 指向 szCursorName 字串，此字串是「SPLWND2」代表「normal cursor.cur」，也就是滑鼠游標不在字串上時的游標檔。爾後檢查結果，假如滑鼠游標確實在字串上時，才來修改 RDX 為 5000，使其為編輯狀態形狀的游標，也就是「text.cur」游標檔。
上面程式片段的最後一行，可有可無，但為了多介紹一個 ShowCursor API，同時也增加篇幅，就留著了。
最後僅剩下一個問題，就能寫出 SPLWND2.ASM 了。這個問題就是，如何計算包含住字串所在的最小矩形。此矩形在工作區的中央，既是水平方向的中央，也是鉛垂方向的中央。要計算這個矩形的範圍，必須知道兩項資料：
關於第 2 個問題，比較好解決，只要呼叫 GetClientRect，就能得到工作區的矩形範圍，其左上角座標當然是（0,0），右下角的 X 座標與 Y 座標其實也是工作區的寬度與高度。見 SPLWND2.ASM 第 30 行，呼叫完後，把工作區的大小存於 rect 結構體，其寬度與高度分別是 rect.right、rect.bottom。見下圖Ⓐ、Ⓑ。
關於第 1 個問題，說難其實也不難。還記得 DrawText 有個重要的特性，如果呼叫 DrawText 時，最後一個參數為 DT_CALCRECT 時，可以計算包含住字串所在的最小矩形，DrawText 稱此矩形為「剪裁矩形」，見第八章。此外，如果要顯示的字串只有一行，還必須填上剪裁矩形的左上角座標，在 SPLWND2 的第 33∼34 行就是做這件事。
但為何將剪裁矩形的左上角座標設為（0,0）呢？這樣做的好處是剪裁矩形左下角的 X 座標與 Y 座標恰好就是包含字串最小矩形的寬度與高度。執行完第 35 行後，包含字串最小矩形的寬度與高度，分別存於 str_rect 結構體的 str_rect.right 與 str_rect.bottom 欄位之中。見下圖Ⓒ、Ⓓ。
而此處剪裁矩形的作用，並非要在其內顯示字串，其目的僅僅是求出包含字串最小矩形的寬度與高度，在監視滑鼠游標時要用到。字串是顯示在工作區的中央，把最後一個參數設為「DT_SINGLELINE or DT_CENTER or DT_VCENTER」即可，其剪裁矩形是整個工作區。
有了「包含字串最小矩形的寬度與高度」、以及「工作區的寬度與高度」兩項資料之後，就能計算包含字串最小矩形的範圍了。請參考下圖，工作區左上角及右下角座標均已知，因此工作區的寬度是 rect.right，見Ⓐ；而包含字串最小矩形的寬度是 str_rect.right，見Ⓒ。包含字串最小矩形左右兩邊至工作區左右兩側邊線的距離相等，因此其大小為
，這也是包含字串最小矩形左上角的 X 座標，x1 之值，見下圖Ⓔ。同理 y1 之值為
。
x2 則是 x1 再加上包含住字串最小矩形的寬度，所以其值為
。同理 y2 之值是 y1 再加上包含住字串最小矩形的高度，也就是
。
到這裏，包含住字串最小矩形的左上角座標，及右下角座標都已計算出來，最後再將其存於 str_rect 結構體內，見 SPLWND2.ASM 第 37∼50 行。此結構體就是在 WM_MOUSEMOVE 訊息時，要監視的矩形區域，如果滑鼠游標在此矩形範圍內，就更改滑鼠游標，成為編輯狀態的游標。