第十七章　功能表（三）

這一章還是談功能表，但是改用以呼叫 CreateMenu、InsertMenuItem、SetMenu 等 Win64 API 來建立主功能表，而不再使用資源描述檔中的 MENU 區塊。以前者方式建立的功能表，較為靈活，可以打造具有客製化特色的功能表，缺點也是顯而易見的，那就是複雜。在進入主題之前，先介紹這一章會用得到的 Win64 API。

與功能表相關的 Win64 API

CreateMenu API

CreateMenu 會建立一個功能表，此功能表最初是空的，一無所有，應用程式可以呼叫 InsertMenuItem、AppendMenu、InsertMenu 在這新建的功能表添加分隔線、選項、彈出選項。CreateMenu 沒有參數，其原型是：

call    CreateMenu

invoke 假指令（對 UASM 而言）或巨集（對 MASM64 SDK 而言）是用來將參數存入暫存器或堆疊中，最後一定會執行 CALL 指令。呼叫 CreateMenu 時，因為沒有參數，所以可以直接使用 CALL，當然也可以使用 invoke。如果 CreateMenu 成功建立功能表，回傳值是其代碼；如果失敗，回傳值是零。

InsertMenuItem API

在功能表中加入新的分隔線、選項、彈出選項。

invoke  InsertMenuItem,\
        hMenu,\         ; handle to menu to be changed
        uItem,\         ; identifier or position
        fByPosition,\   ; value specifying the meaning of uItem
        lpmii           ; pointer to a MENUITEMINFO structure

如果 InsertMenuItem 執行成功，回傳值為非零；反之回傳值為零。底下說明各項參數的意義：

hMenu：要加入新分隔線、選項、彈出選項的功能表代碼。
uItem：新選項位於 uItem 指定的單項識別碼或位置之後。至於是識別碼還是位置，取決於 fByPosition 的值。
fByPosition：fByPosition 為零，表示 uItem 為識別碼；fByPosition 為一，表示 uItem 為位置。
lpmii：MENUITEMINFO 結構體的位址。加入新分隔線、選項、彈出選項由 MENUITEMINFO 中的欄位決定其性質，故必須在 MENUITEMINFO 中填入必要的欄位。

除了 InsertMenuItem 使用 MENUITEMINFO 結構體之外，還有 GetMenuItemInfo 與 SetMenuItemInfo 也使用。底下是 MENUITEMINFO 內的各欄位（註一）：

MENUITEMINFO    STRUCT 
  cbSize        DWORD     ?         ;MENUITEMINFO 的長度，以位元組單位
  fMask         DWORD     ?         ;旗標，指定要存取 MENUITEMINFO 中的哪一欄
  fType         DWORD     ?         ;選項類型
  fState        DWORD     ?         ;選項狀態
  wID           DWORD     2 DUP(?)  ;選項識別碼
  hSubMenu      HMENU     ?         ;子功能表代碼
  hbmpChecked   HBITMAP   ?         ;勾選之選項前的位元圖
  hbmpUnchecked HBITMAP   ?         ;未勾選之選項前的位元圖
  dwItemData    ULONG_PTR ?         ;
  dwTypeData    LPSTR     ?         ;選項文字或圖片
  cch           DWORD     2 DUP (?) ;選項字串長度
  hbmpItem      HBITMAP	  ?         ;以位元圖代替選項字串
MENUITEMINFO    ENDS

MENUITEMINFO 結構體很複雜，底下說明各欄位的意義。最簡單的是第一個欄位，cbSize，是指 MENUITEMINFO 結構體大小，單位是位元組，在呼叫 InsertMenuItem 前必須設定 cbSize 欄位，Windows 靠此數值判斷使用哪個版本的 API。若沒設好 cbSize，就會發生錯誤。

