第十八章　功能表（三）

這一章還是談功能表，但是改用以呼叫 CreateMenu、InsertMenuItem、SetMenu 等 Win64 API 來建立主功能表，而不使用資源描述檔中的 MENU 區塊。以前者方式建立的功能表，較為靈活，可以打造具有客製化特色的功能表，缺點也是顯而易見的，那就是複雜。在進入主題之前，先介紹這一章會用得到的 Win64 API。

與功能表相關的 Win64 API

CreateMenu API

CreateMenu 會建立一個功能表，此功能表最初是空的，一無所有，應用程式可以呼叫 InsertMenuItem、AppendMenu、InsertMenu 在這新建的功能表添加分隔線、選項、彈出選項。CreateMenu 沒有參數，其原型是：

call    CreateMenu

invoke 假指令（對 UASM 而言）或巨集（對 MASM64 SDK 而言）是用來將參數存入暫存器或堆疊中，最後一定會執行 CALL 指令。呼叫 CreateMenu 時，因為沒有參數，所以可以直接使用 CALL，當然也可以使用 invoke。如果 CreateMenu 成功建立功能表，回傳值是其建立好的功能表代碼；如果失敗，回傳值是零。

InsertMenuItem API

在功能表中加入新的分隔線、選項、彈出選項。

invoke  InsertMenuItem,\
        hMenu,\         ; handle to menu to be changed
        uItem,\         ; identifier or position
        fByPosition,\   ; value specifying the meaning of uItem
        lpmii           ; pointer to a MENUITEMINFO structure

如果 InsertMenuItem 執行成功，回傳值為非零；反之回傳值為零。底下說明各項參數的意義：

MENUITEMINFO    STRUCT 
  cbSize        DWORD     ?         ;MENUITEMINFO 的長度，以位元組單位
  fMask         DWORD     ?         ;旗標，指定要存取 MENUITEMINFO 中的哪一欄
  fType         DWORD     ?         ;選項類型
  fState        DWORD     ?         ;選項狀態
  wID           DWORD     2 DUP(?)  ;選項識別碼
  hSubMenu      HMENU     ?         ;子功能表代碼
  hbmpChecked   HBITMAP   ?         ;勾選之選項前的位元圖
  hbmpUnchecked HBITMAP   ?         ;未勾選之選項前的位元圖
  dwItemData    ULONG_PTR ?         ;應用程式自行設定的資料
  dwTypeData    LPSTR     ?         ;選項文字或圖片
  cch           DWORD     2 DUP (?) ;選項字串長度
  hbmpItem      HBITMAP	  ?         ;以位元圖代替選項字串
MENUITEMINFO    ENDS

MENUITEMINFO 結構體很複雜，底下說明各欄位的意義。最簡單的是第一個欄位，cbSize，是指 MENUITEMINFO 結構體大小，單位是位元組，在呼叫 InsertMenuItem 前必須設定 cbSize 欄位，Windows 靠此數值判斷使用哪個版本的 API。若沒設好 cbSize，就會發生錯誤。

第二個欄位，fMask，決定了 InsertMenuItem、GetMenuItemInfo 與 SetMenuItemInfo 會使用 MENUITEMINFO 中的哪些欄位，而其他欄位無用。例如呼叫 InsertMenuItem 之前，把 fMask 為 MIIM_ID，那就必須同時把 wID 欄位設為選項識別碼，這樣呼叫之後就能把新加入的選項設好選項識別碼；如果呼叫 GetMenuItemInfo 之前，fMask 為 MIIM_ID，呼叫後系統會把選項識別碼存入到 wID 欄位中。

底下是 fMask 欄位可以設定的數值，如果要一次設定或是得到某選項的數種資料，可以用「OR」運算子連接，但此 OR 並非 x64 CPU 指令，而是組譯器執行的運算子。

fMask應設定或
獲取的欄位		說　明
MIIM_BITMAP
80H		hbmpItem 在選項中顯示位元圖，要顯示的位元圖代碼存於 hbmpItem 欄位中，位元圖代碼可以由資源中載入，也可以是內建的位元圖，例如 HBMMENU_MBAR_CLOSE、HBMMENU_MBAR_MINIMIZE，分別是關閉、最小化的位元圖，更多的內建位元圖請查閱 MSDN。hbmpItem 也可以是 HBMMENU_CALLBACK，代表擁有者繪製選項，應用程式必須處理 WM_MEASUREITEM 或 WM_DRAWITEM 訊息。
MIIM_CHECKMARKS
8H		hbmpChecked
hbmpUnchecked		 MIIM_CHECKMARKS 是設定勾選的或未勾選的位元圖，此位元圖會顯示在勾選的或未勾選的選項文字之前。hbmpChecked 指定勾選時所顯示的位元圖之代碼；hbmpUnchecked 指定未勾選時所顯示的位元圖之代碼。如果選項狀態是勾選，會顯示 hbmpChecked 所指定的位元圖，但如果 hbmpChecked 為零那麼就會顯示預設圖（即✔）；如果選項狀態是未勾選，會顯示 hbmpUnchecked 所指定的位元圖，但如果 hbmpUnchecked 為零那麼就不顯示位元圖。
MIIM_DATA
20H		dwItemDataWin64 系統中，dwItemData 的資料類型是 ULONG_PTR，長度是 64 位元。設定 MIIM_DATA 之後，dwItemData 可設為某些資料的位址，當 WM_DRAWITEM 訊息傳給視窗函式時，dwItemData 之值會保存於此訊息中 lParam 所指 DRAWITEMSTRUCT 結構體的 itemData 欄位內，可於擁有者繪製選項時使用那些資料。
MIIM_FTYPE
100H		fType 當 fMask 設為 MIIM_FTYPE 時，須於 fType 欄位指定或者獲取選項類型，選項類型可以是下面數值，或是相互間以 OR 運算子運算的結果，但是不能同時指定 MFT_BITMAP、MFT_SEPARATOR、MFT_STRING。
  1. MFT_BITMAP：用位元圖顯示選項而不用文字，該位元圖代碼存於 dwTypeData 欄位且忽略 cch 欄位。MFT_BITMAP 之值為 4。
  2. MFT_MENUBARBREAK：對主選單而言，自此選項開始顯示於下一列；對子功能表、快捷功能表而言，顯示於下一行且兩行間有鉛錘線分隔。MFT_MENUBARBREAK 之值為 20H。
  3. MFT_MENUBREAK：同上，但沒有鉛錘線分隔。MFT_MENUBREAK 之值為 40H。
  4. MFT_OWNERDRAW：具有 MFT_OWNERDRAW 的選項，必須由應用程式擔負起繪製此選項的責任。建立這種選項時，應用程式會收到 WM_MEASUREITEM 訊息，每當更新選項外觀時會收到 WM_DRAWITEM 訊息，應用程式藉著這兩則訊息繪製選項。指定 MFT_OWNERDRAW 時，dwItemData 可以指定應用程式自行定義的數值。應用程式會收到的 WM_MEASUREITEM、WM_DRAWITEM 訊息中，lParam 分別是 MEASUREITEMSTRUCT、DRAWITEMSTRUCT 結構體位址，其中的 itemData 內存著 dwTypeData 自行定義的數值。MFT_OWNERDRAW 之值為 100H。
  5. MFT_RADIOCHECK：當 fState 為 MFS_CHECKED，在 fType 具有 MFT_RADIOCHECK 的選項前以●表示勾選狀態。MFT_RADIOCHECK 之值為 200H。
  6. MFT_RIGHTJUSTIFY：從具有 MFT_RIGHTJUSTIFY 的選項開始，排列在主功能表的右邊。MFT_RIGHTJUSTIFY 只能用於主功能表中的選項，其值為 4000H。
  7. MFT_RIGHTORDER：阿拉伯語、希伯來語版本的 Windows 才能使用，使選項字串由右至左閱讀。
  8. MFT_SEPARATOR：在子功能表、快捷功能表中，具有 MFT_SEPARATOR 時，顯示水平分隔線。dwTypeData、cch 會被忽略。MFT_SEPARATOR 之值為 800H。
  9. MFT_STRING：用字串表示選項，dwTypeData 為字串位址，此字串須以零結尾。cch 為字串長度。MFT_STRING 之值為零。
MIIM_ID
2		wID 存取 wID 欄位。當呼叫 InsertMenuItem、SetMenuItemInfo 前，須把 wID 設定為選項識別碼；呼叫 GetMenuItemInfo 後，wID 會存有選項識別碼。
MIIM_STATE
1		fState 只有當 fMask 設為 MIIM_STATE 時，指定選項狀態，由 fState 欄位表示狀態，可以是下面數值：
  1. MFS_CHECKED：此選項為勾選的，其值為 8。可以設定 hbmpChecked 為某圖片的位元圖代碼，或者設定 hbmpChecked 為零使用預設圖片，以顯示在選項文字前表示勾選狀態。若要設定 hbmpChecked，必須把 fMask 欄位設為 MIIM_CHECKMARKS。
  2. MFS_DEFAULT：此選項為內定的選項，一功能表中只有一個選項是內定的，且以粗體字表示。MFS_DEFAULT 之值為 1000H。
  3. MFS_DISABLED：此狀態的選項是禁用的且以灰色字表示，無法被使用者點選，與 MFS_GRAYED 同義。MFS_DISABLED 之值為 3。
  4. MFS_ENABLED：此狀態的選項是啟用的，可以被使用者點選，其值為 0。
  5. MFS_GRAYED：與 MFS_DISABLED 同義，MFS_GRAYED 為 3。
  6. MFS_HILITE：以高亮度顯示選項，其值為 80H。
  7. MFS_UNCHECKED：未勾選的選項，其值為 0。可以設定 hbmpUnchecked 為某圖片的位元圖代碼，或者設定 hbmpUnchecked 設為零不使用任何圖片，以顯示在選項文字之前表示未勾選狀態。若要設定 hbmpUnchecked，必須把 fMask 欄位設為 MIIM_CHECKMARKS。
