第十三章　浮點數與 SSE 指令

這一章多談一些 SSE 指令，最後將這些指令，應用於計算直角坐標系上已知兩點間的距離以及計算一元二次方程式的兩個根。一如既往，先介紹會用到的指令。

本章用到的指令

假指令：ALIGN

ALIGN 是用來指示組譯器把程式碼或資料對齊某個位址，以提高存取效率，其用法是：

ALIGN   boundary

boundary 是二的冪次方數，例如 2、4、8、16，表示在使用了 ALIGN 之後，下一個指令或資料的存放位址必須是能被 2、4、8、16 整除。雖然 boundary 可以是超過 16，但是會浪費很多記憶體所以很少用。

如果在程式中的資料區段中定義下面資料：

.CONST
n1      DB      1
ALIGN   2
n2      DB      2
ALIGN   4
n3      DW      8086h
ALIGN   8
str1    DB      "TEST ALIGN",0
ALIGN   16
str2    DB      "少年願，眾生念，滅魍魎妖邪！"
szApp   DB      "第一個Win64程式",0

那麼載入記憶體之後，結果如下圖： n2 之前有「ALIGN 2」，所以 n2 的位址必須是能被 2 整除。如上圖，n1 只佔一個位元組，位於位址 7F164000H，本來 n2 應放在位址 7F164001H，但因為有「ALIGN 2」，組譯器安插一個位元組的 0（以粉紅色表示），使 2 放在 7F164002H 處。n3 之前有「ALIGN 4」，所以 n3 的位址必須是能被 4 整除，因此組譯器安插一個位元組的 0 （以橙色表示）就可以讓 n3 放在 7F164004H 處。同理，紅色的兩個位元組的零與綠色的 13 個位元組的零，分別是 AILGN 8、ALIGN 16 所添加的，以便使 str1、str2 字串能在四字組、節的邊界上開始。

這裏整理一下。

  1. ALIGN 2：下個指令或資料，存放於的位址必須能被 2 整除，可視為字組邊界。
  2. ALIGN 4：下個指令或資料，存放於的位址必須能被 4 整除，可視為雙字組邊界。
  3. ALIGN 8：下個指令或資料，存放於的位址必須能被 8 整除，可視為四字組邊界。
  4. ALIGN 16：下個指令或資料，存放於的位址必須能被 16 整除，可視為節邊界。

SSE 指令：MOVAPD 與 MOVAPS

MOVAPD 與 MOVAPS 的語法是：

MOVAPD  目的運算元,來源運算元
MOVAPS  目的運算元,來源運算元

目的運算元與來源運算元必須有一個是 XMM 暫存器，另一個可以是記憶體，也可以是 XMM 暫存器。這兩個指令都是搬移 128 個位元「打包」的浮點數，也就是把來源運算元裏面的 128 個位元的資料搬移到目的運算元，而來源運算元的內容不變。

來看看它們的原文，就能明白它們的意思。MOVAPD 原文是 move aligned packed double-precision，MOVAPS 是 move aligned packed single-precision。還記得第十一章說，單精確度浮點數需要使用 32 個位元表示，雙精確度浮點數則需使用 64 個位元表示。而這兩個指令都是要搬移 128 個位元，所以對 MOVAPD 來說，是搬移兩個雙精確度浮點數；對 MOVAPS 來說，是搬移四個單精確度浮點數。

packed 的意思是把這兩個或四個浮點數打包起來，一次搬移到目的運算元。也就是前一章說的，「串流單指令多資料延伸指令集」（SSE，Streaming SIMD Extensions）。有些文獻把 packed 翻譯成封裝或向量，翻譯成封裝還好瞭解，翻譯成向量，則是因為向量與純量是相對的（見前一章）。不論翻譯成打包、封裝還是向量，其實意思都是指一個指令處理多筆資料。

align 的意思是對齊，也就是說這些資料必須對齊節位址。一個節（paragraph）的大小是 16 個位元組，換句話說，這些資料所在的位址，其數值必須能被 16 整除。如果把位址寫成十六進位數，那麼最右邊一位必須是「0」。使用「ALIGN 16」假指令，就能輕而易舉達到此目的。如果違反這項規定，會引發 CPU 一般保護例外（#GP，general protection exception）而使應用程式當掉。

小木偶用底下的程式，說明 MOVAPD 指令運作過程：

