第二十八章　用 GDI＋ 觀看圖片檔

這一章將簡單介紹 GDI＋，並以本章介紹的幾個 API 撰寫一個可以觀看數種格式的應用程式。

GDI＋ 是什麼？

在第八章時曾介紹過 GDI（graphics device interface，圖形裝置介面），提供了與周邊裝置無關的程式設計方式，甚至連 Windows 作業系統本身在繪製各類元件也都靠 GDI。而本章要介紹的 GDI＋ 是在其後加上一個「＋」，顯然可以簡單地認為是 GDI 的升級改良版本。

的確如此。自 Windows XP 及 Windows Server 2003 開始加入 GDI＋之後，它可以說是作業系統內的一部分了。它提供二維向量圖形、影像處理和印刷樣式三部分；每部分各自對原來的 GDI 進行了改良，也新添了一些功能。對於影像而言，支援更多格式的圖片檔，包括了 PNG、JPG、GIF、Exif、TIFF、WMF、EMF 等。

第八章提過，GDI 僅支援位元圖，也就是 Bitmap 格式的圖片，而 GDI＋ 支援的圖片較多，這也是本章的重點。那麼在使用 GDI＋ 的時候，有什麼要注意的嗎？

使用 GDI＋

在使用 GDI＋ 前，須注意底下三件事：

第一，如果使用 WinInc 含入檔搭配 UASM 組譯，那麼在組合語言原始程式的前面，需把「GDIPLUS.INC」包含進來。同時也要加入「GDIPLUS.LIB」匯入程式庫，以便使連結器知道如何在「GDIPLUS.DLL」找到所使用的 GDI＋ 函式。程式碼如下：

INCLUDE         GDIPLUS.INC
INCLUDELIB      GDIPLUS.LIB

第二，在呼叫 GDI＋ 函式之前，必須先呼叫 GdiplusStartup，以初始化 GDI＋，然後才能呼叫其他 GDI＋ 函式；當不再使用 GDI＋ 時，必須呼叫 GdiplusShutdown 告知系統結束 GDI＋，以釋放 GDI＋ 所使用的資源。

第三，GDI＋ 函式的回傳值與其他 Win64 API 不太一樣。對 GDI＋ 函式而言，回傳值為 0 代表執行成功；回傳值為其他數值，代表執行失敗，而該數值代表錯誤代碼。Windows 特別把 GDI＋ 的回傳值稱為 GpStatus。對 64 位元的 Windows，GpStatus 的長度都是 QWORD，存於 RAX 暫存器內。下表是 GDI＋ API 的回傳值及意義：

表一：GDI＋ 函式回傳值
Status數值說明
OK0執行成功
GenericError1一般錯誤，指的是未被歸類的錯誤
InvalidParameter2參數不正確
OutOfMemory3記憶體不足
ObjectBusy4嘗試操作正在被其他執行緒或程式鎖定的物件
InsufficientBuffer5提供的緩衝區大小不足以存放操作結果
NotImplemented6該函數目前尚未被實作，可能是版本不符或設備未支援
Win32Error7表示來自 Win32 API 的錯誤
WrongState8表示物件的狀態與所需操作不一致，例如在未經初始化狀態下執行繪製操作
Aborted9表示操作被中止
FileNotFound0Ah沒找到檔案
ValueOverflow0Bh執行產生數值溢位的算術運算
AccessDenied0Ch不允許檔案寫入
UnknownImageFormat0Dh未知的圖片檔案格式
FontFamilyNotFound0Eh找不到指定的字形，例如字形名稱不正確或未安裝字形
FontStyleNotFound0Fh找不到指定的字形風格
NotTrueTypeFont10h從 HDC 或 LOGFONT 所擷取的字形不是 TrueType 字形，無法與 GDI＋ 搭配使用
UnsupportedGdiplusVersion11h安裝在系統的 GDI＋ 版本與應用程式不相符
GdiplusNotInitialized12hGDI＋ API 不是處於初始化狀態， 呼叫 GdiplusStartup 以解決此錯誤
PropertyNotFound13h影像中沒有指定的屬性
PropertyNotSupported14h影像格式不支援指定的屬性，因此無法設定
ProfileNotFound15h找不到以 CMYK 格式儲存影像所需的色彩設定檔

底下來介紹本章會用得到的 GDI＋ API，以及一些概念。

GdiplusStartup API

每當要使用 GDI＋ 前，都要呼叫 GdiplusStartup，對 GDI＋ 進行初始工作。GdiplusStartup 的原型如下：

