第二十七章　通用對話盒：開啟舊檔（二）

前一章提過，總管風格的對話盒，可以使用 OPENFILENAME 結構體中的 lpTemplateName 來指定一個包含額外控制項的子對話盒面板，以增加新功能，但是並未提及如何實現。本章將接續這個主題，談談這方面的原理，並舉例子實現它。

原理

先介紹幾個 Win64 API，它們會在本章的例子用到。然後介紹如何撰寫子對話盒面板及有關細節。

GetParent API

GetParent 可以為子視窗取得其父視窗之視窗代碼，其原型如下：

invoke  GetParent,\
        hWnd            ; handle of child window

hWnd 為視窗的視窗代碼。如果 hWnd 為子視窗，回傳值為 hWnd 的父視窗之視窗代碼；如果 hWnd 為頂級視窗（top-level windows）且具有 WS_POPUP 風格，回傳值為擁有者視窗之視窗代碼；如果執行失敗，回傳值為零，可以呼叫 GetLastError 得到進一步說明。

ScreenToClient API

ScreenToClient 會把指定像素的螢幕座標轉換為工作區座標。螢幕座標是以螢幕最左邊、最上面的像素為原點，而工作區座標則是以視窗的左上角為原點。不論是螢幕座標還是工作區座標，原點的座標是 (0,0)。每個視窗都有自己的工作區座標，所以每個視窗左上角的工作區座標都是 (0,0)。在預設情形下，不論是螢幕座標，還是工作區座標，它們的 X 座標都是在原點右方為正，越往右越大；Y 座標在原點下方為正，越往下越大。ScreenToClient 的原型如下：

invoke  ScreenToClient,\
        hWnd,           ; window handle for source coordinates
        lpPoint         ; address of structure containing coordinates

要呼叫 ScreenToClient 轉換座標，須以某個視窗的工作區原點為基準作為轉換，此視窗的代碼即為 hWnd。lpPoint 為 POINT 結構體位址，這結構體的要轉換成工作區座標的螢幕座標。如果 ScreenToClient 執行成功，回傳值為一，且 lpPoint 內的座標會變成轉換後的工作區座標；如果執行失敗，回傳值為零。

WM_GETFONT 與 WM_SETFONT 訊息

應用程式可以呼叫 SendMessage 對視窗發送 WM_GETFONT 訊息，得到該視窗所使用的字形。這時 wParam、lParam 均設為零，如下面程式：

invoke  SendMessage,hWnd,WM_GETFONT,0,0

其中的 hWnd 是視窗代碼。如果執行成功，回傳值為 hWnd 所使用字形代碼；假如回傳值為零，表示 hWnd 使用系統字形。

應用程式也可以呼叫 SendMessage，發送 WM_SETFONT 訊息到某個視窗，設定該視窗要用的字形。這時 wParam 為字形代碼。lParam 可以是一，代表立即重繪視窗；也可以是零，代表不重繪視窗。程式如下：

invoke  SendMessage,hWnd,WM_SETFONT,hFont,lParam

WM_SETFONT 沒有回傳值。設定控制項字形最好的時機是在處理 WM_INITDIALOG 訊息時，如果該字形不再使用時，應呼叫 DeleteObject 將其刪除，例如摧毀控制項時。

WM_CTLCOLORDLG 訊息

在系統繪製對話盒之前，系統會把 WM_CTLCOLORDLG 訊息傳送至對話盒函式中。藉由處理此訊息，可以指定對話盒的背景顏色。這時候 wParam 是對話盒的裝置內容代碼，lParam 是對話盒代碼。當然應用程式可以使用這些資料，也可以不使用這些資料，完全視應用程式的需求來決定。

當應用程式處理完 WM_CTLCOLORDLG 訊息，並由對話盒函式返回系統時，應將在 RAX 內的回傳值設定為畫刷代碼，系統會用這個畫刷繪製對話盒背景顏色。系統不會自動摧毀畫刷，所以當不需要時，應用程式必須負責摧毀畫刷。

如果對話盒函式不處理 WM_CTLCOLORDLG 訊息，系統會由 DefWindowProc API 處理此訊息，DefWindowProc 會選取對話盒預設的系統顏色繪製對話盒背景。

開啟舊檔或另存新檔對話盒的子對話盒

應用程式可以在呼叫 GetOpenFileName 或 GetSaveFileName 所產生的「開啟舊檔」或「另存新檔」對話盒中，新添加一些控制項，增加這兩對話盒的功能。

這些新增的控制項，是在資源描述檔中的對話盒面板中定義。呼叫這兩個 Win64 API 前，在 OPENFILENAME 結構體的 Flags 欄位中指定 OFN_ENABLETEMPLATE，並設定好 hInstance 和 lpTemplateName 欄位。如果對話盒面板已存於記憶體中，也可以設置 OFN_ENABLETEMPLATEHANDLE 旗標，並設定好 hInstance。不論哪一種，還要把 Flags 包含 OFN_EXPLORER，否則系統將假設應用程式使用舊風格而替換掉對話盒。

這兩種情形，由 lpTemplateName 欄位指定的對話盒都是「開啟舊檔」或「另存新檔」的子對話盒，本章以原對話盒稱原來的「開啟舊檔」或「另存新檔」對話盒，以子對話盒稱 lpTemplateName 欄位所指的對話盒。應用程式還要提供總管風格的攔截函式，來處理新增的控制項訊息。

定義子對話盒面板的方式，跟定義一般對話盒面板幾乎一樣，但必須有底下四個風格：

WS_CHILD：因為它是「開啟舊檔」或「另存新檔」對話盒的子對話盒。
WS_CLIPSIBLINGS：確保子對話盒不會覆蓋原對話盒中的原有的控制項。
DS_CONTROL：確保使用者可以使用 Tab 鍵、方向鍵等按鍵在子對話盒和原對話盒中的控制項之間切換。
DS_3DLOOK：確保新增的控制項外觀與原對話盒中的控制項一致。

WS_CLIPSIBLINGS 之值為 4000000h，siblings 是兄弟姊妹的意思，此處指同級視窗；clip 是剪裁的意思，故 WS_CLIPSIBLINGS 的意思就是同級視窗之間相互剪裁。更詳細的說，當具有相同父視窗的子視窗重疊時，預設的情形是後面生成的子視窗會蓋過原先的子視窗。但是如果後面生成的子視窗設定了 WS_CLIPSIBLINGS，那麼重疊的部分不會重新繪製，仍顯現原先的子視窗。子對話盒與原對話盒上的確定、取消、清單盒……等控制項同屬原對話盒的子視窗，也就是說子對話盒與按鈕、取消、清單盒……等控制項的關係是同級視窗，當子對話盒有 WS_CLIPSIBLINGS 風格時，即使重疊也會顯現出原有的控制項。

在第二十一章曾提過，在資源描述檔中以下面格式定義對話盒面板，子對話盒也是用下面格式定義：

nameID  DIALOGEX    x, y, width, height[, helpID]
STYLE WS_CHILD|WS_CLIPSIBLINGS|DS_3DLOOK|DS_CONTROL……
[ optional-statements ]
BEGIN
  control-type "text", id, x, y, cx, cy [, style]
  ⁝
END

上述格式中，STYLE 包含了前面提過的四種風格，當然還可以具有其他風格，可在後面添加，故以「……」表示。

但作為原對話盒的子對話盒，安排其中新增控制項的位置就成了問題，不過至少有三種方法能夠使用。第一種採用預設方式，系統會將原對話盒的高度增加，所增加的高度就是上面格式中的 height。子對話盒的 width，不論是否超過原對話盒寬度，在螢幕上顯示的仍是原對話盒的寬度。但如果 width 小於原對話盒的寬度，須確保新增的控制項仍落在子對話盒範圍內，否則可能看不見或缺少一部份；如果 width 超過原對話盒的寬度，那麼超過的部分不會顯示出來。上面格式中的 x、y 不使用，系統會忽略它們。在上述 BEGIN 與 END 之間的所有新增的控制項，都會放在增加的高度範圍內，也就是在原對話盒控制項的下方。

例如底下的對話盒面板所生成的子對話盒在圖一下面紅色框的部分，上面是原對話盒。

IDDLG   DIALOGEX 10,10,280,16
STYLE   WS_CHILD|WS_CLIPSIBLINGS|DS_3DLOOK\
        |DS_CONTROL
BEGIN
  LTEXT "選擇背景色:",IDS_CLR,50,1,40,12
  COMBOBOX IDCB_CLR,95,0,124,12\
           ,CBS_DROPDOWNLIST
END

子對話盒的原點就是紅色框的左上角，而在 BEGIN 與 END 之間定義的新增控制項左上角座標，都是以這原點為基準，其寬與高的單位均為「對話盒單位（DLU）」。如同圖一 IDS_CLR、IDCB_CLR 兩控制項的左上角座標。

第二種方法是在子對話盒面板中定義一個靜態控制項，並將其識別碼設為 stc32（它定義在 WinInc 中的 DLGS.INC 檔案中，其值為 45fh）。在這種情形下，系統會把 stc32 當作原對話盒，也就是 stc32 的 X、Y 座標為原對話盒的左上角座標，其寬與高為原對話盒的寬與高。雖然實際兩者極可能是不同的，但卻不妨礙系統設定新增控制項的位置。

子對話盒的寬與高最好大於 stc32 的寬與高，除非打算把新增控制項都放在原對話盒內。當然，因為 stc32 的寬與高是對話盒面板自行假設的，其比例必有誤差，所以如果子對話盒略小於 stc32，有時也不會有太大問題。不論如何，最後系統所繪製的對話盒，會以子對話盒的寬度與高度繪出。

然後系統就會把新增的控制項與 stc32 依據以下規則安排位置：

系統把原對話盒繪製於 stc32 的 x、y 所指定的座標處。
如果某新增控制項的 x 比 stc32 的 x 與寬度之和小，那麼新增控制項左上角 X 座標就是 x。
如果某新增控制項的 x 比 stc32 的 x 與寬度之和大，那麼新增控制項左上角 X 座標與 stc32 右緣相距該控制項的 x 減去 stc32 的 x 與寬度之和。
該新增控制項的 Y 座標比照 X 座標，差別在於比較新增控制項的 y 與 stc32 的 y 與高度之和。

上面的 2～4 規則可以理解為，如果新增控制項在原對話盒範圍內，那麼就以對話盒模板上新增控制項的位置為準；如果超過，那麼就把新增的控制項移到距離原對話盒右邊或下邊，且與原對話盒右緣或下緣的距離就是超過的部分。

