很幸運的是，正絃函數是週期函數，每隔 2π，其正弦值會重複出現。例如 sin 4.2π = sin 2.2π = sin 0.2π = sin(-1.8π)= sin(-3.8π)。因此可以利用週期性，將使用者輸入的角度縮減至 -π∼π之間，這樣就能解決這種誤差。原理不難，先計算使用者輸入的角度（若以 x 表示）是 2π的多少倍，而這裏的倍數取最接近的整數（若以 N 表示），那麼就可以把 x 映射至 x-2πN 處。前一章介紹了 SSE 指令的觀念，雖然這指令集非常豐富，也包含平方根指令，但是卻沒有提供計算三角函數與對數的指令。這一章將介紹用組合語言，配合 SSE 指令集，撰寫正弦函數。（蛤，不知道什麼是正弦函數？其實它就是 sin，參閱註一）。
先說明如何計算正弦函數，再說明本章會用到的指令。
泰勒級數（Taylor series，也稱泰勒展開式，Taylor expansion）是一種無窮級數，可以計算三角函數或對數函數的近似值，所計算的項數越多越精確。對於正弦函數而言，泰勒級數是
sin x = x - x33! + x55! - x77! + x99! - x1111! + x1313! - x1515! + x1717! - ……;令 cn=xnn!，n=3,5,7,9…… = x - c3x3 + c5x5 - c7x7 + c9x9 - c11x11 + c13x13 - c15x15 + c17x17 - ……
但是如果採用上式直接計算，於程式碼的安排上不易撰寫，因此還得稍微「變形」，這就是赫納方法（Horner's Method）。推導過程如下：
sin x = x ( 1 - c3x2 + c5x4 - c7x6 + c9x8 - c11x10 + c13x12 - c15x14 + c17x16 - ……);反過來寫 = x ( ……+ c17x16 - c15x14 + c13x12 - c11x10 + c9x8 - c7x6 + c5x4 - c3x2 + 1 );高次項太小，忽略不計 ≈ x ( c17x16 - c15x14 + c13x12 - c11x10 + c9x8 - c7x6 + c5x4 - c3x2 + 1 );令 z = x2 ≈ x ( c17z8 - c15z7 + c13z6 - c11z5 + c9z4 - c7z3 + c5z2 - c3z + 1 );()內前八項都有z的因數，將z提出來 ≈ x ( z [ c17z7 - c15z6 + c13z5 - c11z4 + c9z3 - c7z2 + c5z - c3 ] + 1 );[]內前七項都有z的因數，將z提出來 ⁝ ≈ x ( z( z( z( z( z( z( z( c17z-c15 ) + c13 ) - c11 ) + c9 ) - c7 ) + c5 ) - c3 ) + 1)
到此，撰寫出來的程式碼，就會變得非常簡單了。程式先計算白色小括號內的算式，z 乘以 c17，再減去 c15，假設白色小括號內所得的結果是 A，那麼上面的數學式便能寫成：
sin x ≈ x ( z( z( z( z( z( z( Az+c13 ) - c11 ) + c9 ) - c7 ) + c5 ) - c3 ) + 1)
比較上式天藍色與更上一式白色的部分，便會發現運算過程一樣，都是 z 乘以某數，再加或減一個常數。某數是前一次小括號內的運算結果，常數則是奇數的階乘再取倒數。假如在資料區域是先定義好奇數階乘的倒數（包含正負號），那麼計算過程就更簡單了。每算完一層括號，就乘以 z，然後加上常數，如此一層一層把括號算完。這便是赫納方法的精華，只用乘法與加法便算完一層括號，當算完一層括號後，還是重複乘法與加法。
因此程式要做的，便是設一個迴圈，迴圈內便是進行乘法後做加法，然後就是下次迴圈。而初始化迴圈要做的事就是設定一個指標，指向常數位址；事先計算好 x2，作為 z；計算奇數階乘的倒數（包含正負號），並於定義於資料區域。
利用泰勒級數及赫納方法計算正絃函數，有個缺點，那就是如果 x 越大或越小（離零越遠），誤差越大，這不是我們希望的。請參閱下圖，紅色線是正弦函數，黃色線是計算到 x23 的泰勒級數，兩者在接近零附近重疊（橙色線），但在離零較遠處，誤差較大。如果計算越多項，也能減少誤差，但花費時間越多。很幸運的是，正絃函數是週期函數，每隔 2π，其正弦值會重複出現。例如 sin 4.2π = sin 2.2π = sin 0.2π = sin(-1.8π)= sin(-3.8π)。因此可以利用週期性，將使用者輸入的角度縮減至 -π∼π之間，這樣就能解決這種誤差。原理不難，先計算使用者輸入的角度（若以 x 表示）是 2π的多少倍，而這裏的倍數取最接近的整數（若以 N 表示），那麼就可以把 x 映射至 x-2πN 處。
另外，在圖上沒有辦法觀察到的是，在離零遠的地方，即使是 -π或 π 附近誤差也比較大。這點可以用小算盤計算，就能知道還是會有誤差，不過也有方法解決。先看上圖中，0∼π 之間（背景是灰色），在這範圍內 sin x 相對於 x=π2 是對稱的。這意思是說在這範圍內，以 x=π2 這條鉛錘線（淡藍色虛線）分隔成兩半，左半部與右半部的關係，就像是實物與該物在鏡子裏的像。舉例來說，當 x=π6 或 x=5π6，它們都距離淡藍色虛線 π3 遠，其正弦值都是 0.5。同理，在 0∼-π之間也有類似的情形。
因此還可以利用對稱性，進一步把角度映射到 - π2∼π2之間，這樣又能進一步減少誤差。具體的步驟是①、若 π ≥ x > π2，縮減後的 x = π-x。②、若 π2 ≥ x ≥ - π2，x 不變。③、若 - π2 > x > -π，縮減後的 x = -π-x。
ROUNDSD 的用途是將雙精確度浮點數捨入到最接近的整數，它的語法如下：
ROUNDSD XMM暫存器,來源運算元,立即值
其中來源運算元可以是記憶體變數，也可以是 XMM 暫存器。ROUNDSD 將來源運算元的雙精確度浮點數（可能是 XMM 暫存器的低半部，或是四字組的記憶體變數），依照立即值指定的規則，捨入至整數，再存入目的運算元 XMM 暫存器的低半部（不會改變高半部）。所得的結果，雖是整數，但以雙精確度浮點數的形式儲存。
立即值長度只有八位元，但只有第 0∼3 位元有效，第 4∼7 位元須保持 0。第 0∼3 位元的意義如下：
⑴、第零、一位元：指定了四種捨入方式：
①、00：四捨六入，若遇五，看左邊一位：奇數進位，偶數捨去。例如 3.6 變成 4.0，2.5 變成 2.0，3.5 變 4.0（2.5 遇到五，左邊是 2，故捨去；3.5 遇到五，左邊是 3，故進位）。
②、01：向下捨入，趨向負無窮大。例如 3.6 變成 3.0；-3.6 變成 -4.0。
③、10：向上捨入，趨向正無窮大。例如 3.6 變成 4.0；-3.6 變成 -3.0。
④、11：向零捨入，也就是直接切掉小數部分。例如 3.6 變成 3.0；-3.6 變成 -3.0。
⑵、第二位元：用於決定捨入方式是來自立即值的第 0∼1 位元，還是 MXCSR 控制暫存器。如果是 0，使用立即值的第 0∼1 位元；如果是 1，忽略立即值的第 0∼1 位元，改為使用 MXCSR 暫存器中的捨入模式控制。
⑶、第三位元：是否更新 MXCSR 的 PE 位元（註二）。如果第三位元為一，禁止更新 PE 位元，可以增加效率：如果第三位元為零，正常更新 PE 位元。
ROUNDSD 的捨入通常屬於不精確運算（inexact operation），雖然一般不會真的觸發硬體例外中斷，但 CPU 仍可能需要更新 MXCSR 的 PE 位元。將 imm8 的第三位元設為一，可抑制這種更新，減少的負擔，因此在大量 SSE 運算中可能會效率。
MOVSD 指令是用來把雙精確度浮點數從來源運算元搬移到目的運算元，並不會改變來源運算元之值。其語法是：
MOVSD 目的運算元,來源運算元
目的運算元與來源運算元，其中一個必定是 XMM 暫存器，另一個可以是 XMM 暫存器或 64 位元長的記憶體變數。如果運算元是 XMM 暫存器，那麼只搬移低半部的 64 位元，或把低半部的 64 位元搬移到目的運算元。如果目的運算元是 XMM 暫存器，只會影響低半部，而高半部仍保持原值。
MOVSD 的用途與 MOVQ 非常相像，都是搬移 64 位元的資料，有三點不一樣：①目的運算元是 XMM 暫存器時，MOVSD 不會使高半部歸零，而 MOVQ 會歸零。②MOVSD 的運算元不能是通用暫存器，而 MOVQ 可以。③MOVSD 搬移的是浮點數，MOVQ 搬移的是整數，但這一點在組合語言看來，其實並沒有什麼差別。
ANDPD 與 ANDPS 分別是對 XMM 暫存器內的兩個雙精確度浮點數、四個單精確度浮點數進行「且」運算（即 AND 運算），並將結果存入 XMM 暫存器。它們的語法是
ANDPD XMM暫存器,來源運算元 ANDPS XMM暫存器,來源運算元
其中的來源運算元可以是記憶體變數或 XMM 暫存器。假如來源運算元是記憶體變數的話，那麼必須對齊節位址。如果沒對齊，那麼 CPU 會引發一般保護例外而使應用程式當掉。右上圖說明 ANDPD 指令的運作方式，圖中 XMM1 與 XMM2 中的 1 與 2 僅代表編號，並非特指 XMM1 暫存器與 XMM2 暫存器，而是 XMM0∼15 暫存器都可以。
ANDSD 指令僅僅將雙精確度變成單精確度，因此上圖中的每個運算元都含有四個單精確度浮點數，而 ANDPS 會同時進行四次運算，再將結果存入上圖中的 XMM1 運算元中。有關 ANDPD、ANDSD 還有一些使用技巧，稍後說明。
ORPD 與 ORPS 分別是對 XMM 暫存器內的兩個雙精確度浮點數、四個單精確度浮點數進行「或」運算（即 OR 運算），並將結果存入 XMM 暫存器。它們的語法是
ORPD XMM暫存器,來源運算元 ORPS XMM暫存器,來源運算元
其中的來源運算元可以是記憶體變數或 XMM 暫存器。假如來源運算元是記憶體變數的話，那麼必須對齊節位址。如果沒對齊，那麼 CPU 會引發一般保護例外而使應用程式當掉。右上圖說明 ORPD 指令的運作方式，圖中 XMM1 與 XMM2 中的 1 與 2 僅代表編號，並非特指 XMM1 暫存器與 XMM2 暫存器，而是 XMM0∼15 暫存器都可以。
ORSD 指令僅僅將雙精確度變成單精確度，因此上圖中的每個運算元都含有四個單精確度浮點數，而 ORPS 會同時進行四次運算，再將結果存入上圖中的 XMM1 運算元中。有關 ORPD、ORSD 還有一些使用技巧，稍後說明。
這四個指令的用途是依據立即值的規則，使 XMM 暫存器內的數值與來源運算元進行比較，並把結果寫入 XMM 暫存器。它們的語法是：
CMPPD XMM暫存器,來源運算元,立即值 CMPPS XMM暫存器,來源運算元,立即值 CMPSD XMM暫存器,來源運算元,立即值 CMPSS XMM暫存器,來源運算元,立即值
上述指令的立即值是八位元的常數，可以是下面幾種情形：
| 立即值 | 意義 | 立即值 | 意義 | 立即值 | 意義 | 立即值 | 意義 | |||
| 0 | 等於 | 2 | 小於或等於 | 4 | 不等於 | 6 | 大於 | |||
| 1 | 小於 | 3 | 5 | 大於或等於 | 7 |
當目的運算元內的各浮點數與來源運算元相對應的浮點數比較，如果符合立即值，那麼目的運算元相對應的浮點數所有位元都變成 1，否則都變成 0。例如底下的例子：
;XMM3高 XMM3低;XMM4高 XMM4低 ; 2.0 3.0 ; 2.0 4.0 cmppd xmm3,xmm4,0 ;全為1 全為0 ; 2.0 4.0
立即值為 0，代表檢查是否相等。XMM3、XMM4 高半部都是 2.0，故 XMM3 高半部所有位元都將變為 1；XMM3、XMM4 低半部不相等，故 XMM3 低半部所有位元都將變為 0。換句話說，執行完 CMPPD 之後，XMM4 仍維持原浮點數不變，但是 XMM3 會變成 0FFFFFFFFFFFFFFFF0000000000000000h。
到這兒，諸位看倌應當瞭解，CMPPD、CMPPS、CMPSD、CMPSS 並沒有設定旗標暫存器來控制流程，而是將目的運算元，也就是 XMM 暫存器設為真或偽。那該如何控制流程呢？事實上，SSE 指令有兩套方法可以達到這樣的目的。第一種較為直覺，將 XMM 暫存器內的真或偽搬移至通用暫存器，然後用 CMP/Jcc 判斷條件然後跳躍，這種方法是「條件分支」（conditional branch）。第二種方法是直接使用 XMM 暫存器的真偽值，再加以邏輯運算（例如 ANDPD、ORPD、XORPD 等指令），不需要比較也無須跳躍，這種方法稱為「無分支邏輯」（branchless programming）。
底下小木偶用同一個例子展示這兩種方法。前面提過如果使用者輸入的角度在 -π 與 π 之間，還可以進一步映射至 - π2∼π2 之間，具體的步驟是①、若 π ≥ x > π2，縮減後的 x = π-x。②、若 π2 ≥ x ≥ - π2，x 不變。③、若 - π2 > x > -π，縮減後的 x = -π-x。而底下所展示的兩種方法，就是使用這個例子，都假設使用者所輸入的角度 x，已經存於 XMM0 暫存器，且 x 在 -π∼π之間。
⑴、如果採用條件分支，程式如下：
ALIGN 16 AbsMsk DQ 7FFFFFFFFFFFFFFFh,0;絕對值遮罩 SignMsk DQ 8000000000000000h,0;變號 TwoPiRe DQ 0.159154943091895336;1/(2π) TwoPi DQ 6.283185307179586477;2π Pi DQ 3.141592653589793238;π HalfPi DQ 1.570796326794896619;π/2 NHalfPi DQ -1.570796326794896619;-π/2 ⁝ ;利用分支邏輯，將存於XMM0的x之範圍由[-π,π]，映射到[-π/2,π/2] ;如果x大於π/2，則XMM0=π-x；如果x小於-π/2，則XMM0=-π-x；否則XMM0不變 movsd xmm1,xmm0 movsd xmm2,Pi cmpsd xmm1,HalfPi,2;若x<=π/2，則XMM1低半部位元全是1 movq r11,xmm1 or r11,r11;若R11=0，才跳躍至great:；R11=0，表示x>π/2 jz great;綜合上式，當x>π/2，R11=0，才跳躍至great: movsd xmm3,xmm0 cmpsd xmm3,NHalfPi,5;若x>=-π/2，則XMM3低半部位元全是1 movq r11,xmm3 or r11,r11;若R11不為0，才跳躍至ok:；R11不為0，表示x>=-π/2 jnz ok;綜合上式，當x>=-π/2，R11不為零，才跳躍至ok: xorpd xmm2,SignMsk;XMM2=-π great: subsd xmm2,xmm0 movsd xmm0,xmm2 ok: ⁝
⑵、如果採用無分支邏輯，程式如下（資料區內的常數與⑴相同，省略不列出）：
;利用無分支邏輯，將存於XMM0的x之範圍由[-π,π]，映射到[-π/2,π/2] ;如果x大於π/2，則XMM0=π-x；如果x小於-π/2，則XMM0=-π-x；否則XMM0不變 movsd xmm3,HalfPi;XMM0低;XMM1低;XMM2低;XMM3低;XMM4低; movsd xmm2,xmm0; x;; x; π/2 movsd xmm1,xmm0; x; x; x; π/2 ;x大於π/2與x小於-π/2，這兩個條件相當於|x|>π/2，若符合，則XMM0=±π-x，(若x>π/2，用π-x；若x<-π/2，用-π-x) andpd xmm1,AbsMsk; x; |x|; x; π/2 cmpsd xmm3,xmm1,2; x; |x|; x; 1或0;;若|x|>π/2，則XMM3低半部所有位元為1，否則為0 movsd xmm1,Pi; x; π; x; 1或0; movsd xmm4,xmm3; x; π; x; 1或0; 1或0;若|x|>π/2，則XMM4低半部所有位元為1，否則為0 ;若|x|>π/2，XMM0=-x，否則XMM0=x。ANDPD XMM3,SignMsk目的在於檢查|x|>π/2，若符合使XMM3第63位元為1其餘為0，以利下個指令是否變號 andpd xmm3,SignMsk; x; π; x; 變號?; 1或0 xorpd xmm0,xmm3; ±x; π; x; 變號?; 1或0;若|x|>π/2，XMM0=-x，否則XMM0=x ;若|x|>π/2，XMM1=π(當x為正)或-π(當x為負)；若|x|<=π/2，XMM1=0 cmpsd xmm2,AbsMsk[8],1; ±x; π; 1或0; 變號?; 1或0;檢查x是否為負，若為負XMM2低半部位元全為1，否則為0 andpd xmm2,SignMsk; ±x; π; 1或0; 變號?; 1或0; orpd xmm1,xmm2; ±x; ±π; 1或0; 變號?; 1或0;若|x|>π/2且x為負，XMM1=-π；若|x|>π/2且x為正，XMM1=π andpd xmm1,xmm4; ±x;0或±π; 1或0; 變號?; 1或0 addsd xmm0,xmm1;XMM0=π-x(當x>π/2)或x(當-π/2<=x<=π/2)或-π-x(當x<-π/2)
無分支邏輯的概念是利用比較之後所生成的位元遮罩，來達到無分支卻能有條件分支的功能。例如上面的例子：
如果 x 大於 π/2，則 XMM0=π-x；
如果 x 小於 -π/2，則 XMM0=-π-x；
如果 -π/2≤x≤π/2，則 XMM0=x。
換句話說最後 XMM0 有三種情形，這取決於 x 的範圍。在這兒小木偶謹說明前兩種情形，如何用無分支邏輯能夠在 x 為負時，XMM1=-π；x 為正時，XMM1=π。我想瞭解這之後，在這之前或之後的思路過程，諸位看倌便能舉一反三推導出來。
見上面程式倒數第五行，比較 x（已存於 XMM2）與 0（已定義於常數 AbsMsk[8] 中）何者較小，若 x 較小，表示 x 是負值，XMM2 的低半部位元全是 1（恰好符號位元是 1 時表示負值，這當然是精心安排的），否則全是 0。參考右圖。而此刻 π 已經存於 XMM1 內，因此只須把 XMM2 的 0 或 1 變成只剩下符號位元即可，這就是「andpd xmm2,SignMsk」的作用，遮罩掉其他位元僅剩符號位元。再下一步「orpd xmm1,xmm2」，就把符號位元加在 XMM1 裏 π 的前面的了。
採用無分支邏輯有個技巧，因為浮點數的正負值由符號位元決定，符號位元位於第 63 位元（雙精確度）或第 31 位元（單精確度），因此如果要進行與符號有關的運算，可以使用且、或、互斥或運算，例如
andpd xmm0,7FFFFFFFFFFFFh;|XMM0|orpd xmm0,800000000000h;-|XMM0|xorpd xmm0,800000000000h;變號，即 -XMM0上面的例子中的立即值需要修正，實際上，上面的 SSE 指令並不能使用立即值進行運算，必須將立即值定義成常數，並且要對齊節位址。此外，關於無分支邏輯的思路，也有幾點值得注意：
底下是依據前述的原理，實作的應用程式，其中的 sin 函式，就是計算正弦函數的核心。
1 2 3 4 5 6 7 8
9 10 11 12 13 14 15 16
17 18 19 20 21 22 23 24
25 26 27 28 29 30 31 32
33 34 35 36 37 38 39 40
41 42 43 44 45 46 47 48
49 50 51 52 53 54 55 56
57 58 59 60 61 62 63 64
65 66 67 68 69 70 71 72
73 74 75 76 77 78 79 80
81 82 83 84 85 86 87 88
89 90 |
;sin函式，計算正弦函數。
INCLUDE E:\masm64\include64\masm64rt.inc
EXTRN scanf:PROC
EXTRN printf:PROC
;****************************************************************************************
.DATA
angle DQ ?
szHint DB "輸入角度，我會算出其正弦(sin)值：",0
szFmt1 DB "%lf",0
szFmt2 DB "sin %g度=%.15g",0
;****************************************************************************************
.CODE
;----------------------------------------------------------------------------------------
sin PROC x:QWORD
;計算正弦函數
;輸入：x=角度，單位是度，雙精確度浮點數
;輸出：sin x
movq x,xmm0
jmp start
ALIGN 16
coeff DQ -8.220635246624329717e-18,2.811457254345520763e-15,\ ;-1/19!, 1/17!
-7.647163731819816476e-13,1.605904383682161460e-10,\ ;-1/15!, 1/13!
-2.505210838544171878e-8, 2.755731922398589065e-6,\ ;-1/11!, 1/9!
-1.984126984126984127e-4, 8.333333333333333333e-3,\ ;-1/7!, 1/5!
-1.666666666666666667e-1, 1.0 ;-1/3!, 1
AbsMsk DQ 7FFFFFFFFFFFFFFFh,0 ;絕對值遮罩
SignMsk DQ 8000000000000000h,0 ;變號
TwoPiRe DQ 0.159154943091895336 ;1/(2π)
TwoPi DQ 6.283185307179586477 ;2π
Pi DQ 3.141592653589793238 ;π
HalfPi DQ 1.570796326794896619 ;π/2
NHalfPi DQ -1.570796326794896619 ;-π/2
d2r DQ 1.7453292519943295769e-2;(以弳為單位，弳=角度*π/180)
start: mulsd xmm0,d2r ;把角度的單位變為弳
;使XMM0內的角度，投射在[-π,π]。方法是x=x-N*2π，其中N是最接近的整數。
movsd xmm1,xmm0
mulsd xmm1,TwoPiRe ;這裡先用1/2π簡化邏輯
roundsd xmm1,xmm1,00 ;N=round(x/2π)
mulsd xmm1,TwoPi
subsd xmm0,xmm1
;利用無分支邏輯，將存於XMM0的x之範圍由[-π,π]，映射到[-π/2,π/2]
;如果x大於π/2，則XMM0=π-x；如果x小於-π/2，則XMM0=-π-x；否則XMM0不變
movsd xmm3,HalfPi ;XMM0低;XMM1低;XMM2低;XMM3低;XMM4低;
movsd xmm2,xmm0 ; x ; ; x ; π/2
movsd xmm1,xmm0 ; x ; x ; x ; π/2
;x大於π/2與x小於-π/2，這兩個條件相當於|x|>π/2，若符合，則XMM0=±π-x
;，(若x>π/2，用π-x；若x<-π/2，用-π-x)
andpd xmm1,AbsMsk ; x ; |x| ; x ; π/2
cmpsd xmm3,xmm1,2 ; x ; |x| ; x ; 1或0 ;
movsd xmm1,Pi ; x ; π ; x ; 1或0 ;
movsd xmm4,xmm3 ; x ; π ; x ; 1或0 ; 1或0;
;若|x|>π/2，XMM0=-x，否則XMM0=x。ANDPD XMM3,SignMsk目的在於檢查|x|>π/2，
;若符合使XMM3第63位元為1其餘為0，以利下個指令是否變號
andpd xmm3,SignMsk ; x ; π ; x ; 變號? ; 1或0
xorpd xmm0,xmm3 ; ±x ; π ; x ; 變號? ; 1或0;
;若|x|>π/2，XMM1=π(當x為正)或-π(當x為負)；若|x|<=π/2，XMM1=0
cmpsd xmm2,AbsMsk[8],1; ±x ; π ; 1或0 ; 變號? ; 1或0;
andpd xmm2,SignMsk ; ±x ; π ; 1或0 ; 變號? ; 1或0;
orpd xmm1,xmm2 ; ±x ; ±π ; 1或0 ; 變號? ; 1或0;
andpd xmm1,xmm4 ; ±x ;0或±π ; 1或0 ; 變號? ; 1或0
addsd xmm0,xmm1 ;XMM0=π-x(當x>π/2)或x(當-π/2<=x<=π/2)或-π-x(當x<-π/2)
;初始化級數
ok: movsd xmm1,xmm0 ; x ; x ;
movsd xmm2,coeff ; x ; x ; c19 ;
mulsd xmm1,xmm1 ; x ; z=^2 ; c19 ;
lea r8,coeff
mov rcx,LENGTHOF coeff-1
;赫納方法開始
next: add r8,8
mulsd xmm2,xmm1 ; x ; z ; z*c19;
addsd xmm2,QWORD PTR [r8] ; z ;z*c19+c17
loop next
mulsd xmm0,xmm2
ret
sin ENDP
;----------------------------------------------------------------------------------------
main PROC
invoke printf,ADDR szHint
invoke scanf,ADDR szFmt1,ADDR angle
movq xmm0,angle
call sin
movq r8,xmm0
invoke printf,ADDR szFmt2,angle
invoke ExitProcess,0
main ENDP
;****************************************************************************************
END |
這個程式的原理，都已經說過了，就不在囉嗦了。
原始的正弦函數定義是指直角三角形中，對邊與斜邊之比值。見右圖左半部，△ABC 中，∠B 為直角，斜邊是 AC；∠A 為 x 度，其對邊是 BC。根據正弦的定義，sin x= BC AC 。如果把它畫在笛卡兒坐標系，圓心為原點的單位圓上（單位圓是指半徑為一的圓，見右圖右半邊），sin x=a，不過這時候，x 就可以超過 90 度，甚至到 180、360，還可以超過一圈，於是 x 就可以是正實數；假如讓 x 往順時鐘方向旋轉，x 就變成負值，所以依據這種想法，x 可以是實數。
順帶一提，這兒的 x 代表角度。常用的角度單位有兩種：①度（記為°）。②弳（記為 rad，但常省略）。它們之間的換算是 180°= π rad = π，因此可以導出來 1 ≈ 57.296°。當我們計算 sin x 時，x 的單位可以是度，也可以是弳；但是如果用泰勒級數計算時，就只能用弳了。
MXCSR 是 media and extensions control and status register 的縮寫，是在 CPU 內部的暫存器之一，專門處理與 SSE 指令有關的控制與狀態的暫存器。它的長度是 32 位元，見下圖
這些位元主要可以歸納為五部分：
⑴、異常旗標（第 0∼5 位元）：雖然它們的名稱都是「例外」（exception），但它們實際上扮演的都是「異常狀態旗標」，用來記錄某種浮點異常是否曾發生。
ⓐ、第零位元稱為 IE（invalid operation exception）位元，發生無效運算此位元為一，否則為零。例如計算負數的平方根。
ⓑ、第一位元稱為 DE（denormal exception）位元，當運算元是非正規化數時此位元可能為一，否則為零。
ⓒ、第二位元稱為 ZE（divide-by-zero exception）位元，發生除以零時此位元為一，否則為零。
ⓓ、第三位元稱為 OE（overflow exception）位元，曾發生浮點溢位時此位元為一，否則為零。浮點溢位是指浮點數絕對值太大，超出浮點格式能表示的最大範圍。例如雙精確度浮點數範圍是 2.23×10-308∼1.80×10308，如果計算 (10200)2，就發生浮點溢位。
ⓔ、第四位元稱為 UE（underflow exception）位元，曾發生浮點下溢。如果運算結果太接近 0，小到超出正常浮點格式可表示的範圍，就會發生浮點下溢。例如計算雙精確度浮點數，(10-200)2，就會發生浮點下溢。
ⓕ、第五位元稱為 PE（precision exception）位元，曾發生不精確運算此位元為一，否則為零。當 CPU 運算後的「真正數學結果」，無法被目前的浮點格式精確的表示，必須做近似（rounding），就稱為不精確運算。在許多情形下，都會產生不精確運算。例如因為 0.1 無法精確轉換成浮點數，就會產生不精確運算（見第十一章）。再例如 1÷3 得到的是循環小數，須做近似，也是不精確運算。但是像 0.25+0.5=0.75，這三個數都能精確表示，不必近似處理，就屬於精確運算。發生不精確運算時，並非代表錯誤，也不該讓應用程式當掉，因為在浮點的運算中，這種事經常發生。
⑵、異常遮罩（第 7∼12 位元）：這六個位元用於是否要「忽略」對應的異常。如果遮罩位元為一（這是預設值），SSE 指令會忽略該異常，完成計算並設定狀態旗標，不會打斷程式。如果遮罩位元為零，則啟用對應的浮點異常，當異常發生時，處理器可能產生 SIMD Floating-Point Exception（#XM/#XF），由作業系統或應用程式的異常處理機制處理。
ⓐ、第七位元稱為 IM（invalid operation mask）位元，無效運算異常遮罩。
ⓑ、第八位元稱為 DM（denormal mask）位元，非規格化運算元異常遮罩。
ⓒ、第九位元稱為 ZM（divide-by-zero mask）位元，除以零錯誤異常遮罩。
ⓓ、第十位元稱為 OM（overflow mask）位元，溢位錯誤異常遮罩。
ⓔ、第 11 位元稱為 UM（underflow mask）位元，下溢錯誤異常遮罩。
ⓕ、第 12 位元稱為 PM（precision mask）位元，精確度錯誤異常遮罩。
⑶、捨入模式（第 13∼14 位元）：有四種捨入模式（這兒有例子可供參考）：
ⓐ、四捨六入，若遇五，看左邊一位：奇數進位，偶數捨去。
ⓑ、向下捨入，趨向負無窮大。
ⓒ、向上捨入，趨向正無窮大。
ⓓ、向零捨入，也就是直接切掉小數部分。
⑷、非正規化數的歸零（第 6、15 位元）：為了提升處理非規格化數的效能，CPU 提供了兩種非標準的加速模式：
ⓐ、DAZ（denormals are zeros）：在運算前將來源運算元中的非正規化數值，直接當作 0 處理。
ⓑ、FZ（flush to zero）：在運算後若結果是非正規化數，直接歸零成 ±0 存入。
⑸、第 16∼31 位元，保留不用，皆應設為零。