第十二章　計時器

民國 70 年，國際商業機器公司（IBM）開始出產 IBM PC 個人電腦時，那時在 IBM PC 硬體內部就有一個編號是 8253 的晶片，專門負責計時。這個晶片以頻率 18.2Hz 的方式產生第 8 號中斷（18.2Hz 的意思就是說每秒觸發第 8 號中斷 18.2 次），換句話說每隔 55 毫秒（1÷18.2≑0.0549）就執行一次第 8 號中斷。IBM PC 共有 256 個中斷，編號由零開始到十六進位的 0FFH，我們可以把中斷想成是某種副程式。

到了現在，8253 晶片已經被高精度事件計時器（high precision event timer，縮寫 HPET）取代，並整合到了南橋晶片中，但南橋晶片也保留了 8253 的功能。因此現在的電腦，仍然能執行以前的作業系統，例如 MS－DOS，只要你能找到開機時啟動的方法。

在大部分的情形下，我們不需要精密度很高的計時器，每 55 毫秒觸發一次的精密度已經足夠了。這一章要介紹在 Windows 作業系統中的計時器，並說明如何應用。

計時器

在 Windows 作業系統中，計時器可以看做是一種輸入設備，我們可以指定它每隔一段固定的時間間隔，對應用程式發出 WM_TIMER 訊息。乍看之下，計時器似乎不像鍵盤、滑鼠那麼重要，但是它也有一些不可磨滅的貢獻，例如：

  1. 自動儲存：指定一段時間後，例如五分鐘，應用程式可以自動儲存資料到硬碟上。
  2. 多工：雖然自 Windows 95 之後的 Windwos 作業系統是優先權式的多工（註一），但是如果應用程式要處理大量資料時，可將這些工作切割成許多部份，利用定時器傳來訊息時處理一部份。
  3. 播放音樂：利用定時器在背景播放音樂。
  4. 自動結束的試用版軟體或試玩版電腦遊戲：設定只能讓使用者試用或試玩一段固定時間，就結束程式。
  5. 調整速度：可以利用定時器消除因為 CPU 快慢而造成的速度差異。

以上是計時器的應用，那麼要如何使用計時器呢？首先，我們必須先建立計時器。

SetTimer API

在 Windows 作業系統中，應用程式無法直接讀取第 8 號中斷，這些硬體資源都由 Windows 統籌運用。應用程式必須透過 Windows 來使用這些硬體資源，可以呼叫 SetTimer，建立計時器。Windows 會為此計時器建立一個計數器並初始它，然後每隔 55 毫秒計數器便減一，直到減至零，便對應用程式發出 WM_TIMER 訊息。應用程式收到 WM_TIMER 訊息後，便能在處理此訊息做一些工作。底下是 SetTimer 的用法：

invoke  SetTimer,\
        hWnd,\      ; handle of window for timer messages
        nIDEvent,\  ; timer identifier
        uElapse,\   ; time-out value
        lpTimerFunc ; address of timer procedure

大部分的情形下，lpTimerFunc 為零，那麼 Windows 每隔一段時間間隔（此時間間隔由第三個參數 uElapse 指定）就會把 WM_TIMER 發送給呼叫 SetTimer 時第一個參數所指定的視窗。發送的 WM_TIMER 訊息裏的 wParam 等於計時器識別碼，也就是呼叫 SetTimer 時的第二個參數；而lParam 等於零。因為可以在同個應用程式中用多個不同的 nIDEvent 來多次呼叫 SetTimer，如此就建立多個計時器，這樣就要用 wParam 分辨不同的計時器。其格式如下：

        invoke  SetTimer,hwnd,TIMER_SEC,1000,0  ;建立每秒送出 WM_TIMER 的計時器
        invoke  SetTimer,hwnd,TIMER_MIN,60000,0 ;建立每分送出 WM_TIMER 的計時器
        ⁝
case WM_TIMER:
    switch wParam
    case TIMER_SEC:
        ;每秒一次的處理

    case TIMER_MIN:
        ;每分鐘一次的處理
    endsw
        ⁝