底下舉個例子說明。假設有個子對話盒，其對話盒面板定義如下：

IDDLG   DIALOGEX 10,100,385,190
STYLE   WS_CHILD|WS_CLIPSIBLINGS|DS_3DLOOK|DS_CONTROL
BEGIN
  LTEXT "",stc32,40,10,200,200,WS_BORDER
  LTEXT "檔案資料：",IDS_INFO,320,40,50,65,WS_BORDER
  CONTROL "",IDS_BMP,"STATIC",SS_BITMAP|WS_BORDER,320,110,60,75
  PUSHBUTTON "選項",IDB_OPT,90,173,45,10
END

生成的對話盒如下圖。此對話盒寬度為 385，高度為 190，即子對話盒大小。圖中藍色座標 ( 40,10 )，是 stc32 左上角位置，前面提過要把 stc32 視為原對話盒，雖然 stc32 的寬度與高度都是 200，而原對話盒並非正方形，所以與原對話盒尺寸不符但不管它。選項按鈕的 X 座標是 90，小於 stc32 的 X 座標與位置之和（200＋40），換句話說在水平方向上，選項按鈕在 stc32 範圍內，故選項按鈕的 X 座標是 90。同理，其 Y 座標也沒超出 stc32 範圍，故 Y 座標是 173。「檔案資料：」靜態控制項，IDS_INFO，其 x 為 320，比 stc32 的 x 與寬度之和（40＋200＝240）大；因此 IDS_INFO 的 X 座標距離 stc32 右緣 320－240＝80 處。IDS_INFO 的 y 為 40，比 stc32 的 y 與高度之和（10＋200＝210）小；因此 IDS_INFO 的 Y 座標為 40。見上圖紅色像素座標（甲,40）。

第三種方法是在攔截函式中處理 WM_SIZE 訊息時，呼叫 SetWindowPos 設定新增控制項的位置與尺寸。採取這種方法時，在定義子對話盒的對話盒面板時，新增控制項的位置與尺寸就不重要，隨意定義也無妨，反正都是由 SetWindowPos 的參數決定。

呼叫 SetWindowPos 設定新增控制項的位置及尺寸，若考慮原對話盒內控制項的位置、尺寸並與之對齊，會較為美觀。步驟如下：

呼叫 GetParent 取得原對話盒的視窗代碼。這是因為原對話盒是子對話盒的父視窗。

呼叫 GetDlgItem 取得控制項代碼，此步驟須知控制項識別碼。幸運的是，原對話盒內控制項的識別碼已在 DLGS.INC 檔案內宣告，可參考下表與圖二。（IDOK、IDCANCEL 不在 DLGS.INC 中宣告，而是在 WINUSER.INC 宣告）

識別碼	數值	說明	識別碼	數值	說明
stc2	441h	檔案類型靜態控制項	cmb1	470h	檔案類型複合框
stc3	442h	檔案名稱靜態控制項	cmb13	47ch	檔案名稱複合框
stc4	443h	搜尋位置靜態控制項	cmb2	471h	搜尋位置複合框
lst1	460h	顯示檔案的清單盒	chx1	410h	唯讀複選框
IDOK	1	開啟舊檔按鈕	IDCANCEL	2	取消按鈕
psh15	40eh	說明按鈕

呼叫 GetWindowRect 取得原對話盒上控制項所在的矩形範圍，這矩形左上角及右下角座標是螢幕座標。
計算新增控制項的座標及尺寸。
呼叫 ScreenToClient 將螢幕座標轉換為開啟舊檔或另存新檔的工作區座標。
呼叫 SetWindowPos 設定新增控制項的位置、尺寸。

上面的過程僅僅是定義好子對話盒，以及其內的新增控制項的位置及尺寸，但這還不夠。應用程式必須提供攔截函式，新增控制項所發出的訊息，會發送到攔截函式中；就像其他對話盒上的控制項，把訊息發送到視窗函式一樣。例如，當使用者以滑鼠左鍵點擊子對話盒中的按鈕時，攔截函式會收到 WM_COMMAND 訊息。攔截函式也負責初始化新增的控制項，這些跟其他對話盒函式一樣，在收到 WM_INITDIALOG 訊息時處理。

但要注意，當攔截函式收到 WM_INITDIALOG 訊息時，系統尚未將新增控制項移動到最終位置，所以如果要移動新增控制項的位置，不應在處理 WM_INITDIALOG 訊息時，應在收到 WM_SIZE 訊息時處理。這也就是為什麼第三種方法，要在 WM_SIZE 訊息中設定新增控制項位置尺寸的緣故。

範例一：VIEWBMP5

VIEWBMP5 在開啟舊檔對話盒中新增一個靜態控制項及一個下拉清單型複合框，見下面圖三左邊以紫紅色框框住的部分。這兩個新增的控制項位於開啟舊檔的子對話盒上，用第三種方法使它們在 stc2 與 cmb1 正下方。使用者可以於下拉清單型複合框中選擇顏色，開啟舊檔對話盒的背景色會隨之改變（圖三右邊）。

底下是 VIEWBMP5.EXE.MANIFEST：

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>

<assemblyIdentity

type="win32"

name="AtHome.Wanker.ViewBmp5"

version="1.0.0.0"

processorArchitecture="amd64"

<assemblyIdentity

type="win32"

name="Microsoft.Windows.Common-Controls"

version="6.0.0.0"

processorArchitecture="amd64"

publicKeyToken="6595b64144ccf1df"

language="*"

</dependentAssembly>

</dependency>

</assembly>

底下是 VIEWBMP5.RC：

#include "RESOURCE.H"

#define VBMENU 2000

#define IDM_OPEN 2001

#define IDM_QUIT 2002

#define IDM_HELP 2003

#define IDDLG 3000

#define IDS_CLR 3001

#define IDCB_CLR 3002

VBMENU MENU

BEGIN

POPUP "檔案"

BEGIN

MENUITEM "開啟",IDM_OPEN

MENUITEM "離開",IDM_QUIT

END

MENUITEM "說明",IDM_HELP

END

#define RT_MANIFEST 24

1 RT_MANIFEST MOVEABLE PURE "VIEWBMP5.EXE.MANIFEST"

2004 ICON EYE.ICO

IDDLG DIALOGEX 10,10,280,16

STYLE WS_CHILD|WS_CLIPSIBLINGS|DS_3DLOOK|DS_CONTROL

BEGIN

LTEXT "選擇背景色:",IDS_CLR,0,0,0,0

COMBOBOX IDCB_CLR,0,0,0,0,CBS_DROPDOWNLIST

END

注意到 VIEWBMP5.RC 的第 27～28 行，把新增控制項的位置與尺寸都設為零，絲毫不妨害應用程式的執行與操作。

底下是 VIEWBMP5.ASM：

OPTION CASEMAP:NONE

OPTION WIN64:3

OPTION LITERALS:ON

_WIN32_WINNT EQU 500h ;使用Windows 2000及其以後的OPENFILENAME版本

UNICODE EQU 1 ;使用UNICODE編碼字元

VBMENU EQU 2000

IDM_OPEN EQU 2001

IDM_QUIT EQU 2002

IDM_HELP EQU 2003

IDDLG EQU 3000 ;自訂的子對話盒面板識別碼

IDS_CLR EQU 3001 ;在開啟舊檔對話盒中新增加的「選擇背景色：」靜態控制項識別碼

IDCB_CLR EQU 3002 ;在開啟舊檔對話盒中新增加的下拉清單複合框識別碼

INCLUDE WINDOWS.INC

INCLUDELIB GDI32.LIB

INCLUDELIB KERNEL32.LIB

INCLUDELIB USER32.LIB

INCLUDELIB COMDLG32.LIB

;***************************************************************************************************

.CONST

szClass DW "VIEWBMP",0

szTitle DW 89c0h,770bh,4f4dh,5143h,5716h,0 ;觀看位元圖

szRem DW 89c0h,770bh,42h,4dh,50h,5716h,7247h,6a94h ;觀看BMP圖片檔

DW 7684h,7c21h,55aeh,7a0bh,5f0fh,3002h,0 ;的簡單程式。

szSure DW 78bah,5b9ah,9000h,51fah,55ceh,0ff1fh,0 ;確定退出嗎？

szAsk DW 8a62h,554fh,0 ;詢問

szNote DW 8aaah,660eh,0 ;說明

szExt DW 42,46,62h,6dh,70h,0 ;"*.bmp",0

;底下的篩選字串是「"位元圖(*.bmp)",0,"*.bmp",0,"所有檔案(*.*)",0,"*.*",0,0」

szFiltr DW 4f4dh,5143h,5716h,"(*.bmp)",0,"*.bmp",0,6240h,6709h,6a94h,6848h,"(*.*)",0,"*.*",0,0

szClrD DW 9810h,8a2dh,7684h,80cch,666fh,984fh,8272h,0 ;預設的背景顏色

szClrB DW 6de1h,85cdh,8272h,0 ;淡藍色

szClrG DW 6de1h,7da0h,8272h,0 ;淡綠色

szClrR DW 6de1h,7d05h,8272h,0 ;淡紅色

;***************************************************************************************************

.DATA

hInst DQ ?

ofn OPENFILENAME <>

szFile DW 256 DUP (0)

hOFN DQ ? ;開啟舊檔對話盒的視窗代碼

hStc DQ ? ;新增的靜態控制項代碼

hCmb DQ ? ;新增的複合框代碼

hbrD DQ ? ;預設的背景色畫刷

hbrB DQ ? ;淡藍色畫刷

hbrG DQ ? ;淡綠色畫刷

hbrR DQ ? ;淡紅色畫刷

color DD 0 ;開啟舊檔的背景顏色：0－預設的背景顏色、1－淡藍、2－淡綠、3－淡紅

;***************************************************************************************************

.CODE

;---------------------------------------------------------------------------------------------------

HookPrc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM

LOCAL hFont:HFONT,hStc2:HWND,hStc3:HWND,hCmb1:HWND

LOCAL rcStc2:RECT,rcStc3:RECT,rcCmb1:RECT,ptStc:POINT,ptCmb:POINT

.if uMsg==WM_NOTIFY

ASSUME r11:PTR OFNOTIFY

mov r11,lParam

mov eax,[r11].hdr.code

.if eax==CDN_HELP

;處理使用者按下「說明」按鈕

