第二十四章　萬國碼

緣起

這一章來說一說用組合語言設計 Win64 應用程式時，如何處理、儲存、顯示以萬國碼編碼的字元。首先說明什麼是萬國碼呢？在早期電腦剛發展的初期，大約是民國六、七十年的時候，那時候各國發展各自的字元編碼標準。眾所周知，電腦擅長的是處理數值，但是人類所使用的是各式各樣的文字，所謂字元編碼是指在電腦中以某個數值代表某個文字。

例如美國國家標準學會（American National Standard Institute，ANSI）制定的 ASCII（American Standard Code for Information Interchange，美國標準資訊交換碼），就是以 41h 代表 "A"，以 42h 代表 "B"……完整的 ASCII 碼可以查閱維基百科或 DOS 組合語言附錄四。其他國家也對自己的文字進行編碼，例如日本採用 Shift_JIS，中華民國、香港、澳門常用的是 Big5（大五碼），中國大陸常用的是 GB2312。有這麼多國家地區，採用不同的編碼方式，雖然他們的前面 128 碼都與 ASCII 相容，但還是會造成交換資訊的困難。

例如「豪傑」二字的 Big5 碼分別是 BBA8h、B3C7h，GB2312 中這兩數分別是「花」、「城」。假設在中華民國有個用 Big5 編碼的純文字檔，裏面有「豪傑」一詞；儲存在電腦中，不論式硬碟、隨身碟，都是 BBA8h、B3C7h 兩個十六進位數。如果拿到習慣以 GB2312 編碼的中國大陸上去，用他們的軟體開啟，「豪傑」就變成了「花城」，這誰還能看得懂？這還算好，至少這個例子還對應的是中文字，只是看得不知所云。如果是對應的是符號，或根本不用這數值編碼，那更是看不懂，這就是亂碼產生的原因。

到了網際網路發展並盛行的時代，這問題更加嚴重，不能再採用各行其是的編碼方式了。為了解決這個難題，自民國 73 年開始，有國際組織及許多知名國際廠商共同著手研究，於是在民國 80 年左右，他們公布了研究成果，意即 ISO 10646/Unicode 標準，簡稱 Unicode，中文可翻譯成萬國碼或統一碼。

萬國碼方式收集了幾乎全世界的語言文字與符號，都將其編碼，一個字統一用一個數值表示。經過這些年來的推動，現在已經成為放諸四海皆準的字元編碼方式了。採用這套編碼方式，甚至可以在同一文件中顯示不同的國家的文字。真正完成了使用電腦能顯示、儲存、傳送各國文字，落實統一全球文字交換標準。

這套萬國碼從開始發表的七千多字，逐年擴充，到今年（民國113年）為止，已收錄了十五萬字，還在逐步擴增中。說來可能很多人不敢相信，萬國碼竟然還收錄了古代埃及聖書體（從 13000h 開始是古代埃及聖書體字元）！

Windows 作業系統自 Windows 3.0 開始，編碼方式採用各自國家的編碼方式。例如在中華民國販售的 Windows 3.1 採用 Big5 碼，但在微軟內部稱為 code page 950，「code page」一般翻譯成內碼頁。在中國大陸採用 GB2312，內碼頁是 936；而日文版的 Windows 3.0，內碼頁為 932。

但同一時期，提供給企業用的 Windows NT 3.1 卻已採用萬國碼。後來供個人使用的 Windows 95/98/98 SE/Me 延續 Windows 3.x，仍採用 Big5 或 GB2312 編碼；Windows NT 3.5/4.0/2000 則採用萬國碼。民國 90 年發售的 Windows XP 整合個人與企業使用的系統，採用 Windows NT 的核心，用萬國碼編碼。

說到這兒，現在的 Windows 作業系統內部編碼方式早已是萬國碼，所以現代撰寫程式應該要考慮採用萬國碼編寫程式。那麼對於古老的組合語言來說，能否支援以萬國碼方式撰寫應用程式呢？當然是可以的，否則就不會有這一章了。

簡單的範例

英文字母的萬國碼表示方式

早期，ANSI 制定的 ASCII 編碼方式只採用 7 位元就已足夠。7 個位元能表示 27 個數值，一個數代表一個字，英文字母包含大、小寫共 52 個，加上十個阿拉伯數字及標點符號，127 個數字非常夠用。

但是，前面提過萬國碼的企圖心很大，打算將全世界古往今來，正在使用與曾經使用過的文字都納入其中。如果是這樣，必須使用四個位元組來編碼，四個位元組共 32 個位元，也就是雙字組（亦即組合語言常用的 DWORD），但規定雙字組的最高位元必須為零，所以可以編碼的總數高達 231 個，也就是可以使二十一億多個文字進行編碼，這樣的編碼稱為 UCS－4，它能夠涵蓋所有文字而綽綽有餘。USC 是 universal coded character set 的縮寫，中文可翻譯成通用字元集。

但現實是，即使包含中、日、韓三種常用的文字，總共也不會超過六萬個。假如真的使每個檔案的文字都用 UCS－4 編碼，那每個字都要占用四個位元組，非常浪費空間。於是許多人認為，如果採用兩個位元組來編碼，可以編碼的文字有 216 個文字，也就是 65536 個，已經可以滿足世界上常用的文字了，這樣的編碼方式稱為 UCS－2，它雖然無法涵蓋世界上所有文字，但卻能滿足絕大部份人在絕大部分情況使用。