align   16
number  DQ  40711A7B35F5B126,406189999999999Ah  ;100.45+100√3, 140.3
movapd  xmm0,number

參考下圖，上述程式碼經組譯後，用 x64dbg 載入。假如變數 number 的位址是 7FF6B6B83060，該位址內的數值是雙精確度浮點數，100.45+100√3，以 IEEE 754 格式表示就是 40711A7B35F5B126h。它在記憶體中以小端序排列（低位數在低位址，高位數在高位址），40 是第 56∼63 位元在最高位址，26 是第 0∼7 位元在最低位址。下一個雙精確度浮點數是 140.3，位於更高的位址的 7FF6B6B83068 上。執行完 MOVAPD 後，位於低位址的 100.45+100√3 移至 XMM0 的低半部（0∼63 位元）；位於高位址的 140.3 移至 XMM0 的高半部（64∼127 位元）。浮點數以 IEEE 754 格式表示，是一串十六進位的數值（嚴格來說，其實是更大一串二進位數，除錯器包含 x64dbg 都以十六進位表示），非常不直覺，但是，的確是用這樣的方式儲存於記憶體中。往後，我們也可以用上圖的方式，簡單想像這些數值在記憶體或暫存器之間，是如何操作的。

SSE 指令：ADDPD、SUBPD、MULPD、DIVPD

這四個指令是把位於 XMM 暫存器內的兩個雙精確度浮點數，與另一個 XMM 暫存器或記憶體內的兩個雙精確度浮點數進行四則運算。它們的語法是：

ADDPD   XMM暫存器,來源運算元
SUBPD   XMM暫存器,來源運算元
MULPD   XMM暫存器,來源運算元
DIVPD   XMM暫存器,來源運算元

由上面可知，這四個指令的目的運算元，只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器或記憶體變數。如果來源運算元是記憶體變數，那麼必須對齊節位址；如果沒對齊，那麼 CPU 會引發一般保護例外而使應用程式當掉。這四個指令運算過程都一樣，把目的運算元內的兩個雙精確度浮點數，分別與存於來源運算元相對應位元的兩個雙精確度浮點數，進行四則運算，再將結果存入目的運算元內。

底下說明 SUBPD、DIVPD 指令，因為它們不具有交換律，所以哪個運算元在前，哪個在後就很重要。下圖左邊是 SUBPD 指令圖解，目的運算元、來源運算元分別以 XMM1、XMM2/M128 表示，這裏的 1、2 指的是代號，並非指特定的暫存器（也就是說 XMM1、XMM2 可以是 XMM0∼XMM15 之中的任何一個）；而 M128 指的是記憶體變數，這個指令會用到 128 位元的資料。從圖上，可以很明顯看出來，SUBPD 指令會把 XMM1 的低半部減去 XMM2/M128 的低半部，並將差存於 XMM1 的低半部；同一時間也把 XMM1 的高半部減去 XMM2/M128 的高半部，並將差存於 XMM1 的高半部。

上圖右邊是 DIVPD 的圖解說明，它僅僅是把減法改成除法，而其他過程都一樣，也就是說把 XMM1 的低半部除以 XMM2/M128 的低半部，並將商存於 XMM1 的低半部；同一時間也把 XMM1 的高半部除以 XMM2/M128 的高半部，並將商存於 XMM1 的高半部。ADDPD、MULPD 的過程與 SUBPD、DIVPD 相同，就不多說了。

底下的例子，以數值說明 ADDPD、DIVPD 執行後結果：

x       DQ      5.0, 7.0
y       DQ      4.0, 9.0
z       DQ      2.0, 4.0
movapd  xmm0, x ;XMM0高半部是7.0，低半部是5.0
addpd   xmm0, y ;XMM0高半部是16.0，低半部是9.0
divpd   xmm0, z ;XMM0高半部是4.0，低半部是4.5

右圖僅說明 ADDPD 指令的過程，在執行 ADDPD 前，XMM0 內低半部與高半部分別是 5.0 與 7.0；執行 ADDPD 時，同時與 y 所指位址的 4.0 與較高八個位元組位址內的的 9.0 分別相加；分別得到 9.0 與 16.0，最後存入 XMM0 內。

SSE 指令：ADDSD、SUBSD、MULSD、DIVSD

這四個指令是把位於 XMM 暫存器內的低半部雙精確度浮點數，與另一個 XMM 暫存器或記憶體內的雙精確度浮點數進行四則運算。它們的語法是：