invoke MessageBox,hWnd,OFFSET szRem,OFFSET szNote,MB_OK or MB_ICONINFORMATION

.endif

ASSUME r11:NOTHING

.elseif uMsg==WM_SIZE

mov hStc2,RV(GetDlgItem,hOFN,stc2) ;檔案類型靜態控制項代碼

mov hStc3,RV(GetDlgItem,hOFN,stc3) ;檔案名稱靜態控制項代碼

invoke GetWindowRect,hStc2,ADDR rcStc2 ;取得這兩個控制項所在矩形區域

invoke GetWindowRect,hStc3,ADDR rcStc3 ;此區域為螢幕座標

;計算新增的靜態控制項左上角位置與其寬度與高度，並轉換成工作區座標

mov r9d,rcStc2.top

mov r8d,rcStc2.left

sub r9d,rcStc3.top

mov ptStc.x,r8d ;ptStc.x為新增的靜態控制項左上角像素的X座標

add r9d,rcStc2.top

mov ptStc.y,r9d ;ptStc.y為新增的靜態控制項左上角像素的Y座標

mov ptCmb.y,r9d ;ptCmb.y為新增的複合框左上角像素的Y座標

invoke ScreenToClient,hOFN,ADDR ptStc

mov r10d,rcStc2.right

mov r11d,rcStc2.bottom

sub r10d,rcStc2.left ;新增的靜態控制項的寬度

sub r11d,rcStc2.top ;新增的靜態控制項的高度

;把新增的靜態控制項移到所計算出來的位置

invoke SetWindowPos,hStc,HWND_TOP,ptStc.x,ptStc.y,r10d,r11d,SWP_SHOWWINDOW

;計算新增的複合框左上角位置與其寬度與高度，並轉換成工作區座標

mov hCmb1,RV(GetDlgItem,hOFN,cmb1) ;檔案類型複合框代碼

invoke GetWindowRect,hCmb1,ADDR rcCmb1

mov r11d,rcCmb1.left

mov ptCmb.x,r11d ;ptCmb.x為新增的複合框左上角像素的X座標

invoke ScreenToClient,hOFN,ADDR ptCmb

mov r10d,rcCmb1.right

mov r11d,rcCmb1.bottom

sub r10d,rcCmb1.left ;新增的複合框的寬度

sub r11d,rcCmb1.top ;新增的複合框的高度

;把新增的複合框移到所計算出來的位置

invoke SetWindowPos,hCmb,HWND_TOP,ptCmb.x,ptCmb.y,r10d,r11d,SWP_SHOWWINDOW

.elseif uMsg==WM_INITDIALOG

mov hOFN,RV(GetParent,hWnd) ;獲得開啟舊檔對話盒的視窗代碼

;把新增的靜態控制項與複合框的字形，設為與開啟舊檔對話盒的字形相同

mov hFont,RV(SendMessage,hOFN,WM_GETFONT,0,0)

mov hStc,RV(GetDlgItem,hWnd,IDS_CLR) ;獲得自訂靜態控制項代碼

mov hCmb,RV(GetDlgItem,hWnd,IDCB_CLR) ;獲得自訂複合框代碼

invoke SendMessage,hStc,WM_SETFONT,hFont,1 ;把自訂靜態控制項的文字設為與開啟舊檔同樣字形

invoke SendMessage,hCmb,WM_SETFONT,hFont,1 ;把自訂複合框的文字設為與開啟舊檔同樣字形

;在新增的複合框中添加資料

invoke SendMessage,hCmb,CB_ADDSTRING,0,ADDR szClrD ;把"預設的背景顏色"加入複合框內

invoke SendMessage,hCmb,CB_ADDSTRING,0,ADDR szClrB ;把"淡藍色"加入複合框內

invoke SendMessage,hCmb,CB_ADDSTRING,0,ADDR szClrG ;把"淡綠色"加入複合框內

invoke SendMessage,hCmb,CB_ADDSTRING,0,ADDR szClrR ;把"淡紅色"加入複合框內

;設定上次的顏色選項

invoke SendMessage,hCmb,CB_SETCURSEL,color,0

.elseif uMsg==WM_COMMAND

mov rax,r8 ;R8W＝識別碼

shr eax,16 ;AX＝通知碼

.if r8w==IDCB_CLR

.if ax==CBN_SELCHANGE

;當使用者在複合框中選擇了一種顏色，將該顏色的索引存入color，並將整個子對話盒設為無效區域

invoke SendMessage,hCmb,CB_GETCURSEL,0,0

mov color,eax

invoke InvalidateRect,hWnd,0,1

.endif

.elseif uMsg==WM_CTLCOLORDLG

;依據color之值，設定相對應的畫刷，以改變子對話盒的背景顏色

.if color==0

mov rax,hbrD

.elseif color==1

mov rax,hbrB

.elseif color==2

mov rax,hbrG

.else

mov rax,hbrR

.endif

jmp quit ;注意！處理WM_CTLCOLORDLG後，回傳值為畫刷代碼

.else

exit: xor rax,rax ;未處理的訊息，回傳值設為零

ret

.endif

mov rax,1 ;已處理的訊息，回傳值設為一

quit: ret

HookPrc ENDP

;---------------------------------------------------------------------------------------------------

WndProc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM

LOCAL hBitmap:HBITMAP,rcClnt:RECT,bitmap:BITMAP,hDC:HDC,hdcMem:HDC

.if uMsg==WM_COMMAND

.if r8w==IDM_OPEN

;建立開啟舊檔對話盒，供使用者選擇檔案

mov r11,hWnd

mov r10,hInst

lea r9,szFiltr

lea r8,szFile

lea rdx,szExt

mov ofn.lStructSize,SIZEOF ofn

mov ofn.hwndOwner,r11

mov ofn.hInstance,r10

mov ofn.lpstrFilter,r9

mov ofn.lpstrCustomFilter,0

mov ofn.nFilterIndex,1

mov ofn.lpstrFile,r8

mov ofn.nMaxFile,LENGTHOF szFile

mov ofn.lpstrFileTitle,0

mov ofn.nMaxFileTitle,0

mov ofn.lpstrInitialDir,0

mov ofn.lpstrTitle,0

mov ofn.Flags,OFN_EXPLORER or OFN_SHOWHELP or OFN_ENABLEHOOK or OFN_HIDEREADONLY or\

OFN_ENABLETEMPLATE

mov ofn.lpstrDefExt,rdx

lea r10,HookPrc

mov ofn.lCustData,0

mov ofn.lpfnHook,r10

mov ofn.lpTemplateName,IDDLG ;設為自訂的子對話盒面板

mov ofn.pvReserved,0

mov ofn.dwReserved,0

mov ofn.FlagsEx,0

invoke GetOpenFileName,ADDR ofn

mov hBitmap,RV(LoadImage,hInst,ADDR szFile,IMAGE_BITMAP,0,0,LR_LOADFROMFILE)

;如果無法載入使用者選擇的位元圖，RAX會等於零，不做處理返回

or rax,rax

jz rtn

invoke GetObject,hBitmap,SIZEOF BITMAP,ADDR bitmap

mov r10d,bitmap.bmWidth

mov r11d,bitmap.bmHeight

;計算能容納整張位元圖的視窗需要最小寬度與高度

mov rcClnt.left,0

mov rcClnt.top,0

mov rcClnt.right,r10d

mov rcClnt.bottom,r11d

invoke AdjustWindowRect,ADDR rcClnt,WS_CAPTION or WS_SYSMENU,0

mov r10d,rcClnt.right

mov r11d,rcClnt.bottom

sub r10d,rcClnt.left

sub r11d,rcClnt.top

invoke MoveWindow,hWnd,50,50,r10d,r11d,0

;顯示使用者所選擇的位元圖

mov hDC,RV(GetDC,hWnd)

mov hdcMem,RV(CreateCompatibleDC,hDC)

invoke SelectObject,hdcMem,hBitmap

invoke BitBlt,hDC,0,0,bitmap.bmWidth,bitmap.bmHeight,hdcMem,0,0,SRCCOPY

invoke DeleteDC,hdcMem

invoke ReleaseDC,hWnd,hDC

.elseif r8w==IDM_HELP

invoke MessageBox,hWnd,OFFSET szRem,OFFSET szNote,MB_OK or MB_ICONINFORMATION

.elseif r8w==IDM_QUIT

invoke SendMessage,hWnd,WM_CLOSE,0,0

.endif

.elseif uMsg==WM_DESTROY

invoke PostQuitMessage,0

.elseif uMsg==WM_CLOSE

close: cmp RV(MessageBox,0,ADDR szSure,ADDR szAsk,MB_YESNO or MB_ICONQUESTION),IDYES

jne rtn

invoke DeleteObject,hbrD

invoke DeleteObject,hbrB

invoke DeleteObject,hbrG

invoke DeleteObject,hbrR

invoke DestroyWindow,hWnd

.elseif uMsg==WM_DESTROY

invoke PostQuitMessage,0

.else

def: invoke DefWindowProc,hWnd,uMsg,wParam,lParam

ret

.endif

rtn: xor rax,rax

ret

WndProc ENDP

;---------------------------------------------------------------------------------------------------

main PROC

LOCAL hwnd:HWND,msg:MSG,wc:WNDCLASSEX

invoke GetSysColor,COLOR_BTNFACE ;取得系統預設的對話盒背景顏色

mov hbrD,RV(CreateSolidBrush,eax) ;建立預設的背景色畫刷

mov hbrB,RV(CreateSolidBrush,0ffc040h) ;建立淡藍色畫刷

mov hbrG,RV(CreateSolidBrush,040ff40h) ;建立淡綠色畫刷

mov hbrR,RV(CreateSolidBrush,0d090ffh) ;建立淡紅色畫刷

lea rdx,WndProc

mov hInst,RV(GetModuleHandle,0)

mov wc.cbSize,SIZEOF WNDCLASSEX

mov wc.style,CS_HREDRAW or CS_VREDRAW

mov wc.lpfnWndProc,rdx

mov wc.cbClsExtra,0

mov wc.cbWndExtra,0

mov wc.hInstance,rax

mov wc.hIcon,RV(LoadIcon,hInst,2004)

mov wc.hIconSm,rax

mov wc.hCursor,RV(LoadCursor,NULL,IDC_ARROW)

mov wc.hbrBackground,COLOR_WINDOW+1

mov wc.lpszMenuName,VBMENU

lea rdx,szClass