invoke  GdiplusStartup,\
        pToken,\          ; receives the GDI+ session handle
        pGdipStartInput,\ ; provides GDI+ initialization settings
        pGdipStartOutput  ; returns additional initialization details

pToken 是指向 token 的位址，對 64 位元的 Windows 而言，token 的長度是 QWORD。Token 是 GDI＋ 核心執行環境的標誌，系統用它管理其生命周期，透過 token，GDI＋ 能夠追蹤和清理其內部資源，確保應用程式的穩定性和資源的正確回收。當不再使用 GDI＋ 時，必須呼叫以回收資源，這時候也會用到 token。我們可以簡單地把 token 想像為代碼（handle）。

pGdipStartInput 為結構體 GdiplusStartupInput 的位址，該結構體的欄位是：

GdiplusStartupInput             STRUCT          8
  GdiplusVersion                UINT32          ?   ;GDI＋版本
  DebugEventCallback            DebugEventProc  ?   ;除錯函式位址
  SuppressBackgroundThread      BOOL            ?   ;是否啟用後台執行緒
  SuppressExternalCodecs        BOOL            ?   ;是否允許使用外部編解碼器
GdiplusStartupInput             ENDS

結構體 GdiplusStartupInput 的用途在於初始化 GDI＋，因此在呼叫 GdiplusStartup 前，必須把這個結構體內的各欄位都填上適當的資料。呼叫 GdiplusStartup 時，Windows 藉由這個結構體內的資料，對 GDI＋ 進行初始化工作。底下介紹各欄位：

①、GdiplusVersion：GDI＋ 的版本。目前（民國 114 年）GDI＋ 的版本是 1.0 版，因此這個欄位只能填入 1。資料類型 UINT32 代表 32 位元無號整數。
②、DebugEventCallback：此為除錯函式位址，用於深入測試 GDI＋ 或追蹤錯誤時，可指定自定義函數來記錄除錯事件。如果不需要，可以把這個欄位設為 0。此欄位長度是 64 位元。
③、SuppressBackgroundThread：此為 32 位元的整數，為一布林值，表示是否啟用後台執行緒。預設值為 FALSE，表示啟用後台執行緒；設為 TRUE，不啟用後台執行緒。後台執行緒負責管理內部資源，處理一些低優先級的內部操作。一般情形下，將此欄位設為 FALSE，讓 GDI＋ 自行管理即可。
④、SuppressExternalCodecs：此為 32 位元的整數，為一布林值，表示是否允許使用外部編解碼器。預設值為 FALSE，表示允許載入外部編解碼器。

pGdipStartOutput 為結構體 GdiplusStartupOutput 的位址，此結構可用於提供一些啟動 GDI＋ 後的附加資訊，特別是控制後台執行緒的管理。如果第二個參數所指結構體中的第三個欄位，SuppressBackgroundThread，為 FALSE，則 pGdipStartOutput 可以是 0。GdiplusStartupOutput 結構體的個欄位如下：

GdiplusStartupOutput    STRUCT
  NotificationHook      NotificationHookProc    ?   ;攔截函式位址，用於通知應用程式 GDI＋ 的後台執行緒正在啟動
  NotificationUnhook    NotificationUnhookProc  ?   ;攔截函式位址，用於通知應用程式 GDI＋ 的後台執行緒正在停止
GdiplusStartupOutput    ENDS

在大多數情況下，GdiplusStartupOutput 結構體內的兩欄位均可設為 0，表示不需要用攔截函式處理後台執行緒。然而，當應用程式需要細緻地管理 GDI＋ 的後台執行緒時，可以適當設定這兩個欄位。

如果 GdiplusStartup 執行成功，GdiplusStartup 的回傳值為 0；如果失敗，回傳值為其錯誤碼，見上表一。

GdiplusShutdown API

GdiplusShutdown 會清除 GDI＋ 所使用的資源。每呼叫一次 GdiplusStartup，都應該也呼叫一次 GdiplusShutdown。GdiplusShutdown 的原型如下：

invoke  GdiplusShutdown,\
        token           ; the GDI+ session handle

GdiplusShutdown 只有一個參數，就是從呼叫 GdiplusStartup 得到的 token。在建立任何 GDI＋ 物件之前得先呼叫 GdiplusStartup 初始化，而且也必須先刪除所有 GDI＋ 物件，才能呼叫 GdiplusShutdown。GdiplusShutdown 沒有回傳值。

