第 33 章　把含簡體字的檔名變成正體字

緣起

大陸的十多億人口產生的檔案數量，日益增多。有時必須下載為數眾多的檔案，觀其內容多為簡體字，就連檔案名稱，也都是簡體字。雖然小木偶也看得懂，但畢竟不如正體字來得親近。因此心中有一股衝動，想把這些含有簡體字的檔名，都轉換成正體字。也許有人會問，為何不也順道把檔案內容也改成正體字呢？這是因為，每一種檔案格式都不盡相同，所以難度太高，小木偶僅憑一人之力，難以做到。底下，只敘述把含有簡體字的檔名改成正體字的過程。

查閱網際網路上的資料，多為把簡體字貼在網頁上的編輯框，然後轉換成正體字，再貼回原內容上，就能把原來的簡體字取代為正體字。也許小木偶孤陋寡聞，又或許搜尋能力差，總是查不到能把檔案名稱中的簡體字，改成正體字；更查不到能一次大量轉換的程式。於是心裏想，不如自己寫一個吧。

簡體字與正體字對照表

小木偶查了網路，發現正體字共有數萬字，簡體字也有數百個，當然無法一個字一個字列出來，更遑論做對應表。幸好小木偶查到，在民國一百年至一百零四年間，教育部做了常用詞語調查，並且有了報告並公諸於世，在常用國語詞語報告裏，可以見到這些結果。對小木偶有用的是在《一零零至一零四年常用語詞調查報告書》（中），其中的附錄十八。附錄十八，其實是民國一百零四年的字頻總表，下載後檔名是「附錄18_民國104」，似乎無從判斷要用哪一種軟體開啟。幸好小木偶在該網頁左側，發現有兩個標籤頁，圖片與文件，點選文件，發現有「附錄18_民國104 年常用語詞調查語料統計分析字頻表.xls」的字樣。於是用「Excel」開啟，竟然讀取成功了。讀取之後，共有六個欄位，依序是「字頻順序」、「字」、「字頻」、「累積字頻」、「前一百名高頻字累積百分比」、「總字數累積百分比」。

「附錄18_民國104」檔案的建立過程是從年度暢銷書及雜誌、五大報紙、教科書、人氣部落格、談話性節目的字幕，共有一百九十萬字。然後分析這些字出現次數，由最常出現的「的」開始往下排，到最少出現的字為止，製作成一張有 5289 個字的表格。這種依照出現字的頻率多寡，排成的表格稱為「字頻總表」。對於小木偶要製作的程式而言，只需要第二欄即可。想像一下，假如要把簡體字轉換成正體字，必定要有一張這兩種字的對照表，查表時先由第一筆資料查往下查，直到找到要轉換的簡體字，再查閱對應的正體字即可。為了讓程式能很有效率的查表，越常出現的字，就應該放在越前面，這也就是要使用字頻總表的原因。底下，小木偶描述從「附錄18_民國104」開始，如何製作正體字與簡體字對照表的步驟：

  1. 把「Excel」程式裏的第二欄拷貝下來。
  2. 開啟慣用的文書處理軟體，小木偶習慣用「UltraEdit-32」。在空無一物的新檔案裏，先存檔，在此小木偶將檔名取為「ftc.txt」。存檔時要注意，格式要選擇「UTF-16」。對「UltraEdit-32」而言，「UTF-16」就是萬國碼格式。如果您用其他文書軟體，也要用萬國碼格式儲存。若不先存檔，等下一步驟貼上文字後，「UltraEdit-32」會以內定方式解釋文字編碼，這不一定是萬國碼，因此先儲存空檔案，旨在設定好編碼方式。
  3. 按「Ctrl－V」，把文字貼在「UltraEdit-32」。
  4. 然後去除欄位名稱「字」，再用取代功能，把換行符號取代成空字元，就會變成底下的樣子：
  5. 先按「Ctrl－A」，再按「Ctrl－C」，把這個檔案的內容全部拷貝起來。
  6. 再次存檔。此時才是小木偶真正需要的檔案，也是正體字的字頻總表。
  7. 開啟「ConvertZ.exe」程式，把剪貼簿的內容，由萬國碼正體字，轉換為萬國碼簡體字。
  8. 在「UltraEdit-32」，開啟一新檔案，先把這無內容的檔案存起來，檔名是「fsc.txt」，也要選擇以「UTF-16」格式儲存。
  9. 把剪貼簿內容貼上去，如下圖：
  10. 再次把「fsc.txt」檔案存起來。此為簡體字的字頻總表。

到此為止，小木偶已有兩個檔案，「ftc.txt」與「fsc.txt」，它們就是正體字與簡體字的對照表，而且是按照出現頻率排列的對照表。這兩個檔案，每一檔案有 5289 個字，其編碼範圍都是 4837h∼0ff5eh ( 註一)。於是小木偶心中嘀咕了，因為照理來說，常用中文字的萬國碼，不論是正體字或簡體字，都編在 4e00h∼9fa5h 的範圍內，而且和日文、韓文形狀一樣或稍異的表意文字，都統一編碼在這個範圍內，稱為「中日韓統一表意文字」( CJK Unified Ideographs )，怎會跑到 4837h∼0ff5eh 呢？經過仔細核對（其實是寫了個程式檢查），才知道萬國碼 4837h 是高「䠷」的「䠷」；而 0ff5eh 則是「∼」字。心想這兩個字正體字與簡體字是相同的，因此把這兩字刪除了。這樣的話，「ftc.txt」與「fsc.txt」每一檔案有 5287 個字；「ftc.txt」的範圍是 4e00h∼9fa2h，簡體字範圍是 4e00h∼9f9fh。如此一來，搜尋範圍較小，較有效率。

有了這兩個檔案之後，小木偶打算進一步把這兩個檔案的每個字，以萬國碼的編碼方式，即 UTF-16，寫入組合語言原始碼裏面。這兩個檔案，每一檔案有 5287 個字。小木偶是想把這兩個檔案製作成一張很大的對照表，放在資料段裏，像底下的樣子：

.CONST
TCH DW  7684h,662fh,4e00h,4e0dh,6709h,5728h,4ebah,6211h,9019h,4e86h,4ee5h,5927h,500bh,6703h,70bah,4f86h
        ...............................................................................................
SCH DW  7684h,662fh,4e00h,4e0dh,6709h,5728h,4ebah,6211h,8fd9h,4e86h,4ee5h,5927h,4e2ah,4f1ah,4e3ah,6765h
        ...............................................................................................

上面 TCH 是正體中文的意思，亦即 Traditional Chinese 之意，而 SCH 就是簡體中文，Simplified Chinese 的意思。TCH 所定義資料的第一個字組 7684h，是「的」的萬國碼，而 SCH 所定義的第一個字也是 7684h，也是簡體字的「的」，正、簡體字相同。「的」是中文字中最常用的字，因此排在第一位。同樣的，第二個常用的字是「是」，其正體字與簡體字的字碼都是 662fh。從上面的圖及資料段的部份資料來看，可以有兩點結論：

  1. 萬國碼中，並沒有把正體字分在一區、簡體字分在另一區。事實上也是如此，在萬國碼制定時，為了節省空間，所以把中文、日文、韓文等文字中，如果是起源相同、本義相同、形狀一樣或稍異的表意文字都用同一個編碼。因此不僅是正、簡體字，就連日文、韓文、越南喃字等，都編在「中日韓統一表意文字」的區域裏，其範圍是 4e00h∼9fa5h。另外有些罕用字、異體字，則是編在「中日韓統一表意文字擴展區」內，擴展區有許多區，據小木偶所知，至少有 A 區到 G 區，都在 20000h∼2ffffh。
  2. 將來要把簡體字轉換成正體字，所用的方法就是利用上面的兩個字串變數，TCH 與 SCH。每個簡體字相對於 SCH 的偏移位址，也就是相對應正體字，相對於 TCH 的偏移位址。

底下的程式，ch_to_asm_dw.asm，是用來把 ftc.txt 和 fsc.txt 轉換成 TCH 與 SCH 字串。這樣就有了對照表。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
;把正體字與簡體字的字頻總表（檔名分別是「ftc.txt」與「fsc.txt」），轉換成組合語言的「DW」敘述
                OPTION  CASEMAP:NONE
                .586
                .MODEL  FLAT,STDCALL
__UNICODE__     EQU     1       ;支援UNICODE
INCLUDE         WINDOWS.INC
INCLUDE         KERNEL32.INC
INCLUDE         USER32.INC
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB
;*************************************************************************************************************
.CONST
szTradCh        DW      66h,74h,63h,2eh,74h,78h,74h,0h                                  ;ftc.txt
szSimpCh        DW      66h,73h,63h,2eh,74h,78h,74h,0h                                  ;fsc.txt
szAsm           DW      83,67,72,95,65,78,68,95,84,67,72,95,84,66,76,46,73,78,67,0      ;SCH_AND_TCH_TBL.INC
sMsg00          DW      6210h,529fh,5efah,7acbh,53h,43h,48h,5fh,41h,4eh,44h,5fh,54h     ;成功建立SCH_AND_T
                DW      43h,48h,5fh,54h,42h,4ch,2eh,49h,4eh,43h,3002h                   ;CH_TBL.INC。
sMsg01          DW      958bh,555fh,66h,74h,63h,2eh,74h,78h,74h,5931h,6557h,3002h       ;開啟ftc.txt失敗。
sMsg02          DW      958bh,555fh,66h,73h,63h,2eh,74h,78h,74h,5931h,6557h,3002h       ;開啟fsc.txt失敗。
sTrCh           DB      "TCH  DW "
sSiCh           DB      "SCH  DW "
sDW             DB      "     DW "
szHexFmt        DB      "%xh",0
;*************************************************************************************************************
.DATA?
hOutput         HANDLE  ?       ;標準輸出裝置代碼
hFileTrad       HFILE   ?       ;正體字字頻表的檔案代碼
hFileSimp       HFILE   ?       ;簡體字字頻表的檔案代碼
hFileAsm        HFILE   ?       ;組合語言原始碼，用來存放正體字與簡體字的對照表
hMemText        HGLOBAL ?       ;
hMemAsm         HGLOBAL ?       ;
TradFileSize    DD      ?       ;正體字檔案長度
SimpFileSize    DD      ?
;*************************************************************************************************************
.CODE
;-------------------------------------------------------------------------------------------------------------
;word_to_asm_dw副程式會把pSour所指字串，變成組合語言定義字組的內容。例如「的」的萬國碼是7684h，word_to_asm_dw
;就會把「的」變成「DW  7684h」。word_to_asm_dw不處理BOM，即遇到0feffh，就跳過不處理。
;輸入：pSour－來源字串，每個字佔一字組
;　　　pTarg－存入轉換後的目的位址
;　　　pStrName－用來指定字串名稱
;　　　nLen－pSour所指字串長度，以位元組為單位
;輸出：EAX－在pTarg所指位址中，寫入多少位元組
word_to_asm_dw  PROC    USES esi edi ebx pSour:DWORD,pTarg:DWORD,pStrName:DWORD,nLen:DWORD
                LOCAL   datum:DWORD             ;在ASM檔裏，每行已經處理到第幾筆資料了
                LOCAL   last_address:DWORD      ;pSour所指字串最後位址
                LOCAL   temp_area[16]:BYTE
                mov     ebx,pSour
                mov     edi,pTarg
                mov     last_address,ebx
        .IF WORD PTR [ebx]==0feffh
                add     ebx,2
        .ENDIF
                mov     eax,nLen
                add     last_address,eax
                mov     esi,pStrName
                jmp     move_str
new_line:       mov     esi,OFFSET sDW
move_str:       mov     ecx,SIZEOF sDW
                rep     movsb
                mov     datum,ecx
                xor     eax,eax
next_data:      mov     ax,[ebx]
                INVOKE  wsprintfA,ADDR temp_area,OFFSET szHexFmt,eax
                add     ebx,2
                mov     ecx,eax
                lea     esi,temp_area
                cmp     BYTE PTR [esi],"a"
                jb      arabic_number
                mov     al,"0"
                stosb
arabic_number:  rep     movsb
                cmp     ebx,last_address
                jae     finish
                inc     datum
                cmp     datum,10h
                je      line_feed
                mov     al,","
                stosb
                jmp     next_data
line_feed:      mov     ax,0a0dh
                stosw
                jmp     new_line
finish:         mov     ax,0a0dh
                stosw
                mov     ecx,edi
                sub     ecx,pTarg
                ret
word_to_asm_dw  ENDP
;-------------------------------------------------------------------------------------------------------------
;先讀取「ftc.txt」的內容，存入hMemText裏，再轉換成「DW」，最後把轉換後的純文字存入hMemAsm裏
;再讀取「fsc.txt」的內容，存入hMemText裏，再轉換成「DW」，最後把轉換後的純文字存於上面記憶體區塊之後
main            PROC
                LOCAL   BytesDeal:DWORD
                INVOKE  GetStdHandle,STD_OUTPUT_HANDLE  ;取得標準輸出裝置代碼
                mov     hOutput,eax
;開啟正體字頻表的檔案，並讀取檔案所有內容，存入hMemText記憶體區塊裏，然後關閉該檔案
                INVOKE  CreateFile,OFFSET szTradCh,GENERIC_READ,1,0,3,FILE_ATTRIBUTE_NORMAL,0
        .IF eax==INVALID_HANDLE_VALUE
                mov     edx,OFFSET sMsg01