mov wc.lpszClassName,rdx

invoke RegisterClassEx,ADDR wc

mov hwnd,RV(CreateWindowEx,0,ADDR szClass,OFFSET szTitle,WS_OVERLAPPEDWINDOW,\

50,50,400,200,0,0,hInst,0)

invoke ShowWindow,hwnd,SW_SHOWNORMAL

invoke UpdateWindow,hwnd

.while TRUE

invoke GetMessage,ADDR msg,0,0,0

.break .if rax==0

invoke TranslateMessage,ADDR msg

invoke DispatchMessage,ADDR msg

.endw

invoke ExitProcess,0

main ENDP

;***************************************************************************************************

END main

VIEWBMP5 的原理都已提過，就不再囉嗦了。

範例二：VIEWBMP6

VIEWBMP6 在開啟舊檔對話盒的右邊中新增三個靜態控制項，見圖四右邊以紫紅色框框住的部分。VIEWBMP6 用第二種方法，把這三個控制項定位在對話盒右邊。使用者於清單盒的眾多檔案中挑選一個檔案後，VIEWBMP6 會把該檔案的資料顯示於這三個控制項中，包含預覽圖片。

原始碼

底下是 VIEWBMP6.EXE.MANIFEST：

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>

<assemblyIdentity

type="win32"

name="AtHome.Wanker.VIEWBMP6"

version="1.0.0.0"

processorArchitecture="amd64"

<assemblyIdentity

type="win32"

name="Microsoft.Windows.Common-Controls"

version="6.0.0.0"

processorArchitecture="amd64"

publicKeyToken="6595b64144ccf1df"

language="*"

</dependentAssembly>

</dependency>

</assembly>

底下是 VIEWBMP6.RC：

#include "RESOURCE.H"

#define VBMENU 2000

#define IDM_OPEN 2001

#define IDM_QUIT 2002

#define IDM_HELP 2003

#define IDDLG 3000

#define IDS_INFO 3001

#define IDS_BRWS 3002

#define IDS_BMP 3003

#define stc32 0x45f

VBMENU MENU

BEGIN

POPUP "檔案"

BEGIN

MENUITEM "開啟",IDM_OPEN

MENUITEM "離開",IDM_QUIT

END

MENUITEM "說明",IDM_HELP

END

#define RT_MANIFEST 24

1 RT_MANIFEST MOVEABLE PURE "VIEWBMP6.EXE.MANIFEST"

2004 ICON EYE.ICO

IDDLG DIALOGEX 0,0,269,180

STYLE WS_CHILD|WS_CLIPSIBLINGS|DS_3DLOOK|DS_CONTROL

BEGIN

LTEXT "",stc32,0,0,200,200

LTEXT "",IDS_INFO,204,2,61,66

LTEXT "圖片預覽：",IDS_BRWS,200,82,60,10

CONTROL "",IDS_BMP,"STATIC",SS_BITMAP,200,90,67,85

END

VIEWBMP6.RC 採用 stc32 定位新增的控制項。見第 30～33 行，得知 IDS_INFO、IDS_BRWS、IDS_BMP 的 X 座標不是超過 stc32 的寬度，即 200，就是恰好相等，所以它們與原對話盒右緣邊線的距離是它們 X 座標與 stc32 寬度之差；故 IDS_INFO 距離原對話盒右邊 4 個 DLU 處，IDS_BRWS、IDS_BMP 都緊貼著原對話盒右緣邊線上。IDS_INFO、IDS_BRWS、IDS_BMP 的 Y 座標均小於 stc32 的高度，即 200，故分別距離對話盒上緣邊線 2、82、90 個 DLU 處。

因為有 stc32 定位，故 VIEWBMP6.ASM 不須處理 WM_SIZE 訊息。底下是 VIEWBMP6.ASM：

OPTION CASEMAP:NONE

OPTION WIN64:3

OPTION LITERALS:ON

_WIN32_WINNT EQU 500h ;使用Windows 2000及其以後的OPENFILENAME版本

UNICODE EQU 1 ;使用UNICODE編碼字元

VBMENU EQU 2000

IDM_OPEN EQU 2001

IDM_QUIT EQU 2002

IDM_HELP EQU 2003

IDDLG EQU 3000

IDS_INFO EQU 3001

IDS_BRWS EQU 3002

IDS_BMP EQU 3003

INCLUDE WINDOWS.INC

INCLUDE SHLOBJ.INC

INCLUDELIB GDI32.LIB

INCLUDELIB KERNEL32.LIB

INCLUDELIB USER32.LIB

INCLUDELIB COMDLG32.LIB

INCLUDELIB SHELL32.LIB

;***************************************************************************************************

.CONST

szClass DW "VIEWBMP",0

szTitle DW 89c0h,770bh,4f4dh,5143h,5716h,0 ;觀看位元圖

szRem DW 89c0h,770bh,42h,4dh,50h,5716h,7247h,6a94h ;觀看BMP圖片檔

DW 7684h,7c21h,55aeh,7a0bh,5f0fh,3002h,0 ;的簡單程式。

szSure DW 78bah,5b9ah,9000h,51fah,55ceh,0ff1fh,0 ;確定退出嗎？

szAsk DW 8a62h,554fh,0 ;詢問

szNote DW 8aaah,660eh,0 ;說明

szExt DW 42,46,62h,6dh,70h,0 ;"*.bmp",0

;底下的篩選字串是「"位元圖(*.bmp)",0,"*.bmp",0,"所有檔案(*.*)",0,"*.*",0,0」

szFiltr DW 4f4dh,5143h,5716h,"(*.bmp)",0,"*.bmp",0,6240h,6709h,6a94h,6848h,"(*.*)",0,"*.*",0,0

szCrt DW 5efah,7acbh,6642h,9593h,0ff1ah,13,10,0 ;建立時間：

szAcc DW 6700h,8fd1h,5b58h,53d6h,6642h,9593h,0ff1ah,13,10,0 ;最近存取時間：

szWrt DW 6700h,8fd1h,5bebh,5165h,6642h,9593h,0ff1ah,13,10,0 ;最近寫入時間：

szFmt1 DW "%s%04d/%02d/%02d %02d:%02d:%02d.%03d",13,10,13,10,0

szFmt2 DW 6a94h,6848h,5927h,5c0fh,40,4f4dh,5143h,7d44h,41,0ff1ah,13,10,37,73,54,52,117,0 ;檔案大小：%I64u

;***************************************************************************************************

.DATA

hInst DQ ?

hOFN DQ ? ;開啟舊檔對話盒的視窗代碼

szFile DW 256 DUP (0)

ofn OPENFILENAME <>

;***************************************************************************************************

.CODE

;---------------------------------------------------------------------------------------------------

;把檔案的某個時間存入pBfr所指的位址上。pStr是「建立時間：」、「最近存取時間：」、「最近寫入時間：」

;三字串位址，pFt是FILETIME結構體位址，對應上述三種時間。info每次處理一個時間，呼叫三次處理三種時間。

info PROC pBfr:QWORD,pStr:QWORD,pFt:QWORD

LOCAL utc:SYSTEMTIME,lot:SYSTEMTIME ;utc是世界協調時間，lot是當地時間

invoke FileTimeToSystemTime,pFt,ADDR utc

invoke SystemTimeToTzSpecificLocalTime,0,ADDR utc,ADDR lot

invoke wsprintf,pBfr,OFFSET szFmt1,pStr,lot.wYear,lot.wMonth,lot.wDay,\

lot.wHour,lot.wMinute,lot.wSecond,lot.wMilliseconds

shl rax,1 ;RAX是wsprintf寫入pBfr的字元個數，乘以2後變位元組

add rax,pBfr ;RAX指向下次呼叫時緩衝區位址

ret

info ENDP

;---------------------------------------------------------------------------------------------------

HookPrc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM

LOCAL hFont:HFONT,buffer[256]:WORD,szFn[256]:WORD,w32fa:WIN32_FILE_ATTRIBUTE_DATA

LOCAL hBitMap:HBITMAP,bitmap:BITMAP,rcBmp:RECT,hDC:HDC,hdcMem:HDC

.if uMsg==WM_NOTIFY

ASSUME r11:PTR OFNOTIFYEX

mov r11,lParam

mov eax,[r11].hdr.code

.if eax==CDN_HELP

invoke MessageBox,hWnd,OFFSET szRem,OFFSET szNote,MB_OK

.elseif eax==CDN_SELCHANGE

ASSUME r11:NOTHING

invoke SendMessage,hOFN,CDM_GETFILEPATH,LENGTHOF szFn,ADDR szFn

invoke GetFileAttributesEx,ADDR szFn,GetFileExInfoStandard,ADDR w32fa

invoke info,ADDR buffer,OFFSET szCrt,ADDR w32fa.ftCreationTime ;處理建立時間

invoke info,rax,OFFSET szAcc,ADDR w32fa.ftLastAccessTime ;處理最近存取時間

invoke info,rax,OFFSET szWrt,ADDR w32fa.ftLastWriteTime ;存取最近寫入時間

test w32fa.dwFileAttributes,FILE_ATTRIBUTE_DIRECTORY ;若使用者選擇資料夾，不顯示檔案大小

jnz pnt

mov r8,QWORD PTR w32fa.nFileSizeHigh

rol r8,20h

invoke wsprintf,rax,OFFSET szFmt2,r8 ;處理檔案大小

pnt: invoke SetDlgItemText,hWnd,IDS_INFO,ADDR buffer

invoke GetWindowRect,RV(GetDlgItem,hWnd,IDS_BMP),ADDR rcBmp

mov hDC,RV(GetDC,RV(GetDlgItem,hWnd,IDS_BMP))

mov hdcMem,RV(CreateCompatibleDC,hDC)

;若使用者選擇資料夾，只需顯示白色；如果選擇的是檔案，才顯示所選BMP檔縮圖

test w32fa.dwFileAttributes,FILE_ATTRIBUTE_DIRECTORY

jz pic

invoke BitBlt,hDC,0,0,rcBmp.right,rcBmp.top,hdcMem,0,0,WHITENESS ;只顯示白色

jmp del_dc

pic: invoke LoadImage,hInst,ADDR szFn,IMAGE_BITMAP,0,0,LR_LOADFROMFILE

or rax,rax

jz del_dc

mov hBitMap,rax

invoke GetObject,hBitMap,SIZEOF BITMAP,ADDR bitmap

invoke SelectObject,hdcMem,hBitMap

