在撰寫程式時常常會遇到資料轉移、比較等狀況發生，x86 家族的 CPU 裏有幾個指令是專門處理「字串」的，在這裏所謂的字串，是指在記憶體內連續的位元組或字組，並不一定是 ASCII 字元，也有可能是一段二進位數。這一章裏，小木偶要談談 x86 指令裏的字串處理指令，包含搬移、比較、掃描、儲存、載入五種指令。
除了提到 x86 處理字串的指令之外，無可避免的，還會提到最後一個區段暫存器，ES ( extra segment register，可翻為額外區段暫存器 )，以及兩個索引暫存器，SI ( source index，來源索引暫存器 ) 和 DI ( destination index，目的索引暫存器 )。SI 與 DI 這兩個暫存器常常用來當做指標或索引使用，指向記憶體中的某個位址，待會要提到的 MOVSB 指令就會用到。SI 與 DI 雖然也可以用於運算，但是很少做這樣的用途。
假如要把記憶體中的字串搬移到記憶體的另一處，可以用 MOVSB、MOVSW、MOVSD、MOVSQ，為了單純，這裏只說 MOVSB、MOVSW，其餘指令見註一。MOVSB 英文的意思是「move string byte」，意思是搬移一個位元組的意思。說得更清楚一點，是把記憶體位址 DS:SI 所指位址的一個位元組搬移到 ES:DI 位址上，雖然說是搬移，但原來在 DS:SI 處的內容不變，所以其實是複製或拷貝。也因為是複製記憶體內容，並非運算，所以 MOVSB 不影響旗標。
MOVSB 除了搬移外，還會使 SI 與 DI 還會自動變成下一個位元組的位址。下一個位元組的位址，有可能是讓 SI、DI 都增加一，也有可能都減少一，這要看方向旗標 ( direction flag ) 來決定。假如方向旗標為零，那麼 SI、DI 都會增加一；反之，SI、DI 都減少一。在搬移之前要先設定或清除方向旗標，以決定往高位址搬移還是向低位址搬移。DS:SI 所指位址的字串稱為來源字串，ES:DI 則稱為目的字串。
CLD 與 STD 這兩個 x86 指令的語法是：
CLD STD
它們沒有運算元。CLD 是清除方向旗標 ( clear direction flag ) 的意思，這個指令會讓方向旗標變為 0，以致於每執行一次 MOVSB 指令，使得 SI、DI 都增加一，也就是說資料往高位址處搬移。STD 是設定方向旗標 ( set direction flag ) 的意思，這個指令會讓方向旗標變為 1，以致於每執行一次 MOVSB 指令，使得 SI、DI 都減少一，也就是說資料往低位址處搬移。
底下我們來看看實例：
C:\>c:\tools\symdeb [Enter] Microsoft (R) Symbolic Debug Utility Version 4.00 Copyright (C) Microsoft Corp 1984, 1985. All rights reserved. Processor is [80286] -a [Enter] 1530:0100 mov ax,f000 [Enter] 1530:0103 mov ds,ax [Enter] 1530:0105 mov si,fff5 [Enter] 1530:0108 movsb [Enter] 1530:0109 jmp 108 [Enter] 1530:010B [Enter] →結束程式 -
在 1530:0100∼1530:0103 輸入的程式是把 DS 設為 F000H，第十一章說過 x86 CPU 不認得「MOV DS,F000」這樣的指令，因此只能先把 F000 存入 AX 裏，在藉由「MOV DS,AX」指令讓 DS 變成 F000。接下來把 SI 設為 FFF5。因此可以得知，來源字串是在位址 F000:FFF5 處，這個位址所儲存的八個位元組資料，其實是 BIOS 出廠時的日期。現在執行這三條指令，如下輸入三個「t」指令：
-t [Enter] AX=F000 BX=0000 CX=0000 DX=0000 SP=E9BF BP=0000 SI=0000 DI=0000 DS=1530 ES=1530 SS=1530 CS=1530 IP=0103 NV UP EI PL NZ NA PO NC 1530:0103 8ED8 MOV DS,AX -t [Enter] AX=F000 BX=0000 CX=0000 DX=0000 SP=E9BF BP=0000 SI=0000 DI=0000 DS=F000 ES=1530 SS=1530 CS=1530 IP=0105 NV UP EI PL NZ NA PO NC 1530:0105 BEF5FF MOV SI,FFF5 -t [Enter] AX=F000 BX=0000 CX=0000 DX=0000 SP=E9BF BP=0000 SI=FFF5 DI=0000 DS=F000 ES=1530 SS=1530 CS=1530 IP=0108 NV UP EI PL NZ NA PO NC 1530:0108 A4 MOVSB -
接下來就要執行 MOVSB 了，但是再這之前，先來看一看兩件值得注意的事。第一件事是上面標示天藍色的「UP」，這是 DEBUG/SYMDEB 等除錯器表示旗標暫存器為零時的樣子，若為「DN」則表示旗標暫存器為一。這裏方向旗標設為「UP」，表示 MOVSB 會把字串往高位址搬移。第二件事是檢查 DS:SI 與 ES:DI 所指位址的原先內容，輸入下面兩條指令：
-d ds:fff0 l10 [Enter] F000:FFF0 EA 5B E0 00 F0 30 32 2F-32 32 2F 30 36 00 FC 00 j[`.p02/22/06.|. -d es:di l10 [Enter] 1530:0000 CD 20 C0 9F 00 9A BF E8-80 F1 8E 09 35 0C 2B 0A M @...?h.q..5.+. -
上面用紅字標示起來的是來源字串，用白色標起來的是目的字串。可以猜測，如果執行完八次 MOVSB 後，以白色字表示的目的字串內容會變成跟來源字串一樣。現在輸入「t」指令，SYMDEB 就會讓 CPU 執行第一次的 MOVSB 指令：
-t [Enter] AX=F000 BX=0000 CX=0000 DX=0000 SP=E9BF BP=0000 SI=FFF6 DI=0001 DS=F000 ES=1530 SS=1530 CS=1530 IP=0109 NV UP EI PL NZ NA PO NC 1530:0109 EBFD JMP 0108 -
看到上面的 SI 與 DI，在執行完 MOVSB 指令後，它們倆自動都增加一了 ( 見上面天藍色的字 )。再來看看這兩個字串，輸入底下兩條 SYMDEB 指令：
-d ds:fff0 l10 [Enter] F000:FFF0 EA 5B E0 00 F0 30 32 2F-32 32 2F 30 36 00 FC 00 j[`.p02/22/06.|. -d es:di l10 [Enter] 1530:0000 30 20 C0 9F 00 9A BF E8-80 F1 8E 09 35 0C 2B 0A 0 @...?h.q..5.+. -
如上面所顯示的，CPU 的 MOVSB 指令讓 30 ( 紅字 ) 搬移到 1530:0000 位址處的天藍色字，而原先的內容 ( CD ) 則被覆寫後消失不見。接下來執行兩次「t」指令，如下面：
-t [Enter] AX=F000 BX=0000 CX=0000 DX=0000 SP=E9BF BP=0000 SI=FFF6 DI=0001 DS=F000 ES=1530 SS=1530 CS=1530 IP=0108 NV UP EI PL NZ NA PO NC 1530:0108 A4 MOVSB -t [Enter] AX=F000 BX=0000 CX=0000 DX=0000 SP=E9BF BP=0000 SI=FFF7 DI=0002 DS=F000 ES=1530 SS=1530 CS=1530 IP=0109 NV UP EI PL NZ NA PO NC 1530:0109 EBFD JMP 0108 -d es:0 l10 [Enter] 1530:0000 30 32 C0 9F 00 9A BF E8-80 F1 8E 09 35 0C 2B 0A 02@...?h.q..5.+. -d ds:fff0 l10 [Enter] F000:FFF0 EA 5B E0 00 F0 30 32 2F-32 32 2F 30 36 00 FC 00 j[`.p02/22/06.|. -
從用 a 指令輸入程式到此為止，總共執行了兩次 MOVSB 指令，因此也會搬移兩個位元組的資料到 ES:DI 所指位址 ( 白色字 )，同時 SI、DI 都增加 2 ( 天藍色的字 )，指向下一個要處理的位址。如果要把整個日期字串搬過去，不能像上面程式使用 JMP 指令，這樣會造成現循環的迴圈，讓電腦當掉，應當配合 REP 指令。
單獨的 MOVSB 指令一次只能搬動一個位元組的資料，然而一個字串通常有數個位元組，如果要連續搬移許多位元組，就必須與 REP 指令搭配。REP 是個很特別的指令，它可以跟與處理字串相關的指令搭配一起使用，這樣就會使後面的指令重複執行。重複的次數必須先在計數暫存器 ( 計數暫存器就是 CX )中設定好。例如：
mov cx,8
rep movsb
執行「REP MOVSB」時，會先把 CX 與零進行比較；如果 CX 等於零，則不搬移資料而執行「REP MOVSB」的下一條指令。否則，CX 減一，然後執行 MOVSB 字串指令；接下來會一直重複上面步驟，直到 CX 變為零才停止，然後執行下一條指令。
結論：要搬移一個字串 ( 或說複製一個字串 )，要事先於 DS:SI 設定好來源字串的位址，於 ES:DI 設定好目的字串的位址，在 CX 設定好要搬移幾個位元組，最後執行「REP MOVSB」。看起來很多步驟，但設定好之後，能搬移很長的字串，而且執行速度很快。最後，MOVSB 與 REP MOVSB 都不影響旗標。
MOVSW 指令的用法幾乎和 MOVSB 一樣，差別在於每搬移一次是搬移一個字組，而且使 SI、DI 增減二，亦即增減兩個位元組的位址，以指向下一個位址。
小木偶要介紹的第二個字串處理指令是比較指令，CMPSB 與 CMPSW ( 其實也有 CMPSD、CMPSQ，請參考註一 )。CMPSB 是 compare string byte 的縮寫，意思是一次比較一個位元組；而 CMPSW 則是 compare string word 的縮寫，意思是一次比較一個字組。僅單單用 CMPSB 或 CMPSW 的情況較少，通常會在 CMPSB 或 CMPSW 的前加上 REPE，這樣可以比較多個位元組或字組。REPE 是 repeat while equal 的意思，亦即如果相等就繼續比較，REPE 和 REPZ ( 表示 repeat while zero，如果零值旗標為 ZR，則繼續 ) 是相同的意思的。
用 REPE CMPSB 或 REPE CMPSW 指令比較的兩個字串時，這兩個字串分別放在 DS:SI 與 ES:DI 所指的位址，比較次數則放在 CX。如果 CX 為零，那麼就不會進行比較而執行下一道指令；如果 CX 不為零，那麼每比較一次 CX 減一，同時 SI 與 DI 會自動指向下一個要比較的位址。如果是 REPE CMPSB 表示一個位元組一個位元組比較，故 SI、DI 會自動增加一或減少一；如果是 REPE CMPSW，則每次比較一個字組，SI、DI 會增加二或減少二。
SI、DI 是增加還是減少，視方向旗標決定。如果方向旗標為零表示向高位址比較，SI、DI 會逐步增加；反之則向低位址比較，SI、DI 會逐步減少。到這裏為止，REPE CMPSB/REPE CMPSW 的用法和 REP MOVSB/REP MOVSW 幾乎相同。
那麼，要如何才知道兩個字串相等？其實很簡單，只要檢查零值旗標即可。如果零值旗標被清除 ( 在 DEBUG/SYMDEB 中顯示 NZ )，表示兩字串不同；如果零值旗標被設定 ( 在 DEBUG/SYMDEB 中顯示 ZR )，表示兩字串相同。接下來就可以與 JE 或 JNE 配合，分別跳至字串相等或字串不相等的地方執行。如下：
repe cmpsb ;比較字串
je identical ;若兩字串相同，跳至identical處
回想「REPE CMPSB/REPE CMPSW」的意義是，若相等就繼續比較下個位元組或下個字組；那麼，反過來說，若不相等就會停止比較。也就是說「REPE CMPSB/REPE CMPSW」在比較過程中，只要兩字串某個地方不同，就停止比較，同時清除零值旗標 ( 即 NZ )。這跟第三章的 CMP 一樣。
右圖的例子是比較兩個字串不同時，SI、DI、CX 所代表的意義。如果一開始，來源字串在 DS:0200 處 ( 以白色小字標示 )，目的字串在 ES:0210 處，共要比較 0EH 次 ( 亦即 14 個位元組 )，此數值存於 CX。執行 REPE CMPSB，當比較到位址 205H 與 215H 時，發現不同，CPU 會把零值旗標設為「NZ」，但要注意的是 CMPSB 會讓 SI、DI 指向下一個位址，因此，此時 SI、DI 已經不是第一個不同的位元組所在位址，而是下一個位址了。當比較到 205H 與 215H 時，REPE 都會讓 CX 減一，故 CX 還剩下八次未比較。
總結一下：REPE CMPSB 或 REPE CMPSW 比較在 DS:SI 與 ES:DI 的兩個字串是否相同，CX 代表要比較的次數，若 CX 為零則跳過比較而執行下一道指令。每比較一次，SI 與 DI 會自動增減，以指向下一個比較的位址，同時 CX 減一。當 CX 變為零或比較到兩字串不同之處就停止 REPE CMPSB 或 REPE CMPSW。如果程式要得知在哪個位址開始，兩字串不相同，可以由 SI、DI 來判斷，但是要調整。同樣也可以由 CX 來判斷，但也須調整。
比較字串最常見的用途是搜尋。底下小木偶示範一個例子，SEARCH.EXE，這個程式可以讓使用者輸入最多七個中文字的句子，程式以這句子搜尋唐朝詩人白居易的《琵琶行》中，是否有此句子。
執行 SEARCH.EXE 必須在倚天中文下才能看見中文字，否則是亂碼。欲輸入中文，要先掛上注音輸入法的資料，執行「C:\ET3\ETINMD /PN=C:\ET3\PHONETIC.TAB」，然後可以按「Ctrl－Shift」切換英數與注音輸入。執行結果如下圖：
SEARCH.ASM 完整的程式碼如下，將程式碼存成 SEARCH.ASM 純文字檔，依上圖第一行「ml search.asm」組譯即可得 SEARCH.EXE。
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88
89 90 91 92
93 94 95 96
97 98 |
.MODEL SMALL,C
.386
;*******************************************************************************
mystack SEGMENT STACK
DB 256 DUP (?)
mystack ENDS
;*******************************************************************************
mydata SEGMENT
article DB "潯陽江頭夜送客楓葉荻花秋瑟瑟主人下馬客在船舉酒欲飲無管弦"
DB "醉不成歡慘將別別時茫茫江浸月忽聞水上琵琶聲主人忘歸客不發"
DB "尋聲闇問彈者誰琵琶聲停欲語遲移船相近邀相見添酒迴燈重開宴"
DB "千呼萬喚始出來猶抱琵琶半遮面轉軸撥弦三兩聲未成曲調先有情"
DB "弦弦掩抑聲聲思似訴生平不得志低眉信手續續彈說盡心中無限事"
DB "輕攏慢撚抹復挑初為霓裳後綠腰大弦嘈嘈如急雨小弦切切如私語"
DB "嘈嘈切切錯雜彈大珠小珠落玉盤間關鶯語花底滑幽咽泉流水下灘"
DB "水泉冷澀弦凝絕凝絕不通聲暫歇別有幽愁闇恨生此時無聲勝有聲"
DB "銀瓶乍破水漿迸鐵騎突出刀鎗鳴曲終收撥當心畫四弦一聲如裂帛"
DB "東船西舫悄無言惟見江心秋月白沈吟放撥插弦中整頓衣裳起斂容"
DB "自言本是京城女家在蝦蟆陵下住十三學得琵琶成名屬教坊第一部"
DB "曲罷曾教善才服妝成每被秋娘妒五陵年少爭纏頭一曲紅綃不知數"
DB "鈿頭雲篦擊節碎血色羅裙翻酒污今年歡笑復明年秋月春風等閒度"
DB "弟走從軍阿姨死暮去朝來顏色故門前冷落車馬稀老大嫁作商人婦"
DB "商人重利輕別離前月浮梁買茶去去來江口守空船遶船明月江水寒"
DB "夜深忽夢少年事夢啼妝淚紅闌干我聞琵琶已歎息又聞此語重唧唧"
DB "同是天涯淪落人相逢何必曾相識我從去年辭帝京謫居臥病潯陽城"
DB "潯陽地僻無音樂終歲不聞絲竹聲住近湓江地底溼黃蘆苦竹繞宅生"
DB "其間旦暮聞何物杜鵑啼血猿哀鳴春江花朝秋月夜往往取酒還獨傾"
DB "豈無山歌與村笛嘔啞嘲哳難為聽今夜聞君琵琶語如聽仙樂耳暫明"
DB "莫辭更坐彈一曲為君翻作琵琶行感我此言良久立卻坐促弦弦轉急"
DB "淒淒不似向前聲滿座重聞皆掩泣座中泣下誰最多江州司馬青衫溼"
msg1 DB "此程式會搜尋白居易琵琶行是否有某句文字，",
0dh,0ah,"輸入你要搜尋的文字(最多七個字)：$"
msg2 DB 0dh,0ah,"沒找著。$"
msg3 DB 0dh,0ah,"找著了！$"
msg4 DB 0dh,0ah,"沒輸入文字。$"
buffer DB 15
input DB ? ;要搜尋字串的長度(單位是位元組)
sch_str DB 15 DUP (?) ;要搜尋的字串
exit_c DB ? ;退出碼。0：沒找到。1：有找到。2：使用者沒輸入字
mydata ENDS
;*******************************************************************************
program SEGMENT
ASSUME cs:program,ds:mydata,es:mydata
;-------------------------------------------------------------------------------
main PROC
mov ax,mydata ;AX＝資料段的區段位址
mov ds,ax ;把DS設為資料區段
mov es,ax ;把ES設為和DS同一區段
;印出提示「你輸入的文字(最多七個字)：」，並讓使用者輸入一字串
mov ah,9
mov dx,OFFSET msg1
int 21h ;印出提示文字
mov ah,0ah
mov dx,OFFSET buffer
int 21h ;讓使用者輸入要搜尋的字串
;設定方向旗標、要搜尋的字串長度、搜尋次數
cld ;往高位址方向比較
mov dx,OFFSET msg1-OFFSET article
movzx cx,input ;CX＝要搜尋的字串長度(單位是位元組)
sub dx,cx
inc dx ;DX＝搜尋次數＝文章長度－要搜尋得字串長度＋1
lea bx,article ;BX＝article的位址
or cx,cx ;檢查CX是否為零
jnz search
mov dx,OFFSET msg4 ;若CX＝0，表示使用者未輸入字串
mov exit_c,2
jmp short print
;開始搜尋
;BX：指向琵琶行內容位址，每次搜尋時會往高位址遞增
;DI：每次搜尋時，指向琵琶行中當前要搜尋的位址，由BX取得此位址
;SI：每次搜尋時，指向使用者輸入要搜尋的字串位址
;CX：每次搜尋時要比較多少個位元組
;DX：搜尋次數
search: mov di,bx ;每次搜尋開始處，設定DI為琵琶行中，此次搜尋的位址
mov si,OFFSET sch_str
movzx cx,input ;使用者輸入字串的長度(單位是位元組)
repe cmpsb ;開始此次搜尋的比較
jz match ;若ZR，表示找著了，跳至match
inc bx ;使BX增加一，指向下次搜尋琵琶行內容的位址
dec dx ;搜尋次數減一
jnz search ;若DX不為零，進行下次搜尋，跳至search
mov exit_c,0 ;若DX為零，表示已將琵琶行都搜尋過了，仍找不著
mov dx,OFFSET msg2
jmp print
match: mov exit_c,1
mov dx,OFFSET msg3
print: mov ah,9
int 21h ;印出搜尋結果
.EXIT exit_c
main ENDP
;-------------------------------------------------------------------------------
program ENDS
;*******************************************************************************
END main
|
小木偶把 SEARCH.EXE 的資料區段與額外區段設在同一區段，這樣的好處是所有的變數、比較時的來源字串與目的字串，全都在同一個區段內，就不必擔心要轉換區段的問題。要讓資料區段與額外區段都在同一區段，首先要用 ASSUME 假指令告訴組譯器，見程式第 43 行。然後還要使 DS、ES 設為 mydata 區段，見程式第 46∼48 行。
小木偶用 AH＝0AH/INT 21H 鍵盤緩衝區來輸入要搜尋的字串，參見第三章。緩衝區設在 buffer 開始的 17 個位元組，那麼，第一個位元組要設為多少呢？因為琵琶行是一首七言古詩，一句七字，因此小木偶也設定使用者所搜尋的字串不可超過七個中文字。一個中文字需用兩個位元組表示，再包含輸入完畢的 Enter 鍵所代表的 0DH，共 15 個位元組。由以上來看，緩衝區的第一個位元組應為 15。第二個位元組是使用者所輸入的字串長度，但不包含 Enter 鍵，以 input 為其變數名，input 在使用者輸入完畢後，由 DOS 填入而現在不知數值為何，故以「?」表示。接下來為字串存放處，但要加上 Enter 鍵，且上不知使用者會輸入什麼資料，故有 15 個未初始的位元組。因此程式第 36∼38 行的程式為：
buffer DB 15 input DB ? ;要搜尋字串的長度(單位是位元組) sch_str DB 15 DUP (?) ;要搜尋的字串
小木偶會這樣設定緩衝區，全是因為 AH＝0AH/INT 21H 服務程式就這樣規定而且後面都要用到這些變數。假如使用者輸入「六宮粉黛無顏色」作為搜尋的句子，那麼 input 會變成 0EH，sch_str 字串會變成「A4 BB AE 63 AF BB C2 4C B5 4C C3 43 A6 E2 0D」，「A4BB」是「六」、「AE63」是「宮」……，最後的「0D」是 Enter 鍵。
輸入要搜尋的字串後，就進入程式核心部份了。這時候，BX 指向琵琶行的第一個位元組，BX 會從琵琶行的第一個位元組逐步增一，BX 每增加一就是一次搜尋，每次搜尋都會做字串的比較，每次比較前，都要設定好下面暫存器：
①把 SI 指向使用者輸入的字串，即 sch_str ( 第 78 行 )、
②把 DI 設成為 BX ( 第 79 行 )、
③CX 為使用者輸入的位元組個數，即 input 變數 ( 第 80 行 )，
第一次搜尋，比較「六宮粉黛無顏色」和「潯陽將頭夜送客」，很明顯這兩句完全不同，故這次搜尋 CMPSB 只會比較一個位元組就停止，在這過程中，SI 會由「六」的第一個位元組增至「六」的第二個位元組，DI 也會同步由「潯」的第一個位元組到「潯」的第二個位元組，但 BX 仍不變，見下圖
CMPSB 執行完之後，檢查零值旗標，若設定，就跳到 match 處 ( 程式第 82 行的 jz match」)，表示找到使用者輸入的字串了。但此處並不會發生跳躍，因為兩字串並不相等，零值旗標會被清除，這時應該再做第二次搜尋，就是從第二個位元組開始，只要把 BX 加一 ( 第 83 行 )，就指向琵琶行的第二個位元組了，然後開始第二次搜尋的比較，如下圖。事實上。每次比較都要設定上面①∼③三個暫存器進行比較。
SEARCH.EXE 就依照這方法，逐步增加 BX，依次設好 SI、DI、CX 三個暫存器開始比較，如果沒找著，就讓 BX 再加一，重複上述步驟，那麼程式如何知道什麼時候該停止呢？我們知道，琵琶行共有 616 個字 ( 琵琶行的序言裏就有說明了 )，因此應該要搜尋 1232 次吧？答案並不對。假設使用者輸入要尋找的字串是「六宮粉黛無顏色」，共 14 個位元組，那麼最後 13 個位元組其實是不須搜尋的，因為長度不同，字串必定不同。下圖是最後一次搜尋，如果沒找到使用者輸入的字串，也不必再次搜尋了。
所以最多搜尋的次數為 1232－13，寫成算式，最多搜尋的次數＝琵琶行的位元組個數－使用者輸入的位元組個數＋1。這個算式就是程式的第 60∼63 行。
如果使用者輸入的是琵琶行中的詩句「楓葉荻花秋瑟瑟」，會發生什麼事呢？如下圖所示，當 BX 指到「楓」的第一個位元組時，也會照前面①∼③。這次搜尋的兩句子相同，故 SI、DI 都會由「楓」的第一個位元組增至「瑟」的最後一個位元組。
當比較完這十四個位元組，都相同，CPU 會把零值旗標設為一，執行到第 82 行「je match」會發生跳躍，到 match 標記處，印出「找著了！」的訊息，設定退出碼為一，結束程式。
這個指令會讓八位元的來源運算元移到 16、32 位元的目的運算元中，或讓十六位元的來源運算元移到三十二位元的目的運算元中，且讓目的運算元中的其他高位元都變成 0。其語法是：
MOVZX r16,r/m8 MOVZX r32,r/m8 MOVZX r32,r/m16
其中 r16、r32 代表十六位元或三十二位元的暫存器，r/m8、r/m16 代表八位元或十六位元的暫存器或記憶體變數。如果用 MOV 指令，來源運算元與目的運算元的資料類型必須相同；但是 MOVZX 能把來源運算元擴充至目的運算元。在資料轉換時，使用 MOVZX 是一種簡便而快速的方法。底下舉三個例子說明：
第一個例子
day db 31
mov ax,0FFFFh
movzx ax,day
執行完後，AX 為 31，即 AX＝001FH。因為 day 是八位元的記憶體變數，故將其以 MOVZX 移入 AX 時，最低的八位元變成 day 之值，其他高位元都變成零。
第二個例子。在 SEARCH.EXE 程式裏，使用者是以 AH＝0AH/INT 21H 來輸入的字串的，所輸入的字串長度記錄在緩衝區的第二個位元組 ( 程式第 37 行的 input 變數 )，當要以 REPE CMPSB 比較字串時，字串長度卻要放在 CX 裏；前者是位元組，後者是字組，因此用 movzx cx,input 解決這個問題 ( 程式第 61 行 )。
第三個例子。在程式第 60∼63 行，要計算搜尋次數，要用文章長度減去使用者輸入字串的長度再加一，文章長度是字組，使用者輸入字串的長度是位元組，因此在第 61 行時用 MOVZX 將位元組擴充成字組，存於 CX 裏。
MOVZX 是 80386 及其以後的 CPU 新增的指令，因此在程式的前面必須要加上「.386」或「.486」假指令，以便讓組譯器能使用較高階的 CPU 指令。同時還要注意，.MODEL 在前，.386 在後，才會使用十六位元的定址方式。
LEA 是 load effective address，翻成中文是載入有效位址，其語法如下：
LEA r16,m LEA r32,m
上面的 m 代表記憶體變數或是某個標記 ( Label )，r16、r32 分別代表十六位元或三十二位元的暫存器。LEA 指令是把記憶體變數或標記的位址存到前面的暫存器中。如果是 DOS 程式，所得位址為十六位元，要用 r16；如果是 Win32 程式，所得位址為三十二位元，需用 r32。SEARCH.ASM 的第 65 行，「lea bx,article」，就是把 article 變數的位址放入 BX 暫存器裏，其實也可以用「mov bx,OFFSET article」代替。
LEA 通常是用來取得區域變數的位址。組譯器在組譯時，無法得知區域變數的位址，如果要取得其位址，必須在程式執行時，以 LEA 取得其位址。
MOVSW、MOVSD、MOVSQ 這三個指令與 MOVSB 很類似，很明顯的，這三個指令最後一個英文字母：W、D、Q，分別是 Word、Doubleword、Quadword 的意思，亦即字組、雙字組、四字組。
這三個指令都是依據方向旗標是零還是一，把來源字串搬移到目的字串，但並非搬移一個位元組。MOVSW 是一次搬移一個字組，並使 SI、DI 增減二；MOVSD 是一次搬移一個雙字組，並使 SI、DI 增減四；MOVSQ 只能用於 64 位元的作業系統中，每次搬移一個四字組，並使 RSI、RDI 增減八。
至於是增還是減，則由方向暫存器決定。用「CLD」指令，清除方向暫存器，那麼會往高位址方向搬移，SI、DI 會增加；反之，用「STD」指令，設定方向旗標，就會往低位址方向搬移，SI、DI 會減少。
此外這些指令也能在三十二位元或六十四位元的作業系統中使用。MOVSB、MOVSW、MOVSD 三個指令，都能在十六位元、三十二位元或六十四位元的系統中使用，但是要注意來源字串與目的字串的位址，必須和幾位元的系統配合。也就是說十六位元系統中，來源字串位址是 DS:SI，目的字串位址是 ES:DI ( SI、DI 都是十六位元的暫存器 )；三十二位元系統中，來源字串位址是 ESI，目的字串位址是 EDI ( ESI、EDI 都是三十二位元的暫存器 )；六十四位元系統中，來源字串位址是 RSI，目的字串位址是 RDI ( RSI、RDI 都是六十四位元的暫存器 )。
如果要搬移的資料很多，不論是 MOVSB/MOVSW/MOVSD/MOVSQ 都可以在前加上 REP 指令，而搬移的次數放在計數暫存器裏。最後整理如下表：
| 指令 | 說明 | 來源位址 | 目的位址 | 搬移次數 | 方向旗標 | 每次搬移後 調整 SI、DI |
| 十六位元的 DOS 作業系統 | ||||||
| REP MOVSB | 一次搬移一個位元組，重複搬移 | DS:SI | ES:DI | CX | 0，UP，往高位址搬移 | 加一 |
| 1，DN，往低位址搬移 | 減一 | |||||
| REP MOVSW | 一次搬移一個字組，重複搬移 | DS:SI | ES:DI | CX | 0，UP，往高位址搬移 | 加二 |
| 1，DN，往低位址搬移 | 減二 | |||||
| REP MOVSD | 一次搬移一個雙字組，重複搬移 | DS:SI | ES:DI | CX | 0，UP，往高位址搬移 | 加四 |
| 1，DN，往低位址搬移 | 減四 | |||||
| 三十二位元的 Windows 作業系統 | ||||||
| REP MOVSB | 一次搬移一個位元組，重複搬移 | ESI | EDI | ECX | 0，UP，往高位址搬移 | 加一 |
| 1，DN，往低位址搬移 | 減一 | |||||
| REP MOVSW | 一次搬移一個字組，重複搬移 | ESI | EDI | ECX | 0，UP，往高位址搬移 | 加二 |
| 1，DN，往低位址搬移 | 減二 | |||||
| REP MOVSD | 一次搬移一個雙字組，重複搬移 | ESI | EDI | ECX | 0，UP，往高位址搬移 | 加四 |
| 1，DN，往低位址搬移 | 減四 | |||||
| 六十四位元的 Windows 作業系統 | ||||||
| REP MOVSB | 一次搬移一個位元組，重複搬移 | RSI | RDI | RCX | 0，UP，往高位址搬移 | 加一 |
| 1，DN，往低位址搬移 | 減一 | |||||
| REP MOVSW | 一次搬移一個字組，重複搬移 | RSI | RDI | RCX | 0，UP，往高位址搬移 | 加二 |
| 1，DN，往低位址搬移 | 減二 | |||||
| REP MOVSD | 一次搬移一個雙字組，重複搬移 | RSI | RDI | RCX | 0，UP，往高位址搬移 | 加四 |
| 1，DN，往低位址搬移 | 減四 | |||||
| REP MOVSQ | 一次搬移一個四字組，重複搬移 | RSI | RDI | RCX | 0，UP，往高位址搬移 | 加八 |
| 1，DN，往低位址搬移 | 減八 | |||||
這四個指令之間的關係，和 MOVSB/MOVSW/MOVSD/MOVSQ 四個指令的關係類似，只不過 CMPSB/CMPSW/CMPSD/CMPSQ 是比較兩個字串是否相同。您可以參考上面的表格，把表格裏的 REP 改成 REPE 或 REPNE，其餘用法幾乎一樣；差別在於 CMPSB/CMPSW/CMPSD/CMPSQ 搭配 REPE 或 REPNE 時，不一定會執行到計數暫存器為零時才停止。使用 REPE 時，表示如果比較結果相同則繼續，也可以說比較結果不同時就停止；使用 REPNE 時，表示如果比較結果不同則繼續。