第二個欄位，fMask，決定了 InsertMenuItem、GetMenuItemInfo 與 SetMenuItemInfo 會使用 MENUITEMINFO 中的哪些欄位，而其他欄位無用。例如呼叫 InsertMenuItem 之前，把 fMask 為 MIIM_ID，那就必須同時把 wID 欄位設為選項識別碼，這樣呼叫完之後就能把新加入的選項設好選項識別碼；如果呼叫 GetMenuItemInfo 之前，fMask 為 MIIM_ID，呼叫完後系統會把選項識別碼存入到 wID 欄位中。

底下是 fMask 欄位可以設定的數值，如果要一次設定或是得到某選項的數種資料，可以用「OR」運算子連接，但此 OR 並非 x64 CPU 指令，而是組譯器執行的假指令。

fMask	應設定或獲取的欄位	說　明
MIIM_BITMAP 80H	hbmpItem	選項以位元圖顯示，要顯示的位元圖代碼存於 hbmpItem 欄位中，位元圖代碼可以由資源中載入，也可以是內建的位元圖，例如 HBMMENU_MBAR_CLOSE、HBMMENU_MBAR_MINIMIZE，分別是關閉、最小化的位元圖，更多的內建位元圖請查閱 MSDN。hbmpItem 也可以是 HBMMENU_CALLBACK，代表自行繪製選項，應用程式必須處理 WM_MEASUREITEM 或 WM_DRAWITEM 訊息。
MIIM_CHECKMARKS 8H	hbmpChecked hbmpUnchecked	MIIM_CHECKMARKS 是設定勾選的或未勾選的位元圖，此位元圖會顯示在選項文字之前。hbmpChecked 指定勾選時所顯示的位元圖；hbmpUnchecked 指定未勾選時所顯示的位元圖。hbmpChecked、hbmpUnchecked 都應該是位元圖代碼，但是如果 hbmpChecked 是 NULL，而且 fType、fState 分別設為 MFT_RADIOCHEC、fState 時，則以●表示勾選的選項；如果 hbmpChecked 是 NULL，且 fType、fState 均為零，則以✔表示勾選的選項。
MIIM_DATA 20H	dwItemData	與功能表項相關聯的應用程式定義值。
MIIM_FTYPE 100H	fType	當 fMask 設為 MIIM_FTYPE 時，須於 fType 欄位指定或者獲取選項類型，選項類型可以是下面數值，或是相互間以 OR 運算子運算的結果，但是不能同時指定 MFT_BITMAP、MFT_SEPARATOR、MFT_STRING。 MFT_BITMAP：用位元圖顯示選項而不用文字，該位元圖代碼存於 dwTypeData 欄位且忽略 cch 欄位。MFT_BITMAP 之值為 4。 MFT_MENUBARBREAK：對主選單而言，自此選項開始顯示於下一列；對子功能表、快捷功能表而言，顯示於下一行且兩行間有鉛錘線分隔。MFT_MENUBARBREAK 之值為 20H。 MFT_MENUBREAK：同上，但沒有鉛錘線分隔。MFT_MENUBREAK 之值為 40H。 MFT_OWNERDRAW：具有 MFT_OWNERDRAW 的選項，必須由應用程式擔負起繪製此選項的責任。第一次顯示選項之前，應用程式會收到 WM_MEASUREITEM 訊息，每當更新選項外觀時會收到 WM_DRAWITEM 訊息，應用程式藉著這兩則訊息繪製選項。指定 MFT_OWNERDRAW 時，dwTypeData 可以指定應用程式自行定義的數值。應用程式會收到的 WM_MEASUREITEM、WM_DRAWITEM 訊息中，lParam 分別是 MEASUREITEMSTRUCT、DRAWITEMSTRUCT 結構體位址，其中的同名欄位 itemData 內存著 dwTypeData 自行定義的數值。MFT_OWNERDRAW 之值為 100H。 MFT_RADIOCHECK：當 hbmpChecked 為零且 fState 為 MFS_CHECKED，那麼具有 MFT_RADIOCHECK 類型的選項前以●表示勾選狀態。MFT_RADIOCHECK 之值為 200H。 MFT_RIGHTJUSTIFY：從具有 MFT_RIGHTJUSTIFY 的選項開始，排列在主功能表的右邊。MFT_RIGHTJUSTIFY 只能用於主功能表中的選項，其值為 4000H。 MFT_RIGHTORDER：阿拉伯語、希伯來語版本的 Windows 才能使用，使選項字串由右至左閱讀。 MFT_SEPARATOR：在子功能表、快捷功能表中，具有 MFT_SEPARATOR 時，顯示水平分隔線。dwTypeData、cch 會被忽略。MFT_SEPARATOR 之值為 800H。 MFT_STRING：用字串表示選項，dwTypeData 為字串位址，此字串須以零結尾。cch 為字串長度。MFT_STRING 之值為零。
MIIM_ID 2	wID	存取 wID 欄位。當呼叫 InsertMenuItem、SetMenuItemInfo 前，須把 wID 設定為選項識別碼；呼叫 GetMenuItemInfo 後，wID 會存有選項識別碼。
MIIM_STATE 1	fState	只有當 fMask 設為 MIIM_STATE 時，指定選項狀態，由 fState 欄位表示狀態，可以是下面數值： MFS_CHECKED：此選項為勾選的，其值為 8。若具有勾選狀態，必須進一步設定 hbmpChecked 為某圖片的位元圖代碼，此圖片會顯示在勾選的選項前面；如果 hbmpChecked 設為零，則使用預設圖片。如果 fType 設定 MFT_RADIOCHECK，那麼預設圖片是●。若要設定 hbmpUnchecked，必須把 fMask 欄位設為 MIIM_CHECKMARKS。 MFS_DEFAULT：此選項為內定的選項，一功能表中只有一個選項是內定的，且以粗體字表示。MFS_DEFAULT 之值為 1000H。 MFS_DISABLED：此狀態的選項是禁用的且以灰色字表示，無法被使用者點選，與 MFS_GRAYED 同義。MFS_DISABLED 之值為 3。 MFS_ENABLED：此狀態的選項是啟用的，可以被使用者點選，其值為 0。 MFS_GRAYED：與 MFS_DISABLED 同義，MFS_GRAYED 為 3。 MFS_HILITE：以高亮度顯示選項，其值為 80H。 MFS_UNCHECKED：未勾選的選項，其值為 0。若具有未勾選狀態，必須進一步設定 hbmpUnchecked 為某圖片的位元圖代碼，此圖片會顯示在未勾選的選項前面；如果 hbmpUnchecked 設為零，則不使用任何圖片。若要設定 hbmpUnchecked，必須把 fMask 欄位設為 MIIM_CHECKMARKS。
MIIM_STRING 40H	dwTypeData	以字串表示選項。字串須以零結尾，其位址存於 dwTypeData。cch 為字串長度。MIIM_STRING 可以取代 MFT_STRING。
MIIM_SUBMENU 4	hSubMenu	將某一選項設為彈出選項，能顯示子功能表。當 fMask 指定了 MIIM_SUBMENU 時，須同時於 hSubMenu 指定子功能表之代碼，將該子功能表附在 InsertMenuItem、SetMenuItemInfo 的第一個參數，hMenu，之下。
MIIM_TYPE 10H	fType dwTypeData	必須設定 fType 與 dwTypeData，參考 MIIM_BITMAP、MIIM_FTYPE 與 MIIM_STRING，因為 MIIM_TYPE 將逐步被前三者取代。