invoke SetStretchBltMode,hDC,HALFTONE

invoke SetBrushOrgEx,hDC,0,0,0

mov r9d,rcBmp.right

mov r10d,rcBmp.bottom

sub r9d,rcBmp.left

sub r10d,rcBmp.top

invoke StretchBlt,hDC,0,0,r9d,r10d,hdcMem,0,0,bitmap.bmWidth,bitmap.bmHeight,SRCCOPY

del_dc: invoke DeleteDC,hdcMem

invoke ReleaseDC,hWnd,hDC

.endif

.elseif uMsg==WM_INITDIALOG

mov hOFN,RV(GetParent,hWnd)

mov hFont,RV(SendMessage,hOFN,WM_GETFONT,0,0)

invoke SendMessage,RV(GetDlgItem,hWnd,IDS_INFO),WM_SETFONT,hFont,1

invoke SendMessage,RV(GetDlgItem,hWnd,IDS_BRWS),WM_SETFONT,hFont,1

.else

xor rax,rax ;未處理的訊息，回傳值設為零

ret

.endif

exit: mov rax,1 ;已處理的訊息，回傳值設為一

ret

HookPrc ENDP

;---------------------------------------------------------------------------------------------------

WndProc PROC hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM

LOCAL hBitmap:HBITMAP,rcClnt:RECT,bitmap:BITMAP,hDC:HDC,hdcMem:HDC

.if uMsg==WM_COMMAND

.if r8w==IDM_OPEN

;建立開啟舊檔對話盒，供使用者選擇檔案

mov r11,hWnd

mov r10,hInst

lea r9,szFiltr

lea r8,szFile

lea rdx,szExt

mov ofn.lStructSize,SIZEOF ofn

mov ofn.hwndOwner,r11

mov ofn.hInstance,r10

mov ofn.lpstrFilter,r9

mov ofn.lpstrCustomFilter,0

mov ofn.nFilterIndex,1

mov ofn.lpstrFile,r8

mov ofn.nMaxFile,LENGTHOF szFile

mov ofn.lpstrFileTitle,0

mov ofn.nMaxFileTitle,0

mov ofn.lpstrInitialDir,0

mov ofn.lpstrTitle,0

mov ofn.Flags,OFN_SHOWHELP or OFN_EXPLORER or OFN_ENABLEHOOK or OFN_ENABLETEMPLATE

mov ofn.lpstrDefExt,rdx

lea r10,HookPrc

mov ofn.lCustData,0

mov ofn.lpfnHook,r10

mov ofn.lpTemplateName,IDDLG ;設為自訂的子對話盒面板

mov ofn.pvReserved,0

mov ofn.dwReserved,0

mov ofn.FlagsEx,0

invoke GetOpenFileName,ADDR ofn

mov hBitmap,RV(LoadImage,hInst,ADDR szFile,IMAGE_BITMAP,0,0,LR_LOADFROMFILE)

;如果無法載入使用者選擇的位元圖，RAX會等於零，不做處理返回

or rax,rax

jz rtn

invoke GetObject,hBitmap,SIZEOF BITMAP,ADDR bitmap

mov r10d,bitmap.bmWidth

mov r11d,bitmap.bmHeight

;計算能容納整張位元圖的視窗需要最小寬度與高度

mov rcClnt.left,0

mov rcClnt.top,0

mov rcClnt.right,r10d

mov rcClnt.bottom,r11d

invoke AdjustWindowRect,ADDR rcClnt,WS_CAPTION or WS_SYSMENU,0

mov r10d,rcClnt.right

mov r11d,rcClnt.bottom

sub r10d,rcClnt.left

sub r11d,rcClnt.top

invoke MoveWindow,hWnd,50,50,r10d,r11d,0

;顯示使用者所選擇的位元圖

mov hDC,RV(GetDC,hWnd)

mov hdcMem,RV(CreateCompatibleDC,hDC)

invoke SelectObject,hdcMem,hBitmap

invoke BitBlt,hDC,0,0,bitmap.bmWidth,bitmap.bmHeight,hdcMem,0,0,SRCCOPY

invoke DeleteDC,hdcMem

invoke ReleaseDC,hWnd,hDC

.elseif r8w==IDM_HELP

invoke MessageBox,hWnd,OFFSET szRem,OFFSET szNote,MB_OK or MB_ICONINFORMATION

.elseif r8w==IDM_QUIT

invoke SendMessage,hWnd,WM_CLOSE,0,0

.endif

.elseif uMsg==WM_DESTROY

invoke PostQuitMessage,0

.elseif uMsg==WM_CLOSE

close: cmp RV(MessageBox,0,ADDR szSure,ADDR szAsk,MB_YESNO or MB_ICONQUESTION),IDYES

jne rtn

invoke DestroyWindow,hWnd

.elseif uMsg==WM_DESTROY

invoke PostQuitMessage,0

.else

def: invoke DefWindowProc,hWnd,uMsg,wParam,lParam

ret

.endif

rtn: xor rax,rax

ret

WndProc ENDP

;---------------------------------------------------------------------------------------------------

main PROC

LOCAL hwnd:HWND,msg:MSG,wc:WNDCLASSEX

mov hInst,RV(GetModuleHandle,0)

mov wc.cbSize,SIZEOF WNDCLASSEX

lea rdx,WndProc

mov wc.style,CS_HREDRAW or CS_VREDRAW

mov wc.lpfnWndProc,rdx

mov wc.cbClsExtra,0

mov wc.cbWndExtra,0

mov wc.hInstance,rax

mov wc.hIcon,RV(LoadIcon,hInst,2004)

mov wc.hIconSm,rax

mov wc.hCursor,RV(LoadCursor,NULL,IDC_ARROW)

mov wc.hbrBackground,COLOR_WINDOW+1

mov wc.lpszMenuName,VBMENU

lea rdx,szClass

mov wc.lpszClassName,rdx

invoke RegisterClassEx,ADDR wc

mov hwnd,RV(CreateWindowEx,0,ADDR szClass,OFFSET szTitle,WS_OVERLAPPEDWINDOW,\

50,50,400,200,0,0,hInst,0)

invoke ShowWindow,hwnd,SW_SHOWNORMAL

invoke UpdateWindow,hwnd

.while TRUE

invoke GetMessage,ADDR msg,0,0,0

.break .if rax==0

invoke TranslateMessage,ADDR msg

invoke DispatchMessage,ADDR msg

.endw

invoke ExitProcess,0

main ENDP

;***************************************************************************************************

END main

VIEWBMP6.ASM 與 VIEWBMP5.ASM 差不多，主要差別在於 HookPoc 攔截函式。在 VIEWBMP6.ASM 中，不處理 WM_SIZE、WM_COMMAND 與 WM_CTLCOLORDLG，但是在處理 WM_NOTIFY 訊息中，多了處理 CDN_SELCHANGE 通知碼。當使用者以滑鼠點選 lst1 中的項目時，系統會發出 CDN_SELCHANGE 通知碼，以告知攔截函式使用者改變所選擇的檔案或目錄。

在處理 CDN_SELCHANGE 通知碼，必須完成以下流程：

對開啟舊檔對話盒發出 CDM_GETFILEPATH，取得使用者新選擇的檔案或目錄的完整名稱（第 74 行）。
呼叫 GetFileAttributesEx，取得上述檔案或目錄的資料。（第 75 行）
把上個步驟得到的資料變成字串，再呼叫 SetDlgItemText 把前述字串設為 IDS_INFO 靜態控制項的文字。（第 76～84 行）
取得 IDS_BMP 靜態控制項的視窗大小。（第 85 行）
取得 IDS_BMP 靜態控制項的裝置內容，再建立與其相容的記憶體裝置內容。（第 86～87 行）
依據第 2 步得到的資料，判斷使用者所選擇的是檔案還是目錄。如果是目錄執行步驟 7；如果是檔案執行步驟 8。（第 88～90 行）
依據第 4 步驟的資料，呼叫 BitBlt，把靜態控制項的裝置內容填滿白色，跳至步驟 11。（第 91～92 行）
呼叫 LoadImage，載入所選擇的位元圖檔；呼叫 GetObject，獲得位元圖檔的資料；呼叫 SelectObject，把相容的記憶體裝置內容設為該位元圖檔的資料。（第 93～98 行）
呼叫 SetStretchBltMode、SetBrushOrgEx 設定縮放模式及畫刷初始位置。（第 99～100 行）
依據第 4 步驟的資料，計算縮放後寬度與高度，呼叫 StretchBlt 於 IDS_BMP 靜態控制項繪製位元圖。（第 101～105 行）
刪去相容的記憶體裝置內容、釋放靜態控制項的裝置內容，到這裏就能使用者所選擇的位元圖檔顯示在（第 106～107 行）

底下說明 VIEWBMP6.ASM 程式碼。首先介紹新的 Win64 API，再說明細節部分。

GetFileAttributesEx API

GetFileAttributesEx 用於獲得檔案或目錄的資料，這些資料包含檔案或目錄的屬性、建立時間、上次修改時間、上次存取時間、檔案大小。GetFileAttributesEx　的原型是：

invoke  GetFileAttributesEx,\
        lpFileName,\    ; pointer to string that specifies a file or directory
        fInfoLevelId,\  ; value that specifies the type of attribute information to obtain
        lpFileInfo      ; pointer to buffer to receive attribute information

lpFileName 是檔名或目錄名位址，此處的檔名或目錄名須以零結尾。如果是 ANSI 版的 GetFileAttributesEx，檔名或目錄名的長度限制在 MAX_PATH；如果是寬字元版的，且檔名或目錄名以「\\?\」開頭，那麼其長度可達 32767 個寬字元。例如「\\?\C:\myworld\private」視為「C:\myworld\private」，但以前者形式的檔名或目錄名可超過 32767 個寬字元。

fInfoLevelId 為要獲得的資料種類，目前（民國 113 年）只能是 GetFileExInfoStandard（其值為零）。未來可能會新增其他值，以獲得其他資料。如果 fInfoLevelId 設為 GetFileExInfoStandard，那麼第三個參數，lpFileInfo 就是 WIN32_FILE_ATTRIBUTE_DATA 結構體的位址。目前 fInfoLevelId 只能是 GetFileExInfoStandard，所以 lpFileInfo 也只能是 WIN32_FILE_ATTRIBUTE_DATA 結構體的位址。如果執行成功，返回值為非零值，且 WIN32_FILE_ATTRIBUTE_DATA 結構體會填入正確的資料；如果失敗，返回值為零，可以呼叫 GetLastError 得到更詳細錯誤訊息。