假如第四個參數 lpTimerFunc 不是零，而是某個副程式位址的話，那麼 Windows 每隔一個時間間隔，不再是發送 WM_TIMER 訊息給呼叫 SetTimer 時第一個參數所指定的視窗，而是呼叫該副程式一次。由此看來，此副程式其實是一種回呼函式。假設此回呼函式名稱是 TimerProc，其原型為：

TimerProc   PROC    hwnd:HWND, message:UNIT, iTimerID:UNIT, dwTime:DWORD
            ; 這兒是每隔一個時間間隔要處理的工作
TimerProc   ENDP

Windows 傳給 TimerProc 的第一個參數 hwnd，其實就是呼叫 SetTimer 時的視窗代碼，message 始終是 WM_TIMER，iTimerID 是呼叫 SetTimer 時的回傳值，dwTimer 是啟動 Windows 時已經過多少毫秒。

如果計時器建立失敗，回傳值為零。如果成功建立計時器，其回傳值又分兩種情形：

  1. 如果第一個參數 hWnd 為視窗代碼，那麼回傳值為非零值。
  2. 如果第一個參數 hWnd 為零，那麼 SetTimer 會忽略 nIDEvent 參數，而回傳值為計時器識別碼。爾後要銷毀計時器時，呼叫 KillTimer 時，第一個參數 hWnd 設為零，第二個參數就是此回傳值。

第三個參數是時間間隔，雖然單位是毫秒，但是由於許多因素，無法精確到一毫秒，因此如果真要精確計時，最好不要使用 SetTimes 計時器。如果 uElapse 小於 USER_TIMER_MINIMUM（USER_TIMER_MINIMUM＝0AH），則 uElapse 會設為 USER_TIMER_MINIMUM；如果 uElapse 大於 USER_TIMER_MAXIMUM（USER_TIMER_MINIMUM＝07FFFFFFFH），則 uElapse 會設為 USER_TIMER_MAXIMUM。

KillTimer API

當用不著計時器時，或是程式結束時，必須將計時器銷毀。銷毀計時器的方法是呼叫 KillTimer，其語法如下：

invoke  KillTimer,\
        hWnd,\      ; handle of window that installed timer
        uIDEvent    ; timer identifier

如果 KillTimer 成功銷毀計時器，回傳值為非零；失敗，回傳值為零。

計時器的應用：RNDLINE1.ASM

底下實作一個例子，說明計時器的用法。這個例子是 RNDLINE1.ASM，它會在視窗的工作區內以左上角為起點，隨機取一點為終點繪出一個隨機顏色的線段，而後把該線段的終點作為另一線段的起點，再隨機取一點為終點繪出第二個隨機顏色的線段，如此一直重複直到使用者關閉 RNDLINE1 為止。

RNDLINE1.ASM 牽涉到當前像素、繪製線段及彩色文字，因此先補充有關這方面的知識。底下所要談論的是 GDI 物件之一，畫筆。畫筆與畫刷相似，要先建立後才能使用，畫筆是用來畫出線段、曲線或是圖形（例如矩形、橢圓等）。

CreatePen API

CreatePen 能用指定的風格、寬度以及顏色建立邏輯畫筆。CreatePen 的原型是：

invoke  CreatePen,\
        fnPenStyle,\    ; pen style
        nWidth,\        ; pen width
        crColor         ; pen color

如果成功建立邏輯畫筆，回傳值是此邏輯畫筆的代碼，那麼可以用此邏輯畫筆代碼為參數，呼叫 SelectObject 將此邏輯畫筆選入裝置內容。爾後畫出的線段、曲線都是用這個邏輯畫筆繪製。與前一章畫刷一樣，當所建立的畫筆不用時，必須呼叫 DeleteObject 刪除，以節省資源。如果建立邏輯畫筆失敗，CreatePen 的回傳值是 0。

SelectObject API

SelectObject 使裝置內容內的 GDI 物件設定為新指定的 GDI 物件。例如可以呼叫 SelectObject 將裝置內容中舊有的畫筆，以新建立好的畫筆取代。SelectObject 的原型是：