MIIM_STRING
40H		dwTypeData 在選項中顯示文字字串，該字串須以零結尾，其位址存於 dwTypeData。cch 為字串長度。MIIM_STRING 可以取代 MFT_STRING。
MIIM_SUBMENU
4		hSubMenu 將某一選項設為彈出選項，能顯示子功能表。當 fMask 指定了 MIIM_SUBMENU 時，須同時於 hSubMenu 指定子功能表之代碼，將該子功能表附在 InsertMenuItem、SetMenuItemInfo 的第一個參數，hMenu，之下。
MIIM_TYPE
10H		fType
dwTypeData		 必須設定 fType 與 dwTypeData，參考 MIIM_BITMAP、MIIM_FTYPE 與 MIIM_STRING，因為 MIIM_TYPE 將逐步被前三者取代。

假設要在某個功能表內新添一選項，通常會同時設定選項文字與選項識別碼，那麼就會使用下面程式碼：

        mov     mii.fMask,MIIM_STRING or MIIM_ID
        mov     mii.wID,選項識別碼
        lea     r10,字串變數
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii

上面第一行程式碼中的 MIIM_STRING 常數為 40H，換算為二進位是 0100 0000；MIIM_ID 為 2，二進位是 0010，經過「OR」運算之後為 0100 0010，經由 MENUITEMINFO 將此資料傳給 InsertMenuItem，InsertMenuItem 就能知道使用者要新添的選項具有哪些性質。在 Windows 程式設計中，有許多類似這樣的常數，都稱之為旗標，它們代表了某個位元，若為一表示要決定了某個物件的性質，若為零表示沒有此性質。

SetMenuItemInfo API

SetMenuItemInfo 是用來改變選項某些屬性，其原型為：

invoke  SetMenuItemInfo,\
        hMenu,\         ; handle to menu to be changed
        uItem,\         ; identifier or position
        fByPosition,\   ; value specifying the meaning of uItem
        lpmii           ; pointer to a MENUITEMINFO structure

SetMenuItemInfo 的參數與 InsertMenuItem 相同，意義也都相同，差別在於前者是改變現有選項的屬性，後者是沒有這個選項而新加入這個選項，順帶設定好屬性。底下是這些參數的說明：

如果 SetMenuItemInfo 執行成功，回傳值為非零；如果執行失敗，回傳值為零。當呼叫 SetMenuItemInfo 成功後，應呼叫 DrawMenuBar 重新繪製功能表，以顯示修改過的選項。

DrawMenuBar API

DrawMenuBar 用來重新繪製功能表，通常是添加、刪除或更改功能表屬性（如啟用或禁用選項），甚至是切換不同功能表，而使得功能表發生變化的時候，必須呼叫 DrawMenuBar 更新功能表外觀，否則可能不會變更功能表外觀。DrawMenuBar 的原型是：

invoke  DrawMenuBar,\
        hWnd            ; handle to window with menu bar to redraw

hWnd 是需要更新功能表外觀的視窗之視窗代碼。如果 DrawMenuBar 成功執行，回傳值為非零；若失敗，回傳值為零。

不使用資源描述檔中的 MENU 區塊建立功能表

例子：DRAW5.ASM

這一章的例子是 DRAW5，它的主功能表不使用載入資源中的 MENU 資源，而改用呼叫 CreateMenu、SetMenu、InsertMenuItem 建立，它也是以第十六章的 DRAW2 進行修改而成。由於只修改部分內容，所以 DRAW5 與 DRAW2 大同小異，底下只列出重要且不同的部分，完整的原始檔案請到這裏下載。將其中的 DRAW5.ASM 與 DRAW5.RC 放在同一子目錄，組譯方法與第十六章的 DRAW2 相同，不重複敘述。

1
⁝ 
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
⁝ 
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
⁝ 
363
364
;呼叫 CreateMenu、InsertMenuItem、SetMenu建立主功能表，不用MENU區塊
    ⁝

;底下是WinInc沒有宣告的常數以及更正後MENUITEMINFO結構體
MIIM_STRING     EQU     40H
MIIM_BITMAP     EQU     80H
MIIM_FTYPE      EQU     100H
MY_MENUITEMINFO STRUCT
  cbSize        DWORD     ?
  fMask         DWORD     ?
  fType         DWORD     ?
  fState        DWORD     ?
  wID           DWORD     2 DUP(?)
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPSTR     ?
  cch           DWORD     2 DUP (?)
  hbmpItem      HBITMAP   ?
MY_MENUITEMINFO ENDS
;*****************************************************************************************
.CONST
szIconName      LABEL   BYTE
szClassName     DB      "DRAW5",0
szAppName       DB      "超簡單繪圖",0
szText          DB      "DRAW5僅能繪製橢圓與手繪圖",0dh,0ah,"，且不能存檔也不能編輯。",0
szMouseFmt      DB      "(%03d,%03d)",0
szColor         DB      "黑色紅色綠色藍色"
szClear         DB      5 DUP ("　")
szQuit          DB      "離開",0
szView          DB      "檢視",0
szXy            DB      "座標",0
szPenColor      DB      "畫筆顏色",0
szDraw          DB      "繪圖",0
szEllipse       DB      "橢圓",0
szTrace         DB      "手繪圖",0
szBlack         DB      "黑",0
szRed           DB      "紅",0
szGreen         DB      "綠",0
szBlue          DB      "藍",0
szHelp          DB      "幫助",0
;*****************************************************************************************
         ⁝
  .case WM_CREATE
      ;建立功能表，並將其設為主選單
        call    CreateMenu
        mov     hMenu,rax
        invoke  SetMenu,hWnd,hMenu
      ;在主功能表中插入「離開」選項
        mov     mii.cbSize,SIZEOF mii
        mov     mii.fMask,MIIM_STRING or MIIM_ID
        lea     r10,szQuit
        mov     mii.wID,IDM_QUIT
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii
      ;在主功能表中插入「檢視」子功能表
        call    CreateMenu
        mov     hViewSubMenu,rax
        mov     mii.fMask,MIIM_SUBMENU or MIIM_STRING
        lea     r11,szView
        mov     mii.hSubMenu,rax
        mov     mii.dwTypeData,r11
        invoke  InsertMenuItem,hMenu,1,TRUE,ADDR mii
      ;在主功能表中插入「繪圖」子功能表
        call    CreateMenu
        mov     hDrawSubMenu,rax
        lea     r10,szDraw
        mov     mii.hSubMenu,rax
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,2,TRUE,ADDR mii
      ;在主功能表中插入「幫助」選項
        mov     mii.fMask,MIIM_TYPE or MIIM_ID
        mov     mii.fType,MFT_STRING or MFT_RIGHTJUSTIFY
        lea     r11,szHelp
        mov     mii.wID,IDM_HELP
        mov     mii.dwTypeData,r11
        invoke  InsertMenuItem,hMenu,3,TRUE,ADDR mii
      ;在「檢視」子功能表中插入「座標」選項
        mov     mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE
        mov     mii.fState,MFS_CHECKED
        lea     r10,szXy
        mov     mii.wID,IDM_XY
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hViewSubMenu,0,TRUE,ADDR mii
      ;在「檢視」子功能表中插入「畫筆顏色」選項
        lea     r11,szPenColor
        mov     mii.wID,IDM_COLOR
        mov     mii.dwTypeData,r11
        invoke  InsertMenuItem,hViewSubMenu,1,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入「橢圓」選項
        mov     mii.fMask,MIIM_STRING or MIIM_ID
        lea     r10,szEllipse
        mov     mii.wID,IDM_ELLIPSE
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hDrawSubMenu,0,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入「手繪圖」選項
        mov     mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE or MIIM_FTYPE
        lea     r11,szTrace
        mov     mii.wID,IDM_TRACE
        mov     mii.dwTypeData,r11
        mov     mii.fState,MFS_CHECKED
        mov     mii.fType,MFT_RADIOCHECK
        mov     mii.hbmpChecked,0
        invoke  InsertMenuItem,hDrawSubMenu,1,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入分隔線
        mov     mii.fMask,MIIM_FTYPE
        mov     mii.fType,MFT_SEPARATOR
        invoke  InsertMenuItem,hDrawSubMenu,2,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入「黑」選項
        mov     mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE or MIIM_FTYPE
        lea     r10,szBlack
        mov     mii.wID,IDM_BLACK
        mov     mii.dwTypeData,r10
        mov     mii.fState,MFS_CHECKED
        mov     mii.fType,MFT_RADIOCHECK
        invoke  InsertMenuItem,hDrawSubMenu,3,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入「紅」選項
        mov     mii.fMask,MIIM_STRING or MIIM_ID
        lea     r11,szRed
        mov     mii.wID,IDM_RED
        mov     mii.dwTypeData,r11
        invoke  InsertMenuItem,hDrawSubMenu,4,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入「綠」選項
        lea     r10,szGreen
        mov     mii.wID,IDM_GREEN
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hDrawSubMenu,5,TRUE,ADDR mii
      ;在「繪圖」子功能表中插入「藍」選項
        lea     r11,szBlue
        mov     mii.wID,IDM_BLUE
        mov     mii.dwTypeData,r11
        invoke  InsertMenuItem,hDrawSubMenu,6,TRUE,ADDR mii
      ;更新主選單外觀
        invoke  DrawMenuBar,hWnd
         ⁝
;*****************************************************************************************
END     main

解說

對 winuser.inc 中三個常數及 MENUITEMINFO 的說明

DRAW5.ASM 第 27∼29 行，宣告了三個常數 MIIM_STRING、MIIM_BITMAP、MIIM_FTYPE，其實在 winuser.inc 中有宣告這三個常數，但是有條件。在 winuser.inc 中宣告這三個常數的程式是：

if (WINVER ge 0500h)
MIIM_STRING	EQU	00000040h
MIIM_BITMAP	EQU	00000080h
MIIM_FTYPE	EQU	00000100h
  ⁝
endif

因此，如果 DRAW5.ASM 中，在「INCLUDE WINDOWS.INC」之前，有宣告「WINVER EQU 500H」或大於 500H，那麼就可以省略第 27∼29 行。事實上，WINVER 代表 Windows 版本，WINVER 為 500H，5 是主要版本，00 是次要版本，可以看成 5.00 版，這是西元 2000 年發售的 Windows 2000 的內部版本。也就是說，這三個常數在 Windows 2000 之後才有支援。至於 MENUITEMINFO 結構體的錯誤請參考註一。

在視窗中加入功能表

接下來看底下的第 202∼205 行，這四行指令是呼叫 CreateMenu 建立空的功能表，再呼叫 SetMenu 設定 DRAW5 視窗的功能表為剛剛建立的功能表。程式如下：

      ;建立功能表，並將其設為主選單
        call    CreateMenu
        mov     hMenu,rax
        invoke  SetMenu,hWnd,hMenu