open_error:     INVOKE  WriteConsole,hOutput,edx,SIZEOF sMsg01/2,ADDR BytesDeal,0
                mov     eax,1
                jmp     exit
        .ENDIF
                mov     hFileTrad,eax
                INVOKE  GetFileSize,hFileTrad,0
                mov     TradFileSize,eax
                add     eax,800h
                and     eax,0fffffff0h
                INVOKE  GlobalAlloc,GPTR,eax
                mov     hMemText,eax
                INVOKE  ReadFile,hFileTrad,hMemText,TradFileSize,ADDR BytesDeal,0
                INVOKE  CloseHandle,hFileTrad
;建立SCH_AND_TCH_TBL.INC檔案，這個檔案包和兩個長字串，TCH與SCH，分別代表正體字與簡體字的字頻表，均以萬國碼
;編碼。
                INVOKE  CreateFile,OFFSET szAsm,GENERIC_READ or GENERIC_WRITE,1,0,CREATE_ALWAYS,80h,0
                mov     hFileAsm,eax
;有5287個正體字，每16個字為一行，有331行；每行120個位元組，要39720個位元組；但39720不能被16整除，故取39728
                INVOKE  GlobalAlloc,GPTR,39728
                mov     hMemAsm,eax
                INVOKE  word_to_asm_dw,hMemText,hMemAsm,OFFSET sTrCh,TradFileSize
                INVOKE  WriteFile,hFileAsm,hMemAsm,ecx,ADDR BytesDeal,0
;開啟簡體字頻表的檔案，並讀取檔案所有內容，存入hMemText記憶體區塊裏，然後關閉該檔案
                INVOKE  CreateFile,OFFSET szSimpCh,GENERIC_READ,1,0,3,FILE_ATTRIBUTE_NORMAL,0
                cmp     eax,INVALID_HANDLE_VALUE
                mov     edx,OFFSET sMsg02
                je      open_error
                mov     hFileSimp,eax
                INVOKE  GetFileSize,hFileSimp,0
                mov     SimpFileSize,eax
                INVOKE  ReadFile,hFileSimp,hMemText,SimpFileSize,ADDR BytesDeal,0
                INVOKE  CloseHandle,hFileSimp
                INVOKE  word_to_asm_dw,hMemText,hMemAsm,OFFSET sSiCh,SimpFileSize
                INVOKE  WriteFile,hFileAsm,hMemAsm,ecx,ADDR BytesDeal,0
                INVOKE  CloseHandle,hFileAsm
                INVOKE  WriteConsole,hOutput,OFFSET sMsg00,(OFFSET sMsg01-OFFSET sMsg00)/2,ADDR BytesDeal,0
                sub     eax,eax
exit:           INVOKE  ExitProcess,eax
main            ENDP
;*************************************************************************************************************
END             main

組譯 ch_to_asm_dw.asm 的方法是，先開啟「命令提示字元」，然後輸入下列指令，也就是黃色字。

C:\Users\wanker>SET INCLUDE=C:\masm32\INCLUDE;%INCLUDE% [Enter]

C:\Users\wanker>SET LIB=C:\masm32\LIB;%LIB% [Enter]

C:\Users\wanker>SET PATH=C:\masm32\BIN;%PATH% [Enter]

C:\Users\wanker>SET ML=/coff /link /SUBSYSTEM:CONSOLE [Enter] →這裏大小寫是不同的，要小心

C:\Users\wanker>E: [Enter]

E:\>CD \HomePage\SOURCE\Win32\FN2TC [Enter] →切換到 ch_to_asm_dw.asm 所在目錄

E:\HomePage\SOURCE\Win32\FN2TC>ml ch_to_asm_dw.asm [Enter]
Microsoft (R) Macro Assembler Version 6.15.8803
Copyright (C) Microsoft Corp 1981-2000.  All rights reserved.

 Assembling: ch_to_asm_dw.asm

*************
UNICODE Build
*************

Microsoft (R) Incremental Linker Version 5.12.8078
Copyright (C) Microsoft Corp 1992-1998. All rights reserved.

/SUBSYSTEM:CONSOLE
"ch_to_asm_dw.obj"
"/OUT:ch_to_asm_dw.exe"

E:\HomePage\SOURCE\Win32\FN2TC>ch_to_asm_dw [Enter]
成功建立SCH_AND_TCH_TBL.INC。
E:\HomePage\SOURCE\Win32\FN2TC>

至此，已經建立好正體字與簡體字的對照表了，下一節，會把這張對照表，加入到簡體字檔名變正體字檔名的程式中。在「ch_to_asm_dw.asm」程式碼中，值得要注意的是第 64行的呼叫 wsprintfA API。注意到「ch_to_asm_dw.asm」是支援萬國碼的程式，其意思是「ch_to_asm_dw.asm」輸出至螢幕，輸入檔案名稱，都是接收或釋出萬國碼編碼的字元。但是輸出的「SCH_AND_TCH_TBL.INC」內容，卻必須要能為 ml.exe 組譯器接受的 ANSI 編碼的字元，所以必須用呼叫 wsprintfA API，不可呼叫 wsprintW。

簡體字檔名變正體字檔名：FN2TC.ASM

FN2TC 使用方法

有了正體字與簡體字的對照表後，就可以開始著手撰寫把簡體字的檔名，轉換成正體字檔名的程式了，小木偶稱此程式為 FN2TC.ASM ( FileName To Traditional Chinese )。先看執行畫面，再來說說 FN2TC 的使用方法，最後小木偶會列出原始碼並解說。

FN2TC 是控制台程式，必須在「命令提示字元」下執行，您可以點選「開始」→「附屬應用程式」→「命令提示字元」，就能開啟「命令提示字元」，然後切換到 FN2TC 所在的子目錄，再輸入下面指令：

FN2TC [-C] [driver:][path][\filename]

FN2TC 最多可以接兩個參數，如果超過，就會忽略超過的參數，而不會出錯，程式也能正常執行。第一個參數是「-C」，兩旁加上一對中括弧，代表這個參數可以省略，實際上在命令提示列輸入指令時，不可輸入中括弧。這個參數不區別大小寫，所以用「-c」也可以。如果使用者有輸入「-C」參數，代表 FN2TC 會在螢幕上列出含簡體字的原檔名，並詢問使用者確定是否改名。輸入「Y」鍵代表確定要改名；輸入「N」鍵代表不改名。如果省略「-C」參數，FN2TC 不會發出詢問，直接改名。

第二個參數是「driver:path\filename」，是讓使用者輸入要改名的路徑或是檔案。第二個參數也加了中括弧，代表可以省略，如果「-C」與「driver:path\filename」兩個參數都省略時，FN2TC 會印出使用方法。但不能僅輸入第一個參數，而省略第二個參數，如果這樣，FN2TC 會印出「未輸入檔名」的錯誤訊息。第二個參數中的 driver: 代表磁碟機名稱；path 代表路徑；filename 代表檔案名稱。[driver:][path][\filename] 的寫法，是以前 DOS 時代對檔案的寫法。driver:path\filename，可能有底下三種情形：

  1. 磁碟機名、絕對路徑、檔名全都表示出來。用「driver:path\filename」方式表示檔案時，只有最後一項可以含有萬用字元 ( 萬用字元是指「*」或「?」)，前面的都不能含萬用字元。有關目錄、路徑、檔案，以及絕對路徑、相對路徑及萬用字元的說明，請參閱註一。看底下的三個例子，並參考右圖中，小木偶所使用電腦的「E:」磁碟機部分樹狀目錄：

    FN2TC E:\HomePage\SOURCE\体育.txt  →把 E:\HomePage\SOURCE\体育.txt 改名成正體字「E:\HomePage\SOURCE\體育.txt」
FN2TC E:\HomePage\SOURCE\FN*.*  →把 E:\HomePage\SOURCE\ 目錄內的所有以 FN 開頭的檔案及子目錄都改名成正體字
FN2TC E:\HomePage\SOURCE  →把 E:\HomePage\SOURCE\ 目錄內的所有檔案及子目錄都改名成正體字，相當於「FN2TC E:\HomePage\SOURCE\*.*」

    像上面三個例子，都是由「磁碟機名」下的根目錄開始，往下指定一層一層的子目錄，直到檔名為止的方式，稱為「絕對路徑」。這種方式，能完整的表示檔名，第一個例子就是這種情形。絕對路徑也能搭配含有萬用字元的檔名，第二個例子就是這種情形。較特別的是第三種情形，在第三個例子裏，FN2TC 會檢查「SOURCE」是目錄還是檔案，如果是目錄，那麼就相當於輸入「FN2TC E:\HomePage\SOURCE\*.*」，亦即把「E:\HomePage\SOURCE」目錄裏的所有檔案，都改成正體字；如果是檔案，因為「SOURCE」不含簡體字，因此無作用。事實上，FN2TC 會檢查最後一項是檔案還是目錄，如果是檔案，就將此檔案改成正體字；如果是目錄，就把此目錄下的所有檔案改成正體字。第一種情形中的「体育.txt」也能當成子目錄，如果真的是子目錄，FN2TC 也能把「E:\HomePage\SOURCE\体育.txt」子目錄下的所有檔案名改成正體字，與「E:\HomePage\SOURCE\体育.txt\*.*」是一樣的意思，就如同第三種情形。換句話說，如果使用者輸入的第二個參數是「絕對路徑及檔名」，檔名如果省略，就是要處理該路徑下的所有檔名。

  2. 相對路徑及檔名。從某個磁碟的現在目錄開始，往上層或下層的子目錄，一層一層的指向某個檔案，這種表示檔案的方式，稱為相對路徑。例如，先在「命令提示字元」下輸入「CD E:\HomePage\SOURCE」，那麼系統就會把「E:」磁碟機現在的目錄視為「E:\HomePage\SOURCE」。接下來輸入「FN2TC E:Win32」，這樣的話，FN2TC 就會把「E:\HomePage\SOURCE\Win32」目錄內的所有檔案及子目錄都改名成正體字。像「E:Win32」這種路徑就叫做相對路徑。

    前面的例子，是由現在所在目錄往下層子目錄的方向延伸，那是否可以表示向上層子目錄呢？可以的。必須用「..」，「..」就代表上一層的目錄。例如，「E:」磁碟機現在目錄是「E:\HomePage\SOURCE」。使用者輸入「FN2TC E:..」，那麼 FN2TC 就會處理「E:\HomePage\」子目錄裏的檔案。

  3. 只輸入磁碟機名稱。這種情形，FN2TC 就會到該磁碟機目前的目錄去，找到含有簡體字的檔名，改成正體字。例如，「E:」磁碟機現在目錄是「E:\HomePage\SOURCE」，而使用者輸入「FN2TC E:」，FN2TC 就會把「E:\HomePage\SOURCE」目錄內含有簡體字的檔名或子目錄名，改成正體字。另一個例子，像上圖中，輸入「CD D:\TEST」，切換「D:」磁碟機的現在目錄為「D:\TEST」。然後輸入「FN2TC D:」，就是把「D:\TEST」目錄內的檔名及子目錄名，含有簡體字的，改成正體字。事實上，FN2TC 也會檢查「D:\TEST」是否為目錄抑或檔案，跟前兩種情形一樣。

或許上面的說明，有點兒複雜。您可以想成，FN2TC 會檢查第二個參數的最後一項是目錄還是檔案，如果是目錄，就會把該目錄裏面的所有檔案名稱改成正體字；如果是檔案，就會把該檔案的檔名轉換成正體字。另外如果是檔案名稱，可以使用萬用字元，這時候，FN2TC 就會把符合該萬用字元的檔名改成正體字。這樣就簡單多了。

FN2TC 原始碼

底下是 FN2TC 的原始碼：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
;FN2TC.ASM會把指定目錄或檔案中，所有符合的檔名中，含有的簡體字轉變成正體字。
;使用方法：FN2TC [-C] [path]
;　　　　　參數：-C：FN2TC會列出每一個檔名，使用者要按Y或N鍵，以確定是否改成正體字。Y表示改名，N表示沿用原名
;　　　　　　　　　　若省略「-C」，FN2TC不會詢問，直接改名。（C是confirm的意思，用小寫也行）
;　　　　　參數：path：路徑及名稱，可以包含檔名，檔名也可以包含萬用字元。如果包含檔名，就只改變符合的檔名。如
;　　　　　　　　　　　果只是路徑名稱，就會改變此路徑所在的子目錄或檔名，但不含更下一層的子目錄；如果此路徑包
;　　　　　　　　　　　含檔名，那就僅更改符合的檔名。
;範例：FN2TC "D:\HomePage" --> 會把"C:\HomePage"目錄內所有子目錄名及檔名改成正體字
;　　　FN2TC "D:\HomePage\*.html" --> 會把"C:\HomePage"目錄內，所有副檔名為.html的檔案改名成正體字
;　　　FN2TC D:\HomePage\ch*.html --> 會把"C:\HomePage"目錄內，所有副檔名為.html且檔名前兩字為ch的檔案改名
;FN2TC.ASM為命令列執行的程式，亦即控制台程式。
                OPTION  CASEMAP:NONE
                .586
                .MODEL  FLAT,STDCALL
__UNICODE__     EQU     1       ;支援UNICODE
INCLUDE         WINDOWS.INC
INCLUDE         KERNEL32.INC
INCLUDE         USER32.INC
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB

;路徑名\檔案名的資料結構體（PathFileData）
PATHFILEDATA    STRUC
pFullname       DD      ?       ;完整檔名起始位址，完整檔名包含磁碟機名、路徑名、主檔名及副檔名
pMainFilename   DD      ?       ;主檔名位址
cChar           DD      ?       ;完整檔名的字元數，不含結尾的NULL
PATHFILEDATA    ENDS
;*************************************************************************************************************
.CONST
;SCH_AND_TCH_TBL.INC是簡體中文（Simplified Chinese）與正體中文（Traditional Chinese）對照資料（Data）表。其內
;容為兩個長字串，TCH和SCH，分別代表正體字、簡體字的萬國碼編碼。TCH的第n個字組所代表正體字，就是SCH第n個字組的
;簡體字。此表為《一○○至一○四年常用語詞調查報告書》的附錄18，民國104年常用語詞調查語料統計分析字頻表.xls，其內
;共收錄5289字，但除去「∼」及4837h兩字。因此TCH有5287個字組，SCH也有5287個字組。
INCLUDE         SCH_AND_TCH_TBL.INC
n_words=(OFFSET SCH-OFFSET TCH)/2       ;n_words＝5287h＝TCH字組個數＝SCH字組個數
sUsage          DW      46h,4eh,32h,54h,43h,6703h,628ah,542bh,6709h,7c21h,9ad4h,5b57h   ;FN2TC會把含有簡體字
                DW      7684h,8defh,5f91h,6216h,6a94h,540dh,0ff0ch,6539h,6210h,6b63h    ;的路徑或檔名，改成正
                DW      9ad4h,5b57h,0dh,0ah,4f7fh,7528h,65b9h,6cd5h,0ff1ah,46h,4eh      ;體字使用方法：FN
                DW      32h,54h,43h,20h,5bh,2dh,43h,5dh,20h,5bh,70h,61h,74h,68h,5dh     ;2TC [-C] [path]
                DW      0dh,0ah,3000h,3000h,2dh,43h,0ff1ah,46h,4eh,32h,54h,43h,6703h    ;　　-C：FN2TC會
                DW      5217h,51fah,6bcfh,4e00h,500bh,6a94h,540dh,0ff0ch,4f7fh,7528h    ;列出每一個檔名，使用
                DW      8005h,8981h,6309h,59h,6216h,4eh,9375h,0ff0ch,4ee5h,78bah        ;者要按Y或N鍵，以確
                DW      5b9ah,662fh,5426h,6539h,6210h,6b63h,9ad4h,5b57h,3002h,59h       ;定是否改成正體字。Y
                DW      8868h,0dh,0ah,3000h,3000h,3000h,3000h,793ah,6539h,540dh,0ff0ch  ;表　　　　示改名，
                DW      4eh,8868h,793ah,6cbfh,7528h,539fh,540dh,3002h,82e5h,7701h       ;N表示沿用原名。若省
                DW      7565h,300ch,2dh,43h,300dh,0ff0ch,46h,4eh,32h,54h,43h,4e0dh      ;略「-C」，FN2TC不
                DW      6703h,8a62h,554fh,0ff0ch,76f4h,63a5h,6539h,540dh,3002h,0ff08h   ;會詢問，直接改名。（
                DW      43h,662fh,0dh,0ah,3000h,3000h,3000h,3000h,63h,6fh,6eh,66h       ;C是　　　　conf
                DW      69h,72h,6dh,7684h,610fh,601dh,0ff0ch,7528h,5c0fh,5bebh,4e5fh    ;irm的意思，用小寫也
                DW      884ch,0ff09h,0dh,0ah,3000h,3000h,70h,61h,74h,68h,0ff1ah,8defh   ;行）　　path：路
                DW      5f91h,540dh,7a31h,0ff0ch,53efh,4ee5h,5305h,542bh,6a94h,540dh    ;徑名稱，可以包含檔名
                DW      0ff0ch,6a94h,540dh,4e5fh,53efh,4ee5h,5305h,542bh,842ch,7528h    ;，檔名也可以包含萬用
                DW      5b57h,5143h,3002h,5982h,679ch,5305h,542bh,6a94h,540dh,0ff0ch    ;字元。如果包含檔名，
                DW      5c31h,53eah,0dh,0ah,3000h,3000h,3000h,3000h,3000h,6539h,8b8ah   ;就只　　　　　改變
                DW      7b26h,5408h,7684h,6a94h,540dh,3002h,5982h,679ch,53eah,662fh     ;符合的檔名。如果只是
                DW      8defh,5f91h,540dh,7a31h,0ff0ch,5c31h,6703h,6539h,8b8ah,6b64h    ;路徑名稱，就會改變此
                DW      8defh,5f91h,5167h,7684h,6240h,6709h,5b50h,76eeh,9304h,53cah     ;路徑內的所有子目錄及
                DW      6a94h,0dh,0ah,3000h,3000h,3000h,3000h,3000h,6848h,540dh,7a31h   ;檔　　　　　案名稱
                DW      0ff0ch,4f46h,4e0dh,542bh,66f4h,4e0bh,4e00h,5c64h,7684h,5b50h    ;，但不含更下一層的子
                DW      76eeh,9304h,3002h,0dh,0ah,7bc4h,4f8bh,0ff1ah,0dh,0ah,46h        ;目錄。範例：F
                DW      4eh,32h,54h,43h,20h,22h,43h,3ah,5ch,6dh,61h,73h,6dh,33h,32h     ;N2TC "C:\masm32
                DW      22h,3000h,3000h,3000h,3000h,20h,628ah,43h,3ah,5ch,6dh,61h       ;"　　　　 把C:\ma
                DW      73h,6dh,33h,32h,76eeh,9304h,5167h,6240h,6709h,5b50h,76eeh       ;sm32目錄內所有子目
                DW      9304h,540dh,53cah,6a94h,540dh,6539h,6210h,6b63h,9ad4h,5b57h     ;錄名及檔名改成正體字
                DW      0dh,0ah,46h,4eh,32h,54h,43h,20h,22h,43h,3ah,5ch,6dh,61h,73h     ;FN2TC "C:\mas
                DW      6dh,33h,32h,5ch,2ah,2eh,68h,74h,6dh,6ch,22h,3000h,628ah,43h     ;m32\*.html"　把C
                DW      3ah,5ch,6dh,61h,73h,6dh,33h,32h,76eeh,9304h,5167h,6240h,6709h   ;:\masm32目錄內所有
                DW      526fh,6a94h,540dh,70bah,2eh,68h,74h,6dh,6ch,7684h,6a94h,6848h   ;副檔名為.html的檔案
                DW      6539h,6210h,6b63h,9ad4h,5b57h,13,10,46h,4eh,32h,54h,43h,20h,43h ;改成正體字 FN2TC C
                DW      3ah,5ch,6dh,61h,73h,6dh,33h,32h,5ch,63h,68h,2ah,2eh,68h,74h,6dh ;:\masm32\ch*.htm
                DW      6ch,3000h,628ah,43h,3ah,5ch,6dh,61h,73h,6dh,51,50,76eeh,9304h   ;l　把C:\masm32目錄
                DW      5167h,6240h,6709h,526fh,6a94h,540dh,70bah,2eh,68h,74h,6dh,6ch   ;內所有副檔名為.html
                DW      4e14h,6a94h,540dh,524dh,5169h,5b57h,70bah,99,68h,13,10,3000h    ;且檔名前兩字為ch　
                DW      3000h,3000h,3000h,3000h,3000h,3000h,3000h,3000h,3000h,3000h     ;　　　　　　　　　　
                DW      3000h,3000h,7684h,6a94h,6848h,6539h,6210h,6b63h,9ad4h,5b57h     ;　　的檔案改成正體字
sError01        DW      53c3h,6578h,932fh,8aa4h,3002h                                   ;參數錯誤。
sError02        DW      672ah,8f38h,5165h,6a94h,540dh,3002h                             ;未輸入檔名。
sError03        DW      6a94h,540dh,542bh,6709h,4e0dh,5408h,6cd5h,5b57h,5143h,3002h     ;檔名含有不合法字元。
sError04        DW      932fh,8aa4h,7684h,8defh,5f91h,540dh,6216h,6a94h,540dh,3002h     ;錯誤的路徑名或檔名。
sError05        DW      627eh,4e0dh,5230h,6307h,5b9ah,7684h,6a94h,6848h,3002h           ;找不到指定的檔案。
sError06        DW      767ch,751fh,932fh,8aa4h,0ff01h                                  ;發生錯誤！
szFmtRename     DW      25h,73h,2192h,25h,73h,13,10,0                                   ;%s → %s
szFmtConfirm    DW      662fh,5426h,628ah,300ch,25h,73h,300dh,6539h,540dh,70bah,300ch   ;是否把「%s」改名為「
                DW      25h,73h,300dh,28h,79h,2fh,6eh,29h,0ff1fh,0h                     ;%s」(y/n)？
szFmtExist      DW      300ch,25h,73h,300dh,5df2h,5b58h,5728h,0ff0ch,300ch,25h,73h      ;「%s」已存在，「%s
                DW      300dh,4e0dh,6539h,540dh,3002h,13,10,0                           ;」不改名。
szFmtChgFile    DW      542bh,7c21h,9ad4h,5b57h,7684h,6a94h,540dh,6709h,25h,64h,500bh   ;含簡體字的檔名有%d個
                DW      0ff0ch,5be6h,969bh,6539h,540dh,7684h,6a94h,6848h,6709h,25h      ;，實際改名的檔案有%
                DW      64h,500bh,3002h,0h                                              ;d個。
szFmtDir        DW      76eeh,9304h,0ff1ah,25h,73h,13,10,0                              ;目錄：%s
;*************************************************************************************************************
.DATA
hOutput         DD      ?       ;標準輸出裝置代碼
hInput          DD      ?       ;標準輸出裝置代碼
pParam          DD      ?       ;參數起始位址
fConfirm        DD      ?       ;使用者是否有輸入「-C」參數。有輸入，bConfirm＝1；沒輸入bConfirm＝0
pfd   PATHFILEDATA      <>
w32fd WIN32_FIND_DATA   <>
hFind           DD      ?
old_filename    DW      MAX_PATH DUP (?)
new_filename    DW      MAX_PATH DUP (?)
buffer          DW      MAX_PATH DUP (?)
nChgFileName    DD      0       ;已改名的檔案個數
nFitFileName    DD      0       ;符合條件且含有簡體字檔名的檔案個數
CharWritten     DD      ?
;*************************************************************************************************************
.CODE
;-------------------------------------------------------------------------------------------------------------
;get_parameter副程式用來分析使用者在命令列輸入參數。pCL是命令列位址，pPFD是PATHFILEDATA結構體位址。
get_parameter   PROC    USES esi edi ebx pCL:DWORD,pPFD:DWORD
;取得使用者輸入的參數，FN2TC的參數最多有兩項，「-C」及路徑名。get_parameter副程式分析使用者輸入的參數，然後把
;FindFirstFile可接受的路徑及檔名記錄在PATHFILEDATA結構體內。
;輸入：pCL－使用者在命令列輸入的參數位址
;　　　pPFD－PATHFILEDATA結構體位址。返回時，get_parameter在此位址的PATHFILEDATA結構體，填入適當的資料
;輸出：進位旗標＝CY，表示錯誤，EAX＝錯誤碼
;　　　　　EAX＝0，使用者沒輸入任何參數
;　　　　　EAX＝1，參數錯誤，輸入不是「-C」或「-c」的參數
;　　　　　EAX＝2，只輸入「-C」或「-c」，且未輸入檔名
;　　　　　EAX＝3，路徑名或檔名含有不合法的字元
;　　　　　EAX＝4，錯誤的路徑名或檔名（邏輯錯誤，例如有兩個磁碟機名等等）
;　　　　　EAX＝5，找不到指定的檔案
;　　　　　EAX＝6，其他錯誤
;　　　進位旗標＝NC，表示正確，PATHFILEDATA結構體已填入適當資料
;　　　　　EAX＝使用者是否輸入「-C」參數，有輸入，EAX＝1；沒輸入，EAX＝0
                LOCAL   confirm:DWORD   ;暫時記錄使用者是否輸入「-C」參數，有輸入，confirm為一；否則為零
                LOCAL   driver:DWORD    ;暫時記錄磁碟機個數
                LOCAL   wildcard:DWORD  ;記錄萬用字元個數
                LOCAL   temp_name[MAX_PATH]:WORD
                ASSUME  esi:PTR PATHFILEDATA
                cld
;跳過「fn2tc」。在命令提示字元輸入程式執行時，系統會自動再參數列加上執行檔及其所在路徑名稱，要先忽略它。
;因此要先找到兩個「"」之外的空白，空白之後才是使用者真正輸入的參數。
                xor     edx,edx ;EDX＝「"」個數
                mov     esi,pPFD
                mov     ebx,pCL
                mov     [esi].pMainFilename,edx
                mov     [esi].cChar,edx
                mov     confirm,edx
                mov     driver,edx
                mov     wildcard,edx
g_p_00:         cmp     WORD PTR [ebx],22h      ;「"」字元
                je      g_p_02
                cmp     WORD PTR [ebx],20h      ;空白字元
                je      g_p_03
                cmp     WORD PTR [ebx],0
                je      g_p_04
g_p_01:         add     ebx,2
                jmp     g_p_00
g_p_02:         inc     edx
                jmp     g_p_01
;遇到空白時，檢查EDX是否為奇數。如果EDX為奇數，表示現在已遇到奇數個「"」，亦即此空白在兩個「"」之間，跳到
;g_p_01處繼續尋找兩個「"」之外的空白；如果EDX是偶數，表示此空白是在兩個「"」之外，表示一個參數已結束
g_p_03:         test    edx,1
                jnz     g_p_01