假設要在某個功能表內新添一選項，通常會同時設定選項文字與選項識別碼，那麼就會使用下面程式碼：

        mov     mii.fMask,MIIM_STRING or MIIM_ID
        mov     mii.wID,選項識別碼
        lea     r10,字串變數
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii

上面第一行程式碼中的 MIIM_STRING 常數為 40H，換算為二進位是 0100 0000；MIIM_ID 為 2，二進位是 0010，經過「OR」運算之後為 0100 0010，經由 MENUITEMINFO 將此資料傳給 InsertMenuItem，InsertMenuItem 就能知道使用者要新添的選項具有哪些性質。在 Windows 程式設計中，有許多類似這樣的常數，都稱之為旗標，它們代表了某個位元，若為一表示要決定了某個物件的性質，若為零表示沒有此性質。

DrawMenuBar API

DrawMenuBar 用來重新繪製功能表，通常是在呼叫 InsertMenuItem、RemoveMenu、SetMenuItemInfo 之後使得功能表發生變化，呼叫 DrawMenuBar 更新功能表外觀。DrawMenuBar 的原型是：

invoke  DrawMenuBar,\
        hWnd            ; handle to window with menu bar to redraw

hWnd 是需要更新功能表外觀的視窗之視窗代碼。如果 DrawMenuBar 成功執行，回傳值為非零；若失敗，回傳值為零。