接下來是在這新建的功能表中，添加選項、彈出選項。這裏值得一提的是，如果建立功能表之後，先在空的功能表添加選項、彈出選項，再呼叫 SetMenu 設定功能表也可以。

在功能表中加入陽春的選項

DRAW5 的主功能表有兩個選項、兩個彈出選項，使用者點選彈出選項會出現子功能表，而這些子功能表有些具✔的勾選狀態，有些具有●的勾選狀態。底下將針對這些不同的狀況說明如何呼叫 InsertMenuItem，把它們加入選單內。先說明最簡單的情況，沒有勾選狀態的選項。

沒有勾選狀態的選項最單純，它最重要的屬性是名稱與識別碼，名稱是以零結尾的字串，識別碼則是十六位元的無號數，要設定這兩種屬性，將 MENUITEMINFO 的 fMask 設為 MIIM_STRING or MIIM_ID。MIIM_STRING、MIIM_ID 之值分別是 40H、2，換算成二進位是 0100 0000、0010，它們其實都是旗標。InsertMenuItem 檢查 fMask 的各位元，發現第一個位元為一，就知道應用程式想讓選項有選項識別碼；發現第六個位元為一，就知道要有選項文字。因此要同時設定好選項識別碼及文字，可以用「OR」運算子使 MIIM_STRING、MIIM_ID 相連。

設好 fMask 欄位之後，因為有 MIIM_STRING 所以還要把 dwTypeData 設為選項名稱字串的位址，因為有 MIIM_ID 所以要把 wID 設為選項識別碼。像這樣只添加選項文字與選項識別碼是最單純的了，所以稱之為「陽春的選項」。見第 206∼212 行，或下面程式碼：

      ;在主功能表中插入「離開」選項
        mov     mii.cbSize,SIZEOF mii
        mov     mii.fMask,MIIM_STRING or MIIM_ID
        lea     r10,szQuit
        mov     mii.wID,IDM_QUIT
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii

首先要說明的是，mii.cbSize 必須是 InsertMenuItem 能夠接收的數值，此數值與 Windows 版本有關。如果沒設定此數或設定錯誤，InsertMenuItem 就會執行錯誤。當初小木偶在測試時，因為 MASM64 SDK 與 WinInc 都定義錯了，花了許多時間走了很多冤枉路，幸好最後比對它們不同之處才找到錯誤，見註一。

假如不同時設好這兩個屬性，也是可以的。例如先不設定選項識別碼，等插入選項之後再設，如下面的程式碼：

        mov     mii.cbSize,SIZEOF mii
        mov     mii.fMask,MIIM_STRING
        lea     r10,szQuit
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii
        mov     mii.fMask,MIIM_ID
        mov     mii.wID,IDM_QUIT
        invoke  SetMenuItemInfo,hMenu,0,TRUE,ADDR mii

但是，如果反過來，先呼叫 InsertMenuItem 時已設好識別碼，再呼叫 SetMenuItemInfo 設定選項名稱，該選項不能正常運作。小木偶不知道確切的原因，推測是選項名稱是選項中最重要的部分，必須先確立名稱之後，再對選項修飾。

新添上述的選項還有另一種方式，雖然這是舊用法，但還是說一說。把 fMask 設為 MIIM_TYPE or MIIM_ID，再進一步把 fType 設為 MFT_STRING，最後於 dwTypeData 設定字串的位址，見第 228∼234 行。你會發現使用舊方法要三步驟；而上一種方法僅兩步驟。

添加彈出選項

如何以 InsertMenuItem 添加彈出選項呢？彈出選項沒有選項識別碼，但必須有名稱與子功能表代碼，這裏的子功能表是使用者點選此彈出選項後出現的。因為彈出選項有子功能表，所以必須先呼叫 CreateMenu 建立一功能表，再把 fMask 設為 MIIM_SUBMENU or MIIM_STRING，接著將 MENUITEMINFO 中的 hSubMenu 欄位設為 CreateMenu 建立的功能表代碼。最後將 dwTypeData 設為一個以零結尾的字串之位址，此字串就是彈出選項的名稱。見 DRAW5.ASM 第 213∼220 行。

添加具有✔勾選狀態或●勾選狀態的選項

如何添加具有✔勾選狀態的選項呢？其實不難，跟前面設定不具勾選選項類似，只是多了要將其設為勾選狀態。詳細的說就是先把 MENUITEMINFO 的 fMask 設為 MIIM_STRING or MIIM_ID or MIIM_STATE，接下來選項名稱與識別碼跟前面相同，但多了一步把 MENUITEMINFO 的 fState 欄位設為 MFS_CHECKED。見第 235∼241 行。

      ;在「檢視」子功能表中插入「座標」選項
        mov     mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE
        mov     mii.fState,MFS_CHECKED
        lea     r10,szXy
        mov     mii.wID,IDM_XY
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hViewSubMenu,0,TRUE,ADDR mii

如何添加具有●勾選狀態的選項呢？具有●勾選狀態，必須先設其為勾選狀態，然後才能將其進一步設為●的狀態。所以先把 MENUITEMINFO 的 fMask 設為 MIIM_STRING or MIIM_ID or MIIM_STATE or MIIM_FTYPE，前面已經解釋過前三種，最後一個 MIIM_FTYPE，必須把 fType 設為 MFT_RADIOCHECK。見第 253∼261 行。

添加分隔線

最後一種，如何設定分隔線呢？首先將 fMask 欄位設為 MIIM_FTYPE，然後再把 fType 設為 MFT_SEPARATOR。見第 262∼265 行。

添加選項後呼叫 DrawMenuBar

DRAW5 添加了許多選項，也變更了有些選項的屬性，並不需要每次變更就呼叫 DrawMenuBar，等最後全部完成再一次呼叫 DrawMenuBar 即可。

擁有者繪製的選項（Owner-Drawn Menu Items）

「擁有者繪製的選項」意思是指由應用程式處理有關選項的幾乎所有工作，包含繪製選項文字或是背景圖片、處理被選擇選項的高亮度光棒……等原本由系統處理的工作。正因為系統把這些工作開放給應用程式，所以可以做成許多酷炫的效果。一如既往，先介紹原理及所使用到的 Win64 API，再佐以例子說明。

要製作擁有者繪製的選項，必須先呼叫 CreateMenu 產生一個空的選項，再藉由設定適當的參數呼叫 InsertMenuItem 才能建立擁有者繪製的選項。

如何建立擁有者繪製的選項

其實只要參考上面 InsertMenuItem 的說明，應該就能夠製作出來。主要就是在 fMask 中含有 MIIM_FTYPE 旗標，並在 fType 中設定 MFT_OWNERDRAW 旗標。例如底下的程式碼：

mii     MENUITEMINFO    <?>
          ⁝
        call    CreateMenu
        mov     hMenu,rax
        mov     mii.cbSize,SIZEOF MENUITEMINFO          ;設定MENUITEMINFO結構體大小
        mov     mii.fMask,MIIM_ID or MIIM_FTYPE         ;呼叫InsertMenuItem時，設定選項識別碼及選項類型
        mov     mii.fType,MFT_OWNERDRAW                 ;設定選項類型為擁有者繪製
        mov     mii.wID,2000                            ;選項識別碼為2000
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii    ;於hMenu功能表中添加選項識別碼為2000的選項

這樣設定好之後，如果執行會看見一個空空如也的選項，甚至選項範圍的大小也不大，而且裏面什麼也沒有，這就是「擁有者繪製的選項」。那麼要如何將這個擁有者繪製選項修改成我們想要的樣子呢？首先要修改選項範圍的大小。

WM_MEASUREITEM 訊息

當建立擁有者繪製的選項或某些控制項時，系統會把 WM_MEASUREITEM 訊息傳送到擁有該功能表或控制項的視窗函式之中。應用程式藉由此訊息設定選項或控制項的尺寸。當系統傳來 WM_MEASUREITEM 訊息時，其中 wParam 有兩種情形：①如果是因功能表而傳來的，wParam 為零；②如果是因控制項而傳來的，wParam 為控制項識別碼。

擁有者繪製的物件有兩類：選項和控制項，控制項有很多種，常見的有按鈕（button）、清單（list）、編輯框（edit）……等這些物件，以後再說明。但是因為建立了擁有者繪製的控制項也會發送 WM_MEASUREITEM 訊息，所以在此略為提一提。

WM_MEASUREITEM 訊息的 lParam 則是一個指標，指向結構體 MEASUREITEMSTRUCT 所在的位址。MEASUREITEMSTRUCT 的各欄位如下：

MEASUREITEMSTRUCT       STRUCT
  CtlType       DWORD   ?       ;類型
  CtlID         DWORD   ?       ;控制項識別碼，功能表不用此欄
  itemID        DWORD   ?       ;對控制項而言是項目位置；對功能表而言是選項識別碼
  itemWidth     DWORD   ?       ;功能表選項寬度，單位是像素
  itemHeight    DWORD   ?       ;功能表選像高度，或清單控制項中某個選項的高度
                DWORD   ?       ;為了能對齊四字組而多加的空欄位，在WinInc的winuser.inc中此處也發生錯誤
  itemData      QWORD   ?       ;應用程式自行加入的資料
MEASUREITEMSTRUCT       ENDS

各欄位的說明如下：

  1. CtlType：可能是下表中的其中之一：
    CtlType數值說明
    ODT_MENU1擁有者繪製的功能表
    ODT_LISTBOX2擁有者繪製的清單控制項
    ODT_COMBOBOX3擁有者繪製的下拉式方塊控制項
    ODT_BUTTON4擁有者繪製的按鈕控制項
    ODT_STATIC5擁有者繪製的靜態控制項
    ODT_TAB101擁有者繪製的標籤頁控制項
    ODT_LISTVIEW102擁有者繪製的清單檢視控制項
  2. CtlID：對於擁有者繪製的功能表而言，不用此欄；對控制項而言，為控制項識別碼。
  3. itemID：功能表選項的識別碼或清單、下拉式方塊等控制項的項目位置。清單控制項具有 LBS_OWNERDRAWVARIABLE 時以及下拉式方塊控制項具有 CBS_OWNERDRAWVARIABLE 時，才會使用此欄位定。
  4. itemWidth：功能表中選項的寬度，以像素為單位。在結束此訊息之前，必須把正確值存入 itemWidth 欄位以使系統設定選項寬度。
  5. itemHeight：功能表中選項的高度或清單、下拉式方塊控制項的項目高度，以像素為單位。在結束此訊息之前，必須把正確值存入 itemHeight 欄位以使系統設定選項或項目高度。
  6. itemData：應用程式自行定義的數值。