ADDSD   XMM暫存器,來源運算元
SUBSD   XMM暫存器,來源運算元
MULSD   XMM暫存器,來源運算元
DIVSD   XMM暫存器,來源運算元

由上面可知，這四個指令的目的運算元，只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器或記憶體變數。這四個指令運算過程都一樣，把來源運算元的雙精確度浮點數，與目的運算元的低半部雙精確度浮點數，進行四則運算，再將結果存入目的運算元內。

目的運算元的高半部，不會受這四種指令運算的影響。如果來源運算元是記憶體變數，不需要對齊節位址。如果來源運算元是 XMM 暫存器，那麼是把低半部的雙精確度浮點數，與目的運算元低半部的雙精確度浮點數，進行四則算。

SSE 指令：HADDPD、HSUBPD

HADDPD 指令的原文是 horizontal add packed double-precision，它是 SSE3 指令集的其中一道指令。它的特別之處，在於它不是將位於兩個運算元相對應位元上的浮點數相加，而是將某個運算元內部的浮點數相加，這也就是 horizontal 的意思。HADDPD 的語法是：

HADDPD  XMM暫存器,來源運算元

HADDPD 的目的運算元只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器，也可以是記憶體變數。右上圖是 HADDPD 指令的圖解說明，目的運算元、來源運算元分別以 XMM1、XMM2/M128 表示，這裏的 1、2 指的是代號，並非指特定的暫存器；而 M128 指的是記憶體變數，這個指令會用到 128 位元的資料。HADDPD 會把儲存於目的運算元內的兩個浮點數相加，然後存於目的運算元的低半部（也就是 0∼63 位元）；同一時間也把來源運算元內的兩個浮點數相加，然後存於目的運算元的高半部（也就是 64∼127 位元）。

這兒介紹個小技巧。假如把 HADDPD 的兩個運算元設為相同的 XMM 暫存器，那麼執行後，這個暫存器的高半部與低半部是相等的，而且均為原先高半部與低半部之和。（想看圖解，請按這兒）例如

haddpd  xmm5,xmm5   ;若XMM5高半部是8.0，低半部是9.0。執行後XMM5高半部與低半部皆為17.0

瞭解了 HADDPD 指令後，要瞭解 HSUBPD 指令，也不是困難的事了，因為這兩道指令很相似。先來看 HSUBPD 的語法：

HSUBPD  XMM暫存器,來源運算元

HSUBPD 的目的運算元只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器，也可以是記憶體變數。HSUBPD 會把儲存於目的運算元內的低半部浮點數減去高半部浮點數，然後存於目的運算元的低半部（也就是 0∼63 位元）；同一時間也把來源運算元內的低半部浮點數減去高半部浮點數，然後存於目的運算元的高半部（也就是 64∼127 位元）。

例如底下的例子：

x       DQ      5.0, 7.0
y       DQ      4.0, 9.0
z       DQ      2.0, 4.0
movapd  xmm0, x ;XMM0高半部是7.0，低半部是5.0
haddpd  xmm0, y ;XMM0高半部是13.0，低半部是12.0
hsubpd  xmm0, z ;XMM0高半部是-2.0，低半部是-1.0

HADDPD 與 HSUBPD 指令中，如果來源運算元是記憶體變數，那麼必須對齊節位址。如果沒對齊，那麼 CPU 會引發一般保護例外而使應用程式當掉。

SSE 指令：XORPD 與 XORPS

XORPD 與 XORPS 指令的語法是

XORPD  XMM暫存器,來源運算元
XORPS  XMM暫存器,來源運算元

這兩個指令是對目的運算元與來源運算元，按位元進行互斥或運算。也就是目的運算元第零位元與來源運算元第零位元進行互斥或運算，結果存於目的運算元第零位元；目的運算元第一位元與來源運算元第一位元進行互斥或運算，結果存於目的運算元第一位元；目的運算元第二位元與來源運算元第二位元進行XOR運算，結果存於目的運算元第二位元；……直至所有位元都算完。雖然這樣寫，不過它們是同時進行運算的，並非一個位元算完，再算另一個。

來源運算元以是 XMM 暫存器，也可以是記憶體變數。如果來源運算元是記憶體變數，那麼必須對齊節位址。如果沒對齊，那麼 CPU 會引發一般保護例外而使應用程式當掉。