對簡單功能的 GDI＋ 應用程式而言，GDI＋ 的初始化與清除，可照以下說明進行。通常使 GdiplusStartupInput 設為 <1,0,0,0>，而 pGdipStartOutput 也設為 0。初始化工作，可以在應用程式一開始，或是建立視窗之後進入訊息迴圈之前；而在結束訊息迴圈之後結束 GDI＋。如下面程式碼：

.DATA
hwnd    HWND    ?
token   DQ      ?
status  DQ      ?
gsi     GdiplusStartupInput <1,0,0,0>
          ⁝
main    PROC
          ⁝        
        mov     hwnd,RV(CreateWindowEx,……)
        mov     status,RV(GdiplusStartup,OFFSET token,OFFSET gsi,0)
.while TRUE
        invoke  GetMessage,ADDR msg,0,0,0
.break .if rax==0
        invoke  TranslateMessage,ADDR msg
        invoke  DispatchMessage,ADDR msg
.endw
        invoke  GdiplusShutdown,token
          ⁝

假如使用 WinInc 包含檔，那麼在 GdiPlusInit.INC 內宣告 GdiplusShutdown 的原型有誤，應將其改成：

@DefProto WINGDIPAPI, GdiplusShutdown, stdcall, , <:QWORD>, 4

GdipLoadImageFromFile API

GdipLoadImageFromFile 會根據圖片檔案建立 GpImage 物件。在 GDI＋ 中有許多關於圖形的物件，GDI＋ 函式以這些物件進行繪製、塗色、旋轉等操作。GpImage 只是其中之一，可以把 GpImage 物件想像成是一種代碼，GDI＋ 可以對這 GpImage 物件進行操作；就像視窗代碼一樣，系統可以對視窗代碼進行操作，例如放大、縮小、關閉等。GdipLoadImageFromFile 的原型如下：

invoke  GdipLoadImageFromFile,\
        lpFileName,\    ; pointer to name of the file
        pGpImage        ; pointer to a GpImage object

lpFileName 是檔案名稱的位址，此檔案可以是 PNG、JPG、GIF、Exif、TIFF、WMF、EMF 等格式的圖片檔，而且檔名必須是萬國碼檔名。pGpImage 是 GpImage 物件位址，GpImage 物件指向 GDI＋ 內部的資料，「Gp」代表 GDI plus 的意思。

如果 GdipLoadImageFromFile 執行成功，回傳值為 0；如果失敗，回傳值為其錯誤碼，見上表一。當不再使用 GpImage 物件時，需呼叫 GdipDisposeImage 函式來釋放該物件，以避免發生錯誤。

GdipGetImageWidth API

取得 GpImage 物件的寬度，原型如下：

invoke  GdipGetImageWidth,\
        gdipImage,\     ; GpImage object
        pWidth          ; pointer to width of a GpImage

gdipImage 是 GpImage 物件。pWidth 是變數位址，此變數長 32 位元。當 GdipGetImageWidth 執行成功，回傳值為 0，且系統會把 GpImage 物件中的圖片寬度寫入此變數中，單位是像素；如果失敗，回傳值為其錯誤碼，見上表一。

GdipGetImageHeight API

取得 GpImage 物件的高度，原型如下：

invoke  GdipGetImageHeight,\
        gdipImage,\     ; GpImage object
        pHeight         ; pointer to height of a GpImage

gdipImage 是 GpImage 物件。pHeight 是變數位址，此變數長 32 位元。當 GdipGetImageHeight 執行成功，回傳值為 0，且系統會把 GpImage 物件中的圖片高度寫入此變數中，單位是像素；如果失敗，回傳值為其錯誤碼，見上表一。

GdipCreateFromHDC API

GdipCreateFromHDC 用於建立與指定裝置內容相關聯的 GpGraphics 物件，也就是說從指定的設備內容建立一個 GpGraphics 物件。GpGraphics 是 GDI＋ 的物件之一，它也是一個指標，長度是 64 位元，指向 GDI＋ 內部的資料結構。每當要繪製圖形時，GDI＋ 都是操作 GpGraphics 物件，然後在裝置內容繪出圖形。可以 GpGraphics 物件想像成是 GDI＋ 版的裝置內容。GdipCreateFromHDC 的原型是：

invoke  GdipCreateFromHDC,\
        hdc,\           ; handle to device context
        pGpGraphics     ; pointer to a GpGraphics object