系統將 WM_MEASUREITEM 訊息傳送到具有擁有者繪製之功能表或控制項的視窗函式時，除了 itemWidth、itemHeight 之外，系統均已填好適當值；而 itemWidth、itemHeight 這兩欄位，必須由應用程式自行填入，當返回系統後，系統會根據這兩欄設定好該項目尺寸。由 WM_MEASUREITEM 返回時，必須將 RAX 設為一，也就是將回傳值設為一，讓系統知道已處理完此訊息。

WM_DRAWITEM 訊息

當擁有者繪製的功能表或控制項改變外觀時，系統會將 WM_DRAWITEM 訊息發送到擁有該功能表或控制項的視窗函式中。其中的 wParam 有兩種情形：①如果是因功能表而傳來的，wParam 為零。②如果是因控制項而傳來的，wParam 為控制項識別碼。

WM_DRAWITEM 訊息的 lParam 則是一個指標，指向結構體 DRAWITEMSTRUCT 所在的位址，此結構體的欄位如下：

DRAWITEMSTRUCT  STRUCT
  CtlType       DWORD   ?       ;類型
  CtlID         DWORD   ?       ;控制項識別碼，功能表不用此欄
  itemID        DWORD   ?       ;對控制項而言是項目位置；對功能表而言是選項識別碼
  itemAction    DWORD   ?       ;何時須繪製
  itemState     DWORD   ?       ;繪製完成後項目的狀態
                DWORD   ?       ;為使欄位對齊，在WinInc的winuser.inc中此處也發生錯誤
  hwndItem      HWND    ?       ;功能表代碼或控制項代碼
  hDC           HDC     ?       ;裝置內容代碼
  rcItem        RECT    <>      ;繪製範圍
  itemData      QWORD   ?       ;應用程式自行定義的資料
DRAWITEMSTRUCT  ENDS

如果用 WinInc 包含檔，那麼在 winuser.inc 包含檔內，DRAWITEMSTRUCT 的定義是錯誤的，因為少了在 itemState 之後沒有定義名稱且長為 DWORD 的欄位，請自行更正為上面正確的定義。

DRAWITEMSTRUCT 各欄位的說明如下：

  1. CtlType：見上表。
  2. CtlID：對於擁有者繪製的功能表而言，不用此欄；對控制項而言，為控制項識別碼。
  3. itemID：功能表選項的識別碼或清單、下拉式方塊等控制項的項目位置。
  4. itemAction：是指在怎樣的動作下需要繪製控制項或選項，可能的情形是下面三種情形之一，也可能多種情形：
    itemAction數值說明
    ODA_DRAWENTIRE1控制項需整個繪製
    ODA_SELECT2選擇狀態發生改變
    ODA_FOCUS4控制項獲得或失去輸入焦點
  5. itemState：繪製完成後項目的狀態，可能是下表所列的數值或其組合：
    itemAction數值說明
    ODS_SELECTED1功能表中的項目是被選擇的
    ODS_GRAYED2功能表中的項目是無效的
    ODS_DISABLED4禁用的項目
    ODS_CHECKED8功能表中的項目是被勾選的
    ODS_FOCUS10H此項目具有鍵盤輸入焦點
    ODS_DEFAULT20H此項目是預設的
    ODS_HOTLIGHT40H此項目高亮度顯示，亦即當滑鼠停留在此項目時被突顯出來
    ODS_INACTIVE80H該功能表項目處於非活動狀態，並且具有該功能表的視窗也處於非活動狀態
    ODS_NOACCEL100H有些控制項會在文字下畫有底線以提示快捷鍵，在 ODS_NOACCEL 狀態下則不提示
    ODS_NOFOCUSRECT200H控制項獲得鍵盤輸入焦點時，周圍會出現焦點矩形或高亮度效果，此刻控制項可以用鍵盤操作。但如果處於 ODS_NOFOCUSRECT 狀態，則不會顯示焦點矩形或高亮度效果
    ODS_COMBOBOXEDIT1000H繪製下拉式方塊控制項的編輯框
  6. hwndItem：對功能表而言，為具有此選項的功能表代碼；對控制項而言，為控制項代碼。
  7. hDC：裝置內容代碼，當繪製擁有者繪製的功能表選項或控制項時都會用得著。
  8. rcItem：定義了在 hDC 欄位中繪製的範圍。對控制項而言，系統會自動裁剪超出的部分；對功能表而言，系統不會自動裁剪超出的部分。
  9. itemData：應用程式自行定義的資料。

WM_DRAWITEM 返回時，必須將回傳值設為一，讓系統知道已處理完 WM_DRAWITEM 訊息。

GetSysColor API

GetSysColor API 用於取得顯示元素（display element）的顏色，顯示元素是指螢幕上或視窗上的某部份。語法如下：

invoke  GetSysColor,\
        nIndex          ; display element

nIndex 是顯示元素，底下的表僅列出一些，可以查閱 MSDN 得到更詳細的資料。

nIndex數值說明
COLOR_3DDKSHADOW21三維顯示元素的陰影部分的顏色
COLOR_BACKGROUND1桌面的顏色
COLOR_BTNFACE15三維顯示元素表面的顏色或對話框背景顏色
COLOR_BTNTEXT18按鈕上的文字顏色
COLOR_MENU4功能表背景色
COLOR_MENUTEXT7功能表文字的顏色
COLOR_WINDOWTEXT8視窗工作區文字的顏色

如果 GetSysColor 執行成功，回傳值為顏色值；如果執行失敗，回傳值為零，但是零也是顏色值的一種（零代表黑色），可以用 GetSysColorBrush 確認，如果 GetSysColorBrush 回傳值為零代表不支援此參數。

GetSysColorBrush API

GetSysColorBrush 用來取得塗滿視窗某部分的畫刷代碼，語法如下，參數 nIndex 為顯示元素，也就是上表。

invoke  GetSysColorBrush,\
        nIndex          ; system color index

如果 GetSysColorBrush 執行成功，回傳值是畫刷代碼；如果執行失敗，回傳值為零。經由呼叫 GetSysColorBrush 而得到的畫刷是用來塗滿 Windows 系統的某部分元件，稱為系統畫刷（system color brush），不需要銷毀。

CreateFont API

CreateFont 是用來建立邏輯字形的。如果讀者曾用過 Lotus SmartSuite Word Pro、MS Word 等文書軟體，它們都能讓使用者使用各種不同的字形，並且顯示出來。應用程式要顯示不同的字形，得先建立邏輯字形，底下來看看 CreateFont 的原型：

invoke  CreateFont,\
        nHeight,\               ; height of font
        nWidth,\                ; average character width
        nEscapement,\           ; angle of escapement
        nOrientation,\          ; base-line orientation angle
        fnWeight,\              ; font weight
        fdwItalic,\             ; italic attribute option
        fdwUnderline,\          ; underline attribute option
        fdwStrikeOut,\          ; strikeout attribute option
        fdwCharSet,\            ; character set identifier
        fdwOutputPrecision,\    ; output precision
        fdwClipPrecision,\      ; clipping precision
        fdwQuality,\            ; output quality
        fdwPitchAndFamily,\     ; pitch and family
        lpszFace                ; typeface name

底下是這些參數的說明：

  1. nHeight：字形高度，以邏輯單位表示。邏輯單位（logical units）與映射模式有關，預設的映射模式是 MM_TEXT，在這種映射模式下，邏輯單位等於像素。如果 nHeight 為 0，表示字形高度為預設值。nHeight 可以是正值或負值。參考上圖，如果 nHeight 為正值，則 nHeight 就是圖中的 Height，不包含 ExternalLeading。如果 nHeight 為負值，使 nHeight 取絕對值之後，只包含 Ascent 與 Descent，而排除 InternalLeading。
  2. nWidth：字型的平均寬度，以邏輯單位表示。如果 nWidth 設為零，則系統會自動使用能與 nHeight 匹配的最接近值。使用非零值對點陣字行並不會起太大作用，但對於 TrueType 字形，能輕鬆地用它來獲得比正常字元更寬或更窄的字形。
  3. nEscapement：字元間所連成的直線與水平線之間的夾角，單位是 0.1 度。只有在圖形模式為 GM_ADVANCED 才有效果；如果是 GM_COMPATIBLE 模式，那麼 nEscapement 必須與 nOrientation 之值相同，若不同以 nEscapement 為準。
  4. nOrientation：字形基線（BaseLine，上圖）與水平線之間的夾角，單位是 0.1 度。下表以圖形模式分別是 GM_COMPATIBLE 或 GM_ADVANCED，假設 nEscapement、nOrientation 分別為 0 度或 30 度時，印出「夏蟬飛雪，輪迴不過一瞥。」字串，來說明這些角度：
    圖形模式GM_COMPATIBLEGM_ADVANCED
    nEscapement03000300
    nOrientation30003000
    結果
    第一欄是 GM_COMPATIBLE 模式，所以即使是 nEscapement、nOrientation 各是 0、300，事實上以 nEscapement 為準，所以 nEscapement、nOrientation 均為 0，也就是不轉動。同理，第二欄其實 nEscapement、nOrientation 均為 300，但因為是 GM_COMPATIBLE 模式，只有 nOrientation 有作用，所以字形基線與水平線夾 30 度角。第三欄是 GM_ADVANCED 模式，nEscapement、nOrientation 均有作用，nEscapement 是 0 表示字元的連線（綠線，較簡單的看法是把字元左下角連起來）與水平線夾零度角，nOrientation 是 30 度表示字形基線（紅線）水平線夾 30 度角。第四欄，nEscapement 是 300 表示字元的連線（綠線）與水平線夾 30 度角，nOrientation 是 0 表示字形基線（紅線）水平線夾零度角。這段繪製字串的程式碼如下： 
    szMsJhengHei    DB      "微軟正黑體",0
szText          DB      "夏蟬飛雪，輪迴不過一瞥。",0
  ⁝