UCS－2 轉變成 UCS－4 的方法只需再增加兩個位元組，而且這兩個位元組都是 0。例如「豪」字的萬國碼是 8C6Ah，這是 UCS－2 編碼方式；轉換成 UCS－4 就是 00008C6Ah。不論是 UCS－2 還是 UCS－4，對英文字母、阿拉伯數字及像「,」、「.」、「+」、「-」……等符號而言，都被編成與 ANSI 制定的 ASCII 碼一樣，這樣就能與早期的電腦相容。例如英文字母 "A" 的 ASCII 碼是 41h，轉換成 UCS－2 是 0041h，轉換成 UCS－4 是 00000041h。

結論就是，萬國碼至少可分為 UCS－2 與 UCS－4 兩種編碼方式（事實上還有更多編碼方式），如果所使用的文字是常用文字，那麼使用 UCS－2 就可以了，否則就必須使用 UCS－4。同一份文件或檔案裏只能選擇其中一種，不是 UCS－2 就是 UCS－4，不能混用，以免造成一個字不定長度的缺點。有鑑於 UCS－4 極其少用，所以底下的內容，如不特別聲明萬國碼編碼方式，都是指 UCS－2。

不論是 UCS－2 還是 UCS－4，不管哪種萬國碼編碼方式，都是以兩個位元組或超過兩個位元組的方式將文字編碼，所以應用程式內的文字如果是用萬國碼編成的，一般稱為寬字元應用程式（Wide Character Application）或萬國碼應用程式；如果是以 ANSI 制定的 ASCII 編碼的，可稱為 ANSI 應用程式。而在中華民國、香港等地區使用的 Big5 碼，是在 ASCII 的基礎上擴充一個位元組來表示中文，相容於 ASCII 編碼方式。所以，即使 Big5 編碼的中文字有兩個位元組，也屬於 ANSI 應用程式。在本章之前的程式，都屬於 ANSI 應用程式。

範例：FIRSTU.ASM

底下以第一章的 FIRST.ASM 為例子，說明如何使用組合語言撰寫寬字元應用程式，此程式稱為 FIRSTU.ASM，主檔名最後的 U 代表此為萬國碼版本。注意！因為組譯器，UASM64.EXE 或 ML64.EXE 都只能識別 ANSI/ASCII 格式的原始程式，所以即使編寫寬字元應用程式也是要把原始程式存成 ANSI/ASCII 格式。。原始程式，FIRSTU.ASM 如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
OPTION  CASEMAP:NONE
OPTION  WIN64:3
OPTION  LITERALS:ON     ;使invoke直接接受字串參數

UNICODE EQU     1       ;呼叫Win64 API的寬字元版本

INCLUDE         WINDOWS.INC
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB
;*******************************************************************************
.CONST
;因為「OPTION LITERALS:ON」，可以用「DW」把英文字母轉換成UCS-2編碼
szText  DW      "This sentence is encoded in UCS-2."
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
main    PROC
        invoke  MessageBox,0,OFFSET szText,L"Unicode String",MB_OK
        call    ExitProcess
main    ENDP
;*******************************************************************************
END     main

上面 FIRSTU.ASM 程式碼中以紫紅色標示出來的，就是撰寫萬國碼的關鍵，底下一一說明：

①、OPTION LITERALS:ON：「OPTION LITERALS:ON」假指令是 JWASM/UASM 新增的，主要用途有兩個：
⑴、使 DW 假指令 DW 能組譯以 ASCII 編碼的英文、阿拉伯數字字串，變成 UCS－2 編碼的字串。
⑵、使 INVOKE 假指令能接受字串常數。
預設的「OPTION LITERALS」值是 OFF。
②、加上「UNICODE EQU 1」，指定應用程式呼叫寬字原版本的 Win64 API。見第 5 行。
③、第 13 行的「DW」會把後面的英文字母、阿拉伯數字等組成的 ASCII 字串，逐個位元組拆解，並在高位址新增一個位元組，使高位址的位元組設為零，藉此形成萬國碼。同時自動在最後面加上一個字組的 0。當然，這必須在有「OPTION LITERALS:ON」的前提下。
④、第 18 行，在有「OPTION LITERALS:ON」的前提下，INVOKE 假指令可以直接接受字串常數。如果這個字串常數前有加上「L」，那麼 UASM64.EXE 會把由英文字母、阿拉伯數字等組成的 ASCII 字串，轉變成 UCS－2 編碼的字串。

組譯與連結方式是先開啟「命令提示字元」輸入下面黃色字的指令，製作出來的 FIRSTU.EXE 畫面如右圖：

Microsoft Windows [版本 6.1.7601]
Copyright (c) 2009 Microsoft Corporation.  All rights reserved.

C:\Users\wanker>uasm [Enter]  →執行 UASM.BAT 批次檔，省了許多打字輸入，見第 11 章 UASM.BAT

C:\Users\wanker>SET INCLUDE=C:\UASM\Include

C:\Users\wanker>SET LIB=C:\UASM\lib64

C:\Users\wanker>SET PATH=C:\UASM;C:\UASM\bin64;C:\Windows\system32;C:\Windows;C:
\Windows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\Program Fi
les (x86)\UltraEdit-32

C:\Users\wanker>E:

E:\>CD E:\HOMEPAGE\SOURCE\WIN64
LINK=/SUBSYSTEM:WINDOWS /DEBUG