WIN32_FILE_ATTRIBUTE_DATA 結構體

WIN32_FILE_ATTRIBUTE_DATA 結構體內紀錄了檔案或目錄的屬性及一些資料，各欄位定義如下：

WIN32_FILE_ATTRIBUTE_DATA   STRUCT
  dwFileAttributes          DWORD       ?       ;屬性
  ftCreationTime            FILETIME    <>      ;建立時間
  ftLastAccessTime          FILETIME    <>      ;上次存取時間  
  ftLastWriteTime           FILETIME    <>      ;上次修改時間
  nFileSizeHigh             DWORD       ?       ;檔案長度的高雙字組
  nFileSizeLow              DWORD       ?       ;檔案長度的低雙字組
WIN32_FILE_ATTRIBUTE_DATA   ENDS

底下說明 WIN32_FILE_ATTRIBUTE_DATA 各欄位：

①、dwFileAttributes：檔案或目錄屬性，共有 32 位元，其中的 21 個位元代表 21 個不同屬性，請參閱註二。

②、ftCreationTime：建立檔案或目錄的時間，它是一個 FILETIME 結構體，FILETIME 結構體欄位如下：

FILETIME STRUCT
  dwLowDateTime  DWORD  ?
  dwHighDateTime DWORD  ?
FILETIME ENDS

由這結構體的內容來看，它其實是一個 64 位元的數值，dwLowDateTime 是較低的 32 位元，dwHighDateTime 是較高的 32 位元，兩者組成一個 64 位元的數值（dwHighDateTime×100000000H＋dwLowDateTime）。這個 64 位元的數值代表從西元 1601 年元月元日零時零分零分零秒開始，到建立指定的檔案或目錄經歷多少個 100 奈秒。眾所周知，地球上分為 24 個時區，所以規定 FILETIME 所指的時間都是指世界協調時間（coordinated universal time，簡稱 UTC，也叫世界標準時間）。

FILETIME 計算方式是每天以 86400 秒計算（60*60*24＝86400），平年有 365 天，閏年有 366 天。按上面方法，每一個平年會使 FILETIME 增加 11ED178C6C000h，每個閏年增加 11F9AA3308000h，而 64 位元的最大正整數是 7FFFFFFFFFFFFFFFh，可以推算 FILETIME 能記載到西元 30828 年 9 月 14 日。

舉個例子說明。西元 1601 年元月 24 日義大利傳教士利瑪竇抵達北京。假設當天晚上他用筆記型電腦在 Windows 上，以微軟的 WORD 寫日記，載明他過幾天要覲見明神宗朱翊鈞，並獻上自鳴鐘、坤輿萬國全圖等禮物。於中原標準時間晚上八點三十分整，建立了新檔。因為中原時區比世界協調時間快八小時，所以實際在磁碟上記錄是世界協調時間，西元 1601 年元月 24 日中午 12 時半。那麼這個檔案的建立時間以 FILETIME 表示之計算過程如下：

利瑪竇建立檔案時間距西元 1601 年元月元日零時零分整所經歷秒數＝86400×23＋12×60×60＋30×60＝2032200 秒
2032200秒＝2032200×10⁷個 100 奈秒＝127B95975400h 個 100 奈秒

寫成 FILETIME 結構體為：

create_time FILETIME <95975400h,127Bh>

③、ftLastAccessTime：上次存取時間，其資料類型為 FILETIME，跟前一個欄位一樣，不多贅述。

如果檔案系統不支援上次存取時間，則 FILETIME 會變為 0，例如 DOS 作業系統的檔案系統，FAT12/16 以及 Windows 95/98/Me 使用的是 FAT12/16/32 檔案系統，都僅僅記錄檔案建立時間。所以如果呼叫 GetFileAttributesEx 要取得位於 FAT12/16/32 磁區中檔案上次存取時間，就毫無意義，會填入 0。

④、ftLastWriteTime：上次修改時間，也是最近寫入時間。跟 ftLastAccessTime 一樣，讀取不支援最近修改時間的檔案系統中，此欄位為 0。

⑤、nFileSizeHigh、nFileSizeLow：檔案大小，分別代表高雙字組與低雙字組，單位是位元組。

FileTimeToSystemTime API

FILETIME 所儲存的時間對大部分的人來說，很抽象很不直覺。因此 Windows 提供 FileTimeToSystemTime 函式將 FILETIME 格式的時間轉換為 SYSTEMTIME 的格式。一般人很容易瞭解 SYSTEMTIME 格式的時間。FileTimeToSystemTime 的原型如下：

invoke  FileTimeToSystemTime,\
        lpFileTime,\    ; pointer to file time to convert
        lpSystemTime    ; pointer to structure to receive system time

lpFileTime 是 FILETIME 結構體的位址，其內有要轉換的時間，且必須是在 0～7FFFFFFFFFFFFFFFh 之間的正整數。lpSystemTime 是 SYSTEMTIME 結構體的位址，用於接收轉換後的時間。如果執行成功，回傳值為一且 lpSystemTime 位址上的 SYSTEMTIME 結構體會填上正確的時間；如果執行失敗，回傳值為零。

底下是 SYSTEMTIME 結構體的各欄位：

SYSTEMTIME      STRUCT
  wYear         WORD    ?   ; 西元年份，必須在 1601～30827 之間
  wMonth        WORD    ?   ; 月份，必須在 1～12 之間
  wDayOfWeek    WORD    ?   ; 星期幾，必須在 0～6 之間，0 表示星期天，1 表示星期一，2 表示星期二……
  wDay          WORD    ?   ; 日，必須在 1～31 之間，視月份及是否為閏年決定實際範圍
  wHour         WORD    ?   ; 時，必須在 0～23 之間
  wMinute       WORD    ?   ; 分，必須在 0～59 之間
  wSecond       WORD    ?   ; 秒，必須在 0～59 之間
  wMilliseconds WORD    ?   ; 毫秒，必須在 0～999 之間
SYSTEMTIME      ENDS

SystemTimeToTzSpecificLocalTime API

此 API 把世界協調時間轉換為指定時區的當地時間，原型為：

invoke  SystemTimeToTzSpecificLocalTime,\
        lpTimeZone,\      ; pointer to time zone of interest
        lpUniversalTime,\ ; pointer to universal time of interest
        lpLocalTime       ; pointer to structure to receive local time

lpTimeZone 為 TIME_ZONE_INFORMATION 結構體的位址，這個結構體表明指定的時區；如果 lpTimeZone 為零，函式會使用目前使用中的時區。lpUniversalTime 為 SYSTEMTIME 結構體的位址，這結構體內是要轉換世界協調時間。lpLocalTime 是接收轉換後當地時間的 SYSTEMTIME 結構體位址。如果執行成功，回傳值為一且 lpLocalTime 位址上的 SYSTEMTIME 結構體會填上當地時間；如果執行失敗，回傳值為零。

SetStretchBltMode API

SetStretchBltMode 函式會在指定的裝置內容中設定位元圖縮放模式，其原型為：

invoke  SetStretchBltMode,\
        hdc,\           ; handle of device context
        iStretchMode    ; bitmap stretching mode

hdc 是要設定的裝置內容代碼。iStretchMode 縮放模式，可以是下面四種模式中的一種：

模式	說明
BLACKONWHITE 1	要消除的像素與現有的像素進行 AND 運算。如果是單色的位元圖，將以犧牲白色像素為代價來保留黑色像素。與 STRETCH_ANDSCANS 相同。適合縮放文字或簡單線條的圖案，它們通常是白底黑字，能使文字或線條保持清晰。
COLORONCOLOR 3	把消除的像素刪除，完全不保留資料，與 STRETCH_DELETESCANS 一樣。
HALFTONE 4	將來源範圍中的像素映射至目標範圍時，目標範圍的平均顏色近似來源像素的顏色。設定 HALFTONE 之後，應用程式須呼叫 SetBrushOrgEx 來設定畫刷的起始點。與 STRETCH_HALFTONE 相同。使用此模式，能產生最高品質的圖片，但需要花費較多時間。
WHITEONBLACK 2	要消除的像素與現有的像素進行 OR 運算。如果是單色的位元圖，將以犧牲黑色像素為代價來保留白色像素。與 STRETCH_ORSCANS 相同。適合縮放黑底白色字的圖案，能使文字或線條保持清晰。

如果執行成功，回傳值為原來的縮放模式；否則回傳值為零。

SetBrushOrgEx API

SetBrushOrgEx 對指定的裝置內容設定下一個選入畫刷的起始點，其原型為：

invoke  SetBrushOrgEx,\
        hdc,\           ; handle of device context
        nXOrg,\         ; x-coordinate of new origin
        nYOrg,\         ; y-coordinate of new origin
        lppt            ; points to previous brush origin

hdc 是裝置內容代碼。nXOrg、nYOrg 是下個選入畫刷的起始點 X 座標與 Y 座標。lppt 是 POINT 結構體位址，用於接收原先畫刷的起始點，如不需要這筆資料可將 lppt 設為 0。如果執行成功，回傳值為一；否則回傳值為零。

呼叫 SetStretchBltMode 時，如果設定 HALFTONE 模式，系統會生成一個特定的 halftone brush 來模擬縮放後的像素區塊。如果沒有正確設置畫刷的起始點，畫刷的重複模式可能會與目標區域的邊界不對齊，導致圖案出現「斷層」或「偏移」的問題，稱為 brush misalignment（畫刷對齊錯誤）。這也就是為什麼設定 HALFTONE 模式之後要呼叫 SetBrushOrgEx 的原因。建立畫刷時，預設的起始點是（0,0），如果自始至終都不會改變，也可以不呼叫 SetBrushOrgEx，但為了避免系統自動調整以及為了原始程式可讀性，還是建議要呼叫 SetBrushOrgEx。

StretchBlt API

藉由呼叫 StretchBlt 可以用來縮放圖片。如同 BitBlt，StretchBlt 會將位元圖從來源裝置內容映射到目標裝置內容。不過，與 BitBlt 函式不同，StretchBlt 會根據來源和目標矩形的指定區域來縮放影像。如果來源矩形大於目標矩形，則結果影像會縮小；如果來源矩形小於目標矩形，則結果影像會放大。StretchBlt 原型如下：