hdc 是要把圖形繪於其上的裝置內容代碼，可以經由呼叫 BeginPaint、GetDC 或 CreateCompatibleDC 得到。pGpGraphics 是 GpGraphics 物件的位址。

如果 GdipCreateFromHDC 執行成功，回傳值為 0；如果失敗，回傳值為其錯誤碼，見上表一。當不再使用 GpGraphics 物件時，需呼叫 GdipDeleteGraphics 函式來釋放該物件，以避免發生錯誤。

GdipDrawImageRectI 與 GdipDrawImageRect API

GdipDrawImageRectI 用於將圖形（如位元圖或向量圖形）繪製到指定的 GpGraphics 物件上。這個函式使用整數型態的參數來指定影像的位置，而不是浮點數型態。GdipDrawImageRectI 的原型如下：

invoke  GdipDrawImageRectI,\
        gdipGraphics,\  ; GpGraphics object
        gdipImage,\     ; GpImage object
        x,\             ; the x-coordinate of the upper-left corner of the rendered image
        y,\             ; the y-coordinate of the upper-left corner of the rendered image
        width,\         ; width of the destination rectangle
        height          ; height of the destination rectangle

GdipDrawImageRectI 前兩個參數是指把 GpImage 物件繪製於 GpGraphics 上面。GpImage 物件通常是呼叫 GdipLoadImageFromFile 或 GdipCreateBitmapFromHBITMAP 產生。假如 GpGraphics 是由螢幕裝置內容產生，那麼 GpImage 物件就會顯示於螢幕上。x、y 是視窗工作區座標，系統會把 GpImage 的左上角繪製於此座標上。x、y 是 32 位元無號整數，以像素為單位。width、height 是要繪製的目標矩形的寬度與高度，以像素為單位。假如 width、height 與 GpImage 物件中的寬度與高度不同的話，那麼就會放大或縮小，也可能會拉伸或壓縮。

如果執行成功，回傳值為 0；如果失敗，回傳值為其錯誤碼，見上表一。

還有一個 GdipDrawImageRect GDI＋ API，功能與 GdipDrawImageRectI 類似，函式名稱僅相差一個「I」。GdipDrawImageRect 的原型是：

invoke  GdipDrawImageRect,\
        gdipGraphics,\  ; GpGraphics object
        gdipImage,\     ; GpImage object
        x,\             ; the x-coordinate of the upper-left corner of the rendered image
        y,\             ; the y-coordinate of the upper-left corner of the rendered image
        width,\         ; width of the destination rectangle
        height          ; height of the destination rectangle

GdipDrawImageRectI 與 GdipDrawImageRect 的差別在於，前者的 x、y、width、height 都是 32 位元整數，後者則是 32 位元浮點數（不論是 64 位元或 32 位元的 Windows 中，此處的浮點數都是 32 位元長）。後者適合需要高精度繪製，例如旋轉時使用。

GdipDeleteGraphics API

GdipDeleteGraphics 用於釋放 GpGraphics 物件，以節省資源。其原型為：

invoke  GdipDeleteGraphics,\
        gdipGraphics    ; GpGraphics object

GdipDeleteGraphics 只有一個參數，就是要釋放的 GpGraphics 物件。如果執行成功，回傳值為 0；如果失敗，回傳值為其錯誤碼，見上表一。

GdipDisposeImage API

GdipDisposeImage 用於釋放 GpImage 物件，其原型為：

invoke  GdipDisposeImage,\
        gdipImage       ; GpImage object

GdipDisposeImage 只有一個參數，就是要釋放的 GpImage 物件。如果執行成功，回傳值為 0；如果失敗，回傳值為其錯誤碼，見上表一。

用 GDI＋ 顯示圖片檔

假如要用 GDI＋ 於視窗工作區上顯示圖片檔，是不錯的選擇，因為 GDI＋ 支援許多種格式的圖片檔。底下簡述這段過程：

  1. 呼叫 GdipLoadImageFromFile 把圖片檔變成 GpImage 物件。
  2. 呼叫 GdipCreateFromHDC 建立與裝置內容相關聯的 GpGraphics 物件。
  3. 呼叫 GdipDrawImageRectI 將 GpImage 物件繪製於 GpGraphics 物件上，因為 GpGraphics 物件與裝置內容相關聯，就能把圖片檔顯示其上。

上面的過程是最核心的部分，並不包含使用 GDI＋ 前的初始化及使用後的釋放 GDI＋ 資源，也不包含釋放 GpGraphics 與 GpImage 物件。假如要讓顯示在視窗工作區圖片檔寬度與高度，恰好容納於工作區內，那麼就得調整視窗工作區大小，連帶也會調整視窗大小。