invoke  SelectObject,\
        hdc,\       ; handle to DC
        hgdiobj     ; handle to object

能夠被 SelectObject 選入的 GDI 物件有下面幾種類型：①位元圖（bitmap）、②畫刷（brush）、③字形（font）、④畫筆（pen）、⑤區域（region）。

如果 SelectObject 的第二個參數不是區域，而 SelectObject 又執行失敗，那麼回傳值為零；如果執行成功，回傳值是原先 GDI 物件代碼。如果 SelectObject 的第二個參數是區域，而 SelectObject 又執行失敗，那摩回傳值是 HGDI_ERROR；如果執行成功，那麼回傳值是下列之一：

  1. SIMPLEREGION：區域僅包含一個矩形。
  2. COMPLEXREGION：區域包含兩個或兩個以上的矩形。
  3. NULLREGION：區域是空的。

MoveToEx API

當程式呼叫 BeginPaint 或 GetDC 以獲得視窗工作區的裝置內容代碼時，會將工作區左上角當做當前的像素（像素英文是 pixel，可以看成是螢幕上的點），而 MoveToEx 可以把當前像素移到指定的像素上。MoveToEx 的原型是：

invoke  MoveToEx,\
        hdc,\       ; handle of device context
        X,\         ; x-coordinate of new current position
        Y,\         ; y-coordinate of new current position
        lpPoint     ; address of old current position

如果 MoveToEx 成功設定當前像素，回傳值為非零；如果失敗，回傳值為零。

LineTo API

LineTo 可以把當前像素與指定的終點像素兩點連接起來，繪出一線段來。LineTo 的原型是：

invoke  LineTo,\
        hdc,\       ; device context handle
        nXEnd,\     ; x-coordinate of line's ending point
        nYEnd       ; y-coordinate of line's ending point

LineTo 會用當前的畫筆繪出線段，當前畫筆可以用呼叫 CreatePen、CreatePenIndirect 等 API 建立，然後以 SelectObject 選入到裝置內容中。LineTo 如果成功繪出線段，那麼回傳值為非零，同時當前像素設定為 nXEnd、nYEnd 所指的像素；如果失敗，回傳值為零。

SetTextColor API

SetTextColor 將指定的裝置內容的文字設定為某種顏色。其原型為：

invoke  SetTextColor,\
        hdc,\       ; handle of device context
        crColor     ; text color

如果成功設定文字顏色，回傳值為原來的文字顏色；如果失敗，回傳值為 CLR_INVALID，可以呼叫 GetLastError 得到更進一步的錯誤原因。

RNDLINE1.ASM 原始程式

底下是 RNDLINE1.ASM 原始程式的完整列表。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
;RNDLINE1.ASM：在螢幕上顯示視窗，利用計時器每隔一段時間，在視窗內隨機繪製線段
;組譯方式：
;SET INCLUDE=C:\UASM\Include
;SET LIB=C:\UASM\lib64
;SET PATH=C:\UASM;C:\UASM\bin64;
;SET LINK=/SUBSYSTEM:WINDOWS
;UASM64 -win64 RNDLINE1.ASM
;LINK RNDLINE1.OBJ
        OPTION  CASEMAP:NONE
        OPTION  WIN64:3

INCLUDE         WINDOWS.INC
INCLUDELIB      GDI32.LIB
INCLUDELIB      KERNEL32.LIB
INCLUDELIB      USER32.LIB

TIMER_ID        EQU     1000            ;計時器識別碼
;*******************************************************************************
.CONST
szClassName     DB      "RndLine1",0     ;視窗類別名稱
szAppName       DB      "線段",0
szErr           DB      "錯誤",0
szFmt           DB      "%d Lines",0
szErrMsg0       DB      "CPU不支援。",0
szErrMsg1       DB      "註冊視窗類別失敗。",0
;*******************************************************************************
.DATA
hInstance       HINSTANCE   ?   ;模組代碼
hWnd            HWND        ?   ;視窗代碼
iWidth          DD          ?   ;工作區寬度
iHeight         DD          ?   ;工作區高度
cLines          DD          ?
pnt             POINT       <0,0>
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
;製造一亂數，且小於range，然後存於EAX後返回
get_rnd PROC    range:DWORD
        mov     ecx,30
        bsr     eax,range       ;以二進位表示range，最高位元為1的在第EAX位元
        mov     r11d,7fffffffh  ;使符號位元為0
        sub     ecx,eax         ;ECX＝R11D的符號位元要右移多少次
        sar     r11d,cl         ;執行右移CL次