E:\HomePage\SOURCE\Win64>cd UNICODE [Enter] →切換至 UNICODE 子目錄

E:\HomePage\SOURCE\Win64\UNICODE>uasm64 -win64 FIRSTU.ASM [Enter]
UASM v2.56, Oct 27 2022, Masm-compatible assembler.
Portions Copyright (c) 1992-2002 Sybase, Inc. All Rights Reserved.
Source code is available under the Sybase Open Watcom Public License.

FIRSTU.ASM: 22 lines, 3 passes, 519 ms, 0 warnings, 0 errors

E:\HomePage\SOURCE\Win64\UNICODE>link firstu.obj [Enter]
Microsoft (R) Incremental Linker Version 14.25.28614.0
Copyright (C) Microsoft Corporation.  All rights reserved.

/SUBSYSTEM:WINDOWS /DEBUG

E:\HomePage\SOURCE\Win64\UNICODE>

結論：要製作英文的寬字元應用程式，很簡單，只要在原始程式中設定「OPTION LITERALS:ON」，加入「UNICODE EQU 1」即可。前者使「DW」假指令定義萬國碼字元，後者使應用程式呼叫 Win64 API 的寬字元版本。

中文的寬字元應用程式

對於撰寫中文的寬字元應用程式就沒這麼幸運了，但是還是有方法的。底下先來看看，把 FIRSTU.ASM 改成中文版的 FIRSTUC.ASM 是什麼樣子？主檔名最後一個字元「C」表示中文的意思。底下是 FIRSTUC.ASM 的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
OPTION  CASEMAP:NONE
OPTION  WIN64:3

UNICODE EQU     1       ;呼叫Win64 API的寬字元版本

INCLUDE         WINDOWS.INC
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB
;**********************************************************************************************
.CONST
szTitle DW      986fh,793ah,842ch,570bh,78bch,5b57h,4e32h,0                ;顯示萬國碼字串
szText  DW      9019h,500bh,53e5h,5b50h,662fh,4ee5h,55h,43h,53h,0ff0dh,32h ;這個句子是以UCS－2
        DW      7de8h,78bch,800ch,6210h,3002h,0                            ;編碼而成。
;**********************************************************************************************
.CODE
;---------------------------------------------------------------------------------------------
main    PROC
        invoke  MessageBox,0,OFFSET szText,OFFSET szTitle,MB_OK
        call    ExitProcess
main    ENDP
;**********************************************************************************************
END     main

中文版的寬字元應用程式與 ANSI 應用程式不同之處，也在上面原始碼中以紫紅色的字標示出來了。第 4 行，跟英文版的一樣，「UNICODE EQU 1」用來使應用程式呼叫寬字元版的 Win64 API。第 11∼13 行定義的字串，全部用數值表示。很明顯，第 11 行第一個字組，986Fh 是 UCS－2 編碼，其中文字就是後面註解的「顯」。依此類推，793Ah 是「示」的 UCS－2 編碼 ……，這樣就很好瞭解了。

因為組譯器，不論是 UASM64.EXE 還是 ML64.EXE 都只能讀取 ANSI 制定的 ASCII 純文字檔案，而我們無法在字串中以 UCS－2 編碼，在其他假指令或 x86 指令用 ASCII 編碼。所以只能用上面這樣的變通方式，在表示字串時，以 UCS－2 編碼後的十六進位或十進位數值表示。

還剩下一個問題，難道用中文萬國碼字串，是不是要一個字一個字的查表，查出該字的編碼？當然不是，如果是這樣，寫個程式豈不自虐？在下一章，小木偶會撰寫一個程式，解決這個問題。

組譯、連結 FIRSTUC.ASM 的步驟跟 FIRSTU.ASM 一樣，不再敘述，而它執行的結果如右圖。看起來似乎跟 ANSI 應用程式沒什麼差別，但是如果用 x64dbg 載入它，觀察它在 .CONST 區段的內容，就能看出它確實是如假包換的寬字元應用程式，步驟如下：

  1. 開啟 x64dbg，載入 FIRSTUC.EXE。
  2. 按下四次 F7 鍵，單步追蹤四步之後，已經執行到 RIP 所指的位址 13FEC1020 處，此時已把要印在工作區上的字串位址存入 RDX 內，如下圖。這時資料顯示區還不是該字串的位址，可以把滑鼠游標移到資料顯示區（①處，粉紅色框）按下滑鼠左鍵，按下加速鍵，Ctrl－G，跳出一對話盒。在其編輯框輸入「RDX」，（②處，紅色框）表示使資料顯示區顯示 RDX 所指的位址；也可以直接輸入位址，13FEC4010（在 x64dbg 輸入時，大小寫均可）。輸入完成後按下 Enter 鍵或用滑鼠點選③處的「確認」按鈕 這時候資料顯示區內是以 ASCII 編碼顯示字元，見下圖紫色框。把滑鼠游標移到資料顯示區，按下滑鼠右鍵（見④處），出現快捷功能表。用滑鼠左鍵點選⑤處的「十六進位」彈出選項，再用滑鼠左鍵點選⑥處的「字碼頁」
  3. 然後會出現一個選擇字碼頁對話盒，如下圖。我們要選擇的是萬國碼的編碼方式，UCS－2 或 UCS－4。因為 UCS－2 與 UTF－16 相近，而後面的「LE」或「BE」分別代表小端序（Little-Endian）與大端序（Big-Endian）。x86－64 CPU 的儲存方式是小端序，所以選擇⑦處的 UTF－16LE，然後點擊⑧處的確認按鈕。如下圖：
  4. 終於大功告成，見⑨處的藍色框內，已經能正常顯示以萬國碼編碼的正體中文了。你也可以把藍色框右邊的捲軸往上捲動，可以看到對話和標題欄的文字。