invoke  StretchBlt,\
        hdcDest,\       ; handle of destination device context
        nXOriginDest,\  ; x-coordinate of upper-left corner of dest. rect.
        nYOriginDest,\  ; y-coordinate of upper-left corner of dest. rect.
        nWidthDest,\    ; width of destination rectangle
        nHeightDest,\   ; height of destination rectangle
        hdcSrc,\        ; handle of source device context
        nXOriginSrc,\   ; x-coordinate of upper-left corner of source rectangle
        nYOriginSrc,\   ; y-coordinate of upper-left corner of source rectangle
        nWidthSrc,\     ; width of source rectangle
        nHeightSrc,\    ; height of source rectangle
        dwRop           ; raster operation code

hdcDest 是目標裝置內容代碼，hdcSrc 是來源裝置內容代碼。StretchBlt 會把來源裝置內容中，nXOriginSrc、nYOriginSrc 所代表的 X、Y 座標的像素開始映射到目標裝置內容中 nXOriginDest、nYOriginDest 所代表 X、Y 座標的像素上，然後向右、向下把相對應的像素一一映射。來源裝置內容映射範圍的寬度與高度，分別是 nWidthSrc、nHeightSrc；而映射到目標裝置內容的寬度與高度，分別是 nWidthDest、nHeightDest。如果兩者的寬度、高度不同，就會發生縮放現象，有可能會發生失真。縮放時新增或縮減的像素，由 SetStretchBltMode 決定，它也能減輕失真的情形。在映射過程中並非僅僅複製，可以進行運算，這類運算由 dwRop 決定，與 BitBlt 相同。

其他細節

VIEWBMP6.ASM 第 74～83 行的目的是在 IDS_INFO 靜態控制項顯示使用者所選擇的檔案或目錄資料，可分為兩部分：①如果使用者選擇的是檔案，要顯示檔案的建立時間、上次存取時間、上次修改時間與檔案大小四個項目。②如果是目錄，只顯示前面三項資料。而前三項資料的每一項過程都一樣，就連時間的格式都一樣，只是顯示的項目名稱與時間不同，因此用副程式 info 來完成，既減少程式碼又簡潔明瞭。

info 副程式在第 49～61 行。它的參數有三個：①緩衝區位址，轉換後的時間會變成字串存於該位址。②項目名稱位址，項目名稱就是「建立時間：」、「最近存取時間：」、「最近寫入時間：」三個字串，第一次呼叫時是第一個字串、第二次呼叫時是第二個字串……③FILETIME 位址，分別代表三個時間。info 的回傳值是緩衝區最後一個字元的下一個位址，可用於下次呼叫時的緩衝區位址。也就是說，這個回傳值就是下次呼叫時的第一個參數。

如果使用者選擇的是目錄，那就直接跳至第 84 行，pnt: 標記處，把前面呼叫三次 info 所得的字串設為 IDS_INFO 靜態控制項的文字。如果使用者選擇的是檔案還要多一件事，處理檔案大小。

在 WIN32_FILE_ATTRIBUTE_DATA 結構體中，檔案大小紀錄於 nFileSizeHigh、nFileSizeLow 兩個欄位。一般而言，以 x86/64 CPU 為中央處理器的 IBM PC，在存放數值時，以小端序排列，但此處卻是以大端序排列，所以高雙字組必須與低雙字組互換。第 81～82 行先載入四字組，然後再經由旋轉指令旋轉 32 位元，即可完成高、低雙字組互換。

VIEWBMP6 的其餘部分，都已介紹過，本章就此結束。

註釋

註一：簡單介紹殼層命名空間（Shell Namespace）

檔案命名系統與殼層命名空間（Shell Namespace）

在 DOS 時代要表明一個檔案，必須指定該檔案位於哪一個磁碟機的哪一個目錄，最後才是檔案名稱。例如「C:\MASM611\BIN\ML.EXE」，它就表明了 ML.EXE 在「C:」磁碟機的「\MASM611\BIN\」目錄裏。注意！這兒的檔案與目錄的英文分別是 files 與 directories。

到了 Windows 95/98 的時代，微軟把 DOS 的檔案命名系統做了大幅度的翻新，稱為「殼層命名空間」（shell namespace）。下圖五是開啟 Windows 98 的檔案總管後所呈現的畫面，你可以在左邊的樹狀結構選擇某一項，在右側的清單檢視控制項（list view）會顯示該項目內有那些物件。例如用滑鼠點擊「My Documents」，右側顯示「Miso01.jpg」圖片檔及「Rar.exe」、「UnRar.exe」兩個可執行檔。在圖六中，點擊「印表機」，右側顯示「新增印表機」及「Epson EPL-6200L Advanced」兩個物件。

由此可知，Windows 98 不僅僅管理磁碟機、檔案及目錄，它還管理非檔案物件，例如「Epson EPL-6200L Advanced」、「網路上的芳鄰」、「控制台」……等物件，這些非檔案物件也稱為虛擬物件（virtual objects）。

與 DOS 檔案系統命名空間類似，殼層命名空間有兩個不同的類型：①檔案（files）與②資料夾（folders）。這裏的檔案不僅僅是一般磁碟機上的檔案，它的範圍更大一些，它是指樹狀結構的端點，無法再容納其他物件，也稱為葉節點。像上圖的「C:\My Documents\」內的所有檔案，例如「Miso01.jpg」、「Rar.exe」、「UnRar.exe」，或是「Epson EPL-6200L Advanced」雷射印表機，都視為檔案。

此處的資料夾，英文是 folders，與 DOS 的檔案命名系統稱為目錄的不同，所以把 folders 翻譯成資料夾。資料夾是樹狀結構的節點，它可以包含檔案或其他資料夾。像上圖的「My Documents」、「印表機」都是資料夾。不屬於檔案系統的資料夾有時被稱為虛擬資料夾（virtual folders）。

殼層命名空間的最根本節點是「桌面」（desktop），所有的資料夾或檔案都是由桌面開始。由上圖可以看見，桌面包含了「我的電腦」、「我的文件夾」、「Internet Explorer」……等資料夾物件。在我的電腦資料夾中，有「Win98_se(C:)」物件，它其實是硬碟，在殼層命名空間中，也是資料夾。在「Win98_se(C:)」資料夾內，就是 DOS 的檔案命名系統中的各目錄與檔案。

識別殼層命名空間的檔案及資料夾

在殼層命名空間中，如果要使用檔案或資料夾之前，必須先找到方法識別。對於不是虛擬物件的檔案、目錄等，雖然可以用由磁碟機名稱開始，依序是路徑名、檔案名稱，這樣的完整檔名來表示；可是對於虛擬物件，就無法使用前述方式表示。Windows 提供了另一種方式，不僅能表示虛擬物件，非虛擬物件也能適用。在介紹這種方式之前，得先介紹 SHITEMID 結構體，這個結構體稱為項目識別碼（item ID）。SHITEMID 只有兩個欄位：

SHITEMID STRUCT
  cb     WORD   ?
  abID   BYTE   ? DUP (?)
SHITEMID ENDS

SHITEMID 結構體第一個欄位是 cb，指定了 SHITEMID 結構的大小，以位元組為單位。

第二個欄位是 abID，它是物件的識別碼，長度並不固定，由物件的資料夾決定。由於資料夾對 abID 的值分配沒有統一標準，因此 abID 僅對相關的資料夾有意義。應用程式應將它視為一個記號，用於辨識特定資料夾中的物件。

在某個資料夾內的任一個物件，都有獨一無二的項目識別碼。當然最根本的節點是桌面，它也有自己的項目識別碼。參閱圖五，在桌面內有「我的電腦」、「我的文件夾」、「Internet Explorer」……等物件，每一個都有唯一的項目識別碼；而其下層的每個資料夾與檔案，也都如此。假如要表示「Epson EPL-6200L Advanced」檔案的話，那必須使用一串的項目識別碼，如下圖七：每個項目識別碼都代表一個資料夾或檔案，最左邊的是「桌面」的項目識別碼，其右是代表「我的電腦」的項目識別碼……一直到代表「Epson EPL-6200L Advanced」的項目識別碼，而最後的結尾是一個空的 SHITEMID。像這樣，由一連串的相關的項目識別碼結合起來，以兩個 0 為結尾，可以表示檔案或資料夾的資料結構，稱為項目識別碼列表（item ID lists）。

在處理殼層命名空間的 Win64 API 名稱，多以 SH 為起頭，且常常會用一個指標來表示項目識別碼列表地位址，一般稱此指標為 PIDL（pointer to an item identifier list）。

註二：檔案與目錄的屬性

下表為 WIN32_FILE_ATTRIBUTE_DATA 的結構體中第一個欄位，dwFileAttributes，的說明：