retry:  rdrand  eax
        and     eax,r11d
        cmp     eax,range
        ja      retry
        ret
get_rnd ENDP
;-------------------------------------------------------------------------------
DrawLine PROC   hwnd:HWND
         LOCAL  hdc:HDC,hPen:HPEN,buffer[16]:BYTE,text_color:DWORD
     ;獲得視窗的裝置內容
         invoke GetDC,hwnd
         mov    hdc,rax
     ;建立隨機的顏色，以此顏色建立畫筆，並設定文字顏色
         invoke get_rnd,0ffffffh
         mov    text_color,eax
         invoke CreatePen,PS_SOLID,3,eax
         mov    hPen,rax
         invoke SetTextColor,hdc,text_color
     ;把新建立的畫筆選入裝置內容中
         invoke SelectObject,hdc,hPen  
     ;把當前像素設為上次線段終點
         invoke MoveToEx,hdc,pnt.x,pnt.y,0
     ;在工作區內隨機選擇一點，並存入pnt，以作為下次的起點
         invoke get_rnd,iWidth
         mov    edx,eax
         mov    pnt.x,eax
         invoke get_rnd,iHeight
         mov    pnt.y,eax
     ;把當前的點（上次線段終點）與隨機選擇的點連接起來，形成線段
         invoke LineTo,hdc,edx,eax
         inc    cLines
     ;在工作區右下角顯示已畫出的線段個數
         invoke SetTextAlign,hdc,TA_BOTTOM or TA_RIGHT
         invoke wsprintf,ADDR buffer,OFFSET szFmt,cLines
         invoke TextOut,hdc,iWidth,iHeight,ADDR buffer,eax
         invoke DeleteObject,hPen
         invoke ReleaseDC,hwnd,hdc
         ret
DrawLine ENDP
;-------------------------------------------------------------------------------
WndProc PROC    hwnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
.switch uMsg
.case WM_CREATE
        invoke  SetTimer,hwnd,TIMER_ID,330,0

.case WM_TIMER
        invoke  DrawLine,hwnd

.case WM_SIZE
        mov     r10,lParam
        mov     r11,lParam
        and     r10,0ffffh
        shr     r11,10h
        mov     iWidth,r10d
        mov     iHeight,r11d
        mov     cLines,0

.case WM_DESTROY
        invoke  KillTimer,hwnd,TIMER_ID
        invoke  PostQuitMessage,0
.default
        invoke  DefWindowProc,hwnd,uMsg,wParam,lParam
        ret
.endsw
        xor     rax,rax
        ret
WndProc ENDP
;-------------------------------------------------------------------------------
;check_rdrand用來檢查CPU是否支援RDRAND，如果支援回傳值為1；不支援回傳值為0
check_rdrand    PROC
;並不是所有的CPU都支援RDRAND指令，所以在使用前要先進行檢測：把EAX暫存器置1並執行
;CPUID指令，如果支援RDRAND的話，ECX暫存器的第30位元位會被置為1。
                mov     rax,1
                cpuid
                test    ecx,40000000h
                jnz     support_rdrand
                xor     rax,rax