講到這兒，讓應用程式顯示、儲存或處理的字元，是以萬國碼編碼的方式完成，算是告一段落。再深入一點，就是讓應用程式能以多種不同文字顯示，讓更多國家的人能使用，像這樣的程式稱為多語言應用程式（Multilingual Application）或國際化應用程式（Internationalized Application）。

國際化應用程式（Internationalized Application）

國際化應用程式英文是 internationalized application，或 I18N Application（I18N 是 Internationalization 縮寫，是開頭的 I 和結尾的 n 之間有 18 個字母），是指可以讓使用者選擇某種語言的應用程式，這種應用程式具有多語言介面。要撰寫這種程式，至少有三種方法：

  1. 為每種語言撰寫原始程式（ASM 檔）及資源描述檔（RC 檔），這是早先使用的方法，已逐漸淘汰。嚴格的說，這不能稱為國際化應用程式。
  2. 用資源描述檔內的字串表實現多語言介面。
  3. 以僅含資源的動態連結程式庫實現多語言介面。

本章著重在第二種方法。為了用這種方法撰寫國際化應用程式，必須先瞭解字串表，以及如何載入它。

字串表（String Table）

字串表在資源描述檔內，它屬於資源的一種。可以依底下格式建立字串表：

STRINGTABLE
[optional-statements]
BEGIN
  stringID,string
   ⁝
END

其中 STRINGTABLE 是保留字，代表字串表從這兒開始。optional-statements 是可以省略的，其意義跟資源描述檔中的功能表區塊一樣，請參閱第十六章。

在 BEGIN 與 END 之間才是真正定義了各式各樣的字串，BEGIN/END 也可以用一對「{ }」代替，在它們之間的每一組字串都是由一個十六位元的字串識別碼及字串構成。十六位元可以表示 1∼65535 之間的整數，因此字串識別碼也是在這個範圍內。字串必須以一對引號（"）括住，字串也可以包含換行符號，可以用「\12」或用十六進位「\x0c」表示，也可以用習慣上的「\x0d\x0a」來表示。如果在字串中要表示 "，可以用兩個連續的 " 表示，這樣只會出現一個 "。字串與字串識別碼之間，可以用空白或「,」分隔。底下例子可供參考：

#define IDS_FILE 2000
#define IDS_EDIT 2001
STRINGTABLE
{
  IDS_FILE,"檔案"
  IDS_EDIT "編輯"
}

LoadString API

載入字串表中的字串，可呼叫 LoadString，它的原型是：

invoke  LoadString,\
        hInstance,\     ; handle of module containing string resource
        uID,\           ; resource identifier
        lpBuffer,\      ; address of buffer for resource
        nBufferMax 	    ; size of buffer

hInstance 是模組代碼；uID 是要載入的字串識別碼；lpBuffer 用來指定載入後的字串存放位址；nBufferMax 是存放字串的空間大小，ANSI 版的 API 以位元組為單位，寬字元版以字元為單位，此空間大小包含最後結尾的 0。如果字串長度超過 nBufferMax，那麼只會取得字串的前 nBufferMax－1 個位元組或字元，減掉的一是保留給字串結尾的 0。

LoadString 還有個功能，如果 nBufferMax 設為零，那麼 lpBuffer 所指的位址中會得到該字串的位址，這個位址是唯讀不能寫入。如果要設定 nBufferMax 為零，在編譯 *.RC 檔時，最好能輸入「-n」或「/n」參數，如下：

E:\HomePage\SOURCE\Win64\UNICODE>rc /n muln1.rc [Enter]

「/n」是會使字串表中的字串結尾處加上「NULL」，這樣的好處是程式不必為載入的字串準備一塊記憶體。

撰寫國際化應用程式的策略

要讓應用程式能夠隨使用者的習慣，選取不同的語言介面，應該有許多種方法，但小木偶的思路是像下面這樣：

  1. 在資源描述檔內，字串表建立不同語言的字串時，讓相同語言字串的字串識別碼形成連續的整數。
  2. 在不同語言之間，意義相同的字串的字串識別碼之差相同。例如下面的例子就符合這兩項策略，中文的字串識別碼都在一千多，英文則在五千多；且「編輯」的字串識別碼比「檔案」多一，英文的「Edit」也比「File」多一：
    STRINGTABLE
BEGIN
  1000, "檔案"
  1001, "編輯"
  1002, "語言"
   ⁝
  5000, "File"
  5001, "Edit"
  5002, "Language"
   ⁝
END
  3. 在原始程式中，以一個變數來代表使用者選擇的語言，例如以上述的例子，當使用者選擇中文時，該變數變為 1000；當使用者選擇英文時，該變數變為 5000。
  4. 當使用者改變語言時，要取改變程式介面上的文字時，很容易依據第 3. 所提到的變數，由資源中載入同義字串。

底下實作一個例子說明上面的策略。

第一個國際化應用程式：MULN1