.switch uMsg
  .case WM_PAINT
        invoke  BeginPaint,hWnd,ADDR ps
        invoke  SetGraphicsMode,ps.hdc,圖形模式
        invoke  GetClientRect,hWnd,ADDR rect
        invoke  FillRect,ps.hdc,ADDR rect,hbrBlack
        invoke  SetTextColor,ps.hdc,0ffffffh
        invoke  SetBkColor,ps.hdc,0
        invoke  SelectObject,ps.hdc,hFont
        invoke  DeleteObject,rax
        invoke  DrawText,ps.hdc,OFFSET szText,-1,ADDR rect,DT_SINGLELINE or DT_CENTER or DT_VCENTER
        invoke  EndPaint,hWnd,ADDR ps

  .case WM_CREATE
        invoke  CreateFont,30,0,nEscapement,nOrientation,FW_BOLD,0,0,0,DEFAULT_CHARSET,OUT_DEFAULT_PRECIS,\
                CLIP_DEFAULT_PRECIS,DEFAULT_QUALITY,DEFAULT_PITCH or FF_DONTCARE,OFFSET szMsJhengHei
        mov     hFont,rax
        invoke  CreateSolidBrush,0
        mov     hbrBlack,rax
    程式中的圖形模式可用GM_COMPATIBLE 或 GM_ADVANCED 代入，nEscapement、nOrientation 可用 0 或 300 代入。300 代表 30 度角。
  5. fnWeight：字形的粗細，可以是 0、100、200、300……900，數值越大字體越粗。也可以用以下常數代替：FW_THIN＝100，FW_NORMAL＝400，FW_BOLD＝700，FW_BLACK＝900。
  6. fdwItalic：是否為斜體，1 代表斜體，0 正常。
  7. fdwUnderline：是否有底線。1 代表有底線，0 沒有底線。
  8. fdwStrikeOut ：是否有刪除線，1 代表有刪除線，0 代表沒有刪除線。刪除線是在文字中間的橫線。
  9. fdwCharSet：指定字元集，字元集用來確定字形所支援的字元範圍，使應用程式所建立的字形可以正確顯示。底下是常用且已經在 Windows 系統內預先定義的字元集：
    fdwCharSet數值說明
    ANSI_CHARSET0美國及西歐常使用的字元集
    DEFAULT_CHARSET1執行應用程式的電腦上，系統內定的字元集
    SHIFTJIS_CHARSET128日文字元集
    GB2312_CHARSET134簡體中文字元集
    CHINESEBIG5_CHARSET136正體中文字元集
    如果無法確定用哪一種字元集，就使用 DEFAULT_CHARSET 吧。這是系統內定的字元集，不會錯的。
  10. fdwOutputPrecision：指定字形輸出的精確度，它指定了輸出的字形必須與以下參數 nHeight、nWidth、nEscapement、nOrientation、間距和字型類型所指定的資料相匹配的程度，下表是常用的 fdwOutputPrecision：
    fdwOutputPrecision數值說明
    OUT_CHARACTER_PRECIS2不使用輸出精確度
    OUT_DEFAULT_PRECIS0使用內定的輸出精確度
    OUT_DEVICE_PRECIS5使用裝置字形輸出精確度，裝置字形是在其他周邊設備內建的字形，例如有些印表機就有內建字形
    OUT_OUTLINE_PRECIS8使用 TrueType 字形和其他描邊字形輸出精確度
    OUT_PS_ONLY_PRECIS10只在 PostScript 字形中選擇。如果系統中沒有安裝 PostScript 字形，則使用內定值
    OUT_RASTER_PRECIS6當系統包含多個相同名稱的字形時，選擇點陣字形
    OUT_SCREEN_OUTLINE_
    PRECIS    		9使用螢幕顯示的描邊字形的輸出精度，在螢幕上能保證最佳顯示效果
    OUT_STRING_PRECIS1這個值不是指定字形而讓應程式使用，列舉點陣字形
    OUT_STROKE_PRECIS3這個值不是指定字形而讓應程式使用，列舉 TrueType 字形或其他向量字形
    OUT_TT_ONLY_PRECIS7只在 TrueType 字形中選擇。如果系統中沒有安裝 TrueType 字形，則使用內定值
    OUT_TT_PRECIS4當系統包含多個相同名稱的字形時，選擇 TrueType 字形
  11. fdwClipPrecision：指定裁剪精確度，亦即如何裁剪超出裁剪矩形的字元，常用的方法如下表：
    fdwClipPrecision數值說明
    CLIP_DEFAULT_PRECIS0使用內定裁剪精確度
    CLIP_CHARACTER_PRECIS1不使用裁剪精確度
    CLIP_STROKE_PRECIS2這個值不是指定字形而讓應程式使用，而是列舉點陣、向量或 TrueType 字形
  12. fdwQuality：指定輸出品質，可以是下表數值的其中一種：
    fdwQuality數值說明
    DEFAULT_QUALITY0以系統預設值處理字形外觀，而不特別加強處理
    DRAFT_QUALITY1字形的品質較不重要
    PROOF_QUALITY2字形的品質（平滑度、清晰度）比較重要，即使字形大小不能與所指定的匹配
    NONANTIALIASED_QUALITY3不進行反鋸齒處理
    ANTIALIASED_QUALITY4字形為平滑的，也就是反鋸齒
    CLEARTYPE_QUALITY5以 ClearType 方式反鋸齒
  13. fdwPitchAndFamily：fdwPitchAndFamily分為兩部分：
    　　①：0∼3位元代表字元間距離，其實是字形寬度可以是以下三者之一：
    　　　　DEFAULT_PITCH：內定字距，可能是固定寬度或可變寬度。其值為 0。
    　　　　FIXED_PITCH：固定寬度，其值為 1。
    　　　　VARIABLE_PITCH：可變寬度，其值為 2。
    　　②：4∼8位元則描述了字形外觀或風格，可以是下面數值（這些數值包含了較低的四個位元）：
    　　　　FF_DONTCARE：忽略字形外觀或風格，其值為 0。
    　　　　FF_ROMAN：羅馬字形，例如 MS Serif。其值為 10H。
    　　　　FF_SWISS：瑞士字形，例如 MS Sans Serif。其值為 20H。
    　　　　FF_MODERN：現代字形，例如 Pica、Elite、Courier New。其值為 30H。
    　　　　FF_SCRIPT：手寫或草寫字形，例如 Script、Cursive，其值為 40H。
    　　　　FF_DECORATIVE：裝飾性字型，例如 Old English，其值為 50H。
    在呼叫 CreateFont 時，應將這兩部分以 or 運算子連接，這樣組譯器能算出結果，此結果才是 fdwPitchAndFamily 參數。
  14. lpszFace：字形名稱的位址，字形名稱是以零為結尾的字串，且此字串長度包含結尾的零不能超過 32 個字元。如果 lpszFace 為零或所指的位址為空字串，那麼 GDI 將使用符合其他指定屬性的第一個字形。

CreateFont 的參數很多，共十四個，都是描述邏輯字形的性質，可粗分成三種：字形名稱（lpszFace）、字形大小（nHeight、nWidth）、字形風格與精密度。一般呼叫 CreateFont 時，最重要的是 lpszFace，決定字形名稱，例如「Courier New」、「新細明體」……等，但注意必須以零為結尾的字串。如果不知道字形名稱，可以開啟 MS WORD，點選字形下拉式方塊控制項觀察。

決定字形名稱之後，其次重要的是字形大小，也就是第一個參數，nHeight，其單位是邏輯單位。如果沒有改變映射模式，預定的邏輯單位就是像素。大部分的情況，都會把 nHeight 設為正值，這樣就是上圖中的 Height。

最後字形風格與精密度，但若不特別講究使用預設值即可。也就是除了第一個參數，nHeight，和最後一個參數，lpszFace，之外的其他 12 個參數，都可以設為內定值，由系統自行決定。這樣就很簡單了。

如果應用程式要顯示不同的字形，得先建立邏輯字形，即使要顯示的字形都是名為「Times New Roman」，但一是斜體、一是含有底線，那麼也需建立兩個邏輯字形，然後在繪製出字串之前，用 SelectObject 選擇不同的邏輯字形，再呼叫 DrawText 或 TextOut 畫出。

CreateFont 如果執行成功，回傳值是邏輯字形代碼；如果執行失敗，回傳值是零。邏輯字形不再使用時，應該用 DeleteObject 將其刪除，以免耗費過多資源。一般來說，當選用一個新的邏輯字形時，舊的邏輯字形大概就用不著了，恰好 SelectObject 就是傳回舊的邏輯字形，因此立即就將回傳的舊邏輯字形刪除了。

擁有者繪製選項的例子

解釋完製作擁有者繪製選項的原理之後，實作一個例子：ONDMENU，執行畫面如下。ONDMENU 的主功能表有兩個彈出選項：檔案、字形，以及一個選項：關於。如果使用者以滑鼠點選檔案彈出選項，產生檔案子功能表，內有五個選項：建新檔案、開啟舊檔案、儲存檔案、分隔線、離開，除了分隔線之外，其餘四個選項都是擁有者繪製選項，其文字都是呼叫 DrawText 繪製的；選項前的圖片都是位元圖，透過 BitBlt 傳輸到子功能表的裝置內容而顯現；被選擇選項的紅色光棒則是透過 FillRect 畫出來的。字形彈出選項能產生字形子功能表，其內五個也都是擁有者繪製選項：標楷體、新細明體、「Courier New」、「Times New Roman」、「Microsoft Sans Serif」。背景圖是一張翹著大長腿的美女圖，是透過 BitBlt 傳輸到子功能表的裝置內容而顯現；選項文字用不同的字形表示，則是以 CreateFont、SelectObject 設定並呼叫 DrawText 繪製的；勾選的正方形記號，則是透過 BitBlt 畫在子功能表的裝置內容上。這五個字形的選項是互斥的，只能選擇一個，選了之後工作區內的字形會改變，同時選單內勾選的正方形記號也會變成在點選的選項之前。

ONDMENU.ASM、ONDMENU.RC 及其他圖案檔

ONDMENU.RC 的內容如下：