;刪去「fn2tc」與參數之間的空白或跳格字元。
        .WHILE (WORD PTR [ebx]==20h)||(WORD PTR [ebx]==9)
                add     ebx,2
        .ENDW
                cmp     WORD PTR [ebx],0
                jne     g_p_06
g_p_04:         sub     eax,eax ;如果是0，表示使用者除了空白或跳格字元外，沒有輸入任何東西
g_p_05:         stc
                jmp     g_p_30
;EBX＝第一個參數位址。檢查是否為「-」，如果不是「-」，表示使用者沒有輸入「-C/c」，表示不須確認
g_p_06:         cmp     WORD PTR [ebx],2dh      ;「-」字元
                jne     g_p_14
        .IF (WORD PTR [ebx+2]==43h)||(WORD PTR [ebx+2]==63h)    ;「C」或「c」字元
                mov     confirm,1
                add     ebx,4
                cmp     WORD PTR [ebx],"  "
                je      g_p_08
                cmp     WORD PTR [ebx],9
                jne     g_p_07
        .ELSE
g_p_07:         mov     eax,1   ;錯誤碼，EAX＝1，參數錯誤，輸入不是「-C」或「-c」的參數
                jmp     g_p_05
        .ENDIF
;已處理完使用者是否有「-C」參數，跳過空白或跳格字元
g_p_08:         cmp     WORD PTR [ebx]," "
                je      g_p_10
                cmp     WORD PTR [ebx],9
                je      g_p_10
                cmp     WORD PTR [ebx],0
                jne     g_p_14
g_p_09:         mov     eax,2   ;錯誤碼，EAX＝2，只輸入「-C」或「-c」，且未輸入檔名
                jmp     g_p_05
g_p_10:         add     ebx,2
                jmp     g_p_08
g_p_11:         mov     eax,3   ;錯誤碼，EAX＝3，路徑名或檔名含有不合法的字元
                jmp     g_p_05
;處理NULL字元。先檢查使用者是否在「-C」之後沒有輸入路徑，如果是的話就跳至g_p_09
g_p_12:         cmp     ebx,[esi].pFullname
                jz      g_p_09
                test    edx,1
                je      g_p_23  ;若EDX＝1，表示只輸入奇數個「"」
g_p_13:         mov     eax,4   ;錯誤碼，EAX＝4，錯誤的路徑名或檔名（邏輯錯誤，例如有兩個磁碟機名等等）
                jmp     g_p_05
;執行到此，已經檢查過使用者是否輸入了「-C」參數，也已跳過其後的空白或跳格字元，此刻EBX指向之後不是空白或跳
;格字元的位址，即將開始要檢查路徑名稱，並除去「"」字元。除去的方法是把所有字元再存回EDI所指位址，而一開始，
;EBX和EDI都指向同樣位址。如果遇到「"」，就不存回。同時，也檢查萬用字元、「:」的個數，及檢查有無不合法的字元
g_p_14:         mov     [esi].pFullname,ebx
                mov     edi,ebx
                sub     edx,edx ;EDX＝記錄「"」個數
g_p_15:         movzx   eax,WORD PTR [ebx]
                or      ax,ax
                jz      g_p_12
                cmp     ax,20h
                jb      g_p_11  ;如果比20h小，發生錯誤，跳至g_p_11。
                je      g_p_22  ;如果是空白字元，跳至g_p_22
                cmp     ax,3ch  ;「<」
                je      g_p_11
                cmp     ax,3eh  ;「>」
                je      g_p_11
                cmp     ax,7ch  ;「|」
                je      g_p_11
                cmp     ax,22h  ;「"」
                je      g_p_20
                cmp     ax,3fh  ;「?」
                je      g_p_18
                cmp     ax,2ah  ;「*」
                je      g_p_18
                cmp     ax,5ch  ;「\」
                je      g_p_19
                cmp     ax,3ah  ;「:」
                je      g_p_21
g_p_16:         stosw
g_p_17:         add     ebx,2
                jmp     g_p_15
g_p_18:         mov     wildcard,1
                jmp     g_p_16
;處理「\」字元。首先，先檢查路徑名是否有萬用字元，如果有的話，就發生錯誤，跳至g_p_13處。檢查好後，因為有
;「\」字元，代表使用者所輸入的參數，包含路徑名稱，因此把pfd結構體的fPath欄位設為一。
g_p_19:         cmp     wildcard,1      ;若wildcard＝1，表示在「\」字元之前有出現萬用字元，
                je      g_p_13          ;故發生錯誤
                jmp     g_p_16
;處理「"」。使EDX增加一，但不存於EDI所指位址，這樣就會刪去「"」
g_p_20:         inc     edx
                jmp     g_p_17
;處理磁碟機名的程式。此程式片段是由上面檢查AX＝「:」字元處跳躍而來的。
g_p_21:         inc     driver
                cmp     driver,1;磁碟機名最多只能有一個，否則就發生錯誤
                jne     g_p_13
                mov     ecx,edi
                sub     ecx,[esi].pFullname
                cmp     ecx,2   ;如果有磁碟機名的話，必定在完整路徑名的最前面，也就是最低位址的兩個字元。因
                je      g_p_16  ;此把EDI減去完整路徑起始位址應該要等於2，如果不是2，表示磁碟機名不在最前面
                jmp     g_p_13  ;，表示發生錯誤，跳到g_p_13
;處理空白。先檢查此空白是否在兩個「"」之間，如果是的話，表示此空白為路徑名或檔名的一部分，跳至g_p_16存入EDI
;所指位址；如果不是，表示路徑名已結束了。
g_p_22:         test    edx,1
                jnz     g_p_16
g_p_23:         mov     WORD PTR [edi],0
;檢查是否有萬用字元，如果有的話，表示輸入的參數為檔案，否則檢查是否為目錄
                cmp     wildcard,1
                je      g_p_27
                INVOKE  GetFileAttributes,[esi].pFullname
                cmp     eax,INVALID_FILE_ATTRIBUTES
                je      g_p_25
                test    eax,FILE_ATTRIBUTE_DIRECTORY
                jz      g_p_27
;使用者輸入的參數為目錄，獲得完整路徑名，並在其後加上「\*.*,0」或「*.*,0」
                INVOKE  GetFullPathName,[esi].pFullname,SIZEOF temp_name/2,ADDR temp_name,0
                lea     edx,temp_name
                mov     ecx,eax
                mov     edi,[esi].pFullname
g_p_24:         movzx   eax,WORD PTR [edx]
                stosw
                add     edx,2
                loop    g_p_24
        .IF ax!=5ch
                mov     ax,5ch  ;若最後一個字元不為「\」，FN2TC會自行加上
                stosw
        .ENDIF
                mov     [esi].pMainFilename,edi
                mov     eax,2e002ah     ;*.
                stosd
                mov     eax,2ah         ;*,0
                stosd
                mov     ecx,edi
                sub     ecx,2
                sub     ecx,[esi].pFullname
                shr     ecx,1
                mov     [esi].cChar,ecx
                jmp     g_p_29
g_p_25:         call    GetLastError
                cmp     eax,ERROR_FILE_NOT_FOUND
                jne     g_p_26
                mov     eax,5   ;錯誤碼，EAX＝5，找不到指定的檔案
                jmp     g_p_05
g_p_26:         mov     eax,6   ;錯誤碼，EAX＝6，其他錯誤
                jmp     g_p_05
;使用者輸入的是檔案名稱，有可能包含萬用字元。
g_p_27: INVOKE  GetFullPathName,[esi].pFullname,SIZEOF temp_name/2,ADDR temp_name,ADDR [esi].pMainFilename
                lea     edx,temp_name
                mov     ecx,eax
                mov     [esi].cChar,eax
                sub     [esi].pMainFilename,edx ;[esi].pMainFilename＝完整檔名位址到主檔名位址，有幾個位元組
                mov     edi,[esi].pFullname
                add     [esi].pMainFilename,edi
g_p_28:         movzx   eax,WORD PTR [edx]
                stosw
                add     edx,2
                loop    g_p_28
                mov     [edi],cx
g_p_29:         mov     eax,confirm
                clc
g_p_30:         ret
                ASSUME  esi:NOTHING
get_parameter   ENDP
;-------------------------------------------------------------------------------------------------------------
main            PROC
                LOCAL   pSrMainFn:LPSTR ;原來檔案的主檔名位址
                LOCAL   pTrMainFn:LPSTR ;改名後的主檔名位址
                LOCAL   fChanged:DWORD  ;某個檔名中，有幾個字元改成正體字
;取得標準輸出、輸入裝置的代碼，並分析使用者輸入的參數。
                INVOKE  GetStdHandle,STD_OUTPUT_HANDLE  ;取得標準輸出裝置代碼
                mov     hOutput,eax
                INVOKE  GetStdHandle, STD_INPUT_HANDLE  ;取得標準輸入裝置代碼
                mov     hInput,eax
                call    GetCommandLine
                mov     pParam,eax
                INVOKE  get_parameter,pParam,OFFSET pfd
                jnc     no_error
        .IF eax==0
                mov     edx,OFFSET sUsage
                mov     ecx,OFFSET sError01-OFFSET sUsage
        .ELSEIF eax==1
                mov     edx,OFFSET sError01
                mov     ecx,SIZEOF sError01
        .ELSEIF eax==2
                mov     edx,OFFSET sError02
                mov     ecx,SIZEOF sError02
        .ELSEIF eax==3
                mov     edx,OFFSET sError03
                mov     ecx,SIZEOF sError03
        .ELSEIF eax==4
                mov     edx,OFFSET sError04
                mov     ecx,SIZEOF sError04
        .ELSEIF eax==5
not_find:       mov     edx,OFFSET sError05      
                mov     ecx,SIZEOF sError05
        .ELSE
                mov     edx,OFFSET sError06
                mov     ecx,SIZEOF sError06
        .ENDIF
right_shift:    shr     ecx,1
                INVOKE  WriteConsole,hOutput,edx,ecx,ADDR CharWritten,0
                xor     eax,eax
                jmp     exit
;開始要把含有簡體字的檔名改成正體字。因為FindFirstFile傳回來的資料裏，只有檔案名稱，因此要先把路徑名存入
;old_filename與new_filename兩字串裏，並把這兩個字串中的主檔名起始位址，分別存於pSrMainFn與pTrMainFn變數裏
no_error:       mov     fConfirm,eax
                push    ebx
                lea     edx,old_filename
                push    esi
                lea     ecx,new_filename
                push    edi
                mov     esi,pfd.pFullname
next_char:      cmp     esi,pfd.pMainFilename
                je      find_first
                lodsw
                mov     [ecx],ax
                mov     [edx],ax
                add     ecx,2
                add     edx,2
                jmp     next_char
find_first:     mov     pSrMainFn,edx
                mov     pTrMainFn,ecx
;在螢幕上印出工作目錄（亦即要改檔名的檔案所在目錄）
                mov     WORD PTR [edx],0
                INVOKE  wsprintf,OFFSET buffer,OFFSET szFmtDir,OFFSET old_filename
                INVOKE  WriteConsole,hOutput,OFFSET buffer,eax,OFFSET CharWritten,0
                INVOKE  FindFirstFile,pfd.pFullname,OFFSET w32fd
                cmp     eax,INVALID_HANDLE_VALUE
                je      not_find
                mov     hFind,eax
;把一個符合使用者輸入的檔案名稱（此檔案名稱不含路徑名，存放於w32fd.cFileName欄位裏），填入old_filename、
;new_filename兩字串裏，old_filename的主檔名與w32fd.cFileName一樣，new_filename是用來存放更改後正體中文的檔名
;的字串。在no_error到find_first之間的程式片段，用來儲存old_filename與new_filename的路徑名，而要更改的主檔名
;起始位址，與更改後的主檔名起始位址，分別存放在pSrMainFn與pTrMainFn兩個變數裏
next_file:      lea     esi,w32fd.cFileName
                mov     ebx,pSrMainFn   ;EBX＝原來的檔名起始位址（如有路徑，在EBX所指位址之前）
                mov     edx,pTrMainFn   ;EDX＝後來的檔名起始位址（如有路徑，在EDX所指位址之前）
                mov     fChanged,0
char_in_fn:     lodsw
                mov     [ebx],ax
                add     ebx,2
                cmp     ax,4e00h        ;若原來檔案的檔名所含的字元，在4e00h∼9fefh之間，才是在中
                jb      not_CJK_UI      ;日韓統一表意文字的中文字。萬國碼的中日韓統一表意文字，正
                cmp     ax,9fefh        ;體字與簡體字是夾雜編碼。在這範圍內的字元，才須處理。
                ja      not_CJK_UI
                mov     edi,OFFSET SCH
                mov     ecx,n_words
                repne   scasw
                jecxz   not_CJK_UI      ;如果ECX＝0，表示沒有對應的正體字，只好用原來的字代替
                sub     edi,OFFSET SCH
                add     edi,OFFSET TCH
                cmp     ax,[edi-2]      ;若AX＝[EDI-2]，表示正體字與簡體字的萬國碼相同，也不須
                je      not_CJK_UI      ;做處理，直接跳到not_CJK_UI處。
                mov     ax,[edi-2]
                inc     fChanged
not_CJK_UI:     mov     [edx],ax
                add     edx,2
                or      ax,ax
                jnz     char_in_fn
                cmp     fChanged,0      ;如果fChanged為零，表示這個檔案名稱中，沒有簡體字需要變正體字
                jz      a_find_over
                inc     nFitFileName
                cmp     fConfirm,0      ;如果使用者有輸入「-C」，表示要由使用者確認是否改檔名
                jz      rename          ;如果使用者有輸入「-C」，則fConfirm＝1