邏輯結果來看，XORPD 與 XORPS 一模一樣，都是 128 位元的按位元進行互斥或運算。但 SSE 指令集將它們分開，而不是僅實作一個指令，可能有兩個原因。一是語意清晰度，XORPS 明確指出處理四個單精確度，XORPD 處理兩個雙精確度，可以提高程式碼的可讀性，維護也較為容易。二是當資料型別不匹配時，硬體會產生額外的轉發延遲現象，會影響效率。

這兒提供兩個技巧。

⑴、假如要使某個 XMM 暫存器歸零，可以使用 XORPD 指令。例如要使 XMM5 歸零，就執行「xorpd xmm5,xmm5」。

⑵、假如要使某個 XMM 暫存器內數值變號（即正數變負數，或負數變正數）。方法是先準備常數資料，例如要使 XMM7 內的低半部雙精確度浮點數變號，那可以使用底下程式：

msk_v   DQ  8000000000000000h,0
xorpd   xmm7,msk_v

SSE 指令：MOVMSKPD 與 MOVMSKPS

MOVMSKPD 與 MOVMSKPS 指令的功能，是將 XMM 暫存器中各浮點數的符號位元提取出來，存入通用的暫存器中，做為後續判斷正負數時，提供判斷的資料。它們的語法是：

MOVMSKPD reg,XMM暫存器
UNPCKLPS reg,XMM暫存器

其中 reg 是 32 或 64 位元的通用暫存器。MOVMSKPD 會把位於 XMM 暫存器內，低半部和高半部的兩個雙精確度浮點數的符號位元，依序存入 reg 的第 0、1 位元內，並使 reg 其他高位元清除而變為零。MOVMSKPS 會把位於 XMM 暫存器內的四個單精確度浮點數的符號位元，分別存入 reg 的第 0∼3 位元內，並使其他高位元清除而變為零。

SSE 指令：UNPCKLPD 與 UNPCKLPS

UNPCKLPD 的原文是 unpack and interleave low packed double-precision floating-point，意思是把兩個運算元的低半部雙精確度浮點數「拆解」後，重新打包。而 UNPCKLPS 則是把四個單精確度浮點數「拆解」後，重新打包。它們的語法是：

UNPCKLPD XMM暫存器,來源運算元
UNPCKLPS XMM暫存器,來源運算元

UNPCKLPD、UNPCKLPS 的目的運算元只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器，也可以是記憶體變數。先說 UNPCKLPD，它把來源算運算元的低半部，搬移到目的運算元的高半部，如下圖左邊。這兒提供一個技巧：假如 UNPCKLPD 的兩個運算元都是同一個 XMM 暫存器，那結果就是把這個 XMM 暫存器的低半部複製到高半部，高半部原先的資料會消失。例如底下的程式碼：

unpcklpd  xmm4,xmm4

其效果就相當於把 XMM4 暫存器的低半部複製到高半部。UNPCKLPS 則是把目的運算元內的四個單精確度浮點數拆解，然後再重新打包，結果如上圖右邊。目的運算元的最低雙字組不改變，次低雙字組變為來源運算元的最低雙字組，次高雙字組變為目的運算元原來的次低雙字組，最高字組變為來源運算元的次高字組。換句話說，UNPCKLPD 在目的運算元僅保留原來兩運算元最低和次低的雙字組。

SSE 指令：ADDSUBPD 與 ADDSUBPS

ADDSUBPD 的語法是

ADDSUBPD XMM暫存器,來源運算元

ADDSUBPD 的目的運算元只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器，也可以是記憶體變數。右上圖是 ADDSUBPD 指令的圖解說明，目的運算元、來源運算元分別以 XMM1、XMM2/M128 表示，這裏的 1、2 指的是代號，並非指特定的暫存器；而 M128 指的是記憶體變數，這個指令會用到 128 位元的資料。ADDSUBPD 的用途是把目的運算元的低半部減去來源運算元的低半部，將差存於目的運算元的低半部；同一時間也把目的運算元的高半部加上來源運算元的高半部，將和存於目的運算元的高半部。

ADDSUBPS 的語法是

ADDSUBPS XMM暫存器,來源運算元