MULN1 中的 MU、LN 是指 Multilingual 中 Mu 及 lin，意即多語言應用程式。它執行時會建立一個對話盒畫面如下圖，可讓使用者輸入名字，然後按下「問候」按鈕，可以在對話盒上印出「你好，ＸＸ」的問候語字樣（甲圖）。使用者也可以點選功能表中的語言，有正體中文、簡體中文、英文、西班牙文、印地文四種語言（乙圖），這四種語言是世界使用人口最多的四種語言。一旦使用者改變語言後，例如選擇「印地語」，對話盒中的功能表、控制項上的文字都會隨之變成印地語文字（丙圖）。

先來看看 MULN1.EXE.MANIFEST 的內容，注意，它與前一章簡短很多，因為省略了<assemblyIdentity ……> 元素。這個元素用來描述應用程式本身，如不需要是可以省略的。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
  <dependency>
    <dependentAssembly>
      <assemblyIdentity
        type="win32"
        name="Microsoft.Windows.Common-Controls"
        version="6.0.0.0"
        processorArchitecture="*"
        publicKeyToken="6595b64144ccf1df"
        language="*"
      />
    </dependentAssembly>
  </dependency>
</assembly>

底下是資源描述檔，MULN1.RC，的內容：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
#pragma  code_page(65001)
#include "RESOURCE.H"
#define MANIFEST  24
#define ID_DLG    1000
#define ID_ICON   1001
#define ID_MENU   1002
#define IDS_NAME  2001
#define IDE_NAME  2002
#define IDS_GREET 2003
#define IDB_GREET 2004
#define IDB_QUIT  2005
#define IDM_OPEN  30000
#define IDM_SAVE  30001
#define IDM_QUIT  30002
#define IDM_HELP  30003
#define IDM_TC    31000
#define IDM_SC    32000
#define IDM_EN    33000
#define IDM_ES    34000
#define IDM_HI    35000

ID_DLG  DIALOGEX 350,180,126,56
CAPTION "多語言應用程式範例"
FONT    12,"Times New Roman",400,0,0
STYLE   WS_VISIBLE|WS_OVERLAPPEDWINDOW
BEGIN
  RTEXT    "請輸入姓名：",IDS_NAME,6,3,51,17
  EDITTEXT IDE_NAME,    61, 6,51,9
  LTEXT    "",IDS_GREET,14,20,93,9
  PUSHBUTTON "問候",IDB_GREET,32,32,36,12
  PUSHBUTTON "離開",IDB_QUIT, 74,32,36,12
END

ID_MENU MENU
BEGIN
  POPUP "檔案"
    {
      MENUITEM "開啟",IDM_OPEN
      MENUITEM "儲存",IDM_SAVE
      MENUITEM "離開",IDM_QUIT
    }
  POPUP "語言"
    {
      MENUITEM "正體中文",IDM_TC
      MENUITEM "简体中文",IDM_SC
      MENUITEM "English",IDM_EN
      MENUITEM "Español",IDM_ES
      MENUITEM "स्पेनिश",IDM_HI
    }
  MENUITEM "說明",IDM_HELP
END

1 MANIFEST "muln1.exe.manifest"

ID_ICON ICON "muln1.ico"

STRINGTABLE
BEGIN
  IDM_TC,   "檔案"
  IDM_TC+1, "語言"
  IDM_TC+2, "說明"
  IDM_TC+3, "開啟"
  IDM_TC+4, "儲存"
  IDM_TC+5, "離開"
  IDM_TC+6, "請輸入姓名："
  IDM_TC+7, "問候"
  IDM_TC+8, "離開"
  IDM_TC+9, "你好，"
  IDM_TC+10,"多語言應用程式範例"
  IDM_TC+11,"多語言應用程式範例\x0a第1.00版"
 
  IDM_SC,   "文件"
  IDM_SC+1, "语言"
  IDM_SC+2, "说明"
  IDM_SC+3, "开启"
  IDM_SC+4, "存储"
  IDM_SC+5, "退出"
  IDM_SC+6, "请输入姓名："
  IDM_SC+7, "问候"
  IDM_SC+8, "退出"
  IDM_SC+9, "你好，"
  IDM_SC+10,"多语言应用程序范例"
  IDM_SC+11,"多语言应用程序范例\12第1.00版"

  IDM_EN,   "File"
  IDM_EN+1, "Language"
  IDM_EN+2, "Help"
  IDM_EN+3, "Open"
  IDM_EN+4, "Save"
  IDM_EN+5, "Quit"
  IDM_EN+6, "Please input your name:"
  IDM_EN+7, "Greeting"
  IDM_EN+8, "Quit"
  IDM_EN+9, "Hello, "
  IDM_EN+10,"Multilingual program examples"
  IDM_EN+11,"Multilingual Program Examples\12Version 1.00"

  IDM_ES,   "Archivo"
  IDM_ES+1, "Idioma"
  IDM_ES+2, "Ayuda"
  IDM_ES+3, "Abrir"
  IDM_ES+4, "Guardar"
  IDM_ES+5, "Salir"
  IDM_ES+6, "Por favor, ingrese su nombre:"
  IDM_ES+7, "Hola"
  IDM_ES+8, "Salir"
  IDM_ES+9, "Hola, "
  IDM_ES+10,"Ejemplo de programa multilingüe"
  IDM_ES+11,"Ejemplo de Programa Multilingüe\12Versión 1.00"

  IDM_HI,   "फ़ाइल"
  IDM_HI+1, "भाषा"
  IDM_HI+2, "सहायता"
  IDM_HI+3, "खोलें"
  IDM_HI+4, "सहेजना"
  IDM_HI+5, "बाहर निकलें"
  IDM_HI+6, "कृपया अपना नाम दर्ज करें:"
  IDM_HI+7, "सादर प्रणाम"
  IDM_HI+8, "बाहर निकलें"
  IDM_HI+9, "नमस्ते, "
  IDM_HI+10,"बहुभाषी कार्यक्रम का उदाह"
  IDM_HI+11,"बहुभाषी कार्यक्रम का उदाह\12संस्करण 1.00"