不使用資源描述檔中的 MENU 區塊建立功能表

例子：DRAW5.ASM

這一章的例子是 DRAW5，它的主功能表不使用載入資源中的 MENU 資源，而改用呼叫 CreateMenu、SetMenu、InsertMenuItem 建立，它也是以第十五章的 DRAW2 進行修改而成。由於只修改部分內容，所以 DRAW5 與 DRAW2 大同小異，底下只列出重要且不同的部分，完整的原始檔案請到這裏下載。將其中的 DRAW5.ASM 與 DRAW5.RC 放在同一子目錄，組譯方法與第十五章的 DRAW2 相同，不重複敘述。

;呼叫 CreateMenu、InsertMenuItem、SetMenu建立主功能表，不用MENU區塊

⁝

;底下是WinInc沒有宣告的常數以及更正後MENUITEMINFO結構體

MIIM_STRING EQU 40H

MIIM_BITMAP EQU 80H

MIIM_FTYPE EQU 100H

MY_MENUITEMINFO STRUCT

cbSize DWORD ?

fMask DWORD ?

fType DWORD ?

fState DWORD ?

wID DWORD 2 DUP(?)

hSubMenu HMENU ?

hbmpChecked HBITMAP ?

hbmpUnchecked HBITMAP ?

dwItemData ULONG_PTR ?

dwTypeData LPSTR ?

cch DWORD 2 DUP (?)

hbmpItem HBITMAP ?

MY_MENUITEMINFO ENDS

;*****************************************************************************************

.CONST

szIconName LABEL BYTE

szClassName DB "DRAW5",0

szAppName DB "超簡單繪圖",0

szText DB "DRAW5僅能繪製橢圓與手繪圖",0dh,0ah,"，且不能存檔也不能編輯。",0

szMouseFmt DB "(%03d,%03d)",0

szColor DB "黑色紅色綠色藍色"

szClear DB 5 DUP ("　")

szQuit DB "離開",0

szView DB "檢視",0

szXy DB "座標",0

szPenColor DB "畫筆顏色",0

szDraw DB "繪圖",0

szEllipse DB "橢圓",0

szTrace DB "手繪圖",0

szBlack DB "黑",0

szRed DB "紅",0

szGreen DB "綠",0

szBlue DB "藍",0

szHelp DB "幫助",0

;*****************************************************************************************

⁝

.case WM_CREATE

;建立功能表，並將其設為主選單

call CreateMenu

mov hMenu,rax

invoke SetMenu,hWnd,hMenu

;在主功能表中插入「離開」選項

mov mii.cbSize,SIZEOF mii

mov mii.fMask,MIIM_STRING or MIIM_ID

lea r10,szQuit

mov mii.wID,IDM_QUIT

mov mii.dwTypeData,r10

invoke InsertMenuItem,hMenu,0,TRUE,ADDR mii

;在主功能表中插入「檢視」子功能表

call CreateMenu

mov hViewSubMenu,rax

mov mii.fMask,MIIM_SUBMENU or MIIM_STRING

