①：執行「C:\Users\帳號\UASM.BAT」。②：切換到 DRAW1.ASM 所在資料夾。
③：用「C:\UASM\UASM64.EXE」組譯，注意，其參數「-win64」必須小寫。
④：以「C:\UASM\BIN64\LINK.EXE」連結，如果沒有任何訊息，就表示正確連結成功。
在上一章，小木偶說明了利用計時器發出的訊息（也就是 WM_TIMER 訊息），在裝置內容（device context）上繪製圖形。在這一章裏，將介紹使用者以滑鼠，在裝置內容上繪製圖形，並舉兩個例子。先要說明的是滑鼠訊息。
有些滑鼠上面有三個按鍵，由左而右分別稱為「滑鼠左鍵」、「滑鼠中鍵」與「滑鼠右鍵」。當滑鼠游標在視窗的工作區（client area）內，如果使用者按下滑鼠左鍵，Windows 會對該視窗發出 WM_LBUTTONDOWN 訊息；當使用者鬆開滑鼠左鍵時，則發出 WM_LBUTTONUP 訊息。
像上面這樣按下滑鼠左鍵，立即鬆開的動作，稱之為點擊（click），一般用於在桌面上選擇哪一個視窗，或是在視窗中選擇某個項目。當使用者完成一次點擊，系統會發出兩則訊息，WM_LBUTTONDOWN 與 WM_LBUTTONUP。一般而言，應用程式只需處理 WM_LBUTTONDOWN 即可。
當使用者按下及鬆開滑鼠中鍵時，分別發出 WM_MBUTTONDOWN 以及 WM_MBUTTONUP；當使用者按下及鬆開滑鼠右鍵時，分別發出 WM_RBUTTONDOWN 以及 WM_RBUTTONUP。當使用者按下滑鼠右鍵，再鬆開的動作，一般不稱為點擊，除非使用者是左撇子，並且已設定滑鼠左右鍵交換。
以上這六個訊息中所附帶的 wParam 資料都一樣，表明當按下滑鼠上的按鍵時，是否有按下滑鼠上的其他按鍵或鍵盤上的按鍵。見下表：
| wParam | 數值 | 說明 |
| MK_CONTROL | 8 | 鍵盤上的 Ctrl 鍵被按下 |
| MK_LBUTTON | 1 | 滑鼠左鍵被按下 |
| MK_MBUTTON | 16 | 滑鼠中鍵被按下 |
| MK_RBUTTON | 2 | 滑鼠右鍵被按下 |
| MK_SHIFT | 4 | 鍵盤上的 Shift 鍵被按下 |
| MK_XBUTTON1 | 32 | 第一個滑鼠延伸的按鍵被按下 |
| MK_XBUTTON2 | 64 | 第二個滑鼠延伸的按鍵被按下 |
而這六則訊息所附帶的 lParam 資料，則是發生該訊息時，滑鼠游標所在的座標，此座標是以工作區左上角為原點。X 座標是在 lParam 的第 0∼15 位元，Y 座標則在 16∼31 位元。此外，lParam 內的座標原點是在工作區的左上角。這種相對於工作區左上角為原點的座標，稱為工作區座標（client-area coordinates）；還有一種是相對於螢幕左上角為原點的座標，稱為螢幕座標（screen coordinates）。
有些滑鼠並沒有滑鼠中鍵，而以滾輪取代，然而這種滑鼠的滾輪仍然可以往下按，按下之後也能鬆開。當使用者按下滾輪，一樣會發出 WM_MBUTTONDOWN 訊息，鬆開滾輪也會發出 WM_MBUTTONUP 訊息。
具有滾輪的滑鼠，不但能讓使用者像滑鼠中鍵一樣，按下或鬆開滾輪，也能讓使用者滾動滾輪。當使用者滾動滑鼠滾輪時，系統會把 WM_MOUSEWHEEL 訊息發送給具有輸入焦點的視窗，而不是滑鼠游標下方的視窗，以上所描述的是 MSDN 以及網際網路上所能查到大部分的文獻上所記載的；但是如果真的去做實驗，在 Windows 7 SP1/8/10/11 等較新的作業系統上，那麼系統會把 WM_MOUSEWHEEL 訊息發送給滑鼠游標下方的視窗。
WM_MOUSEWHEEL 訊息所附帶的 wParam 資料，其中的 0∼15 位元表明當滾動滾輪時，是否有按下滑鼠上的按鍵或鍵盤上的按鍵，其意義與上表相同。WM_MOUSEWHELL 訊息所附帶 wParam 的資料中，在其中第 16∼31 位元所表示的 16 位元數值，指示了使用者讓滑鼠滾輪滾動了多少距離。此 16 位元數值可能是正值，也可能是負值。正值代表使用者往前滾動滑鼠滾輪，滾輪最上方的那一點遠離使用者，程式應讓使用者看見先前的資料；負值則表示與前述方向相反，程式應讓使用者能看見較後面的資料。
上述 16 位元數值的絕對值代表使用者讓滑鼠滾輪了多少距離，此距離是 WHEEL_DELTA 的倍數。WHEEL_DELTA 之值為 120，滑鼠滾輪滾動的距離除以 WHEEL_DELTA 就能算出捲動了多少格。大部分的程式設定是轉動滾輪一格，工作區的內容要捲動三列文字。
WM_MOUSEWHEEL 訊息附帶的 lParam 資料則是發生該訊息時，滑鼠游標所在的座標。X 座標是在 lParam 的第 0∼15 位元，Y 座標則在 16∼31 位元。但是此座標是螢幕座標，其原點是在螢幕的左上角，跟 WM_LBUTTONDOWN 等訊息的座標原點不同。
當使用者快速地按下滑鼠左鍵、鬆開，然後再快速地按下、鬆開，系統就會把 WM_LBUTTONDBLCLK 訊息發送給滑鼠游標下方的視窗。像這種快速的連續點擊滑鼠按鍵兩次，稱為雙擊（double click）。使用者也可以用滑鼠中鍵或滑鼠右鍵雙擊視窗，系統會分別發出 WM_MBUTTONDBLCLK 與 WM_RBUTTONDBLCLK 訊息。但是，要注意的是，如果視窗要收到 WM_LBUTTONDBLCLK、WM_MBUTTONDBLCLK 或 WM_RBUTTONDBLCLK 訊息，此視窗必須具有 CS_DBLCLKS 風格才行。可以在註冊視窗類別時，把 WNDCLASSEX 結構體的 style 欄位加上 CS_DBLCLKS 即可。
另外，當使用者以滑鼠左鍵雙擊某個物體時，實際上系統依序發出 WM_LBUTTONDOWN、WM_LBUTTONUP、WM_LBUTTONDBLCLK 與 WM_LBUTTONUP 四則訊息，WM_LBUTTONDBLCLK 是其中的第三則訊息，如果應用程式要處理使用者雙擊的動作，只需處理 WM_LBUTTONDBLCLK 訊息即可。使用者以滑鼠中鍵、右鍵進行雙擊動作時，也一樣個別發出四則訊息。
WM_LBUTTONDBLCLK、WM_MBUTTONDBLCLK 與 WM_RBUTTONDBLCLK 三則訊息中所附帶的 wParam 說明了在雙擊時，是否有其他按鍵按下，其意義可參考「滑鼠訊息中的 wParam」。這三則訊息的 lParam 則是發生雙擊時，滑鼠游標所在的座標，lParam 的第 0∼15 位元，Y 座標則在 16∼31 位元。此座標的原點是在工作區的左上角。
當滑鼠游標在某個視窗的工作區內移動時，系統會對該視窗發出 WM_MOUSEMOVE 訊息。WM_MOUSEMOVE 訊息的 wParam 表明當移動滑鼠游標鍵時，是否有按下滑鼠上其他按鍵或鍵盤上的按鍵，其意義跟上面的「滑鼠訊息中的 wParam」表格一樣。
而 WM_MOUSEMOVE 訊息所附帶的 lParam 資料則是發生該訊息時，滑鼠游標在工作區內的座標。X 座標是在 lParam 的第 0∼15 位元，Y 座標則在 16∼31 位元。此外，lParam 內的座標原點是在工作區的左上角。
說了這麼多滑鼠訊息，底下利用 WM_LBUTTONDOWN、WM_MOUSEMOVE 兩則訊息來製作 DRAW1.ASM。DRAW1.ASM 模擬畫筆在白紙上作畫的動作，當使用者以滑鼠左鍵點擊工作區任一地方，就相當於把畫筆筆尖接觸紙面；若此時移動滑鼠就能在工作區上畫出軌跡來，相當於用畫筆在紙上畫出線條；如果要停止作畫，再以滑鼠左鍵點擊一次，就相當於提起畫筆離開紙面。完整的原始程式如下：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88
89 90 91 92
93 94 95 96
97 98 99 100
101 102 103 104 |
OPTION CASEMAP:NONE
OPTION WIN64:3
INCLUDE WINDOWS.INC
INCLUDELIB GDI32.LIB
INCLUDELIB KERNEL32.LIB
INCLUDELIB USER32.LIB
;*****************************************************************************************
.DATA
hInstance DQ ? ;模組代碼
hwnd HWND ? ;視窗代碼
line_start POINT <> ;起點
line_end POINT <> ;終點
pen_down DQ 0 ;畫筆的狀態，0－提起畫筆，1－放下畫筆
szClassName DB "DRAW1",0
szAppName DB "手繪圖",0
;*****************************************************************************************
.CODE
;-----------------------------------------------------------------------------------------
WndProc PROC hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
LOCAL ps:PAINTSTRUCT,rect:RECT
.switch uMsg
.case WM_PAINT
;當pen_down為一時，表示放下畫筆要繪製圖形；若為0，表示提起畫筆不繪製圖形
invoke BeginPaint,hWnd,ADDR ps
.if pen_down==1
invoke MoveToEx,ps.hdc,line_start.x,line_start.y,0
invoke LineTo,ps.hdc,line_end.x,line_end.y
mov r10d,line_end.x
mov r11d,line_end.y
xchg line_start.x,r10d
xchg line_start.y,r11d
.endif
invoke EndPaint,hWnd,ADDR ps
.case WM_MOUSEMOVE
;當pen_down為一時，表示放下畫筆，要繪製圖形，紀錄滑鼠移動的各像素座標
.if pen_down==1
mov r8,r9
shr r9,10h
and r8,0ffffh
mov line_end.x,r8d ;把像素的X座標存於line_end.x
mov line_end.y,r9d ;把像素的X座標存於line_end.x
invoke InvalidateRect,hWnd,0,0 ;對本身發出WM_PAINT訊息
.endif
.case WM_LBUTTONDOWN
xor pen_down,1 ;切換畫筆狀態（在提起與放下之間切換）
.if pen_down==1
mov r8,r9
shr r9,10h
and r8,0ffffh
mov line_start.x,r8d;把起點的X座標存於line_start.x
mov line_start.y,r9d;把起點的Y座標存於line_start.y
.endif
.case WM_DESTROY
quit: invoke PostQuitMessage,0
.default
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endsw
xor rax,rax
ret
WndProc ENDP
;-----------------------------------------------------------------------------------------
main PROC
LOCAL wc:WNDCLASSEX,msg:MSG
invoke GetModuleHandle,0 ;取得模組代碼
mov hInstance,rax
mov wc.cbSize,SIZEOF WNDCLASSEX
mov wc.style,CS_HREDRAW or CS_VREDRAW
lea rdx,WndProc
mov wc.lpfnWndProc,rdx
mov wc.cbClsExtra,0
mov wc.cbWndExtra,0
mov wc.hInstance,rax
invoke LoadIcon,NULL,IDI_APPLICATION ;取得圖示代碼
mov wc.hIcon,rax ;存入圖示代碼
mov wc.hIconSm,rax ;存入小圖示代碼
invoke LoadCursor,NULL,IDC_ARROW ;取得游標代碼
mov wc.hCursor,rax ;存入游標代碼
mov wc.hbrBackground,COLOR_WINDOW+1
mov wc.lpszMenuName,0
lea rdx,szClassName
mov wc.lpszClassName,rdx
invoke RegisterClassEx,ADDR wc ;註冊視窗類別
invoke CreateWindowEx,0,ADDR szClassName,ADDR szAppName,WS_OVERLAPPEDWINDOW,\
50,50,500,375,0,0,hInstance,0
mov hwnd,rax
invoke ShowWindow,hwnd,SW_SHOWNORMAL
invoke UpdateWindow,hwnd
.while TRUE
invoke GetMessage,ADDR msg,0,0,0
.break .if rax==0
invoke TranslateMessage,ADDR msg
invoke DispatchMessage,ADDR msg
.endw
invoke ExitProcess,0 ;程式結束
main ENDP
;*****************************************************************************************
END main |
開啟「命令提示字元」，然後以下面方式組譯、連結，而我們所要輸入的指令，都以淡藍色框框住：①：執行「C:\Users\帳號\UASM.BAT」。
②：切換到 DRAW1.ASM 所在資料夾。
③：用「C:\UASM\UASM64.EXE」組譯，注意，其參數「-win64」必須小寫。
④：以「C:\UASM\BIN64\LINK.EXE」連結，如果沒有任何訊息，就表示正確連結成功。
執行的結果，如下圖。這是小木偶以滑鼠所繪製的圖形，其實就是寫幾個字。
底下解說 DRAW1.ASM 重要的部分。
首先來看 DRAW1.ASM 如何處理 WM_LBUTTONDOWN 訊息。其實這是 DRAW1.ASM 中最簡單的過程，見 DRAW1.ASM 第 47∼55 行。在處理 WM_LBUTTONDOWN 訊息第一道指令是「XOR pen_down,1」，這道指令會讓使用者每用滑鼠左鍵點擊一次時，使 pen_down 在 0 與 1 之間切換。這是 XOR 運算的特性之一，「某數與同一數連做兩次 XOR 運算仍得到原數」（見第一章 x86 指令：XOR）。
當 DRAW1 剛開始執行時，pen_down 為零，表示畫筆未接觸紙張。當使用者點擊滑鼠左鍵時，系統發送 WM_LBUTTONDOWN 到視窗函式，就會執行到「XOR pen_down,1」，於是 pen_down 變為 1。當使用者再次點擊滑鼠左鍵時，一樣會執行視窗函式中的「XOR pen_down,1」，於是 pen_down 又恢復為 0，變成 DRAW1 當開始執行時的狀態。如此一直重複不已。
當 pen_down 為 1 時，表示開始要用畫筆作圖了，所以要記錄此時滑鼠游標座標，作為線段的起點，這段程式碼在第 50∼54 行；如果 pen_down 為 0，那就什麼都不必做，直接返回。
當 pen_down 為 0 時，其實不需做任何處理，只有當 pen_down 為 1 時，才要畫出直線來，因此處理 WM_MOUSEMOVE 訊息時，用 .if/.endif 來判斷是否要處理，見第 37∼38 行。當 pen_down 為 1 時，把 WM_MOUSEMOVE 訊息中的滑鼠座標記錄起來，當做直線的終點。然後就是呼叫 InvalidateRect，使工作區變為無效，以強迫系統發出 WM_PAINT 訊息，重新繪製工作區。
在處理 WM_PAINT 訊息中，當 pen_down 為 0，不須繪製圖形，但還是要呼叫 BeginPaint 與 EndPaint，以讓無效區變成有效區。
當 pen_down 為 1 時，要做的事情依序是：
要繪製線段，一般是呼叫 LineTo 把當前的像素與 LineTo 的第二、三個參數所指定的像素連接起來。當使用者第一次以滑鼠左鍵點擊工作區時，被點擊到的像素就是線段起點，可呼叫 MoveToEx 將當前像素變為被點擊到的像素，這樣線段的起點就會落在被點擊到的像素。呼叫 MoveToEx 時第二、三個參數設為使用者以滑鼠左鍵點擊時的座標，而該座標就是 WM_LBUTTONDOWN 訊息時所記錄的滑鼠游標座標。見程式第 27 行。
呼叫 LineTo 時，第二、三個參數所指定的像素，則是當使用者移動滑鼠游標時所到達的像素，其座標也就是在處理 WM_MOUSEMOVE 訊息時所記錄的滑鼠游標座標。見程式第 28 行。
然而，大部分的時候，使用者移動滑鼠游標時，會連續產生許多則 WM_MOUSEMOVE 訊息。要繪製出滑鼠游標的軌跡，必須讓前次線段的終點變成這次的起點。第 29∼32 行就是在做這件事情，這四行把原先線段的終點，保存於下次線段的起點。第 31、32 行也可以改用 MOV 指令，小木偶用 XCHG 指令只是標新立異，沒有什麼特別的理由。
當下一則 WM_MOUSEMOVE 訊息進來時，先呼叫 MoveToEx 設置當前像素，此當前像素就是前次線段的終點。接著呼叫 LineTo 繪製線段，而 LineTo 的第二、三個參數則由在處理 WM_MOUSEMOVE 訊息就處理好了。你會發現，這段設置當前像素，到繪製線段，與上述步驟重複，因此從第 23 行到第 55 行就能畫出滑鼠移動的軌跡。
在第十章時，曾經介紹過捲動軸。那時捲動工作區的內容，只能用滑鼠在捲動軸上點擊捲動箭頭或捲動軌道，或者是拖拉捲動方塊。但無法用滑鼠滾輪捲動，但這一切就要改觀了。在提過 WM_MOUSEWHEEL 訊息的相關資料之後，就能將處理 WM_MOUSEWHEEL 訊息的程式碼插入視窗函式之中，這樣就能讓使用者操縱滑鼠滾輪，捲動工作區的內容了。
加上以滑鼠滾輪捲動功能的程式稱為 SYSMTR3.ASM，底下只列出較重要且與 SYSMTR2.ASM 不同之處，完整的程式碼按這裏下載。
1 2 3 4
5 6 7 ⁝
13 14 15 16
17 18 ⁝
30 31 32
33 ⁝ 167 168
169 170 171 172
173 174 175 176
177 178 179 180
181 ⁝ 272 |
OPTION CASEMAP:NONE
OPTION WIN64:3
INCLUDE WINDOWS.INC
INCLUDELIB GDI32.LIB
INCLUDELIB KERNEL32.LIB
INCLUDELIB USER32.LIB
⁝
INCLUDE SYSMTR.INC
;*****************************************************************************************
.CONST
szClassName DB "SystemMetrics",0 ;視窗類別名稱
szAppName DB "Display System Metrics 3",0
szDecFmt DB "%d",0
⁝
;*****************************************************************************************
.CODE
;-----------------------------------------------------------------------------------------
WndProc PROC hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
⁝
.case WM_MOUSEWHEEL
mov stsi.fMask,SIF_ALL
invoke GetScrollInfo,hWnd,SB_VERT,ADDR stsi
mov rax,wParam
shr rax,10h ;AX＝滾輪滾動了多少距離
mov r10b,WHEEL_DELTA
idiv r10b ;有號數除法AX÷R10B計算完後，AL＝商＝滾輪滾動了多少格
movsx r11d,al ;AL＝商，也等於滾輪滾動了多少格
movsx r10d,al
shl r11d,1 ;R11D＝AL×2
add r10d,r11d ;R10D＝AL×2＋AL＝3×AL，每滾動一格，捲動三列
sub stsi.nPos,r10d
mov stsi.fMask,SIF_POS
invoke SetScrollInfo,hWnd,SB_VERT,ADDR stsi,1
invoke InvalidateRect,hWnd,0,1
⁝
END main |
SYSMTR3.ASM 是以 UASM 搭配 WinInc 組譯，因此除了加入處理 WM_MOUSEWHEEL 訊息的程式碼之外，還與 SYSMTR2 有些許不同：
底下來說說 SYSMTR3.ASM 的重軸戲，如何處理 WM_MOUSEWHEEL 訊息。程式第 168∼169 行，讀取垂直捲動軸資料存放於 stsi 結構體中，其中最重要的資料是捲動方塊的位置，這項資料存於 stsi.nPos。當使用者滾動滑鼠滾輪時，就得改變 stsi.nPos 欄位之值。
當滑鼠滾輪滾動時，系統會發送 WM_MOUSEWHEEL 訊息給視窗函式，其中所附帶 wParam 中的第 16∼31 位元，代表滑鼠滾輪滾動的距離。SYSMTR3.ASM 中的第 170∼171 行展示了獲得此 16 位元滾輪滾動距離的方法，並將此數值存於 AX 中。接下來的第 172∼173 行，將 AX 除以 WHEEL_DELTA，以獲得滾輪轉動多少格。因為 WHEEL_DELTA 是 120，以 8 位元表示即可；再加上滑鼠滾輪滾動的距離是 16 位元的有號數，所以要使用八位元有號數除法指令。底下先介紹這個未介紹過的指令，IDIV。
IDIV 是 x86 的有號數除法指令。事實上，x86 的除法指令有兩種，分別是①DIV、②IDIV。它們的語法相同，原理也類似，差別在於 DIV 只能計算正整數的除法，也就是無號數的除法；IDIV 可以計算有號數的除法。DIV 的用法請參閱「Win64 組合語言第四章」，此處僅介紹 IDIV。IDIV 的語法如下：
IDIV 運算元
這裏的運算元其實是除數，可以是變數或暫存器，不能是常數，而其長度可以是八位元、十六位元、三十二位元或六十四位元。除法運算當然有被除數，被除數依照除數的長度，依序放在 AX、DX:AX、EDX:EAX、RDX:RAX 裏面。x86 CPU 的除法運算，被除數是沒有寫出來的，只寫出除數。至於運算之後所得的商以及餘數存放於何處，也略有不同，列於下表：
| 除法方式 | 除數 | 被除數 | 商數 | 餘數 | 範例 | ||
| 運算前 | 運算後 | ||||||
| 八位元除法 | 8 位元變數 或暫存器 | AX | AL | AH | ;－11÷4＝－2⋯⋯－3 MOV AX,0FFF5H MOV CL,4 IDIV CL |
AL=0FEH（商） AH＝0FDH（餘數） CL=4 | |
| 十六位元除法 | 16 位元變數 或暫存器 | DX:AX | AX | DX | ;11÷（－4）＝－2⋯⋯3 MOV DX,0 MOV AX,0BH MOV CX,-4 IDIV CX | AX=0FFFE（商） DX=3（餘數） CX=－4=0FFFCH | |
| 三十二位元除法 只能用於 386等級以上 | 32 位元變數 或暫存器 | EDX:EAX | EAX | EDX | ;－11÷（－4）＝2⋯⋯－3 MOV EDX,0FFFFFFFFH MOV EAX,0FFFFFFF5H MOV ECX,0FFFFFFFCH IDIV ECX | EAX=2（商） EDX=0FFFFFFFDH（餘數） ECX=0FFFFFFFCH | |
| 六十四位元除法 只能用於 x64等級以上 | 64 位元變數 或暫存器 | RDX:RAX | RAX | RDX | ;1CDEFAB1234567890H÷10000000H ;＝1CDEFAB123H⋯⋯4567890H MOV RDX,1 MOV RAX,0CDEFAB1234567890H MOV RCX,10000000H DIV RCX |
RAX=1CDEFAB123H（商） RDX=4567890H（餘數） | |
有號數的表示方式，請參考第九章，這裏說明上表中的範例。以八位元的除法為例，如果要計算「－11÷4＝－2⋯⋯－3」，那麼要把 AX 設為－11，可以直接在原始程式中輸入「MOV AX,－11」，「MOV AX,－0BH」或「MOV AX,0FFF5H」，三者均可。當進行到「IDIV CL」時，CPU 會自行將商、餘數分別存入 AL、AH 中。
不論是無號數或有號數，進行除法運算，都能看成連續的減法運算，此處所說的減法是減少被除數與零的距離。由被除數開始每次往零的方向移動一個除數，直到最接近零且不越過零為止。例如以 －11 除以 4 為例，－11 離零有十一格的距離，因為除以四，所以每次向零移四格，只能移兩次，第三次就會越過零了。移動幾次就是商，而距離零還剩多遠就是餘數。因此 －11 除以 4 得 －2 餘 －3（－2、－3 以八位元的十六進位表示分別是 0FEH、0FDH）。寫成數學式為：
－11＝4×（－2）＋（－3）
基於以上的理由，有號數的除法不論被除數是正數或負數，也不管除數是正數還是負數，其商與除數的乘積必與被除數同號，餘數必與被除數同號。
解釋完 IDIV 指令後，言歸正傳，再回到 WM_MOUSEWHEEL 訊息。為了說明如何處理 WM_MOUSEWHEEL 訊息中的 wParam 資料，用一個例子來說明，應該是很好的方法。假設使用者滾動滑鼠滾輪，結果使 WM_MOUSEWHEEL 的 wParam 中，第 15∼31 位元之值是－240，也就是十六進位的 0FF10H。參考前述說明的 WM_MOUSEWHEEL 訊息資料，滾輪滾動的距離除以 WHEEL_DELTA 才是滾輪滾動的格數，WHEEL_DELTA 之值為 120，因此如果滾輪滾動距離是－240，那麼滾動的格數就是－2，計算方式如下：
－240÷120＝－2
SYSMTR3.ASM 的第 172∼173 行，利用 IDIV 計算出滾輪滾動的格數，並將它存於 AL 暫存器中。因為捲動軸方塊的位置，也就是在 stsi 結構體的 nPos 欄位長度是 DWORD，等一會兒計算出來要捲動多少行之後，必須與 stsi.nPos 作運算，所以在第 174∼175 行將滾動格數由八位元延伸到 32 位元的 R10D、R11D 暫存器內。因為 AL 內是有號數，因此延伸時利用 MOVSX 指令，將其符號保留起來。
一般程式會讓每滾動一格，工作區內的資料會捲動三行，滾動格數再乘以三才是捲動多少行。但是 x86 的乘法指令非常耗時，且只有累加器才能作為被乘數，用起來綁手綁腳，所以有些乘法用位移指令代替。舉個例子來說，例如要將某個數，X，乘以三，可用 2×X＋X 表示，2×X 可以用 x86 指令的「SHL X,1」代替。SYSMTR3.ASM 中的第 176∼177 行演示了這樣的方法。
假如使用者滾動滑鼠滾輪後，使滾動的距離是－240，那麼執行完第 177 行的程式碼之後，R10D 暫存器內之值為－6，表示工作區應捲動－6 行。正號代表向上捲動，stsi.nPos 之值應該減少；負號代表向下捲動，stsi.nPos 之值應該增加。所以第 178 行，使用「SUB stsi.nPos,R10D」來達成上述目的。使用減法可以使捲動正值讓 stsi.nPos 減少；使捲動負值讓 stsi.nPos 增加。
接下來的第 179∼180 行，呼叫 SetScrollInfo API 完成設定捲動軸捲動方塊的位置。第 181 行，呼叫 InvalidateRect 將工作區設為無效區域，以強迫系統重新繪製工作區，而達成捲動的效果。