END

注意到 STRINGTABLE 區塊，從第 57∼123 行是五種語言文字的字串，並且由第 16∼20 行可以看出五種文字的字串識別碼：正體中文的字串識別碼起始於 31000，終止於 31011；簡體中文起始於 32000，終止於 32011……，依此類推。同一種語言的字串識別碼都是連續的整數，不同種的語言則不連續。除此之外，不同語言之間，相對應的字串識別碼所代表的字串，意義相同。例如這五種文字的起始字串識別碼所代表的字串，檔案、文件、File、Archivo、फ़ाइल都是檔案的意思，同理第二個都是語言的意思。

因為 MULN1.RC 內含多種語言，因此在儲存時須注意儲存格式，常見情形如下：

  1. 在預設的情形下，RC.EXE 假設資源描述檔是用正在編譯的系統上 ANSI 代碼頁（code page）儲存的（請參閱Raymond Chen 的文獻）。對在中華民國、香港等地販售的 Windows XP 及其以後系統而言，預設值是 950，這正對應 Big5 編碼，這無法滿足 MULN1 對多語言要求，甚至你在文書處理器上，所見的西班牙文、印地文都是亂碼。
  2. 把 MULN1.RC 設為 UTF－8 編碼。現在只需知道，UTF－8 也是萬國碼的另一種編碼方式，以後再說明。在 MULN1.RC 的第一行有 
    #pragma  code_page(頁碼)
    告知 RC.EXE 這份資源描述檔的編碼方式。65001 就是 UTF－8，950 是 Big5，936 是 GB2312。指定編碼方式後，在儲存資源描述檔時也需指定 UTF－8 格式儲存。對 MULN1.RC 來說，只能指定「#pragma code_page(65001)」。
  3. 讓 RC.EXE 自己去判別。如果沒有特別指定的話，RC.EXE 雖然會用預設的 ANSI 代碼頁，但它也能自動判別。至少小木偶在儲存資源描述檔時，選擇 UTF－16 no BOM 格式儲存，然後用 RC.EXE 編譯是沒有問題的。

在使用資源編譯器，RC.EXE 編譯資源描述檔，MULN1.RC 時，要下達「-n」或「/n」選項，這是因為在呼叫 LoadString 取得字串時，曾使最後一個參數設為零。見前面 LoadString 的說明。

最後是 MULN.ASM 的內容，存檔時必須以 ANSI/ASCII 格式儲存：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
;多語文應用程式。組譯、連結方式：
;1.把MULN1.ASM、MULN1.RC、MELN1.EXE.MANIFEST、MULN1.ICO四個檔案
;  放在同一子目錄裏
;2.開啟命令，依序輸入下面指令
;  uasm64 -win64 muln1.asm
;  rc -n muln1.rc
;  link muln1.obj muln1.res
;MULN1可以讓使用者在編輯框輸入姓名，按問候按鈕，會出現問候語。
;可以經由語言功能表選擇五種語言，改變語言後，主功能表、控制項
;的文字都會隨之改變
OPTION  CASEMAP:NONE
OPTION  WIN64:3

UNICODE   EQU 1
ID_DLG    EQU 1000
ID_ICON   EQU 1001
ID_MENU   EQU 1002
IDS_NAME  EQU 2001
IDE_NAME  EQU 2002
IDS_GREET EQU 2003
IDB_GREET EQU 2004
IDB_QUIT  EQU 2005
IDM_OPEN  EQU 30000
IDM_SAVE  EQU 30001
IDM_QUIT  EQU 30002
IDM_HELP  EQU 30003
IDM_TC    EQU 31000
IDM_SC    EQU 32000
IDM_EN    EQU 33000
IDM_ES    EQU 34000
IDM_HI    EQU 35000

INCLUDE       WINDOWS.INC
INCLUDE       COMMCTRL.INC
INCLUDELIB    KERNEL32.LIB
INCLUDELIB    USER32.LIB
INCLUDELIB    COMCTL32.LIB
INCLUDELIB    MSVCRT.LIB   ;wcscat函式的連結資料在MSVCRT.LIB內
;*********************************************************************
.DATA
hInst    DQ   ?     ;模組代碼
hMenu    DQ   ?     ;主功能表代碼
hFilMenu DQ   ?     ;檔案子功能表代碼
hLngMenu DQ   ?     ;語言子功能表代碼
lng      DD   31000 ;預設的語言
buffer1  DW   40h DUP (0)
buffer2  DW   40h DUP (0)
;*********************************************************************
.CODE
;---------------------------------------------------------------------
chg_lng PROC    hdlg:HANDLE
        LOCAL   mii:MENUITEMINFO,id:DWORD
        lea     r8,buffer1
        mov     mii.cbSize,SIZEOF mii
        mov     mii.fMask,40h   ;MIIM_STRING=40h
        mov     mii.dwTypeData,r8
        mov     edx,lng
        mov     id,edx
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;檔案
        invoke  SetMenuItemInfo,hMenu,0,1,ADDR mii
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;語言
        invoke  SetMenuItemInfo,hMenu,1,1,ADDR mii
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;說明
        invoke  SetMenuItemInfo,hMenu,2,1,ADDR mii
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;開啟
        invoke  SetMenuItemInfo,hFilMenu,0,1,ADDR mii
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;儲存
        invoke  SetMenuItemInfo,hFilMenu,1,1,ADDR mii
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;離開
        invoke  SetMenuItemInfo,hFilMenu,2,1,ADDR mii
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;請輸入姓名
        invoke  SetDlgItemText,hdlg,IDS_NAME,OFFSET buffer1
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;問候
        invoke  SetDlgItemText,hdlg,IDB_GREET,OFFSET buffer1
        inc     id
        invoke  LoadString,hInst,id,OFFSET buffer1,20h  ;離開
        invoke  SetDlgItemText,hdlg,IDB_QUIT,OFFSET buffer1
        ret