1
2
3
4
5
6
7
ONDMENU ICON    MENU.ico
N1W     BITMAP  NEW.bmp
OPN     BITMAP  OPEN.bmp
SAV     BITMAP  SAVE.bmp
EIT     BITMAP  EXIT.bmp
BTY     BITMAP  BEAUTY.bmp
CHK     BITMAP  CHECKED.bmp

注意到，小木偶把六個位元圖的名稱都以三個字母表示，這是特別算計的。因為在組合語言原始程式中，位元圖名稱必須以零結尾，再加上三個英文字母，總共四個位元組，這樣就可以很容易在位元圖名稱的陣列中計算出位址。例如底下的 szBmpName 陣列有六個元素，每個元素都是代表位元圖的名稱三個字母及一個 0 組成，在 WM_CREATE 訊息中，很容易用 szBmpName[4×n] 取得其位址，n 為第幾個元素，從 0 到 5：

szBmpName       DB      "N1W",0,"OPN",0,"SAV",0,"EIT",0,"BTY",0,"CHK",0

另外還有一個更簡單的方法。第十四章提過，資源描述檔中的圖示名稱可以是字串，也可以是十六位元的無號數，位元圖名稱也是如此。所以可以用連續的十六位元無號數，來表示這些位元圖，這樣會比上述方法更簡單，讀者可以自行練習。

雖然 ONDMENU.RC 僅僅七行，但是另外有六張 BMP 圖案檔、一個圖示檔案，而組合語言原始檔 ONDMENU.ASM 約三百六十多行，所以不在這裏列出來，請到這裏下載。在 ONDMENU.ASM 的前幾行，有組譯與連結步驟。

處理 WM_MEASUREITEM 訊息

前面提過，ONDMENU 的功能表中，檔案子功能表有四個擁有者繪製的選項，而字形子功能表有五個擁有者繪製的選項，總共九個。每建立一個選項，系統就會把 WM_MEASUREITEM 訊息傳給視窗函式，所以 ONDMENU 會收到九則 WM_MEASUREITEM 訊息，必須在這時候決定各選項的大小。不過因為前四個選項與後五個選項分別在不同的兩個子功能表內，決定其大小的方式也就分為兩種。當然，在同一個子功能表內的選項大小可以不同，不過 ONDMENU 裏是一樣的。

①：ONDMENU 設定檔案子功能表的四個擁有者繪製的選項寬度與高度都相同，高度為 cyFileMenu，其大小就是預設的選項高度，可以用 SM_CYMENU 為參數呼叫 GetSystemMetrics 得到。每個選項的寬度則是高度的五倍，再加上位元圖寬度。位元圖寬度則是呼叫 GetObject 得到，GetObject 的第一個參數，是位元圖代碼。檔案子功能表的四個擁有者繪製選項的前面，各自有各自的位元圖，雖然圖片不同，但大小均相同，因此只需要得到其中一個位元圖的寬度即可。

②：字形子功能表的全部大小，即為 BEAUTY.bmp 位元圖的大小，而字形子功能表內有五個選項，因此每個選項的高度是 BEAUTY.bmp 高度的五分之一，選項寬度則是 BEAUTY.bmp 的寬度。

底下是處理 WM_MEASUREITEM 訊息以及與該訊息相關的程式碼。因為視窗函式會收到九則 WM_MEASUREITEM 訊息，如果每次都要重新計算選項的寬度與高度，就會多計算好幾次而使效率變低（實際上以現今 CPU 的效率，這一點延遲人類是感覺不出來的）。假如把這計算交由處理 WM_CREATE 訊息時就計算好，那只要算一次即可，效率較高。

  .case WM_CREATE
    ;載入建新檔案、開啟舊檔案、儲存檔案、離開四個選項前的位元圖，及美女圖、勾選正方形圖
        invoke  LoadBitmap,hInstance,OFFSET szBmpName
        mov     hBmp,rax
        invoke  LoadBitmap,hInstance,OFFSET szBmpName[4]
        mov     hBmp[8],rax
        ⁝
        invoke  LoadBitmap,hInstance,OFFSET szBmpName[16]
        mov     hBmp[32],rax
        ⁝
    ;計算檔案功能表各選項的高度及寬度，高度＝預設值，寬度＝高度×5＋位元圖寬度
        invoke  GetSystemMetrics,SM_CYMENU
        mov     cyFileMenu,eax
        mov     cxFileMenu,eax
        shl     cxFileMenu,2
        add     eax,bmp.bmWidth
        add     cxFileMenu,eax
    ;計算字形功能表的高度及寬度，高度＝BEAUTY.bmp高度÷5，寬度＝BEAUTY.bmp寬度
        invoke  GetObject,hBmp[32],SIZEOF BITMAP,ADDR bmp
        mov     eax,bmp.bmHeight
        mov     r11d,5
        xor     edx,edx
        div     r11d
        mov     r10d,bmp.bmWidth
        mov     cyFontMenu,eax
        mov     cxFontMenu,r10d

  .case WM_MEASUREITEM
        ASSUME  r9:PTR MEASUREITEMSTRUCT
        mov     r10d,cxFileMenu
        mov     r11d,cyFileMenu
        cmp     [r9].itemID,IDM_STDKAI  ;檢查選項屬於檔案子功能表還是字形子功能表
        jb      @f                      ;如果是屬於檔案子功能表，跳至@@:處
        mov     r10d,cxFontMenu         ;如果是屬於字形子功能表，重設R10D、R11D
        mov     r11d,cyFontMenu
@@:     mov     [r9].itemWidth,r10d
        mov     [r9].itemHeight,r11d
        ASSUME  r9:NOTHING
        mov     rax,1
        jmp     return

那要怎麼樣才能判斷是因為建立了檔案子功能表中的選項，還是建立了字形子功能表中的選項才引發 WM_MEASUREITEM 訊息的呢？其實很簡單，只要檢查 MEASUREITEMSTRUCT 結構體的 itemID 欄位是否小於 IDM_STDKAI，IDM_STDKAI 是「標楷體」選項的識別碼。如果 itemID 欄位比 IDM_STDKAI 小，代表是因為建立了檔案子功能表中的選項，否則就是建立字形子功能表中的選項。

在處理 WM_MEASUREITEM 訊息時，先假設是因為建立了檔案子功能表中的選項，R10D、R11D 為檔案子功能表選項的寬與高。再檢查 MEASUREITEMSTRUCT 結構體的 itemID 欄位，決定是因為建立了哪個子功能表中的選項，如果假設正確就可直接將 R10D、R11D 存入 MEASUREITEMSTRUCT 結構體的 itemWidth、itemHeight 欄位裏，然後返回。如果假設錯了，還得先把 R10D、R11D 重設為字形子功能表選項的寬與高，然後再存入 itemWidth、itemHeight 欄位裏。

在這裡還有兩處值得一提。一是由六個元素組成的 hBmp 陣列，這個陣列是用來依序儲存「建新檔案」、「開啟舊檔案」、「儲存檔案」、「離開」四個選項前的位元圖代碼。而第四個元素是 BEAUTY.bmp 的代碼，第五個元素是 CHECKED.bmp 的代碼，前者是美女圖顯示於字形子功能表的背景，後者用於字形子功能表選項前的正方形勾選記號。位元圖代碼的資料類型是 HBITMAP，是八個位元組長，因此定義為：

hBmp            HBITMAP 6 DUP (?)

所以要存取 hBmp 陣列的位元圖代碼可以用 hBmp[8×m]，m 是第幾個元素，m 由 0 到 5。若 m 為 4，計算結果為 hBmp[32]，就是美女圖代碼。

第二個值得一提的是 ASSUME 與 PTR 假指令。

PTR 運算子

在第二章時，曾介紹過 PTR 運算子，它是用來強制改變運算元的資料類型。例如底下的例子，雖然 number 定義為雙字組，但是卻可用 PTR 強制變為字組，最後 CX 變為5678H：

number  DD      12345678h
        ⁝
        mov     cx,WORD PTR number

事實上，PTR 有兩種用法，這兒要介紹第二種用法。當 PTR 後面接著的是結構體時，組譯器會把 PTR 當成是指向該結構體的指標，這需要與 ASSUME 假指令配合，請看底下 ASSUME 假指令的說明。

ASSUME 假指令

ASSUME 的用法有許多種，此處只列出 ONDMENU 用到的兩種：

ASSUME   dataregister:qualifiedtype [[, dataregister:qualifiedtype]]
ASSUME   [[register:]]NOTHING [[, register:NOTHING]]

ASSUME 的第一種用法是使某個通用暫存器具有特定的資料類型。dataregister 是指通用暫存器，包含 RAX、RBX……、R8、R9……等六十四位元的暫存器，或是前述暫存器更小位元的暫存器，例如 EAX、AX、AL……等暫存器；qualifiedtype 是資料類型，可以是 QWORD、DWORD、WORD……等，也可以是結構體（事實上，結構體是應用程式自行宣告的資料類型）。例如底下的例子把 BX 設定為 WORD 資料類型：

ASSUME  bx:WORD

其實這是多此一舉，因為 BX 本就是十六位元，長度本就是一個字組。事實上，如果 dataregister 與 qualifiedtype 長度不相符，還會導致錯誤而無法組譯。「ASSUME dataregister:qualifiedtype」比較常見的用法是用在結構體上，尤其是結構體的指標上。例如：

ASSUME r9:PTR MEASUREITEMSTRUCT

「PTR MEASUREITEMSTRUCT」的運算結果是得到 MEASUREITEMSTRUCT 結構體的指標，所以上面的程式是告訴組譯器，R9 是指向 MEASUREITEMSTRUCT 結構體的指標。如果要存取該結構體內的欄位，只要再加上該欄位的偏移位址即可。例如要把 itemID 欄位內的資料存入 EAX 暫存器內，可以用以下程式：

msi     MEASUREITEMSTRUCT   <?>
        ⁝
lea     r9,msi
ASSUME  r9:PTR MEASUREITEMSTRUCT
mov     eax,[r9].itemID

或許有讀者會問，可不可以使用「ASSUME r9:MEASUREITEMSTRUCT」呢？答案是不可以，這樣的話就是使 R9 變為 MEASUREITEMSTRUCT 資料類型，這兩者長度顯然是不符合，會發生錯誤。

ASSUME 的第二種用法是「ASSUME register : NOTHING」，取消對 register 的假設，以避免後續程式中對 register 錯誤的解釋。

處理 WM_DRAWITEM 訊息