lea r11,szView

mov mii.hSubMenu,rax

mov mii.dwTypeData,r11

invoke InsertMenuItem,hMenu,1,TRUE,ADDR mii

;在主功能表中插入「繪圖」子功能表

call CreateMenu

mov hDrawSubMenu,rax

lea r10,szDraw

mov mii.hSubMenu,rax

mov mii.dwTypeData,r10

invoke InsertMenuItem,hMenu,2,TRUE,ADDR mii

;在主功能表中插入「幫助」選項

mov mii.fMask,MIIM_TYPE or MIIM_ID

mov mii.fType,MFT_STRING or MFT_RIGHTJUSTIFY

lea r11,szHelp

mov mii.wID,IDM_HELP

mov mii.dwTypeData,r11

invoke InsertMenuItem,hMenu,3,TRUE,ADDR mii

;在「檢視」子功能表中插入「座標」選項

mov mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE

mov mii.fState,MFS_CHECKED

lea r10,szXy

mov mii.wID,IDM_XY

mov mii.dwTypeData,r10

invoke InsertMenuItem,hViewSubMenu,0,TRUE,ADDR mii

;在「檢視」子功能表中插入「畫筆顏色」選項

lea r11,szPenColor

mov mii.wID,IDM_COLOR

mov mii.dwTypeData,r11

invoke InsertMenuItem,hViewSubMenu,1,TRUE,ADDR mii

;在「繪圖」子功能表中插入「橢圓」選項

mov mii.fMask,MIIM_STRING or MIIM_ID

lea r10,szEllipse

mov mii.wID,IDM_ELLIPSE

mov mii.dwTypeData,r10

invoke InsertMenuItem,hDrawSubMenu,0,TRUE,ADDR mii

;在「繪圖」子功能表中插入「手繪圖」選項

mov mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE or MIIM_FTYPE

lea r11,szTrace

mov mii.wID,IDM_TRACE

mov mii.dwTypeData,r11

mov mii.fState,MFS_CHECKED

mov mii.fType,MFT_RADIOCHECK

mov mii.hbmpChecked,0

invoke InsertMenuItem,hDrawSubMenu,1,TRUE,ADDR mii

;在「繪圖」子功能表中插入分隔線

mov mii.fMask,MIIM_FTYPE

mov mii.fType,MFT_SEPARATOR

invoke InsertMenuItem,hDrawSubMenu,2,TRUE,ADDR mii

;在「繪圖」子功能表中插入「黑」選項

mov mii.fMask,MIIM_STRING or MIIM_ID or MIIM_STATE or MIIM_FTYPE

lea r10,szBlack

mov mii.wID,IDM_BLACK

mov mii.dwTypeData,r10

mov mii.fState,MFS_CHECKED

mov mii.fType,MFT_RADIOCHECK

invoke InsertMenuItem,hDrawSubMenu,3,TRUE,ADDR mii

;在「繪圖」子功能表中插入「紅」選項

mov mii.fMask,MIIM_STRING or MIIM_ID

lea r11,szRed

mov mii.wID,IDM_RED

mov mii.dwTypeData,r11

invoke InsertMenuItem,hDrawSubMenu,4,TRUE,ADDR mii

;在「繪圖」子功能表中插入「綠」選項

lea r10,szGreen

mov mii.wID,IDM_GREEN

mov mii.dwTypeData,r10

invoke InsertMenuItem,hDrawSubMenu,5,TRUE,ADDR mii

;在「繪圖」子功能表中插入「藍」選項

lea r11,szBlue

mov mii.wID,IDM_BLUE

mov mii.dwTypeData,r11

invoke InsertMenuItem,hDrawSubMenu,6,TRUE,ADDR mii

;更新主選單外觀

invoke DrawMenuBar,hWnd

⁝

;*****************************************************************************************

END main

解說