AdjustWindowRectEx API

AdjustWindowRectEx 能根據應用程式所指定的工作區寬度與高度，計算視窗大小。AdjustWindowRectEx 僅計算視窗的尺寸，並不會真正改變其尺寸，因此還要把所得的視窗大小，以參數傳給 CreateWindowEx 或 SetWindowPos 才能真正讓視窗內的工作區，符合應用程式所指定的。AdjustWindowRectEx 的原型如下：

invoke  AdjustWindowRectEx,\
        lpRect,\        ; pointer to client-rectangle structure
        dwStyle,\       ; window styles
        bMenu,\         ; menu-present flag
        dwExStyle       ; extended style

底下說明這些參數的意義：

  1. lpRect 是 RECT 結構體位址。在呼叫 AdjustWindowRectEx 前，此結構體內必須已存有指定的工作區左上角及右下角座標；如果 AdjustWindowRectEx 執行成功，此結構體會變為視窗的左上角及右下角座標，而此視窗的工作區恰好是呼叫前應用程式所指定的。
  2. dwStyle 是視窗風格，因為有些視窗風格會影響視窗大小，故此參數表示視窗風格對視窗尺寸的影響。dwStyle 不能是僅僅 WS_OVERLAPPED 單獨存在，因為 WS_OVERLAPPED 之數值是 0，並不提供任何額外的視窗風格。
  3. bMenu 用於表示視窗是否有主功能表，主功能表也會增加視窗高度。如果具有主功能表，應將 bMenu 設為 1；否則設為 0。
  4. dwExStyle 是視窗的額外風格，它也會改變視窗尺寸。

lpRect 所指的 RECT 結構體在呼叫前，左上角座標不一定必須是 ( 0,0 )，可以是其他座標。我們可以把 RECT 結構體的左上角與右下角座標，想像成是螢幕座標，而其差值就是工作區的寬度與高度。AdjustWindowRectEx 計算時，會將邊框、標題欄等因素考慮進去，而使左上角座標往左上方擴充，右下角座標往右下方擴充，以至於使 RECT 結構體變成視窗的左上角與右下角座標，但其工作區的左上角與右下角座標仍不變，只是沒表示出來。

AdjustWindowRectEx 不會將 WS_VSCROLL 或 WS_HSCROLL 納入考慮。若要考慮捲動軸，請使用 SM_CXVSCROLL 或 SM_CYHSCROLL 呼叫 GetSystemMetrics。如果主功能表有兩列，那麼 AdjustWindowRectEx 無法處理，必須用 SM_CYMENU 為參數呼叫 GetSystemMetrics，得到主功能表每列高度。如果 AdjustWindowRectEx 執行成功回傳值為 1，否則為零。

範例 VIEWIMG

接下來就將上面所提過的原理及 GDI＋ API 應用在組合語言裏，撰寫一個能觀看較多格式圖片檔的 VIEWIMG 應用程式。底下是 VIEWIMG.EXE.MANIFEST 的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
  <assemblyIdentity
    type="win32"
    name="AtHome.Wanker.ViewImg"
    version="1.0.0.0"
    processorArchitecture="amd64"
  />
  <dependency>
    <dependentAssembly>
      <assemblyIdentity
        type="win32"
        name="Microsoft.Windows.Common-Controls"
        version="6.0.0.0"
        processorArchitecture="amd64"
        publicKeyToken="6595b64144ccf1df"
        language="*"
      />
    </dependentAssembly>
  </dependency>
</assembly>

底下是 VIEWIMG.RC 的內容：

1
2
3
4
5
6
#include "RESOURCE.H"

#define RT_MANIFEST 24
1       RT_MANIFEST MOVEABLE PURE "VIEWIMG.EXE.MANIFEST"

2000    ICON    EYE.IC

底下是 VIEWIMG.ASM 的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
OPTION  CASEMAP:NONE
OPTION  WIN64:3
OPTION  LITERALS:ON

UNICODE  EQU    1      ;使用UNICODE編碼字元

