在上面的輸入字串編輯框輸入文字後，按下「轉換」按鈕後，就會在底下的輸出字串編輯框內出現轉換後的結果，它們就是對應「中華民國」四字的 UCS－2 編碼，見上圖右邊對話盒。然後可以按下「複製」按鈕將結果複製到剪貼簿，然後就可以在應用程式的原始碼中貼上這一串十六進位數，甚至後面還有註解說明這串十六進位數是什麼。是不是很方便？這一章小木偶打算編寫一個應用程式，A2U.ASM，它能夠把中文字、英文字母、阿拉伯數字或符號轉換成以 UCS－2 編碼表示。A2U 是一種工具程式，可以用來撰寫以組合語言為開發工具，而且其字串為萬國碼編碼的應用程式。例如，要在應用程式中定義一字串「中華民國」，執行 A2U 後生成下圖左邊的對話盒
在上面的輸入字串編輯框輸入文字後，按下「轉換」按鈕後，就會在底下的輸出字串編輯框內出現轉換後的結果，它們就是對應「中華民國」四字的 UCS－2 編碼，見上圖右邊對話盒。然後可以按下「複製」按鈕將結果複製到剪貼簿，然後就可以在應用程式的原始碼中貼上這一串十六進位數，甚至後面還有註解說明這串十六進位數是什麼。是不是很方便？
A2U 的原理其實很簡單，並沒有想像中的困難。前面提過，有關處理文字的 Win64 API 都有兩個版本，ANSI 版本與寬字元版本。一般而言，如果應用程式支援萬國碼，那麼都應該呼叫寬字元版的 Win64 API，否則呼叫 ANSI 版的。但這並非鐵律，事實上要呼叫哪一種版本的 Win64 API，其實應用程式可以自行決定。甚至可以在一應用程式所呼叫的 Win64 API，有些是 ANSI 版，有些是寬字元版。
假如在原始程式中一開始，沒有宣告
UNICODE EQU 1
那麼呼叫處理文字的 Win64 API 都是 ANSI 版，如果要呼叫寬字元版，可以自行於 API 函式名稱之後自行加入「W」即可。
A2U 就屬於這種情形。使用者於輸入字串編輯框內輸入文字，可以經由 GetWindowTextW 與 GetWindowTextA 取得輸入文字，前者是 UCS－2 編碼，後者是 ANSI 編碼。這裏必須直接指定呼叫的函式名稱，這名稱結尾的「W」不能省略，「A」卻可以省略。這是因為沒宣告「UNICODE EQU 1」，所以 GetWindowText 等於 GetWindowTextA。
以上面為例，如果使用者輸入「中華民國」字串，那麼 A2U 將其變成「 DW 4e2dh,83efh,6c11h,570bh,0 ;中華民國」。在「 DW 」與「;中華民國」之間的一連串十六進位數值字串，是經由 GetWindowTextW 取得的萬國碼字元計算得到的；其後的「;中華民國」則是經由 GetWindowTextA 取得的 ANSI 字元得到的。
由 GetWindowTextW 與 GetWindowTextA 取得的資料要放在哪兒呢？A2U 可以在 .DATA 區段裏準備一塊記憶體空間，供它們使用。但這種方法不太好，因為撰寫原始程式時，並不知道使用者輸入多少文字。A2U 採用另一種方法，向作業系統申請配置記憶體來存放它們。
有關向 Windows 提出配置記憶體的方式，提供了好幾種方式，可以花費許多篇幅詳細描述。不過這個網頁只是入門，所以也只是簡略描述兩種記憶體管理方式：①全域記憶體、②堆積。
向 Windows 申請配置記憶體，早在 Windows 3.1 時代就有，那時候記憶體有兩種類型，全域（global）與局部（local）的，前者所得到的記憶體在另一區段，後者在同一區段。到了 Windows 95 以及其後的版本，每個應用程式都有自己獨立的 4GB 記憶體，不再區分全域與局部。應用程式向 Windows 要求配置記憶體，通常是呼叫 GlobalAlloc，雖然在 Win64 API 中還是有 LocalAlloc，應用程式仍然可以呼叫它；不過 LocalAlloc 內卻是呼叫 GlobalAlloc 來配置記憶。底下僅說明 GlobalAlloc。
GlobalAlloc 用於配置全域記憶體，這裏雖然用「全域」二字，但其實就是配置一塊記憶體，「全域」二字是沒什麼意義的。GlobalAlloc 的原型是：
invoke GlobalAlloc,\
uFlags,\ ; object allocation attributes
dwBytes ; number of bytes to allocate
uFlags 是指定配置記憶體的屬性，可以有下面幾種情形：
| uFlags | 數值 | 說明 |
| GMEM_FIXED | 0 | 分配固定記憶體區塊。分配的記憶體區塊不會移動，GlobalAlloc 返回時，回傳值就是所分配的記憶體區塊的起始位址。 |
| GMEM_MOVEABLE | 2 | 分配可移動記憶體區塊。必須使用 GlobalAlloc 的回傳值作為 GlobalLock 的參數進行鎖定，才能獲取記憶體區塊的起始位址。 |
| GMEM_ZEROINIT | 40h | 將分配的記憶體區塊內所有位元組都設為零。 |
| GHND | 42h | 相當於 GMEM_MOVEABLE 與 GMEM_ZEROINIT。 |
| GPTR | 40h | 相當於 GMEM_FIXED 與 GMEM_ZEROINIT |
如果 GlobalAlloc 執行失敗，回傳值是 0，可呼叫 GetLastError 取得錯誤碼。如果 GlobalAlloc 執行成功，那麼回傳值是記憶體區塊代碼，可分為兩種情形：
不論固定或可移動的記憶體區塊，在不使用之後都必須呼叫 GlobalFree 釋放記憶體區塊。此外，GlobalAlloc 與其他記憶體管理函式，例如 HeapAlloc，比較起來效率較差，且功能較少。所以微軟建議，應用程式應該使用 HeapAlloc。然而，GlobalAlloc 仍然擅長與 DDE、剪貼簿函式和 OLE 資料物件一起使用。
當應用程式已不需要 GlobalAlloc 或 GlobalReAlloc 所配置的記憶體區塊時，呼叫 GlobalFree 釋放這塊記憶體空間，它的用法是：
invoke GlobalFree,\
hMem ; handle to the global memory object
hMem 是記憶體區塊代碼，它是 GlobalAlloc 或 GlobalReAlloc 的回傳值。如果 GlobalFree 執行成功，回傳值為 0；否則回傳值就是原參數。
堆積這個名字取得很奇怪，但是可以把它想成是一種記憶體。堆積可以分為兩種：①預設堆積（default process heap）與②私有堆積（private heap）。
當 Windows 作業系統執行應用程式時，都會為該應用程式建立預設堆積。預設堆積通常是給系統使用的，例如使用者執行 ANSI 版的應用程式並且輸入文字時，這些文字是 ANSI 編碼。而在 Windows XP 以及其後的作業系統核心是用萬國碼編碼，這時候系統會自動把輸入的文字轉變為萬國碼。在轉換過程中，需要記憶體時用到的就是預設堆積。那麼應用程式是否可以使用預設堆積呢？答案是可以的，但這樣容易造成混亂。
基於上述原因，以及效率，應用程式也可以建立自己的私有堆積。注意！預設堆積是 Windows 建立的，應用程式只是將它拿來使用而已，所以是呼叫 GetProcessHeap，用 Get 並非 Create；而私有堆積卻是自行建立的，所以是呼叫 HeapCreate，非 Get。底下先介紹如何向 Windows 獲得預設堆積的代碼以及建立私有堆積。
如果要使用預設堆積的話，必須先呼叫 GetProcessHeap，它沒有參數：
invoke GetProcessHeap
如果失敗，回傳值是零，可以呼叫 GetLastError 得到錯誤代碼；如果呼叫成功，回傳值是該應用程式的預設堆積代碼。得到此堆積代碼後還必須向 Windows 申請，在此堆積內分配記憶體區塊，才能真正使用記憶體，呼叫 HeapAlloc 可以達成此目標。
HeapCreate 用於建立私有堆積，它的原型是：
invoke HeapCreate,\
flOptions,\ ; heap allocation flag
dwInitialSize,\ ; initial heap size
dwMaximumSize ; maximum heap size
如果 HeapCreate 執行失敗回傳值是 0；如果 HeapCreate 執行成功回傳值是私有堆積代碼，還須向 Windows 申請，在此堆積內分配記憶體區塊，才能真正使用記憶體，同樣是呼叫 HeapAlloc 達成此目標。HeapCreate 的三個參數意義如下：
| flOptions | 數值 | 說明 |
| HEAP_NO_SERIALIZE | 1 | 在只有一個執行緒或多個執行緒但只有一個執行緒呼叫該特定堆積函數時，使用 HEAP_NO_SERIALIZE 可增加效率。 |
| HEAP_GENERATE_EXCEPTIONS | 4 | 當在堆積內分配記憶體區塊發生錯誤時，產生例外（exception）而非傳回零。見稍後的 HeapAlloc。 |
| HEAP_CREATE_ENABLE_EXECUTE | 40000h | 在預設的情形下，所建立的堆積不論其內容為何，都是不可執行的，這是為了增強系統的安全性。但如果指定了 HEAP_CREATE_ENABLE_EXECUTE，則可以執行其內的機械碼。 |
| 0 | 0 | 如果都不需要上面三種情形，可以設為 0。 |
有關 HEAP_NO_SERIALIZE 的描述，稍後在 HeapAlloc 會再一起說明。
HeapAlloc 用於向系統申請分配位於堆積內的記憶體區塊，系統會從堆積中分配一塊記憶體區塊給應用程式使用。HeapAlloc 的原型是：
invoke HeapAlloc,\
hHeap,\ ; handle to the private heap block
dwFlags,\ ; heap allocation control flags
dwBytes ; number of bytes to allocate
| dwFlags | 數值 | 說明 |
| HEAP_NO_SERIALIZE | 1 | 如果呼叫 HeapCreate 時已指定 HEAP_NO_SERIALIZE，呼叫 HeapAlloc 時就不需再指定此選項，因為分配到的記憶體區塊會延續堆積的性質。 |
| HEAP_GENERATE_EXCEPTIONS | 4 | 如果呼叫 HeapCreate 時已指定 HEAP_GENERATE_EXCEPTIONS，呼叫 HeapAlloc 時就不需再指定此選項，因為分配到的記憶體區塊會延續堆積的性質。 |
| HEAP_ZERO_MEMORY | 8 | 把分配到的記憶體區塊內容設為零。 |
| 0 | 0 | 如果都不需要上面三種情形，就可以把 dwFlags 設為 0。 |
如果 HeapAlloc 執行成功，回傳值是分配到的記憶體區塊起始位址，應用程式可利用此位址存取該記憶體區塊，也能以此位址為參數呼叫 HeapFree 釋放記憶體區塊。如果 HeapAlloc 執行失敗，且沒有指定 HEAP_GENERATE_EXCEPTIONS，回傳值是零；如果有指定 HEAP_GENERATE_EXCEPTIONS，可能會產生下表中的一個例外狀況，如需詳細資訊，請參閱 GetExceptionCode。
| 例外狀況 | 說明 |
| STATUS_NO_MEMORY | 因為缺少可用的記憶體或堆積損毀。 |
| STATUS_ACCESS_VIOLATION | 因為堆積損毀或函式參數不正確。 |
釋放 HeapAlloc 或 HeapReAlloc 所配置的記憶體區塊，原型是：
invoke HeapFree,\
hHeap,\ ; handle to the heap
dwFlags,\ ; heap freeing flags
lpMem ; pointer to the memory to free
hHeap 是堆積代碼，指出要釋放的記憶體區塊位於哪一個堆積內，它是 HeapCreate 或 GetProcessHeap 的回傳值。dwFlags 的意義與 HeapCreate 的 flOptions 參數相同，請自行參閱。lpMem 要釋放的記憶體區塊位址，它是 HeapAlloc 或 HeapReAlloc 的回傳值。如果 HeapFree 執行成功，則回傳值為非零；如果執行失敗，回傳值為零，呼叫 GetLastError 以取得更多資訊。
一旦呼叫 HeapFree 成功之後，被釋放的記憶體區塊內容有可能已被修改，所以不應該再去存取它。如果對相同的 lpMem 呼叫兩次 HeapFree 可能會造成堆積毀損，要謹慎。
對於應用程式已不再需要的私有堆積，應該呼叫 HeapDestroy 摧毀掉，以節省系統資源。HeapDestroy 的原型是：
invoke HeapDestroy,\
hHeap ; handle to the heap
hHeap 是要摧毀的堆積代碼。HeapDestroy 只能摧毀私有堆積；預設堆積是無法摧毀，除非結束應用程式。如果私有堆積內有許多呼叫 HeapAlloc 或 HeapReAlloc 生成的記憶體區塊未釋放，也可以直接呼叫 HeapDestroy 一次就全部摧毀。
A2U 的名稱是 ANSI 字元變成萬國碼字元（ANSI to unicode 之意），原始程式如下：
1 2 3 4 5 6
7 8 9 10 11 12
13 14 15 16 17 18
19 20 21 22 23 24
25 26 27 28 29 30
31 32 33 34 35 36
37 38 39 40 41 42
43 44 45 46 47 48
49 50 51 52 53 54
55 56 57 58 59 60
61 62 63 64 65 66
67 68 69 70 71 72
73 74 75 76 77 78
79 80 81 82 83 84
85 86 87 88 89 90
91 92 93 94 95 96
97 98 99 100 101 102
103 104 105 106 107 108
109 110 111 112 113 114
115 116 117 118 119 120
121 122 123 124 125 126
127 128 129 130 131 132
133 134 135 136 137 138
139 140 141 142 143 144
145 146 147 148 149 150
151 152 153 154 155 156
157 158 159 160 161 162
163 164 165 166 167 168
169 170 171 172 173 174
175 176 177 178 179 180
181 |
;A2U把位於輸入編輯框內的字串變成萬國碼，顯示於下方的輸出編輯框。輸出編輯框
;內是萬國碼字元所代表的十六進位數值，其後是中文字註解。例如使用者輸入「這
;是萬國碼」，輸出編輯框變成(;之後的中文註解自第80個位元組開始)
; DW 9019h,662fh,842ch,570bh,78bch,0 ;這是萬國碼
OPTION CASEMAP:NONE
OPTION WIN64:3
IDD_DLG EQU 1000
IDE_IN EQU 1001
IDE_OUT EQU 1002
IDB_CNVT EQU 1003
IDB_COPY EQU 1004
IDB_QUIT EQU 1005
ID_ICON EQU 1006
INCLUDE WINDOWS.INC
INCLUDE COMMCTRL.INC
INCLUDELIB KERNEL32.LIB
INCLUDELIB USER32.LIB
INCLUDELIB COMCTL32.LIB
;*******************************************************************************
.CONST
sDW DB " DW "
szFmtN DB "%xh,",0
szFmtZ DB "0%xh,",0
;*******************************************************************************
.DATA
hInst DQ ? ;模組代碼
hEdtIn DQ ? ;輸入字串編輯框代碼
hEdtOut DQ ? ;輸出字串編輯框代碼
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
cnvt PROC USES rsi rdi r12 r13 r14 r15
LOCAL hHeap:QWORD,pMemA:QWORD,pMemW:QWORD,pMemO:QWORD
LOCAL len:DWORD,cbIn:DWORD,cbOut:DWORD,col:DWORD
LOCAL buffer[32]:BYTE ;用於暫時存放hEdtOut最後面的註解
;計算所需要得堆積空間，為輸入字串編輯框內的字元數乘以4，再加上輸出編輯框所需空間
invoke GetWindowTextLengthW,hEdtIn
or eax,eax ;EAX＝hEdtIn編輯框內字串的字元數
jz exit
inc eax ;EAX加一是為了在結尾加上0
mov r8d,eax
shl r8d,1 ;R8D＝需多少位元組才能容納hEdtIn內的字串
mov cbIn,r8d ;pMemA、pMemW有多少位元組，兩者相同
mov r10d,11
sub rdx,rdx
div r10d ;hEdtOut每行大約有11個中文字
inc eax ;不管能否整除，都增加一行
shl eax,7 ;hEdtOut每行大約一百零幾個位元組，所以乘以128較快
mov cbOut,eax ;pMemO有多少位元組
shl r8d,1 ;乘以2是因為pMemA、pMemW長度一樣
add eax,r8d
mov hHeap,RV(HeapCreate,0,eax,0)
;由堆積中分配三塊記憶體pMemA、pMemW、pMemO，分別存放輸入字串編輯框內容的ANSI字串
;、寬字元字串以及輸出字串編輯框的內容
mov pMemA,RV(HeapAlloc,hHeap,HEAP_ZERO_MEMORY,cbIn)
mov r12,rax ;R12用於指向輸入編輯框以ANSI編碼的內容指標
mov pMemW,RV(HeapAlloc,hHeap,HEAP_ZERO_MEMORY,cbIn)
mov r13,rax ;R13用於指向輸入編輯框以寬字元編碼的內容指標
mov pMemO,RV(HeapAlloc,hHeap,HEAP_ZERO_MEMORY,cbOut)
mov rdi,pMemO
;讀取輸入字串編輯框的內容兩次，分別以ANSI字串、寬字元字串存入pMemA、pMemW內
mov r8d,cbIn
shr r8d,1
invoke GetWindowTextW,hEdtIn,pMemW,r8d
mov len,eax
invoke GetWindowTextLengthA,hEdtIn
inc eax
invoke GetWindowTextA,hEdtIn,pMemA,eax
;開始處理pMemW、pMemA的內容。每次取出pMemW內的一個字元，此為寬字元，每字元兩位元組
;hEdtOut一行的開始都是「 DW 」，並設R14為buffer位址、使col歸零
bgn_ln: mov rcx,SIZEOF sDW
mov rsi,OFFSET sDW
mov col,ecx
rep movsb
lea r14,buffer
;讀取在pMemW內R13所指位址上的字元，此字元為萬國碼，讀取後存於R15W，呼叫wsprintf
;將其轉換為十六進位數值字串，填入「 DW 」與註解之間的區域內
next: movzx r15,WORD PTR [r13]
.if r15w>=0a000h ;若R15W大於或等於0A000h，必須在十六進位數值前加「0」
lea rdx,szFmtZ;否則組譯器會誤認為是變數名稱
.else
lea rdx,szFmtN
.endif
invoke wsprintf,rdi,rdx,r15d
mov r10,rax
add r10d,col
;檢查十六進位的數值字串是否已達第80格
cmp r10d,80
ja end_ln ;如果有，跳至end_ln
add rdi,rax
add r13,2
mov col,r10d
;把在pMemA內R12所指位址上的字元存入buffer內R14所指的位址上
mov dx,[r12]
.if r15w<100h
mov [r14],dl ;如果R15W<100，表示DX是英文字母或阿拉伯數字，僅需把一個位
inc r12 ;元組移至R14所指的位址上
inc r14
.else
mov [r14],dx ;否則DX是Big5編碼的中文字，應移動兩個位元組
add r12,2
add r14,2
.endif
dec len ;檢查pMemW中還有沒有未處理的字元
jnz next ;若len等於0，表示所有在pMemW內的字元都處理完成，那
mov ax,2030h ;麼先存入「 0」，再於十六進位數值之後至第80格之間填
stosw ;入空白，最後將buffer內的資料移至EDI所指位址
add col,2
;於十六進位的數值字串之後至第80格之間，填入空白
end_ln: mov rcx,81
dec rdi ;除去「,」
sub ecx,col
jle no_blk ;如果RCX等於零或小於零，就不需要填上空白
mov al," " ;由col至第80格都要填上空白
rep stosb
no_blk: mov al,";" ;「;」是註解的開始
stosb
;把buffer的內容移至RDI所指位址(buffer的內容是註解)
lea rsi,buffer
mov rcx,r14
sub rcx,rsi
rep movsb
mov ax,0a0dh ;換行及歸位字元
stosw
cmp len,0 ;若len等於0，表示全部處理完成
jnz bgn_ln
mov BYTE PTR [rdi-2],0
invoke SetWindowText,hEdtOut,pMemO
invoke HeapDestroy,hHeap
exit: ret
cnvt ENDP
;-------------------------------------------------------------------------------
DlgProc PROC hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
.if uMsg==WM_INITDIALOG
;設定對話盒標題欄的圖示
invoke SendMessage,hDlg,WM_SETICON,ICON_SMALL,RV(LoadIcon,hInst,ID_ICON)
;獲得輸入編輯框、輸出編輯框代碼
mov hEdtIn,RV(GetDlgItem,hDlg,IDE_IN)
mov hEdtOut,RV(GetDlgItem,hDlg,IDE_OUT)
.elseif uMsg==WM_COMMAND
mov rax,r8 ;R8W＝識別碼
shr rax,10h ;AX＝通知碼
.if ax==BN_CLICKED
.if r8w==IDB_QUIT
jmp quit
.elseif r8w==IDB_CNVT
call cnvt
.elseif r8w==IDB_COPY
invoke GetWindowTextLength,hEdtOut ;檢查hEdtOut編輯框內是否有文字
.if eax!=0
invoke SendMessage,hEdtOut,EM_SETSEL,0,-1 ;選擇hEdtOut編輯框所有文字
invoke SendMessage,hEdtOut,WM_COPY,0,0 ;複製到剪貼簿內
.endif
.endif
.endif
.elseif uMsg==WM_CLOSE
quit: invoke EndDialog,hDlg,0
.else ;其他未處理的訊息返回 FALSE
xor rax,rax
ret
.endif ;已處理的訊息，返回 TRUE
mov rax,1
ret
DlgProc ENDP
;-------------------------------------------------------------------------------
main PROC
call InitCommonControls
mov hInst,RV(GetModuleHandle,0)
invoke DialogBoxParam,hInst,IDD_DLG,0,OFFSET DlgProc,0
invoke ExitProcess,0
main ENDP
;*******************************************************************************
END main |
底下是 A2U.RC：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28 |
#include "RESOURCE.H"
#define MANIFEST 24
#define IDD_DLG 1000
#define IDE_IN 1001
#define IDE_OUT 1002
#define IDB_CNVT 1003
#define IDB_COPY 1004
#define IDB_QUIT 1005
#define ID_ICON 1006
IDD_DLG DIALOGEX 340,150,228,104
CAPTION "Big5碼轉換成Unicode"
FONT 10,"Courier New",400,0,0
STYLE WS_VISIBLE|WS_OVERLAPPEDWINDOW
BEGIN
LTEXT "輸入字串：",1,3,3,40,10
EDITTEXT IDE_IN ,45, 3,177,39,ES_AUTOVSCROLL|ES_MULTILINE
LTEXT "輸出字串：",2,3,45,40,10
EDITTEXT IDE_OUT,45,45,177,39,ES_MULTILINE|ES_AUTOHSCROLL|ES_AUTOVSCROLL|ES_READONLY
DEFPUSHBUTTON "轉換",IDB_CNVT, 69,88,45,12
PUSHBUTTON "複製",IDB_COPY,123,88,45,12
PUSHBUTTON "離開",IDB_QUIT,177,88,45,12
END
1 MANIFEST "a2u.exe.manifest"
ID_ICON ICON "unicode.ico" |
底下是 A2U.EXE.MANIFEST：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 |
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
<assemblyIdentity
type="win32"
name="AtHome.Wanker.A2U"
version="1.0.0.0"
processorArchitecture="amd64"
/>
<dependency>
<dependentAssembly>
<assemblyIdentity
type="win32"
name="Microsoft.Windows.Common-Controls"
version="6.0.0.0"
processorArchitecture="amd64"
publicKeyToken="6595b64144ccf1df"
language="*"
/>
</dependentAssembly>
</dependency>
</assembly>
|
把上述 A2U.ASM、A2U.RC、A2U.EXE.MANIFEST 都存入「E:\HomePage\SOURCE\Win64\UNICODE」子目錄內，然後開啟「命令提示字元」，輸入下面指令組譯與連結：
Microsoft Windows [版本 10.0.19045.5131] (c) Microsoft Corporation. 著作權所有，並保留一切權利。 C:\Users\wanker>set include=c:\uasm\include [Enter] C:\Users\wanker>set lib=c:\uasm\lib64 [Enter] C:\Users\wanker>path c:\uasm;c:\uasm\bin64 [Enter] C:\Users\wanker>e: [Enter] E:\>cd HomePage\SOURCE\Win64\UNICODE [Enter] E:\HomePage\SOURCE\Win64\UNICODE>uasm64 -win64 a2u.asm [Enter] UASM v2.57, Aug 10 2024, Masm-compatible assembler. Portions Copyright (c) 1992-2002 Sybase, Inc. All Rights Reserved. Source code is available under the Sybase Open Watcom Public License. a2u.asm: 176 lines, 3 passes, 366 ms, 0 warnings, 0 errors E:\HomePage\SOURCE\Win64\UNICODE>rc a2u.rc [Enter] Microsoft (R) Windows (R) Resource Compiler Version 10.0.10011.16384 Copyright (C) Microsoft Corporation. All rights reserved. E:\HomePage\SOURCE\Win64\UNICODE>link a2u.res a2u.obj [Enter] Microsoft (R) Incremental Linker Version 14.25.28614.0 Copyright (C) Microsoft Corporation. All rights reserved. E:\HomePage\SOURCE\Win64\UNICODE>
A2U.ASM 最重要的部分就是 cnvt 副程式，所以直接切入主題，先解說 cnvt 副程式。
進入 cnvt 副程式的第一條指令在第 41 行，是呼叫 GetWindowTextLengthW 求出輸入字串編輯框內的字元個數。輸入字串編輯框的代碼是 hEdtIn，在第 138 行呼叫 GetDlgItem 可以得到。注意！GetWindowTextLengthW 後有個「W」，表示是以萬國碼編碼去計算字元個數。例如假如使用者輸入「香草幽蘭」，那麼回傳值就是 4，需要 8 個位元組的空間才能容納 hEdtIn 的文字；假如輸入的是「Vanilla Orchid」，那就有 14 個字元，需 28 個位元組的空間。
接下來要呼叫 HeapCreate 建立私有堆積，如成功建立堆積代碼存於 hHeap 內，這個私有堆積內需要容納三個記憶體區塊：
①起始位址為 pMemW 的記憶體區塊，儲存 hEdtIn 內的字串，此字串以萬國碼編碼而成。
②起始位址為 pMemA 的記憶體區塊，儲存 hEdtIn 內的字串，此字串以 ANSI 編碼而成。
③起始位址為 pMemO 的記憶體區塊，儲存 A2U 處理 hEdtIn 的最後結果，也是輸出編輯框的內容。
因為 hHeap 要容納這三個記憶體區塊，所以把它的初始大小設為這三個記憶體區塊大小之和。（此大小以位元組為單位）
先說明如何得到 pMemW 記憶體區塊需要多少位元組。前面提過呼叫 GetWindowTextLengthW 即可得到在 hEdtIn 內的字元個數，因為是呼叫寬字元版本，所以所得的字元數是指以萬國碼編碼所得的字元數，可是並不包含零。為了表示字串的結尾所以 A2U 把呼叫 GetWindowTextLengthW 的回傳值再加一，以儲存 0。而每個萬國碼字元佔了兩個位元組，必須再乘以 2 才是 pMemW 的大小，這是以位元組為單位。乘以 2 可以用向左移一個位元，亦即「SHL R8D,1」代替（第 46 行）。最後把結果存於 cbIn 變數內。這段程式在第 42∼47 行。
在 A2U 裏簡化了設定 pMemA 的大小。還記得嗎？用 ANSI 編碼的字元，英文字母佔了一個位元組，中文字佔用了兩個位元組（這兒的中文字是相容於 ANSI 編碼的 Big5 編碼，見前一章），而 pMemA 的大小可以比實際所需大，卻不可比較小，否則就會發生錯誤。對比前面說萬國碼編碼的英文字母佔了兩個位元組，一定比較多，所以直接使 pMemA 記憶體區塊大小（以位元組為單位），也等於 cbIn。
還剩下要計算出 pMemO 的大小，舉個例子可能比較好瞭解。假如在 hEdtIn 內使用者輸入的字串是「唱九歌，吟離騷，楚辭寫竹簡。」，那麼在 hEdtOut 的字串如下圖所示：
這也是 pMemO 的內容。當然在 pMemO 內的字元依序排好並不會換下一列，A2U 必須自行加上換行及歸位字元（圖二並未顯示這兩個字元），才可以在 hEdtOut 顯示如上圖的樣子。圖二中的「DW」前後的淡藍色方框代表空白；中間是「唱九歌，吟離騷，楚辭寫竹簡。」轉換成十六進位後形成的數值，姑且稱為十六進位數值字串；最後面是註解。由圖二看來，一行最多 11 個字，加上「 DW 」以及後面的中文註解、換行及歸位字元，每行約一百零餘個位元組。寧願多算一些也不要算太少而發生錯誤，所以假設每一行有 128 個位元組。第 50 行先把 hEdtIn 內的字元數（包含結尾記號的 0）除以 11，所得的商加一（餘下的字元也要佔一行），就得到 hEdtOut 會有幾行；再乘以 128（可以用向左移 7 個位元替代），得到的就是 pMemO 的大小，存於 cbOut 內，以位元組為單位，見第 48∼53 行。最後得到私有堆積的初始大小，為 cbIn×2＋cbOut，見 54∼55 行。
私有堆積和記憶體區塊大小都已算出，接下來的第 56∼64 行就是建立私有堆積與在此堆積內分配記憶體區塊。注意！在第 56 行，呼叫 HeapCreate 建立私有堆積時，把它設為「可成長」的堆積，這樣比較有彈性。
A2U 用 R12、R13、RDI 三個暫存器作為指標，分別指向 pMemA、pMemW、pMemO 記憶體區塊。每當讀取 pMemA 內的一個字元，R12 會視英文字母或中文字而增加一或二，指向下次要讀取的字元；每次讀取 pMemW 內的一個字元，R13 會隨之增加二；每次把資料寫入 pMemO，RDI 會隨著寫入多少位元組就增加多少。
為什麼用這三個暫存器作為指標，不另設三個變數作為指標？原因在於它們是不變的暫存器，在呼叫 Win64 API 之後，其值也不改變，所以即使在呼叫 wsprintf 之後，也能保持其指標。要達到這個目的，可以在第 36 行使用 USES 選項，在其之後所列出來的暫存器，都會在 cnvt 副程式一開始將其推入堆疊，而在結束 cnvt 前再由堆疊取回原值。
在接下去說明之前，把 pMemA、pMemW、pMemO 三個記憶體區塊整理成下表：
| 記憶體區塊 | 編碼方式 | 每字元佔多少位元組 | 指標 |
| pMemA | ANSI | 英文字：一個位元組 中文字：兩個位元組 | R12 |
| pMemW | UCS－2 | 兩個位元組 | R13 |
| pMemO | ANSI | 英文字：一個位元組 中文字：兩個位元組 | RDI |
第 65∼72 行，讀取 hEdtIn 的內容兩次，第一次是把 hEdtIn 內的字元以 UCS－2 的編碼讀出存於 pMemW 內，第二次則是以 ANSI 的編碼方式讀出存入 pMemA 裏面。接下來進入 cnvt 最重要的部分：進入迴圈把 pMemA、pMemW 記憶體區塊的內容轉換成圖二的樣子，並存入 pMemO 記憶體區塊內，直至 len 變為零為止（len 是 pMemW 內所含的字元個數）。其流程圖如右：
這裏先說明 col 變數的意義。參考圖二的黃色字可知，它是用來記錄某一列已存入幾個位元組的資料，因為 hEdtOut 內的編碼是 ANSI，所以也代表這一列已存入幾個字元。設置 col 變數的目的是要計算在什麼時候要換下一列。底下說明 cnvt 最重要的部分，參考右圖①∼②（A2U.ASM 第 75∼78 行），每一列一開始是把「 DW 」字串存入 pMemO 記憶體區塊內 RDI 所指的位址上，而「 DW 」字串有 11 個字元，所以每列的一開始，col 就等於 11（也就是「SIZEOF sDW」，其中的空白並沒完全表示出來）。
這裏還設定 R14 為 buffer 的位址，buffer 是用來暫時存放註解。A2U 是在同一次迴圈內讀取 pMemW 內的 UCS－2 字元以及讀取在 pMemA 內的 ANSI 字元，舉個例子說明較易瞭解。假如使用者在 hEdtIn 中輸入「中華民國=ROC」，那麼在 pMemW 與 pMemA 中的內容分別是：
第一次執行迴圈時，A2U 先讀取 UCS－2 編碼的「中」字，4e2dh，將其換成十六進位數值字串存於 pMemO 內 RDI 所指位址（圖三④∼⑥，A2U.ASM 第 82∼88 行），然後把 R10D 設為 col，再把 R10D 加上剛剛存入的十六進位數值字串有幾個位元組，檢查 R10D 是否超過 80（圖三⑦∼⑧，A2U.ASM 第 89∼92 行）。如果沒有，就把 RDI、R13、col 設為正確值並讀取 pMemA 中的 Big5 碼 0a4a4h，將其存入 buffer 中 R14 所指的位址上（圖三⑨∼⑩，A2U.ASM 第 94∼107 行）。
在這次迴圈執行中，把十六進位數值字串存於 RDI 所指位址，也把 Big5 碼存於 R14 所指的位址。這樣就完成一個字元的處理，使 len 減一，即圖二⑪∼⑫（A2U.ASM 第 108∼109 行）。如此，每次迴圈都處理在 pMemW 與 pMemA 的字元各一個，直至所有字元都處理完畢，len 也會減至 0，這時要把字元「"0"」存入，作為字串的結尾，圖二的⑬（A2U.ASM 第 110∼111 行）。
這時不論 col 有沒有到達 80，都要把最後一列暫時存放於 buffer 內的 ANSI 字元移至 RDI 所指位址。還有一種情形，也要完成同樣的事，那就是如果 col 等於 80 或超過 80 時也要做同樣的事，即右圖⑮，A2U.ASM 第 122∼126 行。當然在這之前，要用空白填充至第 80 格，這段程式在 A2U.ASM 第 113∼119 行。
上面解釋了 A2U.ASM 最重要的部分，除了還剩一小部分未解釋，沒在圖二中畫出來。這一小部分是在 A2U.ASM 的第 97∼107 行，從 pMemA 中 R12 所指的位址中取出一字元，存於 buffer 中 R14 所指位址中時，這一字元有可能是一個位元組，也可能是兩個位元組。取決於這個字元是哪一種文字，如果是英文及阿拉伯數字，則字元佔一個位元組；如果是中文字，則佔兩個位元組。那麼要如何判別呢？A2U.ASM 所採用的方法是，在相對應的 pMemW 中的字元可提供線索，如果是前者，那麼高位元組是零；如果是後者，高位元組不是零。
在 cnvt 最後面，就是把 pMemO 的內容設為 hEdtOut 的內容，以及摧毀堆積。摧毀堆積前，不需要一一釋放堆積內的三個記憶體區塊。
使用者按下 A2U 對話盒的複製按鈕，會把 hEdtOut 內容複製到剪貼簿內。這是怎麼做到的呢？在 A2U.ASM 第 154∼157 行闡明這件事。首先呼叫 GetWindowTextLength API 檢查 hEdtOut 內容的長度是否為零，如果為零表示 hEdtOut 沒有內容，不需處理。
GetWindowTextLength 用於計算視窗標題欄有多少個字元，因為控制項也是視窗的一種，所以它也可以計算控制項內的字元個數。它的原型是：
invoke GetWindowTextLength,\
hWnd ; handle of window or control with text
hWnd 是要取得字元個數的視窗代碼或控制項代碼。如果 GetWindowTextLength 執行成功，回傳值是字元個數；如果 hWnd 標題欄沒有文字，回傳值是零。在某些情形下，尤其是雙位元組字元集（DBCS），取得的字元個數可能會比實際得多。
假如對編輯框發出 EM_SETSEL 訊息的話，就能設定編輯框內選取的文字。方法是呼叫 SendMessage：
invoke SendMessage,hEdit,EM_SETSEL,wParam,lParam
EM_SETSEL 沒有回傳值。wParam 為選取開始的字元位置（最前面是位置零），lParam 為選取結束的字元後一個位置。如果 wParam 為 0 且 lParam 為－1，則會選取編輯框中的所有文字。如果 wParam 為－1，則會將目前的選取範圍取消。如果開始的字元位置比結束大，那麼系統會自動調整，以較小的為開始位置，較大的為結束位置。
例如編輯框的代碼是 hEdit，而其內的文字是「紛飛燕，繁花絢，綻放艷如仙。」，然後呼叫 SendMessage：
invoke SendMessage,hEdit,EM_SETSEL,4,9
那麼選取的文字是「繁花絢，綻」。這是因為「紛」的位置是零，「飛」的位置是一，所以位置四是「繁」；而位置九是「放」，但這是選取結束位置的後一個位置，所以位置八才是選取字元的結束位置，它是「綻」。假如寫成下面程式碼：
invoke SendMessage,hEdit,EM_SETSEL,9,4
結果仍然一樣。
應用程式可以發送 WM_COPY 訊息給編輯框、簡單型複合框與下拉型複合框，這樣的話會把這三種控制項中被選取的文字，以 CF_TEXT 格式複製到剪貼簿上。呼叫時，wParam 與 lParam 均不使用，應設為零。例如編輯框的代碼是 hEdit，那麼底下的程式：
invoke SendMessage,hEdit,WM_COPY,0,0
能把 hEdit 中選取的文字複製到剪貼簿中。
有了 A2U 之後，要用組合語言撰寫萬國碼應用程式，不再是難事了。