ADDSUBPS 的目的運算元只能是 XMM 暫存器，故上面語法中直接寫 XMM 暫存器；而來源運算元可以是 XMM 暫存器，也可以是記憶體變數。ADDSUBPS 與 ADDSUBPD 類似，進行減、加交互運算。ADDSUBPS 把目的運算元分成四個單精確度浮點數，與來源運算元的四個單精確度浮點數同一時間進行加、減法運算，而運算方式由低位元至高位元依序是減、加、減、加，最後將結果存入目的運算元。右上圖是 ADDSUBPS 的圖解說明，目的運算元、來源運算元分別以 XMM1、XMM2/M128 表示，這裏的 1、2 指的是代號，並非指特定的暫存器；而 M128 指的是記憶體變數，這個指令會用到 128 位元的資料。

如果 ADDSUBPD 與 ADDSUBPS 指令的來源運算元是記憶體變數，那麼必須對齊節位址。如果沒對齊，那麼 CPU 會引發一般保護例外而使應用程式當掉。

ADDSUBPD 與 ADDSUBPS 指令本來是設計用於計算複數的乘法。眾所周知，複數可以寫成 a+bi 的形式，其中的 i 是√-1。假如有兩個複數相乘，那麼實部相減，虛部相加：

(a+bi)(c+di)=(ac-bd)+(ad+bc)i

例子：FP3（計算兩點間距離）

底下的例子，是利用 SSE 指令計算在直角座標系上，兩點間的距離，原始程式如下。將它儲存成 FP3.ASM，然後在命令提示字元中組譯、連結即可，FP3 也是在命令提示字元中執行。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
;FP3計算直角座標系（笛卡兒座標），兩點間的距離，這兩點分別是(273.655080756887729,140.3)
;與(100.45,40.3)。273.655080756887729其實是100.45+100√3的近似值
INCLUDE E:\masm64\include64\masm64rt.inc
EXTRN   printf:PROC
;**********************************************************
.DATA
ALIGN     16
pt1       DQ    273.655080756887729,140.3 ;x1=273.655.,y1=140.3
pt2       DQ    100.45,40.3               ;x2=100.45  ,y2=40.3
distance  DQ    ?
szFmt  DB "笛卡兒座標系上，點(%.10g,%g)到點(%g,%g)的距離是%g",0
;***********************************************************
.CODE
;-----------------------------------------------------------
main    PROC;XMM0高  XMM0低;XMM1高 XMM1低
        movapd  xmm0,pt1;  y1      x1
        movapd  xmm1,pt2;  y1      x1; y2     x2
        subpd   xmm0,xmm1;y=y1-y2 x=x1-x2; y2     x2
        mulpd   xmm0,xmm0;  y2      x2; y2     x2
        haddpd  xmm0,xmm1; x2+y2  x2+y2; y2     x2
        sqrtsd  xmm0,xmm0; x2+y2 √x2+y2; y2     x2
        movq    r11,xmm0;R11=XMM0低半部
        mov     r8,pt1[8]
        mov     r10,pt2[8]
        invoke  printf,ADDR szFmt,pt1,r8,pt2,r10,r11
        invoke  ExitProcess,0
main    ENDP
;***********************************************************
END

FP3.ASM 必須用到數學裏的勾股弦定理（也叫畢氏定理，Pythagoras' theorem）。勾是指較短的直角邊，股是較長的直角邊，而弦則是直角的對邊。勾股弦定理指的就是直角三角形中

弦2=勾2+股2

如右上圖，FP3 計算的是 (100.45, 40.3) 到 (100.45+100√3, 140.3) 之間的距離。勾是兩個 Y 座標相減；股是兩個 X 座標相減，而弦則是兩點之間的連線，所以弦等於勾與股的平方和再開根號。也因為計算勾的平方與股的平方，所以計算兩座標相減時，不必理會用大的減去小的，反正結果都是正值。

像這樣計算兩點 X、Y 座標的差，再求差的平方，這樣的情形，利用 SSE 單一指令處理多筆資料的特性，能簡化程式碼，也能增進效率（雖然這個程式計算很少，不須考慮什麼效率）。

FP3.ASM 第 17∼18 行，將這兩點座標分別載入 XMM0 與 XMM1 暫存器裏面，再用 SUBPD 同時計算 X、Y 座標之差，得到的就是勾與股的長度。因為 SSE 沒有計算平方的指令，所以用最原始的方法，把 XMM0 乘以 XMM0，也就是 MULPD，權充平方。