DRAW5.ASM 第 27～29 行，宣告了三個常數 MIIM_STRING、MIIM_BITMAP、MIIM_FTYPE，其實在 winuser.inc 中有宣告這三個常數，但是有條件，必須宣告 WINVER 常數且其值為 500H 或更大才行。在 winuser.inc 原來的的程式是：

if (WINVER ge 0500h)
MIIM_STRING	EQU	00000040h
MIIM_BITMAP	EQU	00000080h
MIIM_FTYPE	EQU	00000100h
  ⁝
endif

因此，如果 DRAW5.ASM 中，在「INCLUDE WINDOWS.INC」之前，有宣告 WINVER 常數至少為 500H，那麼就可以省略第 27～29 行，至於 MENUITEMINFO 結構體的錯誤請參考註一。

接下來看第 202～205 行，這四行指令是呼叫 CreateMenu 建立空的功能表，再呼叫 SetMenu 設定 DRAW5 視窗的功能表為剛剛建立的功能表。接下來是在這新建的功能表中，添加選項、彈出選項。這裏值得一提的是，如果建立功能表之後，先在空的功能表添加選項、彈出選項，再呼叫 SetMenu 設定功能表也可以。

DRAW5 的主功能表有兩個選項、兩個彈出選項，使用者點選彈出選項會出現子功能表，而這些子功能表有些具✔的勾選狀態，有些具有●的勾選狀態。底下將針對這些不同的狀況說明，先說明最簡單的情況，沒有勾選狀態的選項。

沒有勾選狀態的選項最單純，它最重要的屬性是名稱與識別碼，名稱是以零結尾的字串，識別碼則是十六位元的無號數，要設定這兩種屬性，將 MENUITEMINFO 的 fMask 設為 MIIM_STRING or MIIM_ID。因為有 MIIM_STRING 所以還要繼續設定 dwTypeData 為表示名稱字串的位址，因為有 MIIM_ID 所以要設定 wID。見第 207～212 行。此外，如果先不設定選項識別碼，等插入選項之後再設也是可以的，例如下面的程式碼：

        mov     mii.cbSize,SIZEOF mii
        mov     mii.fMask,MIIM_STRING
        lea     r10,szQuit
        mov     mii.dwTypeData,r10
        invoke  InsertMenuItem,hMenu,0,TRUE,ADDR mii
        mov     mii.fMask,MIIM_ID
        mov     mii.wID,IDM_QUIT
        invoke  SetMenuItemInfo,hMenu,0,TRUE,ADDR mii

如果反過來，先呼叫 InsertMenuItem 時已設好識別碼，再呼叫 SetMenuItemInfo 設定選項名稱，該選項不能正常運作。小木偶不知道確切的原因，推測是選項名稱是選項中最重要的部分，必須先確立名稱之後，再對選項修飾。

新添上述的選項還有另一種方式，雖然這是舊用法，但還是說一說。把 fMask 設為 MIIM_TYPE or MIIM_ID，再進一步把 fType 設為 MFT_STRING，最後於 dwTypeData 設定字串的位址，見第 228～234 行。你會發現使用舊方法要三步驟；而上一種方法僅兩步驟。

如何以 InsertMenuItem 添加彈出選項呢？彈出選項沒有選項識別碼，但必須有名稱與子功能表代碼，這裏的子功能表是使用者點選此彈出選項後出現的。因為彈出選項有子功能表，所以必須先呼叫 CreateMenu 建立一功能表，再把 fMask 設為 MIIM_SUBMENU or MIIM_STRING，接著將 MENUITEMINFO 中的 hSubMenu 欄位設為 CreateMenu 建立的功能表代碼。最後將 dwTypeData 設為一個以零結尾的字串之位址，此字串就是彈出選項的名稱。見 DRAW5.ASM 第 213～220 行。

如何添加具有✔勾選狀態的選項呢？其實不難，跟前面設定不具勾選選項類似，只是多了要將其設為勾選狀態。詳細的說就是先把 MENUITEMINFO 的 fMask 設為 MIIM_STRING or MIIM_ID or MIIM_STATE，接下來選項名稱與識別碼跟前面相同，但多了一步把 MENUITEMINFO 的 fState 欄位設為 MFS_CHECKED。見第 235～241 行。