當要顯示擁有者繪製選項時，系統會把 WM_DRAWITEM 訊息傳給視窗函式，lParam 是 DRAWITEMSTRUCT 結構體的位址，並且 lParam 之值會存入 R9 暫存器內，在繪製選項時，少不了得讀取此結構體內的資料。本來可以跟處理 WM_MEASUREITEM 的方式一樣，假設「ASSUME R9:PTR DRAWITEMSTRUCT」直接存取 lParam 所指的資料，但是每次呼叫 Win64 API 之後，R9 之值會改變，所以必須另起爐灶才行。有兩種方法：

①：另外找一個不會因為呼叫 Win64 API 而改變的暫存器，其實不變的暫存器都可以，例如 RBX、RSI 等。

②：把 R9 所指位址的 DRAWITEMSTRUCT 結構體存入另一個結構體內。ONDMENU 採用這種方法，並把後者定義在 dis 區域變數中。也就是開始處理 WM_DRAWITEM 訊息的前幾行指令：

  .case WM_DRAWITEM
      ;把lParam指向的DRAWITEMSTRUCT內資料複製到dis區域變數內
        mov     rcx,SIZEOF DRAWITEMSTRUCT
        lea     rdi,dis
        mov     rsi,r9
        rep     movsb
        ⁝

處理 WM_DRAWITEM 訊息也分成兩部分，一是處理檔案子功能表，二是處理字形子功能表。但在分開處理之前，還有三件事是處理兩個子功能表都會做的事：

⑴、文字背景模式設為透明。繪製兩個子功能表都必須把文字背景模式設為 TRANSPARENT。可以呼叫 SetBkMode 把背景模式設為 TRANSPARENT，這樣文字的背景變成透明，才能顯現出背景圖來。如果不設成透明，會變成下圖的樣子。因為滑鼠游標懸停的選項（即被選擇的選項）文字與背景同色，所以根本看不出來選項文字。

⑵、建立相容於 dis.hdc 的記憶體裝置內容。在繪製檔案子功能表與字形子功能表的時候，都會要把位元圖顯示在子功能表的裝置內容中，前者要畫出四個選項文字前的位元圖，後者要畫出美女背景圖。這時須呼叫 BitBlt，因此呼叫 CreateCompatibleDC 建立記憶體裝置內容。

⑶、設定文字顏色。在繪製檔案子功能表與字形子功能表的時候，被選擇的文字顏色均為白色，未被選擇的文字顏色均使用預設的顏色。程式如下：
      ;設定選項文字顏色，選擇的用白色，未選擇的用預設的選項文字顏色
        mov     edx,clrMenuText
        test    dis.itemState,ODS_SELECTED
        jz      @f
        mov     edx,0ffffffh
預設的選項文字顏色，可以用 COLOR_MENUTEXT 為參數，呼叫 GetSysColor，再將所獲得的顏色存於 clrMenuText。

處理好兩個子功能表相同的三件事之後，就得判斷 dis.itemID 是否小於 IDM_STDKAI，來區分⑴處理檔案子功能表還是處理⑵字形子功能表內的選項。先來看看如何處理繪製檔案子功能表內的選項。

⑴、繪製檔案子功能表內的選項的步驟是⒜繪製紅色光棒或背景色、⒝繪製選項文字、⒞繪製選項文字前的位元圖。注意！第⒜項工作一定要最先繪製，而⒝、⒞兩項誰先誰後則無關緊要。如果第⒜項比⒝、⒞後繪製，那麼紅色光棒或背景色就會覆蓋掉選項文字及位元圖，選項裏什麼都沒有，即使還是可以正常操作。

先說明⒜中的紅色光棒和背景色如何繪製。其實很簡單，只是呼叫 FillRect 即可，被選擇的選項參數畫刷為紅色畫刷，未被選擇的選項參數畫刷為功能表預設背景畫刷，整段程式如下：

      ;繪製選項的背景色，選擇的為紅色，未選擇的為預設值
        mov     r8,hbrMenuBk
        test    dis.itemState,ODS_SELECTED
        jz      @f
        mov     r8,hbrRed
@@:     invoke  FillRect,dis.hDC,ADDR dis.rcItem,r8

在檢查是否為被選擇的選項時，使用 TEST 指令，而不是 CMP 指令，是因為選項的狀態除了被選擇／未被選擇，還有許多種例如勾選／未勾選等等。每種狀態都用一個位元表示，因此有許多種組合，使用 TEST 檢查 ODS_SELECTED 代表的位元是最簡單的一種方式。

剛提過，每次更新選項系統就會把 WM_DRAWITEM 訊息傳給視窗函式，跟 WM_MEASUREITEM 訊息一樣，視窗函式僅需針對該選項處理即可。意思是說在處理 WM_DRAWITEM 時，所繪製的文字或圖案不應超過 DRAWITEMSTRUCT 中 rcItem 欄位的矩形範圍，但這沒有強制規定。另外，rcItem 矩形左上角座標的原點卻是位於整個子功能表第零個選項的左上角，參考下圖： 假如一個選項的高度是 20 個像素，亦即 cyFileMenu 等於 20，那麼將要繪製第零個選項時 rcItem 左上角座標是 ( 0,0 )，將要繪製第一個選項時 rcItem 左上角座標是 ( 0,20 )……依此類推。

基於上述原因，如果要把選項文字之前的位元圖鉛錘置中的話，必須把 cyFileMenu 減去 cyBmFile（此為位元圖高度），然後除以二，最後加上 rcItem 左上角的 Y 座標。程式碼如下：

      ;把記憶體裝置內容的位元圖複製到檔案子功能表的裝置內容中
        mov     edx,cxBmFile    ;位元圖顯示在子功能表的裝置內容，X座標由左緣開
        shr     edx,1           ;始半個位元圖寬的地方
        mov     r8d,cyFileMenu  ;Y座標在鉛錘置中處，但位置一、二、三……還要加上
        sub     r8d,cyBmFile    ;鉛錘高度距離子功能表多遠
        shr     r8d,1
        add     r8d,dis.rcItem.top
        invoke  BitBlt,dis.hDC,edx,r8d,cxBmFile,cyBmFile,hdcMem,0,0,SRCCOPY
⑵、繪製字形子功能表內的選項時的步驟是⒜繪製背景的美女圖、⒝建立邏輯字形、⒞以邏輯字形繪製選項文字、⒟繪製代表勾選的正方形。與⑴的道理相同，必須先繪製⒜的美女圖，若後繪製美女圖那麼先畫出來的東西都會被背景美女圖蓋過。

⒜、或許有些讀者會有疑問，上面的步驟怎麼沒有繪製紅色光棒的步驟呢？ONDMENU 是用巧妙的方法把紅色光棒繪製出來，簡單的說是利用 BitBlt 最後一個參數的特性，dwRop 有許多種，其中的 MERGECOPY 可以使裝置內容的畫刷與來源位元進行 AND 運算，這樣就能將紅色光棒表現出來了，程式碼如下：

        invoke  SelectObject,hdcMem,hBmp[32]    ;將BEAUTY.bmp選入記憶體裝置內容
        invoke  SelectObject,dis.hDC,hbrRed     ;將紅色畫刷選入功能表的裝置內容
        mov     r11,SRCCOPY                     ;如果選項是未被選擇的，用SRCCOPY
        test    dis.itemState,ODS_SELECTED      ;如果選項是被選擇的，用MERGECOPY
        jz      @f
        mov     r11,MERGECOPY
@@:     invoke  BitBlt,dis.hDC,dis.rcItem.left,dis.rcItem.top,cxFontMenu,\
                cyFontMenu,hdcMem,dis.rcItem.left,dis.rcItem.top,r11d

⒝、呼叫 CreateFont 建立邏輯字形時，最重要的三個參數是 nHeight、fdwCharSet、lpszFace，在 ONDMENU 中 nHeight 是選項高度減四，這樣可以讓選項文字在選項內鉛錘置中。fdwCharSet 使用系統內定的字元集，DEFAULT_CHARSET，即可。最麻煩的是 lpszFace，字形名稱，在 .CONST 區段內有以下的定義：

szStdKai        DB      "標楷體",0
szNewMing       DB      "新細明體",0
szCourierNew    DB      "Courier New",0
szTimesNewRoman DB      "Times New Roman",0
szMSSansSerif   DB      "Microsoft Sans Serif",0
ALIGN           8
paryFont        LPSTR   OFFSET szStdKai,OFFSET szNewMing,OFFSET szCourierNew
                LPSTR   OFFSET szTimesNewRoman,OFFSET szMSSansSerif

paryFont 的名稱有 p 代表指標也就是位址，ary 表示陣列，換句話說 paryFont 是由位址組成的陣列，這些位址其實就是五種字形名稱的位址。下圖是某次以 x64dbg 對 ONDMENU.EXE 除錯時，記憶體中的內容。在位址 564060H 處的數值是 0C0H，在位址 564061H 處的數值是 0C9H，而一個中文字用兩個位元組表示，0C0C9H 就代表「檔」字。下圖的解讀方式就跟 x64dbg 的資料顯示區一樣。

對照上面程式，paryFont 的位址本應該在 szMSSansSerif 之後的 5640ABH 處，但因為「ALIGN」假指令（參考註二），組譯器插入五個位元組的零（以黃色框圍住）並使其移至位址 5640B0H 處（橙色箭頭所指處），該位址也是第零個元素的位址，第零個元素內容是 56406AH（以藍色框線圍住，這是小序端，參考這裏），此為「標楷體」字串的位址；第一個元素位於位址 5640B8H 處，其值為 564071H，是「新細明體」字串的位址……依此類推。 在 Win64 系統中，位址都以 64 位元表示，64 位元就是八個位元組，因此只要能知道第幾個元素，輕易就能算出字形的所在位址。程式如下：

      ;建立邏輯字形
        movzx   rax,WORD PTR dis.itemID
        sub     rax,IDM_STDKAI          ;RAX＝paryFont內的第幾個元素
        lea     r10,paryFont[rax*8]     ;R10＝該元素的位址
        mov     r11,[r10]               ;R11＝該元素的內容＝字形名稱的位址
        mov     rsi,r11                 ;RSI＝字形名稱的位址，呼叫DrawText時才用
        mov     ecx,cyFontMenu
        sub     ecx,4
        mov     rdi,rcx                 ;RCX＝字形高度
        invoke  CreateFont,ecx,0,0,0,FW_THIN,0,0,0,DEFAULT_CHARSET,OUT_DEFAULT_PRECIS,\
                CLIP_DEFAULT_PRECIS,DEFAULT_QUALITY,DEFAULT_PITCH or FF_DONTCARE,r11