接下來用水平加法，HADDPD，計算兩座標差的平方和。把 XMM0 的低半部與高半部相加，結果存於 XMM0 的低半部。雖然 HADDPD 也會把 XMM1 的高半部與低半部相加，但這對 FP3 而言並無用處，後來會捨棄不用。最後一步，利用 SQRTSD，求 XMM0 低半部的平方根（第 23 行）。

最後將 XMM0 的低半部存入 R11 暫存器（第 26 行），呼叫 printf 將結果印在螢幕上，結束程式。

例子：FP4（計算一元二次方程式的根）

FP4 讓使用者輸入三個數值，分別代表一元二次方程式，ax2+bx+c=0，的係數，a、b、c。FP4 會計算此方程式的解。原始程式如下，它也是主控臺程式，需在命令提示字元下執行。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
;FP4讓使用者輸入一元二次方程式，ax^2+bx+c=0，的係數
;FP4計算該方程式的兩根
INCLUDE E:\masm64\include64\masm64rt.inc
EXTRN   printf:PROC
EXTRN   scanf:PROC
;********************************************************************
.DATA
ALIGN   16
b       DQ      ?
a       DQ      ?
b_p     DQ      ?
c       DQ      ?
one     DQ      1.0
n_four  DQ      -4.0
x1      DQ      ?
x2      DQ      ?
SIGN_MK DQ      8000000000000000h, 0
szHint  DB      "請輸入一元二次方程式，ax^2+bx+c=0，的三個係數",0Dh,0Ah
        DB      "三個係數之間，以空格格開：",0
szFmt1  DB      "%lf %lf %lf",0
szFmt2  DB      "兩根為%g、%g。",0
szErr1  DB      "輸入錯誤。",0
szErr2  DB      "a不可為0。",0
szErr3  DB      "沒有實數解。",0
;********************************************************************
.CODE
;--------------------------------------------------------------------
main    PROC
        invoke   printf,ADDR szHint
        invoke   scanf,ADDR szFmt1,ADDR a,ADDR b,ADDR c
        cmp      rax,3
        jz       chk_a
        lea      rcx,szErr1
        jmp      error
chk_a:  cmp      a,0
        jnz      ok
        lea      rcx,szErr2
error:  call     printf
        jmp      exit
ok:     mov      rax,b
        mov      b_p,rax;XMM0高 XMM0低;XMM1高 XMM1低;XMM2高 XMM2低;
        movapd   xmm0,b;  a      b;
        movapd   xmm1,b_p;  a      b;  c     b;
        movapd   xmm2,one;  a      b;  c     b;  -4     1;
        mulpd    xmm0,xmm1; ac     b2;  c     b;  -4     1;
        mulpd    xmm0,xmm2;-4ac    b2;  c     b;  -4     1;
        xorpd    xmm1,SIGN_MK;-4ac    b2;  c    -b;  -4     1;
        haddpd   xmm0,xmm0;b2-4ac b2-4ac;  c    -b;  -4     1;
        movmskpd r11d,xmm0
        test     r11,1       ;測試D是否為負數，D=b2-4ac
        jz       pos
        lea      rcx,szErr3
        jmp      error
pos:    addsd    xmm2,xmm2;  D      D;  c    -b;  -4     2;
        sqrtpd   xmm0,xmm0; √D    √D;  c    -b;  -4     2;
        mulsd    xmm2,a; √D    √D;  c    -b;  -4     2a;
        unpcklpd xmm1,xmm1; √D    √D; -b    -b;  -4     2a;
        unpcklpd xmm2,xmm2; √D    √D; -b    -b;  2a     2a;
        addsubpd xmm1,xmm0; √D    √D;-b+√D -b-√D;  2a     2a;
        divpd    xmm1,xmm2; √D    √D;  x1    x2;  2a     2a;
        movapd   x1,xmm1
        invoke  printf,ADDR szFmt2,x1,x2
exit:   invoke  ExitProcess,0
main    ENDP
;********************************************************************
END

說明

一元二次方程式指的是像 x2+bx+c=0 的方程式，有三個係數。當 FP3 讓使用者輸入完成之後，在第 31 行檢查 scanf 是否真的讀取到三個數值。二次方程式還有個條件，x2 的係數不可是零，所以 FP3 在第 35 行檢查 a 是否為零。只有通過這兩項檢驗，才能繼續執行程式，否則退出程式。