input_again:    INVOKE  wsprintf,OFFSET buffer,OFFSET szFmtConfirm,pSrMainFn,pTrMainFn
                INVOKE  WriteConsole,hOutput,OFFSET buffer,eax,OFFSET CharWritten,0
                INVOKE  ReadConsole,hInput,OFFSET buffer,3,OFFSET CharWritten,0
                lea     ebx,buffer
                cmp     WORD PTR [ebx],4eh      ;「N」
                je      a_find_over
                cmp     WORD PTR [ebx],6eh      ;「n」
                je      a_find_over
                cmp     WORD PTR [ebx],59h      ;「Y」
                je      rename
                cmp     WORD PTR [ebx],79h      ;「y」
                jne     input_again
rename:         INVOKE  MoveFile,OFFSET old_filename,OFFSET new_filename
                or      eax,eax
                jnz     success_rename
                call    GetLastError
                cmp     eax,ERROR_ALREADY_EXISTS;檢查檔案是否存在
                jne     finish
                INVOKE  wsprintf,OFFSET buffer,OFFSET szFmtExist,pTrMainFn,pSrMainFn
                jmp     pnt_msg
success_rename: inc     nChgFileName
                INVOKE  wsprintf,OFFSET buffer,OFFSET szFmtRename,pSrMainFn,pTrMainFn
pnt_msg:        INVOKE  WriteConsole,hOutput,OFFSET buffer,eax,OFFSET CharWritten,0
a_find_over:    INVOKE  FindNextFile,hFind,OFFSET w32fd
                or      eax,eax
                jnz     next_file
finish:         INVOKE  FindClose,hFind
                pop     edi
                pop     esi
                pop     ebx
                INVOKE  wsprintf,OFFSET buffer,OFFSET szFmtChgFile,nFitFileName,nChgFileName
                INVOKE  WriteConsole,hOutput,OFFSET buffer,eax,OFFSET CharWritten,0
                INVOKE  CloseHandle,hOutput
                INVOKE  CloseHandle,hInput
exit:           INVOKE  ExitProcess,eax ;EAX＝返回系統的錯誤碼，若EAX＝0，表示錯誤；若EAX＝1，表示正常
main            ENDP
;*************************************************************************************************************
END             main
;https://www.pconlife.com/

FN2TC 是控制台程式，並非一般視窗程式。組譯方法與視窗程式稍有不同，差別在於連結時，須下達「/SUBSYSTEM:CONSOLE」參數。組譯與連結過程如下：

E:\HomePage\SOURCE\Win32\FN2TC>SET INCLUDE=C:\masm32\INCLUDE;%INCLUDE% [Enter]

E:\HomePage\SOURCE\Win32\FN2TC>SET LIB=C:\masm32\LIB;%LIB% [Enter]

E:\HomePage\SOURCE\Win32\FN2TC>SET PATH=C:\masm32\BIN;%PATH% [Enter]

E:\HomePage\SOURCE\Win32\FN2TC>SET ML=/coff /link /SUBSYSTEM:CONSOLE [Enter]

E:\HomePage\SOURCE\Win32\FN2TC>ml fn2tc.asm [Enter]
Microsoft (R) Macro Assembler Version 6.15.8803
Copyright (C) Microsoft Corp 1981-2000.  All rights reserved.

 Assembling: fn2tc.asm

*************
UNICODE Build
*************

Microsoft (R) Incremental Linker Version 5.12.8078
Copyright (C) Microsoft Corp 1992-1998. All rights reserved.

/SUBSYSTEM:WINDOWS
"fn2tc.obj"
"/OUT:fn2tc.exe"

E:\HomePage\SOURCE\Win32\FN2TC>

解說 FN2TC

這一節，小木偶要談談 FN2TC 運作原理，可分為幾個部份來說：命令列字串、FindFirstFile/FindNextFile/FindClose 的用法、GetFileAttributes、GetFullPathName、分析 get_parameter 副程式

命令列字串

一般執行控制台程式時，都是先執行 CMD.EXE 程式，開啟一個稱為「命令提示字元」的視窗，在「命令提示字元」下輸入程式名稱就算是執行了。有時也會在程式名稱後面加上一些參數，能夠指定控制台程式做哪些事，或是怎麼做。這些被使用者輸入的程式名稱以及參數，稱為「命令列字串」。要獲得使用者輸入的命令列字串，可以在程式裏呼叫 GetCommandLine API ( 在 FN2TC.ASM 的第 319 行 )，這個 API 沒有參數，傳回值是使用者輸入的「命令列字串」位址。例如下面的例子：

E:\HomePage\SOURCE\Win32\FN2TC>fn2tc -C [Enter]  →GetCommandLine 所傳回的字串是「fn2tc -C」再加上 NULL。

E:\HomePage\SOURCE\Win32\FN2TC>D: [Enter]

D:\>E:fn2tc -C C:\masm32 [Enter]  →GetCommandLine 所傳回的字串是「E:fn2tc -C C:\mams32」再加上空字元

D:\>E:fN2tC -c 体育.txt [Enter]  →GetCommandLine 所傳回的字串是「E:fN2tC -c 体育.txt」再加上空字元

從上面的三個例子，就應該能知道，GetCommandLine 所傳回來的命令列字串，其實就是複製使用者所輸入的所有字元而已。

如果使用 Olly Debug 除錯，並且要在除錯時輸入參數，是否可以做到呢？答案是當然可以。底下舉個例子。例如想要對「E:\HomePage\SOURCE\Win32\FN2TC\fn2tc.exe」程式除錯，其步驟如下：

  1. 執行 Olly Debug 後，點選主選單的「File」→「Open...」，會出現「Select 32-bit executable and specify arguments」對話盒。
  2. 然後在這個對話盒的「清單檢視」控制項選擇「fn2tc.exe」，如標示①的地方。接著在對話盒底下的「arguments:」輸入參數，例如輸入「-C 体育.txt」，如標示②的地方。這樣 Olly Debug 就會把「-C 体育.txt」當成參數。如有必要，也可以在底下的「Current dir:」輸入現在的目錄。如下圖所示：

而在上述對話盒裏輸入的參數是「-C 体育.txt」的話，在 Olly Debug 呼叫 GetCommandLine 傳回來的命令列字串是「"E:\HomePage\SOURCE\Win32\FN2TC\fn2tc.exe" -C 体育.txt」，與在命令提示字元的結果略微不同。也就是說，Olly Debug 所傳回來的參數，會用兩個「"」把程式名稱括起來，而且程式名稱會以包含磁碟機名的絕對路徑表示；而後的參數，全按照使用者輸入參數的結果。如下圖所示，在①用綠線框住的是呼叫 GetCommandLine 後，所傳回「命令列字串」位址，而其內容在②和③用紅線框住的區域，就是GetCommandLine 所傳回來的「命令列字串」：

不管是在命令提示字元下載入執行的程式，或是用 Olly Debug 載入除錯的程式，如果在原始碼中有下面敘述：

__UNICODE__     EQU     1       ;支援UNICODE
INCLUDE         WINDOWS.INC

那麼組譯連結後所得的程式，在處理字元時，是以萬國碼方式處理的。當其呼叫 GetCommandLine 傳回來的命令列字串是以萬國碼編碼；如果沒有上面的敘述，那程式是使用 ANSI 編碼，則該命令列字串也是以 ANSI 編碼。在極大部分的情形下，前者一個字佔用兩個位元組，後者只佔用一個位元組。這在組合語言裏，處理字元時要小心處理，否則很容易發生錯誤。

FindFirstFile/FindNextFile/FindClose 的用法

如果要一次處理大量的特定檔案，可以用 FindFirstFile/FindNextFile/FindClose 搭配萬用字元，會非常方便。萬用字元的說明，請按這裏。此處說明 FindFirstFile/FindNextFile/FindClose 三個 Win32 API 的用法。這三個 Win32 API 的原型是：

HANDLE WINAPI FindFirstFile(
  __in   LPCTSTR lpFileName,
  __out  LPWIN32_FIND_DATA lpFindFileData
);

BOOL WINAPI FindNextFile(
  __in   HANDLE hFindFile,
  __out  LPWIN32_FIND_DATA lpFindFileData
);

BOOL WINAPI FindClose(
  __inout  HANDLE hFindFile
);

FindFirstFile 的功用是在指定的目錄中搜尋符合的檔案或目錄。FindFirstFile 第一個參數是檔名位址，第二個參數是 WIN32_FIND_DATA 結構體位址。呼叫 FindFirstFile 前要把 lpFileName 及 lpFindFileData 這兩個表示位址的變數填好適當值，再行呼叫。如果 FindFirstFile 搜尋失敗，EAX 傳回的返回值是 INVALID_HANDLE_VALUE ( INVALID_HANDLE_VALUE 之值為－1 )，並非 FALSE。此時可以再進一步呼叫 GetLastError，得到錯誤的原因。如果 FindFirstFile 執行成功，系統會把搜尋代碼 ( search handle )，存於 EAX 暫存器，並在 lpFindFileData 所指的 WIN32_FIND_DATA 結構體內填好找著的第一個檔案或目錄的資料。我們的程式，就可以利用搜尋代碼及 WIN32_FIND_DATA 內的資料，對檔案進行拷貝、刪除、更名等過程。

由 FindFirstFile 傳回來的搜尋代碼，還可以用在 FindNextFile 的第一個參數，可作為下次搜尋的資料，繼續尋找下一個符合的檔案。FindNextFile 的第二個參數是 WIN32_FIND_DATA 結構體位址。如果 FindNextFile 成功的找著符合的檔案，就會傳回 TRUE，並把找到檔案的相關資料填入 WIN32_FIND_DATA 結構體內，我們的程式可以利用在 WIN32_FIND_DATA 結構體內的資料，進行檔案處理。如果 FindNextFile 執行失敗或找不到符合的檔案，會傳回 FALSE，再進一步呼叫 GetLastError 得到失敗原因，如果是因為沒有符合的檔案而招致呼叫失敗，那麼 GetLastError 會傳回 ERROR_NO_MORE_FILES。如果已經沒有符合的檔案而且也不再要進行搜尋，那麼就該呼叫 FindClose 關閉此次搜尋。FindClose 只有一個參數，就是由 FindFirstFile 傳回來的搜尋代碼。

藉由三個 API 的特性，我們可以設計一個迴圈，這樣就能處理所有符合檔案或目錄了。整個流程，可以參考右圖。接著，小木偶要說明的是 FindFirstFile 的兩個參數，先說 WIN32_FIND_DATA 結構體，後說 lpFileName。WIN32_FIND_DATA 結構體內的欄位如下：

WIN32_FIND_DATA         STRUCT
dwFileAttributes        DWORD           ?               ;屬性
ftCreationTime          FILETIME        <>              ;檔案建立時間
ftLastAccessTime        FILETIME        <>              ;最近存取時間
ftLastWriteTime         FILETIME        <>              ;最近修改時間
nFileSizeHigh           DWORD           ?               ;檔案大小，高位址的雙字組
nFileSizeLow            DWORD           ?               ;檔案大小，低位址的雙字組
dwReserved0             DWORD           ?
dwReserved1             DWORD           ?
cFileName               BYTE            MAX_PATH DUP (?);檔名 ( 不包含路徑名 )
cAlternateFileName      BYTE            14 DUP (?)      ;短檔名
WIN32_FIND_DATA         ENDS

WIN32_FIND_DATA 結構體的第一個欄位，dwFileAttributes，是指檔案屬性，如下表所示，dwFileAttributes 欄位可以是下表中的一個或數個的聯集：

屬性數值說明
FILE_ATTRIBUTE_ARCHIVE20H 保存，表示檔案需備份，通常是提供給備份軟體或備份命令使用的。當使用者建立或修改檔案時，會自動把該檔案設定具有 FILE_ATTRIBUTE_ARCHIVE 屬性，以提示備份軟體這個檔案尚未備份；備份後，此屬性自動取消。如果使用者再次修改檔案，會再次設定 FILE_ATTRIBUTE_ARCHIVE 屬性。我們可藉此屬性，設計備份軟體，僅備份修改過的檔案，不備份未更動的檔案。
FILE_ATTRIBUTE_COMPRESSED800H 壓縮，表示檔案或目錄為壓縮的。對檔案來說，表示此檔案被壓縮過。對目錄來說，有了此屬性後，此目錄裏新建的檔案會被壓縮。
FILE_ATTRIBUTE_DEVICE40H 保留
FILE_ATTRIBUTE_DIRECTORY10H 目錄。具有此屬性時，表示此為目錄，而非檔案。
FILE_ATTRIBUTE_ENCRYPTED4000H 加密。對檔案來說，是內容加密。對目錄來說，是對將來新建的檔案自動設定加密屬性。
FILE_ATTRIBUTE_HIDDEN2H 隱藏，一般而言，具有此屬性的檔案或目錄，在檔案總管裏見不著。但可以在「檔案總管」→「工具」→「資料夾選項」→「檢視」→「顯示所有檔案及資料夾」裏設定成「顯示所有檔案及資料夾」，這樣的話，即使具有 FILE_ATTRIBUTE_HIDDEN 屬性，也能見得著。
FILE_ATTRIBUTE_NORMAL80H 檔案沒有設置其他屬性，此屬性只能單獨使用。
FILE_ATTRIBUTE_NOT_CONTENT_INDEXED2000H
FILE_ATTRIBUTE_OFFLINE1000H 離線。檔案內容暫時不可用，此屬性被遠端儲存裝置 ( remote storage ) 軟體所用，不可任意更改這種屬性。
FILE_ATTRIBUTE_READONLY1H 唯讀。對檔案而言，應用程式只能讀取，不能修改或刪除。對目錄而言，應用程式不能刪除。
FILE_ATTRIBUTE_REPARSE_POINT400H
FILE_ATTRIBUTE_SPARSE_FILE200H 稀疏檔案。
FILE_ATTRIBUTE_SYSTEM4H 系統檔，表示此檔案或目錄是作業系統的一部份，
FILE_ATTRIBUTE_TEMPORARY100H 暫存檔。通常關閉暫存檔檔案代碼時，系統會刪除此檔案。
FILE_ATTRIBUTE_VIRTUAL10000H