dwFileAttributes	數值	說明
FILE_ATTRIBUTE_READONLY	1	唯讀的檔案。應用程式可以讀取檔案，但無法寫入或刪除檔案。目錄上不接受這個屬性。
FILE_ATTRIBUTE_HIDDEN	2	隱藏的檔案或目錄。
FILE_ATTRIBUTE_SYSTEM	4	作業系統使用的一部分或獨佔使用的檔案或目錄。
FILE_ATTRIBUTE_DIRECTORY	10h	具有此屬性的並非檔案，而是目錄。
FILE_ATTRIBUTE_ARCHIVE	20h	已備份的檔案或目錄。當建立新檔案或修改某個檔案，系統會自動設定此屬性，表示此檔案是新的或已更改，需要進行備份。備份軟體會使用此屬性來檢查檔案是否尚未備份，如果檔案具有此屬性，就將其備份，待備份完成並取消此屬性；如果檔案不具此屬性，表示該檔已備份過了，可以跳過。
FILE_ATTRIBUTE_DEVICE	40h	保留給系統使用。
FILE_ATTRIBUTE_NORMAL	80h	未設定其他屬性的檔案。此屬性只有在單獨使用時才有效。
FILE_ATTRIBUTE_TEMPORARY	100h	暫存檔。應用程式建立此屬性的檔案時，系統會儘可能將資料保留在快取記憶體中，而不寫入硬碟。如果應用程式不再需要暫存檔，應關閉暫存檔後刪除，保留在快取記憶體的資料也不會寫入硬碟。如果應用程式沒刪除暫存檔，那麼應用程式結束後，系統會把在快取記憶體的資料寫入暫存檔。
FILE_ATTRIBUTE_SPARSE_FILE	200h	此為疏鬆檔案（sparse file）。像磁碟影像檔、虛擬機器使用的虛擬磁碟等檔案，包含大量連續未使用的區域，可以設為疏鬆檔案。系統會針對此類檔案進行特別儲存方式，增加儲存效能。
FILE_ATTRIBUTE_REPARSE_POINT	400h	具有重新分析點的檔案或目錄，或是符號連結的檔案。
FILE_ATTRIBUTE_COMPRESSED	800h	具有此屬性的檔案或子目錄，系統會自動進行壓縮。對於檔案，所有資料會被壓縮；對於目錄，新建的檔案和子目錄都會被壓縮。
FILE_ATTRIBUTE_OFFLINE	1000h	無法立即使用具有這種屬性的檔案，因為實際上這檔案的資料儲存在離線的裝置上。通常很久未曾使用的大檔案，其資料會被系統搬移至磁帶機或雲端等大容量儲存裝置，並標示此檔案為 FILE_ATTRIBUTE_OFFLINE，如果有應用程式存取它，系統會提示「檔案正在從離線存儲恢復」等字樣。應用程式不應隨意變更此屬性。
FILE_ATTRIBUTE_NOT_CONTENT_INDEXED	2000h	內容索引服務（content indexing service）是 Windows 中的一種功能，透過掃描檔案的內容與屬性，建立索引以加速搜尋操作。例如，當使用者在檔案總管中搜尋檔案名稱或內容時，索引可顯著縮短搜尋時間。而具有此屬性的檔案或目錄，指示作業系統跳過該檔案或目錄的索引過程。通常暫存檔不需索引以避滿增加負擔，含有敏感資料的檔案也應避免納入索引。此屬性不會阻止檔案名稱的搜尋，僅影響檔案內容的索引。
FILE_ATTRIBUTE_ENCRYPTED	4000h	加密的檔案或目錄。對於檔案，檔案中的所有資料流均已加密；對於目錄，新建的檔案與子目錄預設為加密。只能在 NTFS 檔案系統上使用，如果將加密的檔案複製到不支援加密的檔案系統，例如 FAT32，那麼加密屬性將遺失。此屬性不能同時與 FILE_ATTRIBUTE_COMPRESSED 共存。
FILE_ATTRIBUTE_INTEGRITY_STREAM	8000h	完整性資料流是 Resilient File System（ReFS，可靠檔案系統）的一項功能，它使用檢查碼來驗證檔案或目錄的資料完整性，確保在存取時檢測並修復資料損壞（例如由於硬體錯誤引起的問題）。只有在 Windows 10 或 Windows Server 2012 R2 及之後的作業系統才能更完善的支援 ReFS。具有此屬性的目錄與使用者資料流（user data stream，包含檔案的主要內容與附加的資料內容）都會受到校驗保護，確保資料在存取或傳輸過程中不被損壞。
FILE_ATTRIBUTE_VIRTUAL	10000h	保留給系統使用。
FILE_ATTRIBUTE_NO_SCRUB_DATA	20000h	不讓背景資料完整性掃描器（即 Scrubber）讀取使用者資料流。具有此屬性的目錄，僅有繼承功能。此屬性僅在 Storage Spaces 和 ReFS 支援，且不包含於普通的目錄列表中。Scrubber 是一種背景程式，專為 ReFS 和 Storage Spaces 設計，用於定期檢查和修復檔案系統中的資料完整性問題，此過程通常在背景中運行，對系統性能有一定影響。Windows 8 或 Windows Server 2012 及之後的作業系統才支援此屬性。
FILE_ATTRIBUTE_EA	40000h	具有擴充屬性的檔案或目錄，僅供系統內部使用且很少使用。
FILE_ATTRIBUTE_RECALL_ON_OPEN	40000h	此屬性僅出現在目錄列舉類型（如 FILE_DIRECTORY_INFORMATION、FILE_BOTH_DIR_INFORMATION 等）中。具有此屬性的檔案或目錄，在本機上沒有完整的真實資料，可能只有檔案名稱、大小、日期等，真實資料通常儲存於雲端。因此開啟此類檔案或目錄，會花費較長時間。
FILE_ATTRIBUTE_PINNED	80000h	分層存儲（Hierarchical Storage）是指根據檔案的使用頻率、重要性等因素，將檔案自動移動到不同層級的存儲媒介中。例如經常使用的檔案保留在高速 SSD 或本機磁碟上；很少使用檔案移動到低成本的雲端或磁帶機上。具有此屬性的檔案或目錄，分層存儲軟體會確保它們始終儲存在本機。
FILE_ATTRIBUTE_UNPINNED	100000h	具有此屬性的檔案或目錄，只有在使用者開啟時，才由遠端載入，否則只有部分在本機上。只有分層存儲管理軟體才需要使用此屬性。
FILE_ATTRIBUTE_RECALL_ON_DATA_ACCESS	400000h	具有此屬性的檔案，其部分資料為儲存於本機，其餘存於遠端；具有此屬性的目錄，有部分檔案或子目錄存於遠端。這些遠端的資料只有在需要存取時，從遠端取回，因此會花費較長時間。

通知碼	說明
CDN_FILEOK -606	當使用者已經指定檔案名，並按下「開啟舊檔」按鈕時，發出此通知碼。
CDN_FOLDERCHANGE -603	當使用者變更資料夾時，發出此通知碼。不論是從 cmb2 複合框中變更或從 lst1 內的資料夾項目變更，都會發出此通知碼。
CDN_HELP -605	當使用者按下「說明」按鈕時，發出此通知碼。
CDN_INCLUDEITEM -608	當使用者變更資料夾時，會為該資料夾內的每個項目發出此通知碼，供攔截函式處理該項目；但只有在 Flags 設定 OFN_ENABLEINCLUDENOTIFY 旗標時，才會發出此通知碼。
CDN_INITDONE -601	當系統已經把對話盒上的控制項移到適當位置之後，發出此通知碼。
CDN_SELCHANGE -602	當使用者在 lst1 清單盒控制項中，選擇新的項目時，會發出此通知碼。
CDN_SHAREVIOLATION -604	當使用者按下「開啟舊檔」按鈕，且所選取的檔案發生網路共用違規時，發出此通知碼。

訊息	說明	wParam	lParam	回傳值
CDM_GETFILEPATH 465h	獲得使用者在對話盒中所選取檔案或路徑名稱	緩衝區大小，以字元為單位	接收檔案或路徑名稱的緩衝區位址	若執行成功，傳回值是檔名或路徑名長度（以字元為單位，包含結尾的零），且 lParam 所指位址為完整檔名或路徑名；若緩衝區太小，回傳值為所需的緩衝區大小，且 lParam 所指位址之內容不變；若發生錯誤，傳回值小於零
CDM_GETFOLDERIDLIST 467h	獲得對話盒中目前開啟之資料夾的項目識別碼列表（item identifier list，參閱註一）	緩衝區大小，以位元組為單位	接收項目識別碼列表之緩衝區位址	若執行成功，傳回值是項目識別碼列表長度（以位元組為單位，包含結尾的零），且 lParam 所指位址為項目識別碼列表；若緩衝區太小，回傳值為所需的緩衝區大小，且 lParam 所指位址之內容不變；若發生錯誤，傳回值小於零
CDM_GETFOLDERPATH 464h	獲得在對話盒中目前開啟之資料夾的路徑名稱	緩衝區大小，以字元為單位	接收路徑名稱的緩衝區位址	若執行成功，傳回值是路徑名長度（以字元為單位，包含結尾的零），且 lParam 所指位址為路徑名；若緩衝區太小，回傳值為所需的緩衝區大小，且 lParam 所指位址之內容不變；若發生錯誤，傳回值小於零
CDM_GETSPEC 464h	獲得在對話盒中，使用者選取不包含路徑的檔案名稱	緩衝區大小，以字元為單位	接收檔案名稱的緩衝區位址	若執行成功，傳回值是檔名長度（以字元為單位，包含結尾的零），且 lParam 所指位址為檔名；若緩衝區太小，回傳值為所需的緩衝區大小，且 lParam 所指位址之內容不變；若發生錯誤，傳回值小於零
CDM_HIDECONTROL 469h	隱藏對話盒中的某個控制項	要隱藏的控制項識別碼	不使用，應設為零	無
CDM_SETCONTROLTEXT 468h	設定對話盒中某個控制項的文字	要設定文字的控制項識別碼	要設定的字串位址	無
CDM_SETDEFEXT 46ah	設定預設副檔名	不使用，應設為零	預設副檔名位址，不能包含「.」	無

第二十七章　通用對話盒：開啟舊檔（二）

原理

GetParent API

ScreenToClient API

WM_GETFONT 與 WM_SETFONT 訊息

WM_CTLCOLORDLG 訊息

開啟舊檔或另存新檔對話盒的子對話盒

範例一：VIEWBMP5

更多的子對話盒與攔截函式資料

開啟舊檔或另存新檔對話盒的通知碼

對開啟舊檔或另存新檔對話盒發送的訊息

範例二：VIEWBMP6

原始碼

GetFileAttributesEx API

WIN32_FILE_ATTRIBUTE_DATA 結構體

FileTimeToSystemTime API

SystemTimeToTzSpecificLocalTime API

SetStretchBltMode API

SetBrushOrgEx API

StretchBlt API

其他細節

註釋

註一：簡單介紹殼層命名空間（Shell Namespace）

檔案命名系統與殼層命名空間（Shell Namespace）

識別殼層命名空間的檔案及資料夾

註二：檔案與目錄的屬性

第二十七章 通用對話盒：開啟舊檔（二）

原理

GetParent API

ScreenToClient API

WM_GETFONT 與 WM_SETFONT 訊息

WM_CTLCOLORDLG 訊息

開啟舊檔或另存新檔對話盒的子對話盒

範例一：VIEWBMP5

更多的子對話盒與攔截函式資料

開啟舊檔或另存新檔對話盒的通知碼

對開啟舊檔或另存新檔對話盒發送的訊息

範例二：VIEWBMP6

原始碼

GetFileAttributesEx API

WIN32_FILE_ATTRIBUTE_DATA 結構體

FileTimeToSystemTime API

SystemTimeToTzSpecificLocalTime API

SetStretchBltMode API

SetBrushOrgEx API

StretchBlt API

其他細節

註釋

註一：簡單介紹殼層命名空間（Shell Namespace）

檔案命名系統與殼層命名空間（Shell Namespace）

識別殼層命名空間的檔案及資料夾

註二：檔案與目錄的屬性

第二十七章　通用對話盒：開啟舊檔（二）