support_rdrand: ret
check_rdrand    ENDP
;-------------------------------------------------------------------------------
main    PROC
        LOCAL   wc:WNDCLASSEX,msg:MSG
        call    check_rdrand            ;檢查CPU是否支援RDRAND
        lea     rdx,szErrMsg0
        or      rax,rax                 ;若RAX＝0，不支援，跳至error:處
        jz      error
        invoke  GetModuleHandle,0       ;取得模組代碼
        mov     hInstance,rax
        mov     wc.cbSize,SIZEOF WNDCLASSEX
        mov     wc.style,CS_HREDRAW or CS_VREDRAW
        lea     rdx,WndProc
        mov     wc.lpfnWndProc,rdx
        mov     wc.cbClsExtra,0
        mov     wc.cbWndExtra,0
        mov     wc.hInstance,rax
        invoke  LoadIcon,NULL,IDI_APPLICATION   ;取得圖示代碼
        mov     wc.hIcon,rax                    ;存入圖示代碼
        mov     wc.hIconSm,rax                  ;存入小圖示代碼
        invoke  LoadCursor,NULL,IDC_ARROW       ;取得游標代碼
        mov     wc.hCursor,rax                  ;存入游標代碼
        mov     wc.hbrBackground,COLOR_WINDOW+1
        mov     wc.lpszMenuName,0
        lea     rdx,szClassName
        mov     wc.lpszClassName,rdx
        invoke  RegisterClassEx,ADDR wc         ;註冊視窗類別
        lea     edx,szErrMsg1
.if rax==0
error:  invoke  MessageBox,0,rdx,OFFSET szErr,MB_ICONERROR or MB_OK
        jmp     quit
.endif
        invoke  CreateWindowEx,0,ADDR szClassName,ADDR szAppName,WS_OVERLAPPEDWINDOW,\
                CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,0,0,hInstance,0
        mov     hWnd,rax
        invoke  ShowWindow,hWnd,SW_SHOWNORMAL
        invoke  UpdateWindow,hWnd
.while TRUE
        invoke  GetMessage,ADDR msg,0,0,0
.break .if rax==0
        invoke  TranslateMessage,ADDR msg
        invoke  DispatchMessage,ADDR msg
.endw
quit:   invoke  ExitProcess,0                   ;程式結束
main    ENDP
;*******************************************************************************
END     main

RNDLINE1.ASM 第 81 行，在處理 WM_CREATE 訊息時，建立了每隔 330 毫秒發送 WM_TIMER 訊息給視窗函式的計時器。在處理 WM_DESTROY 訊息時，呼叫 KillTimer 刪除此計時器，因為此刻即將退出程式，計時器也就沒用了。

在 RNDLINE1 執行過程中，Windows 會每隔 330 毫秒，發出 WM_TIMER 訊息給視窗函式。視窗函式在處理這則訊息時，呼叫 DrawLine 副程式。在 DrawLine 副程式中，先獲得裝置內容代碼（第 53∼55 行），然後以亂數製造任意一種顏色，等會兒會用這種顏色畫線並顯示已畫出幾條線的文字。所以緊接著第 56∼63 行就是呼叫 CreatePen 建立邏輯畫筆與呼叫 SetTextColor 設定文字顏色，然後是呼叫 SelectObject 將裝置內容的畫筆設定為剛才建立的畫筆。

本來接下來就是要呼叫 LineTo 畫出線段，LineTo 所畫出的線段是把當前像素與由亂數形成的 X、Y 座標所代表的像素連接起來。但是因為每次呼叫 GetDC 後，Windows 都會把當前像素設為左上角，如果直接呼叫 LineTo 畫線段的話，那麼每次的線段起點都是左上角，這並不符合原來的想法。解決的方法就是把前次的終點保存起來，在呼叫 LineTo 之前，先呼叫 MoveToEx 將當前像素設為前次終點，這樣畫出來的線段就能首尾相連。

前次終點保存在 pnt 變數裏，這個變數其實是一個 POINT 結構體。程式一開始時，為工作區的左上角，其座標是 ( 0, 0 )，見第 33 行。每次呼叫 DrawLine 時，都會隨機指定一個像素，作為線段的終點，RNDLINE1 也必須將這個像素的座標保存下來，以作為下次線段的起點。

計時器的另一種用法

RNDLINE1.ASM 中的計時器是把 WM_TIMER 訊息發送給視窗函式，但是也可以讓 Windows 將 WM_TIMER 訊息發送給某個回呼函式。底下的 RNDLINE2.ASM 就是這樣的例子。不過小木偶不打算把它完整的列出來，只列出重要的部分。