WIN32_FIND_DATA 的第二、三、四個欄位，分別表示檔案建立時間、最近存取的時間、最近修改時間，均以 FILETIME 格式記錄。nFileSizeHigh、nFileSizeLow 合起來是一個六十四位元的數，代表檔案大小，以位元組為單位，因此檔案大小為 nFileSizeHigh×100000000H＋nFileSizeLow 位元組；如果是目錄，則此欄位為 0。接下來的 dwReserved0 只有在 dwFileAttributes 欄位中包含了 FILE_ATTRIBUTE_REPARSE_POINT 屬性才有意義，否則此欄位無用。dwReserved1 是保留的欄位，留待將來使用。cFileName 是一個長 260 個字元的字串，表示檔名 ( 僅含主檔名與副檔名，不包含路徑 )。cAlternateFileName 為一個 14 位元組長的字串，其內記錄著短檔名，短檔名是指 DOS 使用的 8.3 形態，亦即 8 個位元組長的主檔名，再加上 3 個位元組長的副檔名，其間以「.」隔開。

底下，小木偶要說明的是 FindFirstFiile 的第一個參數，lpFileName。lpFileName 是表示檔案名稱字串的位址，這個表示檔案名稱的字串，也可以包含磁碟機名或路徑名。通常是寫成下面的形式，第一個是絕對路徑，第二個是相對路徑，這兩種路徑的說明，請按這裏。

X:\sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy
X:sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy

「X:」是磁碟機名稱；sub-dir-1、sub-dir-2…是目錄名稱；xxxxxx.yyy 是檔案名稱，其中「xxxxxx」是主檔案名，「yyy」是副檔名。在這個表示檔案名稱的字串中，某些部份是可以省略的，分成下面幾種情形說明。不管是哪一種情形，只有最後一項可以使用萬用字元；前面的項目都不能使用萬用字元，如果使用了，FindFirstFile 會發生錯誤，並傳回 INVALID_HANDLE_VALUE 錯誤值，如果再呼叫 GetLastError，GetLastError 會傳回 ERROR_INVALID_NAME。所謂最後一項，通常是檔案名稱；但也可能是檔名省略情況下，最後一層的目錄名稱。此外，lpFileName 所指的檔名或目錄名字串，即使含有空白字元，也不能用一對「"」括住，否則會發生錯誤，傳回 INVALID_HANDLE_VALUE，再進一步呼叫 GetLastError 後，得到 ERROR_INVALID_NAME；事實上不需用「"」就行了。底下我們看看 lpFileName 所指的字串，可以有哪些情形：

完整的檔名：包含磁碟、路徑、檔案三者全部表示出來。其格式像底下的樣子：

X:\sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy
X:sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy

第一種情形，較為單純，從磁碟機名、路徑名、檔案名依序排列出來，像這種情形稱為「絕對路徑」，FindFirstFile 依序就能找到檔案。第二種情形稱為「相對路徑」，FindFirstFile 會從「X:」磁碟機的現在目錄開始搜尋「sub-dir-1」子目錄，再由「sub-dir-1」子目錄裏搜尋「孫」目錄，「sub-dir-2」......直到「sub-dir-n」目錄裏的「xxxxxx.yyy」檔案為止。而關「現在目錄」的說明，請參考註一後半部的說明。不管是使用絕對路徑或相對路徑，雖然路徑名稱不可使用萬用字元，但是檔案名稱可以使用萬用字元，如果再搭配 FundNextFile，就可以搜尋特定種類的檔案。底下的例子是尋找「C:\masm32\bin\ml.exe」可執行檔。

;*************************************************************************************************************
.DATA
filename        DB              "C:\masm32\bin\ml.exe",0
w32fd           WIN32_FIND_DATA <>
;*************************************************************************************************************
.CODE
;-------------------------------------------------------------------------------------------------------------
                ......  ......
                INVOKE  FindFirstFile,OFFSET filename,OFFSET w32fd

要注意的是，如果 FindFirstFile 執行成功，在 w32fd.cFileName 的位址上的檔名是「ml.exe」，並不含磁碟機及路徑名稱。如果把上例中的 filename 字串改成「filename DB "C:\masm32\bin\*.exe",0」，再和 FindNextFile 搭配，就能搜尋到在「C:\masm32\bin」目錄中，所有副檔名為 .exe 的檔案了。

省略檔名：如果省略檔名的話，其格式像

X:\sub-dir-1\sub-dir-2\......\sub-dir-n
X:sub-dir-1\sub-dir-2\......\sub-dir-n

這種情形，其實就是尋找指定的目錄。第一種情形是絕對路徑，從「X:」磁碟機的根目錄開始找；第二種情形是相對路徑，從「X:」磁碟機現在的目錄開始。不管哪一種情形，最後一個目錄之後不能有「\」，不然的話，就會出現 INVALID_HANDLE_VALUE，如果再呼叫 GetLastError，GetLastError 會傳回 ERROR_FILE_NOT_FOUND。只有最底層的目錄名稱，sub-dir-n，可以使用萬用字元；其餘目錄名稱，都不能出現萬用字元。先看看第一種情形，舉個例子說明，看看底下的例子：

;*************************************************************************************************************
.DATA
filename        DB              "C:\masm32\bin",0
w32fd           WIN32_FIND_DATA <>
;*************************************************************************************************************
.CODE
;-------------------------------------------------------------------------------------------------------------
                ......  ......
                INVOKE  FindFirstFile,OFFSET filename,OFFSET w32fd

這樣的話，FindFirstFile 會把「bin」的資料填在 w32fd 結構體內，所以在 w32fd.cFileName 為「bin」，w32fd.dwFileAttributes 內，就會包含 FILE_ATTRIBUTE_DIRECTORY 屬性，其他各欄位的資料也都是「bin」的資料。但是，如果把 filename 字串變成：

filename        DB              "C:\masm32\bin\",0

就會使 FindFirstFile 產生錯誤，FindFirstFile 會傳回 INVALID_HANDLE_VALUE。進一步呼叫 GetLastError，會得到 ERROR_FILE_NOT_FOUND。所以，最後面有沒有「\」差別很大。如果是第二種情形，使 lpFileName 變成相對路徑，會讓使用情形變得受到很大的限制。如果讓上面例子中的 filename 變成：

filename        DB              "C:masm32\bin",0

那麼，只有在「C:」磁碟機現在目錄為根目錄時，呼叫 FindFirstFile 才會成功；否則都會發生錯誤，進一步呼叫 GetLastError，會得到 ERROR_FILE_NOT_FOUND。

省略磁碟機或路徑名：如果是省略磁碟機名稱，那麼 FindFirstFile 就會由現在的磁碟機開始搜尋，像下面第一種情形；如果是省略路徑名稱，那麼就是由現在的目錄搜尋，像下面第二種情形；如果磁碟機與路徑名稱都省略，那就從現在的磁碟機與現在目錄開始搜尋。

\sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy
X:xxxxxx.yyy
xxxxxx.yyy

省略路徑名及檔名：在這種情形下，就只剩磁碟機名。FindFirstFile 會找到該磁碟機的現在目錄，並把該磁碟機的現在目錄填入 lpFindFileData 所指的 WIN32_FIND_DATA 結構體內。但是如果該磁碟機的現在目錄是根目錄的話，FindFirstFile 會發生錯誤，進一步呼叫 GetLastError，會得到 ERROR_FILE_NOT_FOUND 錯誤碼。

省略磁碟機及檔名：在這種情形下，就只剩路徑名。FindFirstFile 會從現在磁碟機開始搜尋，直到指定的目錄。最底層的目錄可以使用萬用字元，其餘不行。

講了這麼多，總共五種情形，有一點複雜。簡單的說，FindFirstFile 在執行時，只是依照程式設計師所給的 lpFileName 位址，找到該位址的字串。然後依照程式設計師所給的路徑，往下尋找一層一層的目錄，直到符合的檔案或目錄為止。如果沒有磁碟機名或路徑名，就以現在的磁碟機或現在的目錄開始搜尋。其實，FindFirstFile 對檔案或目錄是一視同仁的，只要符合字串，都能找到。FindNextFile 也是如此。

GetFileAttributes API

GetFileAttributes API 是用來取得檔案或目錄的屬性，這些屬性包含系統檔、暫存檔、唯讀檔…等等，其原型是

DWORD   WINAPI  GetFileAttributes(
  __in  LPCTSTR lpFileName
);

GetFileAttributes 只有一個參數，就是檔案名稱或路徑名稱的位址，檔案名稱或路徑名稱可以使用「絕對路徑」或「相對路徑」。如果 GetFileAttributes 成功執行，EAX 會返回檔案或目錄的屬性。這個屬性和 WIN32_FIND_DATA 結構體的 dwFileAttributes 欄位所定義的相同，可以參考這裏。如果呼叫 GetFileAttributes 失敗，傳回的錯誤碼是 INVALID_FILE_ATTRIBUTES，必須進一步呼叫 GetLastError 才能得到發生錯誤的原因。常見產生錯誤的原因，有下面幾種情形：

  1. 檔案名稱或路徑名稱包含萬用字元，呼叫 GetLastError 後會得到 ERROR_INVALID_NAME 錯誤碼。
  2. 檔案名稱或路徑名稱包含不合法的字元，呼叫 GetLastError 後會得到 ERROR_INVALID_NAME 錯誤碼。
  3. 在指定的檔案或目錄不存在，呼叫 GetLastError 後會得到 ERROR_FILE_NOT_FOUND 錯誤碼。

GetFullPathName API

GetFullPathName API 是用來獲取某個檔案的完整路徑名稱及檔案名稱。其原型為：

DWORD    WINAPI  GetFullPathName(
  __in   LPCTSTR lpFileName,
  __in   DWORD   nBufferLength,
  __out  LPTSTR  lpBuffer,
  __out  LPTSTR* lpFilePart
);

lpFileName 是「某個檔案」的檔名位址，以 NULL 結尾，可以是短檔名 ( 即 DOS 作業系統的 8.3 檔名 )，也可以包含磁碟機名稱或網路磁碟機名稱。GetFullPathName 會把完整的檔名，填入 lpBuffer 所指定位址的緩衝區內，而此緩衝區的大小為 nBufferLength。lpFilePart 是緩衝區內完整檔名最後一項的位址，如果不需要此資料，可以把 lpFilePart 設為 0。如果 GetFullPathName 執行成功，會傳回填入緩衝區內的字元數，此字元數不包含 NULL 字元。如果緩衝區太小，亦即 nBufferLength 太小，以致於無法容納完整檔名而失敗，返回值是完整檔名正確的的字元數，此字元數包含 NULL 字元。程式可以藉由檢查返回值的字元數，是否大於緩衝區大小，如果大於，就表示緩衝區太小無法容納完整檔案名稱。如果是其他原因導致的錯誤，返回值為 0，需要進一步呼叫 GetLastError，才能得知發生錯誤的原因。

GetFullPathName 的運作方式，其實只是把現在磁碟機、現在目錄，與 lpFileName 所指位址的字串結合在一起。假如 lpFileName 內的字串本身就是完整的路徑名稱與檔案名稱，那麼 GetFullPathName 只是將此字串照抄到緩衝區內。此外，GetFullPathName 並不檢查 lpFileName 所指的字串，是否含有路徑名、檔名所不合法的字元；也不會檢查語法上的錯誤，例如兩個磁碟機名也不會造成錯誤。此外，GetFullPathName 並不會檢查 lpFileName 所指的檔案是否真的存在。

分析 get_parameter 副程式

get_parameter 副程式有點瑣碎，如果詳細解說，有點見樹不見林的感覺，而且失去重點。因此小木偶在這裏，只提出幾個觀念。

①如何分辨空白字元是檔名的一部份，還是分隔參數的字元

分析使用者輸入的「命令列字串」會發現，參數與參數之間是以空白字元分隔。空白字元的萬國碼是 0020h，而檔案或目錄名稱也可以含有空白字元。因此要如何分辨空白字元，是檔名或目錄名的一部份，還是參數的分隔記號，是一大難題。幸好在「命令提示字元」裏，含有空白字元的檔名或目錄名，必須用兩個「"」括起來。例如底下的例子：

"C:\Program Files"
C:\"Program Files"
C:\"Program Files"\"Debugging Tools for Windows (x64)"
C:\"Program Files\Debugging Tools for Windows (x64)"
C:\Progra"m F"iles\"Debugging Tools for Windows (x64)"