chg_lng ENDP
;---------------------------------------------------------------------
DlgProc PROC    hDlg:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
        LOCAL   pCaption:QWORD,pText:QWORD
.if uMsg==WM_INITDIALOG
      ;設定對話盒標題欄左邊的圖示為資源中定義的圖示
        invoke  SendMessage,hDlg,WM_SETICON,ICON_SMALL,RV(LoadIcon,hInst,ID_ICON)
      ;設定對話盒的主功能表為資源中定義的功能表
        mov     hMenu,RV(LoadMenu,hInst,ID_MENU)
        invoke  SetMenu,hDlg,hMenu
      ;取得檔案子功能表及語言子功能表代碼
        mov     hFilMenu,RV(GetSubMenu,hMenu,0)
        mov     hLngMenu,RV(GetSubMenu,hMenu,1)

.elseif uMsg==WM_COMMAND
        mov     rax,r8   ;R8W＝識別碼
        shr     rax,10h  ;AX＝通知碼
  .if ax==0
    .if r8w==IDB_QUIT
        jmp     quit
    .elseif r8w==IDB_GREET
grt:  ;按下「問候」按鈕，先取得編輯框內字串，再檢查該字串是否為空字串
      .if RV(GetDlgItemText,hDlg,IDE_NAME,ADDR buffer2,SIZEOF buffer2-1)==0
        mov     WORD PTR buffer1,0
      .else
        mov     edx,lng
        add     edx,9
        invoke  LoadString,hInst,edx,ADDR buffer1,20h
        invoke  wcscat,ADDR buffer1,ADDR buffer2
      .endif
        invoke  SetDlgItemText,hDlg,IDS_GREET,ADDR buffer1
    .elseif r8w==IDM_OPEN
    .elseif r8w==IDM_SAVE
    .elseif r8w==IDM_QUIT
        jmp     quit
    .elseif r8w==IDM_HELP
      ;取得MessageBox彈出對話盒字串位址及標題位址
        mov     edx,lng
        add     edx,11
        invoke  LoadString,hInst,edx,ADDR pText,0
        mov     edx,lng
        add     edx,10
        invoke  LoadString,hInst,edx,ADDR pCaption,0
      ;顯示MessageBox彈出對話盒
        invoke  MessageBox,hDlg,pText,pCaption,MB_OK
    .elseif (r8w>=IDM_TC) && (r8w<=IDM_HI)
        movzx   rax,r8w
        mov     lng,eax
        invoke  chg_lng,hDlg
        invoke  DrawMenuBar,hDlg
        mov     edx,lng
        add     edx,10
        invoke  LoadString,hInst,edx,ADDR pCaption,0
        invoke  SetWindowText,hDlg,pCaption
        jmp     grt
    .endif
  .endif

.elseif uMsg==WM_CLOSE
quit:   invoke  EndDialog,hDlg,0

.else   ;其他未處理的訊息返回 FALSE
        xor     rax,rax
        ret
 
.endif  ;已處理的訊息，返回 TRUE
        mov     rax,1
        ret
DlgProc ENDP
;---------------------------------------------------------------------
main    PROC
        call    InitCommonControls
        mov     hInst,RV(GetModuleHandle,0)
        invoke  DialogBoxParam,hInst,ID_DLG,0,OFFSET DlgProc,0
        invoke  ExitProcess,0
main    ENDP
;*********************************************************************
END     main

如前所述，MULN1 最重要的功能是可以由功能表上的選項，改變對話盒所顯示的語言文字。處理這過程中，最重要的變數是第 45 行的 lng，它是 language 的簡寫，預設值是 31000，也就是正體中文起始字串識別碼。當使用者選擇語言功能表中的選項改變語言時，lng 之值會隨之改變，但都是某種語言在資源字串表中，起始字串的字串識別碼。

例如使用者選擇英文，由第 29 行得知，英文的選項識別碼，IDM_EN 是 33000，lng 會變成 33000，這恰好也是 MULN1.RC 中第 85 行，英文的起始字串識別碼；又例如使用者選擇印地文，lng 會變成 34000，這也恰好是 MULN1.RC 中的 IDM_HI。當然，這是故意安排成這樣的。為什麼這樣安排，瞭解了 chg_lng 副程式的運作，就知道為何這樣安排。