1
2
3
4
5
6
7
8
9
10
⁝ 
50
51
52
⁝ 
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
⁝ 
164
165
;RNDLINE2.ASM：在螢幕上顯示視窗，利用計時器每隔一段時間，在視窗內隨機繪製線段
;組譯方式：
;SET INCLUDE=C:\UASM\Include
;SET LIB=C:\UASM\lib64
;SET PATH=C:\UASM;C:\UASM\bin64;
;SET LINK=/SUBSYSTEM:WINDOWS
;UASM64 -win64 RNDLINE2.ASM
;LINK RNDLINE2.OBJ
        OPTION  CASEMAP:NONE
        OPTION  WIN64:3
        ⁝
;-------------------------------------------------------------------------------
DrawLine PROC   hwnd:HWND, uMsg:UINT, iTimerID:WPARAM, dwTime:LPARAM
         LOCAL  hPen:HPEN,hdc:HDC,buffer[16]:BYTE,text_color:DWORD
        ⁝
DrawLine ENDP
;-------------------------------------------------------------------------------
WndProc PROC    hwnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
.switch uMsg
.case WM_CREATE
        invoke  SetTimer,hwnd,TIMER_ID,330,OFFSET DrawLine

.case WM_SIZE
        mov     r10,lParam
        mov     r11,lParam
        and     r10,0ffffh
        shr     r11,10h
        mov     iWidth,r10d
        mov     iHeight,r11d
        mov     cLines,0

.case WM_DESTROY
        invoke  KillTimer,hwnd,TIMER_ID
        invoke  PostQuitMessage,0
.default
        invoke  DefWindowProc,hwnd,uMsg,wParam,lParam
        ret
.endsw
        xor     rax,rax
        ret
WndProc ENDP
;-------------------------------------------------------------------------------
        ⁝
;*******************************************************************************
END     main

最重要不同是第 87 行，SetTimer 的最後一個參數改成「OFFSET DrawLine」，這樣就會使 Windows 將 WM_TIMER 訊息發送給 DrawLine 副程式。正因為如此，整個視窗函式，從第 83∼108 行，都不需處理 WM_TIMER。而 DrawLine 是被 Windows 作業系統所呼叫，因此是回呼函式。Windows 傳來的參數有四個，雖然只有第一個參數 hwnd 用得著，第二個參數 uMsg 必定是 WM_TIMER，其他兩個參數在這個程式中用不到，但還是將其全部列出來，見 RNDLINE2.ASM 第 51 行。

註釋

註一：多工（multitasking）

多工是在一段時間內同時執行多個程式（精確的講法是行程，process）。某個程式可以在正在執行的程式還沒結束之前，就執行而後者會中斷但不一定是結束。因此，多工可看成電腦以交錯的方式執行多個程式片段，但因為電腦執行速度很快，以人類的角度看來似乎是同時執行許多程式，而實際上是這些程式共享 CPU 和記憶體。當然中斷的程式必須保存其狀態（例如記憶體內容和暫存器內容），然後才能載入另一個程式並將控制權轉移給它。

多工分為兩種：①協調式多工（cooperative multi-tasking）與②優先權式多工（preemptive multi-tasking）。

協調式多工是指正在執行的程式主動交出控制權，然後作業系統再將其交給其他程式。這種多工多半是由於 CPU 未能有效支援或效能不夠而發展出來的多工。如果有一個程式不交回控制權或者當掉了，那麼整個作業系統就當掉了，只有重新啟動一途。例如建構在 MS－DOS 下的 Windows 3.1 就屬於協調式多工。

優先權式多工也叫先佔式多工，在這種多工之下，每個程式的執行時間由作業系統來分配，一個程式的時間使用完之後，系統就會將 CPU 分配給下一個程式（這種動作稱為context switching），沒有一個程式能獨佔 CPU。這種多工之下，一個程式當掉，不會影響另一個程式。OS/2、Windows NT/2000/XP/Vista/7/8.x/10/11、UNIX/Linux/Solaris/Mac-OS 都屬於這種多工方式。