如何添加具有●勾選狀態的選項呢？具有●勾選狀態，必須先設其為勾選狀態，然後才能將其進一步設為●的狀態。所以先把 MENUITEMINFO 的 fMask 設為 MIIM_STRING or MIIM_ID or MIIM_STATE or MIIM_FTYPE，前面已經解釋過前三種，最後一個 MIIM_FTYPE，必須把 fType 設為 MFT_RADIOCHECK。見第 253～261 行。

最後一種，如何設定分隔線呢？首先將 fMask 欄位設為 MIIM_FTYPE，然後再把 fType 設為 MFT_SEPARATOR。見第 262～265 行。

註解

註一：MENUITEMINFO 結構體

在 MASM64 SDK 與 WinInc 中，MENUITEMINFO 結構體的定義分別 win64.inc 與 winuser.inc 包含檔內，其內容如下：

MASM64 win64.inc

WinInc winuser.inc

小木偶

MENUITEMINFO    STRUCT
  cbSize        UINT      ?
  fMask         UINT      ?
  fType         UINT      ?
  fState        UINT      ?
  wID           UINT      ?
                DWORD     ?
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPTSTR    ?
  cch           UINT      ?
                DWORD     ?
  hbmpItem      HBITMAP   ?
MENUITEMINFO    ENDSMENUITEMINFOA   STRUCT
  cbSize        DWORD     ?
  fMask         DWORD     ?
  fType         DWORD     ?
  fState        DWORD     ?
  wID           DWORD     ?
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPSTR     ?
  cch           DWORD     ?
  if (WINVER ge 0500h)
    hbmpItem    HBITMAP   ?
  endif
MENUITEMINFOA   ENDSMENUITEMINFO    STRUCT 
  cbSize        DWORD     ?
  fMask         DWORD     ?
  fType         DWORD     ?
  fState        DWORD     ?
  wID           DWORD     2 DUP(?)
  hSubMenu      HMENU     ?
  hbmpChecked   HBITMAP   ?
  hbmpUnchecked HBITMAP   ?
  dwItemData    ULONG_PTR ?
  dwTypeData    LPSTR     ?
  cch           DWORD     2 DUP (?)
  hbmpItem      HBITMAP	  ?
MENUITEMINFO    ENDS

但這兩個定義都是錯的。不論是 32 位元還是 64 位元的 Windows 中，UINT 代表無號整數（unsigned integer），長度應為 DWORD，但在 win64.inc 中誤植為 QWORD。WinInc 中的 MENUITEMINFO 在 winuser.inc 中宣告，其中的 wID 與 cch 兩欄位長度為 DWORD 是沒錯，但是比它們高四個位元組的位址是一個空下來沒使用的雙字組，所以它們的下一個欄位的位址必須再比它們的位址增加八個位元組才對。小木偶曾撰寫程式，呼叫 GetMenuItemInfo 反向推論而驗證此一想法，並將正確的 MENUITEMINFO 結構體寫在上表最右欄。

另外，WinInc 中的 MENUITEMINFO 有兩個版本，分別對應 ANSI 編碼的字串與寬字元編碼的字串。它們之間的差別只有 dwTypeData 欄位的資料類型不同，前者是 LPSTR，後者如下：

dwTypeData  LPWSTR  ?

不過，不論是 LPSTR 或 LPWSTR，實際上都是 QWORD，它們都代表字串位址，其實是沒有差別。

第十七章 功能表（三）

與功能表相關的 Win64 API

CreateMenu API

InsertMenuItem API

DrawMenuBar API

不使用資源描述檔中的 MENU 區塊建立功能表

例子：DRAW5.ASM

解說

註解

註一：MENUITEMINFO 結構體

第十七章　功能表（三）