在說這原因之前，這兒還要多說一點題外話。使用者選擇功能表上的選項或按下對話盒中的按鈕，系統都會對 MULN1 的對話盒函式發出 WM_COMMAND，如果是前者，wParam 的第 16∼31 位元不使用，設為零；如果是後者，wParam 第 16∼31 位元稱為通知碼，而此刻通知碼是 BN_CLICKED，其值恰好也是零。所以 MULN1 把這兩事件擺在一起處理，MULN1 是靠按鈕識別碼跟選項識別碼區別它們。第 103、142 行的 .if ax==0/.endif 內包含了另一個 .if/.endif，被包含的 .if/.endif 檢查 R8W（R8W 為按鈕識別碼或選項識別碼）來確定使用者操作的是選項還是按鈕。

chg_lng 副程式

言歸正傳，回到如何把功能表上的選項文字及控制項文字都換成其他語言文字。

要更改選項文字，方法是呼叫 SetMenuItemInfo，SetMenuItemInfo 的詳細用法請參閱第十八章，這兒簡單扼要的說，對於 MULN1 只須設定 MENUITEMINFO 結構體中的三個欄位即可：①把 cbSize 欄位為 MENUITEMINFO 結構體有多少位元組。②把 fMask 欄位為 MIIM_STRING，WinInc 缺少宣告此常數之值，但查閱網路可找到此數為 40h。③把 dwTypeData 欄位設為要變更文字的字串位址，此位址就是 buffer1 的位址，LoadString 由資源載入的字串將存於此位址。這三步驟見第 53∼56，設定好之後，MENUITEMINFO 結構體就不需改變，改變的是 buffer1 內的字串內容。

從資源的字串表中載入的字串，存入 buffer1 內，這過程要呼叫 LoadString。LoadString 的第二個參數是資源字串表中的字串識別碼，用區域變數 id 表示，在第 57、58 兩行已把 lng 存入 id。

chg_lng 需要改變的選項文字有六項，這六項的字串識別碼排成連續的正整數，所以只要知道起始的字串識別碼，每處理完一個選項後，使 id 增加一，就能載入下個字串了。見第 59∼75 行。至於更換按鈕上的文字，也是一樣的道理，就不贅述。

MULN1 就介紹到這兒，底下說明在 MULN1 中新的指令或函式。

wcscat 與 strcat

wcscat 功用是合併字串，它並不是 Win64 API，而是 C 語言程式庫內建的標準函式，所以如果應用程式中要呼叫它，要先引入 MSVCRT.LIB 函式庫。wcscat 中的 wc 是 wide character 的意思，它的原型是：

invoke  wcscat,\
        pDestination,\  ; Null-terminated destination string
        pSource         ; Null-terminated source string

pDestination 是目的字串的位址，pSource 是來源字串的位址，這兩個字串都必須以零結尾，而且其字元也都必須以萬國碼編碼。wcscat 會在 pDestination 位址上的目的字串尾端（結尾的零前的一個位址），填上來源字串，達到合併字串的功能。

strcat 用來把兩個字串連接起來，strcat 的使用方式都跟 wcscat 一樣，只是 strcat 是 ANSI 版本，也就是說 strcat 只能處理 ASCII 字元所組成的字串。呼叫這兩個函式之前，須注意 pDestination 所指位址上的字串之後，必須有足夠的空間可容納來源字串，否則很容易覆蓋其後的資料，而發生錯誤，嚴重甚至引發溢位錯誤。

RV 巨集函式

RV 是 UASM64 內建的巨集函式，因為 Windows 應用程式中的巨集名稱會區分大小寫，所以 RV 也必須都用大寫，否則會發生錯誤。RV 是回傳值（return value）的意思，它用於在呼叫函式之後，把回傳值存於 RAX 暫存器中，而可以直接與另一指令搭配。它的語法是：

RV(函式名稱, 參數列表)

當然僅僅如此還不是完整的指令，只是指令的一部份。準確地說必須把整個「RV(函式名稱, 參數列表)」視為 RAX 運算元，再與指令其他部分搭配。例如要取得模組代碼，本來是寫成下面的樣子

invoke  GetModuleHandle,0
mov     hInst,rax

如果使用 RV 巨集函式，可以寫成一行，把 RV(GetModuleHandle,0) 看成是 RAX：

mov     hInst,RV(GetModuleHandle,0)

RV 除了與 x86 指令，像 MOV、ADD……搭配之外，也可以用在 .if/.endif、.while/.endw……或 invoke 假指令。例如要設定視窗標題欄左邊的圖示，一般是寫成像底下的程式，需要兩行程式碼：

invoke  LoadIcon,hInst,IDI_APPLICATION
invoke  SendMessage,hDlg,WM_SETICON,ICON_SMALL,rax

如果改用 RV 巨集，就變成一行，如下：

invoke  SendMessage,hDlg,WM_SETICON,ICON_SMALL,RV(LoadIcon,hInst,IDI_APPLICATION)

後記

本章就介紹到這兒，已經初步介紹了萬國碼，以及如何在組合語言中，對由英文、阿拉伯數字組成的字元以萬國碼方式編碼。下一章將介紹使用中文的萬國碼編碼方式產生字串，這也可以擴充而應用到其他語言的文字。

前一章以及本章總共介紹了三個 C 語言的標準函式，sprintf、wcscat、strcat，再加上第四章介紹的 wsprintf，這四個函式都沒有限定緩衝區大小，某些情況會有緩衝區溢位上的安全問題，因此許多文獻，包含 MSDN 都建議不要使用這些函式。微軟早已準備好一些 Win64 API 函式可供使用，但需要整理，等小木偶整理好再添加到某個附錄中吧。