上面這些例子，都是合法的。事實上它們都是 Windows 作業系統內重要的目錄。上面的五個例子中，前兩個例子是一樣的，後三個也都相同。仔細觀察後，可以得到結論：只要是在兩個「"」之間的空白字元，不管幾個空白字元，都是檔名或目錄的一部份。而這兩個「"」，也可以在任意位置，只要能把空白字元括住，空白字元就是檔名或目錄的一部份。因此，在兩個「"」之外的空白字元，就代表是參數之間的分隔符號。可以這麼思考，因為「"」是兩兩成對的，所以空白字元出現前，有偶數個「"」，代表空白字元在兩個「"」之外，是參數間的分隔符號。我們可以設一個初始值為 0 的變數，去記錄「"」的個數；再設另一個變數記錄位址，此變數所記錄的位址由「命令列字串」的低位址開始往高位址，一個字元、一個字元逐一檢查。如果遇到「"」時，就讓記錄「"」的變數加一；如果遇到空白字元時，就檢查記錄「"」的變數是偶數還是奇數。如果是偶數，就表示此空白字元在兩個「"」之外，為參數之間的分隔符號；如果是奇數，就表示此空白字元在兩個「"」之內，為檔名或目錄名的一部份。

有了這個觀念之後，就比較簡單了。在 FN2TC 原始碼的第 131∼153 行，用來尋找「命令列字串」的程式名稱。在第 133 行，設定 EDX 為零，把 EDX 當做是計算「"」個數的變數；而第 135 行，把 EBX 設為指向「命令列字串」的起始位址。程式的第 141 行到第 148 行的迴圈，是去搜尋程式名稱的結尾。在第 141 行，檢查是否遇到「"」字元，如果遇到了就跳躍至第 149 行，使 EDX 增加一；第 143 行，如遇到空白字元，則跳躍至第 153 行，檢查 EDX 是否為偶數，如果是偶數，到第 155 行，表示找著了代表分隔程式名稱與第一個參數的空白字元。

get_parameter 不只上面的迴圈用這個觀念，在第 201∼228 行，也一樣的觀念，去找到第二個參數的結尾。第 203 行，把 EDX 設為零，記錄「"」個數。第 216∼217 行，檢查是否為「"」字元，如果是的話，跳躍至第 237 行，使 EDX 加一。第 209 行，檢查是否為空白，如果是的話就跳躍至第 250 行，檢查 EDX 是否為偶數。如果是偶數，就到第 252 行，表示命令列字串已經結束。

②使用者在命令提示字元輸入的「"」並非檔名或目錄名的一部份，須除去

前面第①提過，檔案名稱或目錄名稱可以使用空白字元。如果要在命令提示列中輸入檔名或目錄名時，而此檔名或目錄名含有空白字元時，需用一對「"」括起來。例如，下面的例子，假設要把「C:\Documents and Settings\UserXP\My Documents」目錄中的所有含簡體字的檔名改成正體字，應該是要輸入下面的指令：

E:\HomePage\SOURCE\Win32\FN2TC>FN2TC "C:\Documents and Settings\wanker\My Documents" [Enter]

但是對於 Win32 API 而言，檔名或目錄名是不能有「"」的，必須以 NULL 結尾，如果有「"」會發生錯誤，例如 FindFirstFile 就是如此。因此在呼叫 Win32 API 之前，要把「"」除去。這工作，也是由 get_parameter 副程式完成的。這段程式碼在第 224 行∼ 257 行。小木偶利用的原理是，用 EBX 指向「命令列字串」，EDI 也指向 EBX 位址。然後由低位址向高位址檢查每個「命令列字串」的字元，而每個字元又存入到 EDI 所指的位址。但是如果檢查到「"」，那就不儲存。而後的字元，就會存在「"」字元所在位址，於是「"」就被覆蓋成後面的字元了，因而消除「"」字元。程式第 237 行，是檢測到「"」字元，如果是的話，就使計算「"」個數的 EDX 加一，然後就跳到第 227 行，不儲存，直接處理下一個字元；如果是其他字元，都會跳到 226 行，把字元存入 EDI 所指位址。

③解決「命令提示字元」中的檔名與 FindFirstFile 中檔名的不同解讀

從 FN2TC 使用方法、FindFirstFile/FindNextFile/FindClose 的用法以及上面②處的說明，您當可發現一件棘手的地方，那就是在「命令提示字元」處輸入的檔名，與 FindFirstFile 處所定義的檔名，並不完全相同。例如，如果使用者在「命令提示字元」輸入下面例子：

E:\HomePage\SOURCE\Win32\FN2TC>fn2tc c:\masm32\

這是允許的，其意義很明顯，因為「c:\masm32」是個目錄，所以上述指令就是把，「c:\masm32\」路徑中含有簡體字的檔名或字目錄改成正體字；但是 FindFirstFile 卻不接受這樣的檔名，必須改成「c:\masm32\*.*」才行，否則就會產生錯誤。除此之外，小木偶分析過，總共有下面幾種情況是「FN2TC」與「FindFirstFile」對參數的解釋，有所出入的情況：

FN2TC 的例子使用者本意 ( 或命令提示元內的意義 ) FindFirstFile 第一個參數
FN2TC "C:\Documents and Settings\*.*"處理「C:\Documents and Settings」目錄裏的檔案 不允許，因為檔名不可有「"」，會發生 INVALID_HANDLE_VALUE 錯誤，再進一步呼叫 GetLastError 後，得到 ERROR_INVALID_NAME。須除去引號才能正確執行。
FN2TC C:\masm32\bin\ 處理「C:\masm32\bin」目錄裏的檔案不允許，會發生 INVALID_HANDLE_VALUE 錯誤，再進一步呼叫 GetLastError 後，得到 ERROR_FILE_NOT_FOUND 錯誤碼。須轉換成「C:\masm32\bin\*.*」，才能正確執行。
FN2TC C:\masm32\bin 處理「C:\masm32\bin」目錄裏的檔案允許，不發生錯誤，但僅處理「bin」目錄名，因此須轉換成「C:\masm32\bin\*.*」才符合使用者的需求。
FN2TC C:
FN2TC C:.		 「FN2TC C:」與「FN2TC C:.」都是要處理 C: 磁碟機現在目錄內的檔名及子目錄名 把「C:」與「C:.」當成參數呼叫 FindFirstFile，結果都一樣，可分成兩種情形來說：
若 C: 磁碟機現在目錄為根目錄，會出現 INVALID_HANDLE_VALUE 錯誤，再進一步呼叫 GetLastError 後，得到 ERROR_FILE_NOT_FOUND 錯誤碼。
若 C: 磁碟機現在目錄不是根目錄，不發生錯誤，但僅處理 C: 磁碟機現在目錄的名稱，非處理現在目錄裏的檔案。
因此這兩種情形，都應改成「C:.\*.*」就行了。
FN2TC C:.. 處理 C: 磁碟機現在目錄的上一層目錄內的檔名及子目錄名 把「C:..」當成參數呼叫 FindFirstFile，不發生錯誤，但僅處理 C: 磁碟機現在目錄的上一層目錄本身，但非處理其目錄裏的檔案。須改成「C:..\*.*」

上表中，第一個例子是當使用者在命令提示字元，輸入指令，「FN2TC "C:\Documents and Settings\*.*"」時，一定得加上兩個「"」，以便讓 FN2TC 知道，要把「C:\Documents and Settings」目錄內的檔名更改為正體字，而不是「C:\Documents」目錄。但是卻不能以「"C:\Documents and Settings\*.*"」再加上 NULL 結尾的字串作為 FindFirstFile 的第一個參數，因為檔名裏不能使用「"」字元。因此在第一個例子中，要把「"」除去，而除去「"」的方法，在②已提過了。而 FindFirstFile 會以 NULL 結尾，所以能清楚知道是「C:\Documents and Settings」目錄。

上表中的第二和第三個例子裏，因為「bin」是「C:\masm32」目錄裏的一個子目錄，所以當使用者在命令提示字元，輸入指令，「FN2TC C:\masm32\bin\」或「FN2TC C:\masm32\bin」時，其實是要把「C:\masm32\bin」目錄裏的檔名更改為正體字。但是在第二個例子中，如果把「C:\masm32\bin\」再加上 NULL 為結尾的字串當做 FindFirstFile 的第一個參數，會使 FindFirstFile 發生錯誤。而在第三個例子中，如果把「C:\masm32\bin」再加上 NULL 為結尾的字串當做 FindFirstFile 的第一個參數，系統會誤以為就是指「C:\masm32\bin」目錄本身，而非其內的檔案。當然這個「bin」目錄不含簡體字，所以其實對 FN2TC 的作用來說，是毫無作用，但卻已經誤會了使用者的本意。所以第二和第三個例子，都必須在呼叫 FindFirstFile 之前，把參數改成「C:\masm32\bin\*.*」再加上 NULL 結尾的字串才行。

上表中的第四個例子，不論是使用者輸入「FN2TC C:」或「FN2TC C:.」，都是要使 FN2TC 把「C:」磁碟機現在目錄裏的檔名，轉換成正體字。但是如果把「C:」或「C:.」再加上 NULL 為結尾的字串，當成 FindFirstFile 的第一個參數，FindFirstFile 傳回來的就是「C:」磁碟機現在目錄，而非目錄裏的檔案，這跟使用者的本意不同。另外還有一個問題，如果「C:」磁碟機的現在目錄是根目錄的話，結果會發生 ERROR_FILE_NOT_FOUND 錯誤。但如果把「C:」或「C:.」都轉換成「C:.\*.*」再加上 NULL 結尾，再呼叫 FindFirstFile，那麼結果就是傳回「C:」磁碟機現在目錄裏的檔名。

上表中的第五個例子，如果使用者輸入「C:..」，表示使用者是想要處理「C:」磁碟機現在目錄的上一層目錄內，所有檔案及其目錄。然而以「C:..」再加上 NULL 作為字串，當做 FindFirstFile 的參數，不發生錯誤，但是處理的是「C:」磁碟機現在目錄的上層目錄名，並非其內的檔案及目錄。所以應該要把「C:.」改成「C:.\*.*」，才能表示使用者要處理的是「C:」磁碟機現在目錄的上一層目錄內，所有檔案及其目錄。

由上面的分析，可以發現，FN2TC 要處理的情形，其實只有兩種：①使用者所輸入的參數僅僅只有目錄名稱，沒有檔案名稱；與②使用者輸入的參數包含檔案名稱。前者必須在路徑之後，添加上「*.*」，然後處理的方式就大同小異了。

在程式的第 256 行，呼叫 GetFileAttributes，取得使用者輸入的參數是檔案還是目錄。如果是目錄，就到第 262 行，此行呼叫 GetFullPathName 取得完整的路徑名稱。呼叫 GetFullPathName 的目的是處理使用者輸入的參數是相對路徑，能轉換成完整的路徑。因為這時候，已經確定是目錄了，所以必須在路徑最後面加上「*.*」，這樣才能讓 GetFindFirstFile 正確執行。這段程式在第 262∼278 行。接下來的第 279∼283 行，是計算完整檔名的字元個數，然後跳到第 305 行，設定 EAX 及清除進位旗標，返回主程式。如果在第 256 行，檢查到使用者輸入的參數是檔案而不是目錄，就跳到第 293 行，呼叫 GetFullPathName 取得完整檔名，並計算出完整檔名含有幾個字元後，設定 EAX 並清除進位旗標後，返回主程式。

④PATHFILEDATA 結構體

首先，使用者輸入的參數，經過 get_parameter 分析後，還希望能把一些資料保留起來，以便讓主程式能夠運用。例如使用者輸入的完整檔名位址、主檔名位址、完整檔名的字元個數等等資料，都會為主程式所運用，必須保留下來。這些資料太多了，只靠 EAX 無法做到，所以小木偶在程式第 22∼27 行定義了一個結構體，稱為「PATHFILEDATA」。在呼叫 get_parameter 副程式之前，要把 PATHFILEDATA 結構體的位址作為第二個參數，傳給 get_parameter。如果 get_parameter 如果成功的分析出參數及檔名，那麼返回主程式時，get_parameter 會把 PATHFILEDATA 內的欄位填入正確值。PATHFILEDATA 欄位如下：

PATHFILEDATA    STRUC
pFullname       DD      ?       ;完整檔名起始位址，完整檔名包含磁碟機名、路徑名、主檔名及副檔名，但這四項不一定都會出現。
pMainFilename   DD      ?       ;主檔名位址
cChar           DD      ?       ;完整檔名的字元數，不含結尾的NULL
PATHFILEDATA    ENDS

一進入 get_parameter 後，在程式第 136∼137 行，就是初始化 PATHFILEDATA 結構體，也就是讓這些欄位都變為 0。pFullname

檔案改名：MoveFile API

註一：目錄與檔案 ( 兼談現在目錄、絕對路徑、相對路徑 )

在還沒發明電腦的時代裏，辦公室裏也必須處理許多檔案，假如把所有檔案都存放在一個櫃子裏，沒有分類，那麼必定會很混亂，以後要查閱檔案也不容易找到。因此，條理分明的人，一定會分門別類的把同一類的檔案歸類到同一個資料夾裏面。有時候，在一個資料夾裏面，可能直接存放檔案，也可以再細分成更小的類別，或是兩者皆有。於是就在資料夾裏，有時有檔案，也有較細分的資料夾，同時都存在。

電腦的磁碟機 ( driver )，就如同櫃子一樣，儲存著大量的檔案。同樣的，也應把檔案分門別類收納儲存。在 DOS 時代，磁碟機名稱是用英文字母加上冒號表示。例如「A:」表示「A:」磁碟機，「B:」表示「B:」磁碟機，這兩個磁碟機名稱是已被淘汰的軟式磁碟機名稱，從「C:」磁碟機開始才是硬式磁碟機 ( 俗稱硬碟，大陸稱硬盤 ) 或隨身碟、光碟機等等。如果您的電腦上，超過 26 個磁碟機，那麼大小寫才代表不同的磁碟機；如果沒超過，大小寫代表相同的磁碟機。