INCLUDE         WINDOWS.INC ;包含GDIPLUS.INC，宣告GDI＋函式
INCLUDE         GDIPLUS.INC ;包含GDIPLUS.LIB，使GDI＋函式能順利連結
INCLUDELIB      GDIPLUS.LIB
INCLUDELIB      GDI32.LIB
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB
;*******************************************************************************
.DATA
hInst           DQ      ?
gdipToken       DQ      ?   ;Token
gdipImage       DQ      ?   ;GpImage物件
gdipGraphics    DQ      ?   ;GpGraphics物件
gdipStart       GdiplusStartupInput <1,0,0,0>   ;初始化GDI＋所需資料
szClassName     DW  "VIEWIMG",0
szTitle         DW  770bh,5716h,7a0bh,5f0fh,0   ;看圖程式
szFileName      DW  "re2r.jpg",0                ;圖片檔的檔名
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
WndProc PROC    hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
LOCAL   hDC:HDC,ps:PAINTSTRUCT,cxImg:DWORD,cyImg:DWORD,rcWnd:RECT
.if uMsg==WM_PAINT
        mov     hDC,RV(BeginPaint,hWnd,ADDR ps)
    ;把圖片檔變成GpImage物件、建立與hDC相關聯的GpGraphics物件，得到GpImage的尺寸
        invoke  GdipLoadImageFromFile,OFFSET szFileName,OFFSET gdipImage
        invoke  GdipCreateFromHDC,hDC,OFFSET gdipGraphics
        invoke  GdipGetImageWidth,gdipImage,ADDR cxImg
        invoke  GdipGetImageHeight,gdipImage,ADDR cyImg
    ;計算視窗尺寸，以符合圖片尺寸
        mov     rcWnd.left,0
        mov     rcWnd.top,0
        mov     eax,cxImg
        mov     ecx,cyImg
        mov     rcWnd.right,eax
        mov     rcWnd.bottom,ecx
        invoke  AdjustWindowRectEx,ADDR rcWnd,WS_OVERLAPPEDWINDOW,0,0
    ;設定視窗位置及尺寸
        mov     r10d,rcWnd.right
        mov     r11d,rcWnd.bottom
        sub     r10d,rcWnd.left
        sub     r11d,rcWnd.top
        invoke  SetWindowPos,hWnd,0,50,50,r10d,r11d,SWP_NOZORDER
    ;把GpImage物件繪製於GpGraphics上
        invoke  GdipDrawImageRectI,gdipGraphics,gdipImage,0,0,cxImg,cyImg
    ;釋放GpImage與GpGraphics物件
        invoke  GdipDisposeImage,gdipImage
        invoke  GdipDeleteGraphics,gdipGraphics
        invoke  EndPaint,hWnd,ADDR ps

.elseif uMsg==WM_DESTROY
        invoke  PostQuitMessage,0

.else
def:    invoke  DefWindowProc,hWnd,uMsg,wParam,lParam
        ret

.endif
rtn:    xor     rax,rax
        ret
WndProc ENDP
;-------------------------------------------------------------------------------
main    PROC
        LOCAL   hwnd:HWND,msg:MSG,wc:WNDCLASSEX
        mov     hInst,RV(GetModuleHandle,0)
        mov     wc.cbSize,SIZEOF WNDCLASSEX
        lea     rdx,WndProc
        mov     wc.style,CS_HREDRAW or CS_VREDRAW
        mov     wc.lpfnWndProc,rdx
        mov     wc.cbClsExtra,0
        mov     wc.cbWndExtra,0
        mov     wc.hInstance,rax
        mov     wc.hIcon,RV(LoadIcon,hInst,2004)
        mov     wc.hIconSm,rax
        mov     wc.hCursor,RV(LoadCursor,0,IDC_ARROW)
        mov     wc.hbrBackground,COLOR_WINDOW+1
        mov     wc.lpszMenuName,0
        lea     rdx,szClassName
        mov     wc.lpszClassName,rdx
        invoke  RegisterClassEx,ADDR wc
        mov     hwnd,RV(CreateWindowEx,0,ADDR szClassName,OFFSET szTitle,\
                WS_OVERLAPPEDWINDOW,50,50,400,200,0,0,hInst,0)
        invoke  GdiplusStartup,OFFSET gdipToken,OFFSET gdipStart,0
        invoke  ShowWindow,hwnd,SW_SHOWNORMAL
        invoke  UpdateWindow,hwnd
.while TRUE
        invoke  GetMessage,ADDR msg,0,0,0
.break .if rax==0
        invoke  TranslateMessage,ADDR msg
        invoke  DispatchMessage,ADDR msg
.endw
        invoke  GdiplusShutdown,gdipToken
        invoke  ExitProcess,0
main    ENDP
;*******************************************************************************
END      main

這個程式的原理都已經提過，不多說了。