例如使用者點選字形子功能表中，位置第二的選項，也就是點選「Courier New」字形，Windows 會將 WM_DRAWITEM 訊息傳給視窗函式，而其 DRAWITEMSTRUCT 的 itemID 欄位為 2102。這些選項的識別碼是多少，必須去查閱 ONDMENU.ASM 第 154∼165 行。ONDMENU 要做的就是計算出「Courier New」字串位址，將其減掉 IDM_STDKAI（IDM_STDKAI 等於 2100），得到在 paryFont 裏的第幾個元素，此時 RAX 為 2。

接下來要執行的是「LEA R10,paryFont[RAX×8]」指令，LEA 會取得來源運算元的位址，將其存於 R10 內。RAX 乘以八，就得到此位址距離 paryFont 陣列開始位址有多少個位元組，前面的 paryFont 位址是 5640B0H，所以 paryFont[RAX×8] 的位址是 5640C0H，執行完 LEA 後，R10 等於 5640C0H。

接下來的指令是「MOV R11,[R10]」，意思是讀取 R10 所指位址的記憶體內容，將其存入 R11。也就是把位址 5640C0H 的內容，56407AH，存入 R11。最後 R11 等於 56407AH，到此 R11 之值就是「Courier New」字串位址。

然後是「MOV RSI,R11」，這個指令把 ONDMENU 辛辛苦苦計算得到的字形名稱位址存在 RSI 中，等到在功能表選項中印出選項文字時用得著，因為選項文字就是字形名稱。接下來的三行計算 CreateFont 的 nHeight 參數，前面已敘述過了，不多講了。

可能有人會問，「不變的暫存器」不是說不可隨意改變其值嗎？這兒怎能使用 RSI 暫時保存自行名稱位址呢？事實上，在宣告視窗函式時，加上了「USES」，如下： 

WndProc PROC    USES rsi rdi hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM

就能把 USES 之後的暫存器列表存入堆疊中，等視窗函式返回時，再恢復原值。

⒞、繪製選項文字，必須依據不同字形繪製的文字字形也不同看起來似乎很難，但前面已建立好邏輯字形，也已將字形名稱位址存在 RSI 中，因此不像想像中的難。程式碼如下，呼叫 SelectObject 時第二個參數，RAX，其實就是 CreateFont 的回傳值，意思就是把建立的邏輯字形選入裝置內容內。

      ;將此邏輯字形選入功能表的裝置內容中然後繪製選項文字
        invoke  SelectObject,dis.hDC,rax
        invoke  DeleteObject,rax        ;原來的字形已不用，銷毀它
        add     dis.rcItem.left,edi     ;選項文字在選項開始之處一個字形寬度開始
        invoke  DrawText,dis.hDC,rsi,-1,ADDR dis.rcItem,DT_SINGLELINE or DT_VCENTER

⒟、最後一件事是在勾選的選項前，繪製一正方形代表此選項為勾選的。不過這件事是只有選項為勾選狀態時，才需要進行。檢查這狀態也很容易，檢查 DRAWITEMSTRUCT 的 itemState 欄位是否含 ODS_CHECKED 即可。程式碼如下：

      ;繪製勾選狀態
        test    dis.itemState,ODS_CHECKED
        jz      @f
        invoke  SelectObject,hdcMem,hBmp[40]
        mov     r8d,cyFontMenu
        sub     r8d,14
        shr     r8d,1
        add     r8d,dis.rcItem.top
        invoke  BitBlt,dis.hDC,2,r8d,14,14,hdcMem,0,0,SRCINVERT

此正方形的寬與度皆為 14 個像素，位元圖代碼是 hBmp 陣列的第五個元素，在「TEST dis.itemState,ODS_CHECKED」之後，便將 hBmp[40] 選入記憶體裝置內之中，再呼叫 BitBlt 將其傳輸給功能表裝置內容，就能畫出正方形了；但又不是真正的傳輸過去，而是把正方形與其後面的美女圖進行互斥或運算，這樣才不會就是一個勾選的方塊而顯得太呆版。

處理 WM_DRAWITEM 訊息的最後面，就是將呼叫 DeleteDC，把記憶體裝置內容銷毀。這一步，不論是⑴繪製檔案子功能表，還是⑵繪製字形子功能表都必須做，因為在分開處理之前，都曾建立記憶體裝置內容。

ONDMENU 其他部分，在前面都已介紹過了，就不多說了，而且這一章內容也夠多了。

註解

註一：MENUITEMINFO 結構體

在 MASM64 SDK 與 WinInc 中，MENUITEMINFO 結構體分別定義在 win64.inc 與 winuser.inc 包含檔內，其內容如下：

MASM64 win64.incWinInc winuser.inc正確
MENUITEMINFO    STRUCT
  cbSize        UINT      ?
  fMask         UINT      ?
  fType         UINT      ?
  fState        UINT      ?
  wID           UINT      ?
                DWORD     ?
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPTSTR    ?
  cch           UINT      ?
                DWORD     ?
  hbmpItem      HBITMAP   ?
MENUITEMINFO    ENDS
MENUITEMINFOA   STRUCT
  cbSize        DWORD     ?
  fMask         DWORD     ?
  fType         DWORD     ?
  fState        DWORD     ?
  wID           DWORD     ?
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPSTR     ?
  cch           DWORD     ?
  if (WINVER ge 0500h)
    hbmpItem    HBITMAP   ?
  endif
MENUITEMINFOA   ENDS
MENUITEMINFO    STRUCT 
  cbSize        DWORD     ?
  fMask         DWORD     ?
  fType         DWORD     ?
  fState        DWORD     ?
  wID           DWORD     2 DUP(?)
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPSTR     ?
  cch           DWORD     2 DUP (?)
  hbmpItem      HBITMAP	  ?
MENUITEMINFO    ENDS

這兩個定義都是錯的。不論是 32 位元還是 64 位元的 Windows 中，UINT 代表無號整數（unsigned integer），長度均為 DWORD，但在 win64.inc 中誤植為 QWORD。WinInc 中的 MENUITEMINFO 在 winuser.inc 中宣告，其中的 wID 與 cch 兩欄位長度為 DWORD 是沒錯，但是比它們高四個位元組的位址是一個空下來沒使用的雙字組，所以它們的下一個欄位的位址必須再比它們的位址增加八個位元組才對。小木偶曾撰寫程式，呼叫 GetMenuItemInfo 反向推論而驗證此一想法，並將正確的 MENUITEMINFO 結構體寫在上表最右欄。

另外，WinInc 中的 MENUITEMINFO 有兩個版本，分別對應 ANSI 編碼的字串與寬字元編碼的字串。它們之間的差別只有 dwTypeData 欄位的資料類型不同，前者是 LPSTR，後者如下：

dwTypeData  LPWSTR  ?

不過，不論是 LPSTR 或 LPWSTR，實際上都是 QWORD，它們都代表字串位址，對組合語言而言其實是沒有差別。

為何要將在 wID、cch 之後，多出兩個沒有名稱的欄位呢？主要是為了加速記憶體的存取。在 64 位元的電腦中，如果所存取的資料位址是存取資料長度的整數倍，那麼存取速率較快，反之 CPU 需要額外的時脈週期來存取資料，會降低效率。例如要存取雙字組的資料，如果此資料在位址 495000H，會比在位址 495002H 存取得快；這是因為雙字組長 4 個位元組，495000H 能被 4 整除，而 495002H 不能被 4 整除。像這種所存取的資料位址是存取資料長度的整數倍，稱為「對齊」，能增加存取效率，理由與晶片內電路設計有關。

在 MENUITEMINFO 結構體中，wID 之後多了一個無名的欄位，就是要使 hSubMenu 對齊在八位元組的位址上，當然這個前提是 MENUITEMINFO 結構體定義在節的位址上。（節，英文稱為 paragraph，16 個位元稱為一個節。在 64 位元的 Windows 系統中，凡是什麼什麼代碼，像功能表代碼、位元圖代碼……，其長度均為四字組，即 QWORD）

註二：ALIGN 假指令

ALIGN 是用來指示組譯器把程式碼或資料對齊某個位址，以提高存取效率，其用法是：

ALIGN   boundary

boundary 是二的冪次方數，例如 2、4、8、16，表示在使用了 ALIGN 之後，下一個指令或資料的存放位址必須是能被 2、4、8、16 整除。雖然 boundary 可以是超過 16，但是會浪費很多記憶體所以很少用。

如果在程式中的資料區段中定義下面資料：

.CONST
n1      DB      1
ALIGN   2
n2      DB      2
ALIGN   4
n3      DW      8086h
ALIGN   8
str1    DB      "TEST ALIGN",0
ALIGN   16
str2    DB      "少年願，眾生念，滅魍魎妖邪！"
szAppName       DB      "第一個Win64程式",0

那麼載入記憶體之後，結果如下圖： n2 之前有「ALIGN 2」，所以 n2 的位址必須是能被 2 整除。如上圖，n1 只佔一個位元組，位於位址 7F164000H，本來 n2 應放在位址 7F164001H，但因為有「ALIGN 2」，組譯器安插一個位元組的 0（以粉紅色表示），使 2 放在 7F164002H 處。n3 之前有「ALIGN 4」，所以 n3 的位址必須是能被 4 整除，因此組譯器安插一個位元組的 0 （以橙色表示）就可以讓 n3 放在 7F164004H 處。同理，紅色的兩個位元組的零與綠色的 13 個位元組的零，分別是 AILGN 8、ALIGN 16 所添加的，以便使 str1、str2 字串能在四字組、節的邊界上開始。

這裏整理一下。

  1. ALIGN 2：下個指令或資料，存放於的位址必須能被 2 整除，可視為字組邊界。
  2. ALIGN 4：下個指令或資料，存放於的位址必須能被 4 整除，可視為雙字組邊界。
  3. ALIGN 8：下個指令或資料，存放於的位址必須能被 8 整除，可視為四字組邊界。
  4. ALIGN 16：下個指令或資料，存放於的位址必須能被 16 整除，可視為節邊界。