上述所講的資料夾，可以看成目錄，目錄底下，可以存放檔案，也可以存放更細的目錄。在 DOS 時代，微軟稱為「目錄」( directory )；到了 Windows 時代，稱為「資料夾」( folder )，兩者意義相同。在一個磁碟機底下，可能有好幾個目錄以及許多檔案；而每個目錄也可能有好幾個目錄以及許多檔案，......，如此一層一層往下。所以，一般而言，用底下的方式表示檔案：

driver:\sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy

「driver:」表示磁碟機名稱，每個磁碟機最上層的目錄稱為「根目錄」，例如「C:」磁碟機的根目錄為「C:\」。如果要指明某個檔案，就必須由磁碟機開始，然後是一連串的目錄名稱，這些目錄名稱都以「\」分隔，最後才終於指到檔案名稱。例如「sub-dir-1」、「sub-dir-2」……都是目錄名稱，代表「sub-dir-1」底下，有一個子目錄「sub-dir-2」，「sub-dir-2」底下有個子目錄「sub-dir-3」……，一直到最後一個目錄，「sub-dir-n」，而指定的 xxxxxx.yyy 檔案就在「sub-dir-n」目錄裏。或者，也可以反過來說，xxxxxx.yyy 檔案在「sub-dir-n」目錄裏，而「sub-dir-n」目錄在「sub-dir-(n-1)」目錄裏......，「sub-dir-2」目錄在「sub-dir-1」目錄裏，而「sub-dir-1」目錄的上一層目錄就是根目錄了。每個目錄之間，用反斜線，「\」分開，這一長串的「\sub-dir-1\sub-dir-2\......\sub-dir-n\」稱為「路徑」，經由路徑，可以找到檔案。上面一長串的「driver:\sub-dir-1\sub-dir-2\......\sub-dir-n\xxxxxx.yyy」，也可以簡化成

driver:\path\filename

檔案名稱由兩部份組成，主檔名與副檔名，中間以「.」分開，在最後一個「.」左邊的稱為主檔名，右邊的稱為副檔名。像上面的「xxxxxx」是主檔名，「yyy」是副檔名。一般而言，取檔名時要有意義，是指主檔名而言，以便讓我們一看就知道是什麼檔案。副檔名是用來區分此檔案是由哪一種軟體產生的或是泛指某一類的檔案，例如「.docx」是微軟 OFFICE WORD 軟體產生的文件檔、「.mp4」是影音檔、「.mp3」是音樂檔、「.jpg」是照片檔、「.exe」是可執行程式……等等。檔案名稱可以用數個「.」字元，只有最後一個「.」才是區分主檔名與副檔名。有時也可以沒有副檔名。

例如，MASM32 的組譯器，ml.exe，是放在 C: 磁碟機的一個「bin」子目錄裏，而「bin」子目錄又是在根目錄下的「masm32」子目錄內，「masm32」子目錄的上一層目錄就是「C:」磁碟機的根目錄了，所以表示方式如下：

c:\masm32\bin\ml.exe

其中「C:」就是磁碟機名，「\masm32\bin\」稱為路徑。但把「C:\mams32\bin\」當成路徑名，亦未嘗不可，其中界線是很模糊的。由磁碟機的根目錄開始，經一串目錄名構成的路徑，最後才是檔案名稱，像這種表示方式稱為「絕對路徑」。還有另一種稱為「相對路徑」的表示方式，也能找到特定檔案。稍後再談「相對路徑」。

為檔案或目錄取個名字，是很重要的事，最好是能望文生義。即使日子久了，也能知道這個檔案是什麼。在 32 位元的 Windows 作業系統中，並不是任意字元都作為檔案名稱或目錄名稱，需符合下列規定：

  1. 記錄在磁碟中的檔名或目錄名，都是以萬國碼編碼方式記錄的，且只能使用 0020h 或 0020h 以上的字元 ( 0020h 是空白字元 )。在 0020h 以下的字元，常用來實現某些操作，例如換行、跳格等等，因此不能作為檔案或目錄名稱。
  2. 一些特殊字元，例如：「:」、「\」、「/」、「<」、「>」、「|」、「"」、「*」、「?」，不能用於檔名或目錄名，原因如下：
  3. 「.」可用於檔名，而一個檔名也可以有許多個「.」，但是最後一個「.」是用來區分主檔名與副檔名的。例如「FN2TC.ASM」中，FN2TC 是主檔名，ASM 是副檔名。
  4. 雖然檔案名稱可以用「.」字元，不過如果是單獨的「.」與單獨的「..」，另有意義，並非代表檔案。如果只是單獨的「.」，就代表現在的目錄；而「..」，就表示上層目錄，因此檔名不可以是「.」或「..」。例如在「命令提示字元」進行底下的操作： 
    C:\masm32\bin>dir ml.exe [Enter] →dir 是列出目錄 ( directory ) 內的檔案之意，所以「dir ml.exe」就是列出目錄裏的 ml.exe 檔案。
 磁碟區 C 中的磁碟是 WINDOWS XP PRO 如果只輸入「dir」，那麼就會列出該目錄的所有檔案。
 磁碟區序號:  9858-1328

 C:\masm32\bin 的目錄

1999/03/29  下午 03:45           372,736 ml.exe
               1 個檔案         372,736 位元組
               0 個目錄  79,776,759,808 位元組可用

C:\masm32\bin>dir .\ml.exe [Enter] →因為「.」代表現在目錄，所以「dir .\ml.exe」就代表列出現在目錄裏面的 ml.exe 檔案，所以其實和「dir ml.exe」是一樣的意思。
 磁碟區 C 中的磁碟是 WINDOWS XP PRO   現在的目錄就是上一行前面的「C:\masm32\bin」，命令提示字元會把它印在最前面。事實上，命令提示字元會記錄每個磁碟機的現在目
 磁碟區序號:  9858-1328              錄，並且在螢幕最前面，印出當前磁碟機的現在目錄，等待使用者輸入指令。

 C:\masm32\bin 的目錄

1999/03/29  下午 03:45           372,736 ml.exe
               1 個檔案         372,736 位元組
               0 個目錄  79,776,759,808 位元組可用

C:\masm32\bin>e: [Enter] →在「命令提示字元」只輸入磁碟機名，代表切換磁碟機之意。即使切換到「E:」磁碟機，「C:」磁碟機的現在的目錄還是「C:\masm32\bin」。

E:\HomePage\SOURCE\Win32\FN2TC>dir c:ml.exe [Enter]  →實驗看看。列出 C: 磁碟機現在目錄裏的 ml.exe 檔案，跟前面的一模一樣。果真如此，電腦會記住磁碟機的現在目錄。
 磁碟區 C 中的磁碟是 WINDOWS XP PRO
 磁碟區序號:  9858-1328

 C:\masm32\bin 的目錄

1999/03/29  下午 03:45           372,736 ml.exe
               1 個檔案         372,736 位元組
               0 個目錄  79,776,759,808 位元組可用

E:\HomePage\SOURCE\Win32\FN2TC>cd c:.. [Enter] →cd 是改變目錄 ( change directory ) 的意思，「..」是上層目錄，所以「cd c:..」就是把 C: 磁碟機的
                                                現在目錄變成上一層的目錄。所以 C: 磁碟機的現在目錄變成「C:\masm32」了。
E:\HomePage\SOURCE\Win32\FN2TC>c: [Enter] →切換到「C:」磁碟機

C:\masm32> →現在目錄已經變成原來目錄的上一層的目錄了，就是「C:\masm32」
  5. 如果遇到英文字母，是不區分大小寫的。但是當您第一次建立檔案或改檔名時，會依照您所輸入的檔名，大小寫如實填入；但是如果列出、拷貝、刪除檔案時，就不區分大小寫。例如 MASM32 的組譯器是「c:\masm32\bun\ml.exe」，在「命令提示字元」輸入「dir c:\masm32\bin\ML.exe」，照樣能把「ml.exe」列出來。

「?」與「*」這兩個字元，稱為萬用字元 ( 或叫通配字元，英文稱為 wild card )，可以代表任意字元。先說說「?」字元，它代表一個或零個任意字元。例如「prime?.asm」檔案，可以是「prime1.asm」，也可以是「prime2.asm」或是「primea.asm」等等，凡是「prime」後任意一個字，再加上「.asm」檔案都可以符合「prime?.asm」。此外「?」其實也可以是代表一個中文字，甚至其他語文的字。例如目錄裏有「prime.asm」、「prime男.asm」、「prime女.asm」，如果下指令「dir prime?.asm」，前述三個檔案都會列出來。如果多個「?」連在一起，那麼只要是不多於「?」個數的字元，都符合。例如目錄裏有「prime.asm」、「prime1.asm」、「prime01.asm」、「prime001.asm」，如果下指令「dir prime??.asm」，只有前三個會列出來。

「*」可代表任意個任意字元。小木偶想，還是看底下的例子，較易理解：

此外萬用字元有一項限制，只能出現在路徑或是完整檔名的最後一項，例如：

C:\masm32\bin\*.exe
C:\masm32\bin\m?.exe
C:\masm32\b*

像上面第三個例子，即使最後一項是目錄名稱，也能使用萬用字元，所以上面的第三個例子是正確的路徑名稱，它是處理「C:\masm32」目錄裏面任何以「b」開頭的檔名或子目錄名。除了最後一項可用萬用字元外，其他位置都不能使用，例如底下的例子是錯誤的：

C:\masm32\*\ml.exe

小木偶覺得，在「命令提示字元」處理大量檔案時，搭配萬用字元，非常方便，這大概是「命令列介面」( CLI ) 比圖形使用者介面 ( GUI ) 方便的地方吧！然而有些圖形使用者界面的程式，也擷取這個優點，可以用萬用字元，例如「Total Commander」就行。

檔名與目錄名已講完，底下小木偶要介紹「絕對路徑」與「相對路徑」。「絕對路徑」是指描述檔案時，由磁碟機開始，依序是根目錄、根目錄下一層的子目錄、再下一層的目錄......直到檔案為止。例如描述 MASM32 的組譯器，如果使用「c:\masm32\bun\ml.exe」方式表達，就是「絕對路徑」。「相對路徑」指的是從現在的目錄開始，往上層或往下層目錄，直至指定的檔案。例如底下的操作：

D:\HomePage\SOURCE\Win32\FN2TC>cd c:\masm32 [Enter] →cd 是切換目錄的意思，英文是 change directory。

D:\HomePage\SOURCE\Win32\FN2TC>dir c:bin\ml.* [Enter] →「C:」磁碟機的現在目錄是「c:\masm32\」，指令「dir c:bin\ml.*」的意思就是把「C:」磁碟機現在目錄
 磁碟區 C 中的磁碟是 WINDOWS XP PRO                      下一層的「bin」子目錄，裏面主檔名是 ml 的所有檔案列出來。此處的「bin\」就是相對路徑。
 磁碟區序號:  9858-1328

 C:\masm32\bin 的目錄

2001/07/22  上午 03:31             9,687 ml.err
1999/03/29  下午 03:45           372,736 ml.exe
               2 個檔案         382,423 位元組
               0 個目錄  79,768,842,240 位元組可用

D:\HomePage\SOURCE\Win32\FN2TC>dir c:..\m*.* [Enter] →「C:..\」也是相對路徑，是指「C:」磁碟機現在目錄的上一層目錄。
 磁碟區 C 中的磁碟是 WINDOWS XP PRO
 磁碟區序號:  9858-1328

 C:\ 的目錄

 2018/01/17  下午 02:10    <DIR>          masm32
               0 個檔案               0 位元組
               1 個目錄  79,768,342,528 位元組可用

D:\HomePage\SOURCE\Win32\FN2TC>

上述操作中的第一條指令，使得系統把「C:」磁碟機的現在目錄切換到「C:\masm32\」。第二條指令，「dir」是顯示目錄裏的檔案，此目錄內的檔案是緊接著的「c:bin\ml.*」，此時的「c:bin\」就是相對路徑。要得到完整的路徑，就得從「C:」磁碟機的現在目錄開始，也就是從「C:\masm32\」開始；然後與相對路徑結合，最後得到真正的路徑，「C:\masm32\bin」。如果要從相對路徑，得到上層目錄，就要使用連續的兩個「..」，例如上述操作的第三條指令。因為「C:」磁碟機的現在目錄是「C:\masm32\」，上層目錄就是「C:\」，即「C:」磁碟機的根目錄，所以「dir c:..\m*.*」的意思，就是顯示「C:」磁碟機根目錄裏所有以「m」開頭的檔案或目錄。

get_parameter 副程式的目的是在「命令提示列」中提取 FN2TC 的參數，而 FN2TC 的參數最多有兩個。藉由呼叫 GetCommandLine API 可以取得命令列的參數位址，當然分析完之後要把結果，做成資料返回主程式。但因為返回主程式的資料太多，因此小木偶把這些資料集合起來，變成 PATHFILEDATA 結構體。因此 get_parameter 有兩個參數，pCL 與 pPFD，前者是命令字串位址，後者是 PATHFILEDATA 結構體位址。兩者都要在呼叫 get_parameter 之前，就已設定好。而 pCL 與 pPFD 的意義，見 FN2TC 的第 116∼133 行。

https://zhidao.baidu.com/question/1829870312612506220.html