一元二次方程式的兩個根分別是 x=－b＋√b2－4ac 2a、 －b－√b2－4ac 2a，仔細觀察，會發現計算這兩個根的過程中，有兩樣特點：一是有進行平方根的運算，所以在開根號前，應該要檢查判別式，b2－4ac，是否為負數，如果是負數代表「沒有實數解」，印出這訊息後退出程式。二是，這兩個根的計算方式非常相像，差別在於根號前方一個是加、一個是減。

因為有第二個特點，所以在開方之前，只需計算判別式一次即可。假如我們再仔細分析判別式，你會發現 b2 是一次乘法，4ac 是兩次乘法，利用 SSE 指令的特性，僅執行 MULPD 一次，而計算兩個乘法運算。要達到這個目的，必須重複載入 b 至 XMM 暫存器。因此在第 41∼42 行複製 b 到 b_p 變數裏，然後在第 9∼12 行依照 b、a、b_p、c 的排列，執行兩次 MOVAPD 就可以載入四個雙精確度浮點數（執行第三次 MOVAPD 是為了計算分母的 2a 與 －4ac。接下來第 45∼46 行）。然後執行兩次 MULPD，就能計算出 b2、－4ac。

第 48 行的「HADDPD XMM0,XMM0」，是很有趣的指令。見右圖左上角的 XMM0 暫存器（它代表目的運算元）的低半部，HADDPD 把將它與高半部相加（紫線），存入低半部（紅線），於是 XMM0 低半部變為 b2－4ac；在同一時間，左下角的 XMM0（表示來源運算元）低半部與它的高半部相加（橙色線），再存入目的運算元的高半部（棕線）。小木偶說它有趣，是因為執行完後，XMM0 高半部與低半部都變成判別式，也就是 b2－4ac。

判斷 XMM0 的判別式是正數還是負數，可以用 MOVMSKPD，它會把 XMM0 的符號位元，存於通用暫存器。這兒的通用暫存器可以是 32 位元或 64 位元，且可以任意選擇，小木偶這兒用 R11。因為已經經過「HADDPD XMM0,XMM0」處理了，所以高半部或低半部相同，只需檢查其中一個即可。

如果判別式為負值，那麼符號位元為一，R11 會變成 0011b（這是二進位）。用「TEST R11,1」檢查後，零值旗標不為零，印出「沒有實數解」的訊息後，離開程式。如果判別式為正值或零，那麼符號位元為零，R11 會變成 0000b（這是二進位）。用「TEST R11,1」檢查後，零值旗標為零，跳躍至 pos: 處繼續執行。

接下來，使 XMM1 低半部變號，製造出－b（第 47 行）；在 XMM2 低半部製造出 2a（第 54、56 行）、計算√D（第 55 行）。接下來的第 57、58 行，執行 UNPCKPD，分別把 XMM1、XMM2 的低半部各自複製到高半部。

接著的第 59 行，ADDSUBPD 也是個有趣的指令。它一個指令同時把低半部相減、高半部相加。這非常符合我們需要的。就是前面提過根號前方一個是加、一個是減。接著的是第 60 行，DIVPD，它是一個指令進行兩次除法運算。最後方程式的兩根在 XMM1 的低半部與高半部，執行 MOVAPD 將其存入記憶體中（第 61 行）。

後記

這一章本來只是想介紹如何處理浮點數，後來發現處理浮點數最方便的方法，竟然還是使用 SSE 指令，於是乎多介紹了這些指令。當然囉，僅僅介紹指令沒什麼意義，所以又加上了兩個例子。

從 DOS 開始學習組合語言，到能掌握組合語言撰寫 Windows 應用程式，在精進組合語言方面，沒有投入更多心力，畢竟 Windows 系統太複雜，可以學的知識太多。這次，為了處理浮點數（以前是用 x87 指令處理），學習較為先進的 SSE/SSE2 指令，算是長了知識吧！。

還有件事也值得記下來，那便是人工智慧。這次學習 SSE/SSE2 指令，幾乎靠人工智慧，大約不到一個星期就能入門。在人工智慧問世之後，如果你想學習新知識，便會有一位很好的老師教你，它（它自己說它沒有性別，所以不是他，也不是她，那是祂嗎？我不知道）博學多聞，且對每項領域都很專精，更重要的是，極度有耐心。不論你的問題多好笑多愚蠢，它也不會嘲笑你，反而是一步一步的詳細解說。把握這個美好的時代，努力精進吧！