一般檔案大約有幾百 KB，多的也可達數百 MB，而 DOS 最多能處理 2GB 的檔案，不管是前述的哪一種情形，都無法一次顯示在螢幕上。小木偶模仿 PCTOOLS 的畫面，一次只顯示 256 個位元組 ( 100H，即十六進位的 100 )，在本章小木偶稱為「一頁」。
前一章介紹了如何利用 AH＝3EH/INT 21H 及 AH＝3FH/INT 21H 獲得一個目錄裡所指定的檔案名稱，在這一章裡小木偶要介紹利用 DOS 服務程式讀取指定檔案的內容，並顯示於螢幕之上，程式名稱是 VIEW.ASM，組譯連結後生成 VIEW.EXE，而下圖卻是利用 VIEW.EXE 觀察自己的內容：
一般檔案大約有幾百 KB，多的也可達數百 MB，而 DOS 最多能處理 2GB 的檔案，不管是前述的哪一種情形，都無法一次顯示在螢幕上。小木偶模仿 PCTOOLS 的畫面，一次只顯示 256 個位元組 ( 100H，即十六進位的 100 )，在本章小木偶稱為「一頁」。
由上圖可以得知 VIEW.EXE 有六項功能，按「Esc」鍵退出程式、按「J」鍵讓使用者輸入要觀看檔案的哪一段內容、按「PgUp」或「PgDn」鍵觀看往前或往後 100H 個位元組的資料、按「Home」或「End」鍵觀看檔案頭或檔案尾的內容。有這些功能，可想而知，VIEW.ASM 檔案一定不會很小，所以應該好好規劃流程。小木偶規劃的主要流程圖如右圖：
整個流程可以切割成數個「小的程式片段」，把每個小的程式片段分別寫好再串接在一起，就大功告成了。這些小的程式片段，可分為下面幾部分：
這段程式很容易，不外乎是呼叫 AH＝0AH/INT 21H 輸入檔名與 AH＝3DH/INT 21H 開啟檔案。
呼叫 AH＝3FH/INT 21H 可自檔案指標處讀取檔案內容，但是使用者不一定是照順序讀取檔案來觀察，所以要先呼叫 AH＝42H/INT 21H 設好檔案指標，只要設好檔案指標，要撰寫讀取檔案並顯示的程式不會太困難。
但問題在於要顯示檔案內容時，連帶要顯示這些內容位於檔案何處，這也就是要顯示檔案指標。不幸的是，沒有一個 DOS 服務程式能夠讀取檔案指標，所以得另外定義變數來記錄檔案指標。檔案指標是三十二位元，而在真實模式下運行的 DOS 程式是十六位元，所以定義兩個十六位元的變數，小木偶替這兩個變數取名為 fp_low 與 fp_high，前者是低字組，後者是高字組 ( 低字組位於低位址、高字組位於高位址，fp 是 file pointer 的意思 )。設定檔案指標、讀取並顯示的程式如下：
set_fp_on_bgn: mov cx,fp_high
mov dx,fp_low
mov al,0 ;以檔案起頭為基準
set_fp: mov ah,42h ;設定檔案指標在CX:DX處
mov bx,f_handle
int 21h
read_file: mov ah,3fh
mov bx,f_handle
mov cx,100h ;讀取100H個位元組
mov dx,OFFSET buffer
int 21h
INVOKE print_data,4,OFFSET buffer,fp_low,fp_high,ax
如果使用者按下某些鍵，例如「PgDn」鍵、「PgUp」鍵或其他 VIEW 所關注的按鍵，由其他程式片段設定好新的 fp_high:fp_low，然後跳至「set_fp_on_bgn:」標記處設定檔案指標。例如使用者按下「Home」鍵，那就把 fp_high:fp_low 設為零，然後跳至「set_fp_on_bgn:」標記處即可。不管哪一個按鍵，處理完 fp_high:fp_low 之後都會跳至「set_fp_on_bgn:」標記處，設定以檔案頭為基準，移動檔案指標，接著讀取檔案並顯示。
print_data 是把讀取到的檔案內容顯示在螢幕上。第一個參數，4，代表由螢幕第四列開始顯示；第二個參數，OFFSET buffer，代表要顯示的資料位於位址 buffer 所指之處；第三、四個參數，fp_high:fp_low，表示顯示的檔案內容位於檔案何處；最後一個參數，AX，表示要顯示的檔案內容有多少個位元組。一般來說，AX 是 100H，但如果檔案指標接近檔案尾端，就有可能會小於 100H。
要讓使用者輸入按鍵可呼叫 AH＝00H/INT 16H，之所以不呼叫 DOS 服務程式，是因為程式需要處理像「Home」鍵、「End」鍵這類不帶 ASCII 的按鍵，且又不須把按鍵印在螢幕上。取得使用者輸入的按鍵後，根據其掃描碼執行不同的程式片段，以更改檔案指標，這段程式可以利用 .IF/.ELSEIF/.ELSE/.ENDIF 假指令來撰寫，這樣會較為簡潔。下面就是這段程式的樣子：
get_key: mov ah,0
int 16h ;使用者輸入按鍵
.IF ah==24h ;使用者按下「J」鍵
此處為處理按鍵「J」的程式
.ELSEIF ah==49h ;使用者按下「PgUp」鍵
此處為處理按鍵「PgUp」的程式
.ELSEIF ah==51h ;使用者按下「PgDN」鍵
此處為處理按鍵「PgDn」的程式
.ELSEIF ah==47h ;使用者按下「Home」鍵
此處為處理按鍵「Home」的程式
.ELSEIF ah==4fh ;使用者按下「End」鍵
此處為處理按鍵「End」的程式
.ELSEIF ah==1 ;使用者按下「Esc」鍵
此處為處理按鍵「Esc」的程式
.ELSE
jmp get_key ;使用者按下其他按鍵
.ENDIF
jmp read_file
.IF/.ELSEIF/.ELSE/.ENDIF 處理六種按鍵，其處理程式分別放在不同的「.ESLEIF」區間之中。至於其餘按鍵都交由「.ELSE」處理，其餘按鍵的處理方式很簡單，因為這種按鍵不是 VIEW 要處理的，故直接跳到「get_key:」標記，讓使用者重新按按鍵。至於「AH==」之後的數值，是比對呼叫 AH＝00H/INT 16H 後傳回來按鍵的掃描碼，鍵盤上按鍵的掃描碼請參考第十三章註一。
如果使用者想要觀察檔案的任一處，那麼按下「J」鍵，J 代表 Jump，跳到那一處觀察的意思。這時候，VIEW 除了讓使用者輸入數值之外，也應該要印出提示。對於較友善且人性化的程式，提示要說明使用者應該輸的注意事項才對。對於 VIEW 而言，該提示應該要說明：
等輸入完畢，還要檢查使用者輸入的正確與否，最後不管正確或不正確都要清除提示與使用者輸入的數值。這一段過程，小木偶把它製作成一個 input_number 副程式。如果使用者輸入的數值在此範圍內，就會清除進位旗標並設定新的 p_high:p_low；如果使用者輸入了不合法的字元，例如不是數字，或超出範圍，input_number 會設定進位旗標。底下就是這一段程式的樣子：
.IF ah==24h ;使用者按下「J」鍵
call input_number
jc get_key
mov p_high,cx
mov p_low,dx
jmp st_fp_on_bgn
使用者按下「PgUp」鍵時，可能有兩種狀況，情形不同，處理方式也不同。
第一種情形是如果檔案指標已經在檔案頭了，那麼即使按下「PgUp」鍵，也不能再讀取檔案中的資料，所以應該不處理，跟按下非 VIEW 要處理的六種鍵一樣，直接跳至「get_key:」標記，讓使用者重新按按鍵。這種情形只要檢查 fp_high 及 fp_low 是否均為零，只有兩者都是零的時候才跳至 get_key: 標記處；兩者中只要有一個不為零，就是第二種情形。
第二種情形是一般的情形，就是檔案指標不在檔案頭，這時候如果按下「PgUp」鍵時，是顯示上一頁的資料，所以只要把 p_high:p_low 減去 100H 即可 ( 須考慮到借位的問題，需用 SBB 指令 )，然後跳至「set_fp_on_bgn:」標記處重新設定檔案指標。綜合這兩種情形，處理使用者按下「PgUp」鍵的程式為：
.ELSEIF ah==49h ;使用者按下「PgUp」鍵 cmp fp_high,0 ;檢查檔案指標是否在檔案頭，即檢查 jnz not_bgn ;fp_high:fp_low是否為0:0，若為零表示 cmp fp_low,0 ;在檔案頭，即使按下「PgUp」鍵，也 jz get_key ;無作用，跳至get_key:處 not_bgn: sub fp_low,100h ;若不在檔案頭，使檔案指標往檔案頭 sbb fp_high,0 ;移100H個位元組 jmp set_fp_on_bgn
使用者按下「PgDn」鍵時，情況較為複雜，小木偶舉幾個實例說明，大概比較容易瞭解。
假如有個檔案長度是 210H 個位元組，現在檔案指標指在 100H 的位置。當使用者按下「PgDn」鍵時，毫無懸念，讓檔案指標加 100H，變成 200H，接著直接跳至「read_file:」標記處讀取檔案即可。如果這時候再按一次「DgDn」鍵，那麼此刻檔案指標已經是在最後一頁了 ( 這一頁只顯示 10H 個位元組的資料 )，所以不必處理，直接跳至「get_key:」標記，讓使用者重新按按鍵。
AH＝3FH/INT 21H 主要是用來讀取檔案，但是此 DOS 服務程式也會默默地將檔案指標移到讀取結束的位置。所以不必真的去呼叫 AH＝42H/INT 21H 設定檔案指標，也就是上一段說的“直接跳至「read_file:」標記處讀取檔案即可”。不過，我們自行定義要記錄檔案指標的 fp_high:fp_low 兩變數，必須要由自己的程式加上 100H。
假如檔案長度是 200H 個位元組，現在檔案指標指在 100H 的位置。當使用者按下「PgDn」鍵時，處理方式卻跟上面不太一樣。這是因為檔案指標在 100H 時，在螢幕上所顯示的檔案內容是從 100H 到 1FFH，其最後一個位元組恰好是檔案尾，也就是說如果還要讓檔案指標再加上 100H，結果還是在檔案尾，根本讀不到檔案內容。基於以上原因，小木偶還是把檔案指標加上 100H 之後，再檢查檔案長度是否能被 100H 整除，如果不能就跳至「read_file:」處；如果能整除，再檢查是否已到檔案尾，如果尚未到檔案尾，也跳至「read_file:」處，如果到檔案尾，就表示不必處理，但剛剛已經讓 fp_high:fp_low 加上 100H，所以將其還原即可。而這段程式與按下「End」鍵的一樣，故無條件跳至「divisible:」標記處。
經過以上分析，使用者按下「PgDn」鍵時，程式如下：
.ELSEIF ah==51h ;使用者按下「PgDn」鍵 mov dx,f_len_low mov cx,f_len_high mov ax,dx and dx,0ff00h ;CX:DX＝最後一頁 cmp cx,fp_high ja next_page cmp dx,fp_low ;如果CX:DX＝fp_high:fp_low，表示 je get_key ;已到最後一頁跳至get_key:處 next_page: add fp_low,100h ;如果如果CX:DX＜fp_high:fp_low， adc fp_high,0 ;表示未到最後一頁 test ax,0ffh ;檢查檔案大小是否能被100H整除 jnz read_file ;如果不能整除，就讀取檔案 cmp cx,fp_high ;如果能整除，檢查是否已到後一頁 ja read_file ;如果不是，讀取檔案 cmp dx,fp_low ;如果是，最後一頁要顯示的位元組 jz divisible ;個數為零，與「End」鍵一樣
處理這個按鍵的方式最簡單，只需把 fp_high:fp_low 設為 0:0 即可，程式碼如下：
.ELSEIF ah==47h ;使用者按下「Home」鍵 mov fp_low,0 ;設定檔案指標為fp_high:fp_low＝0:0 mov fp_high,0 jmp set_fp_on_bgn
使用者按下「End」鍵時，似乎是把檔案指標移到檔案尾端就完成了，但真的是如此嗎？假設真是這樣，那麼用 AH＝3FH/INT 21H 讀取時，因為檔案指標已在檔案尾端，所以是讀不到檔案內容的。前面提過，VIEW 每次只顯示 100H 個位元組的內容，而大部分的檔案長度應該不會恰好是 100H 的整數倍，所以最後一頁可能不是顯示 100H 個位元組，而且可能比這小。所以按下「End」鍵的處理方式可分成兩種情形：
第一種情形。對大部分檔案長度不能為 100H 所整除的檔案而言，計算最後一頁的檔案指標並不難。例如有個檔案其長度為 2197 個位元組，換成十六進位是 895H，所以最後一頁的檔案指標應指在 800H 處，也就是把檔案長度的低字組 0∼7 位元遮罩掉即可，利用 AND 指令就能達到目的。
但是對於檔案長度能被 100H 整除的檔案而言，就不能這樣計算了。因為把 0∼7 位元遮罩掉後，檔案指標會移到檔案尾，解決的方法是最後一頁必須往前移一頁。例如有個檔案長度是 2048，換成十六進位是 800H，遮罩 0∼7 位元後，檔案指標變成 800H，結果就移到檔案尾，這當然不對，應該要把指標移到 700H 才對，也就是再減去 100H。綜合以上討論，處理按下「End」鍵的程式如下：
.ELSEIF ah==4fh ;使用者按下「End」鍵 mov cx,f_len_high ;設定檔案指標為距離檔案尾 mov dx,f_len_low ;(檔案長/100h之餘數)個位元組，也可以說 and dx,0ff00h ;距離檔案頭(f_len_high:f_len_low AND mov fp_high,cx ;FF00)個位元組 mov fp_low,dx test f_len_low,0ffh ;檢查檔案長度是否能被100H整除 jnz set_fp_on_bgn ;如果不能，跳至set_fp_on_bgn:處 divisible: sub fp_low,100h ;如果能，檔案指標往檔案頭移100H sbb fp_high,0 jmp set_fp_on_bgn
前面幾個處理按鍵的方法，在設定檔案指標時，都是以檔案頭為基準，處理「End」按鍵也是如此；但其實不一定都必須以檔案頭為基準，小木偶想以「End」按鍵為例子，說一說如果要以檔案尾為基準，該如何處理。我們先看看程式碼：
.ELSEIF ah==4fh ;使用者按下「End」鍵 mov cx,f_len_high mov ax,f_len_low mov fp_high,cx mov fp_low,ax ;使fp_high:fp_low＝檔案尾 and ax,0ffh ;檢查檔案長度是否能被100H整除 jz divisible ;如果能整除，跳至divisible: and fp_low,0ff00h ;設定檔案指標為距離檔案頭(f_len_high sub cx,cx ;:f_len_low AND FF00)個位元組 sub dx,dx sub dx,ax ;CX:DX＝0-(f_len_low AND FF) sbb cx,0 mov al,2 jmp set_fp divisible: sub fp_low,100h sbb fp_high,0 jmp set_fp_on_bgn
觀察上面的程式碼，很明顯，一樣可分成兩種情形：一種是檔案長度恰好能被 100H 整除；另一種是不能被 100H 整除。小木偶並沒有改寫前者的處理方式，要做也不是不可以只是小木偶偷懶沒做。改寫後者的方式也不難，只須在呼叫 AH＝42H/INT 21H 前，使 CX:DX 變為負數即可。也有兩種方法可使得 CX:DX 變為負數：Ⓐ在這裡小木偶用 0 減去 AX 之值，再用 SBB 指令使高字組為 －1 ( 見白色的程式碼 )；Ⓑ利用第六章所說的，某數的二補數就是其負數。利用 NEG 指令計算其二補數，可以減少程式碼，如下。可以用底下的三行代替上面的白色程式碼：
mov dx,ax
mov cx,-1
neg dx
到此，VIEW.ASM 的主要架構已解說完畢，來看看完整的原始程式。
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88
89 90 91 92
93 94 95 96
97 98 99 100
101 102 103 104
105 106 107 108
109 110 111 112
113 114 115 116
117 118 119 120
121 122 123 124
125 126 127 128
129 130 131 132
133 134 135 136
137 138 139 140
141 142 143 144
145 146 147 148
149 150 151 152
153 154 155 156
157 158 159 160
161 162 163 164
165 166 167 168
169 170 171 172
173 174 175 176
177 178 179 180
181 182 183 184
185 186 187 188
189 190 191 192
193 194 195 196
197 198 199 200
201 202 203 204
205 206 207 208
209 210 211 212
213 214 215 216
217 218 219 220
221 222 223 224
225 226 227 228
229 230 231 232
233 234 235 236
237 238 239 240
241 242 243 244
245 246 247 248
249 250 251 252
253 254 255 256
257 258 259 260
261 262 263 264
265 266 267 268
269 270 271 272
273 274 275 276
277 278 279 280
281 282 283 284
285 286 287 288
289 290 291 292
293 294 295 296
297 298 299 300
301 302 303 304
305 306 307 308
309 310 311 312
313 314 315 316
317 318 319 320
321 322 323 324 |
;VIEW 能讓使用者輸入檔名，而後顯示這個檔案的內容
;組譯：ml view.asm
.MODEL SMALL,C
.386
;*******************************************************************************
.STACK
;*******************************************************************************
video SEGMENT PARA AT 0b800h ;視訊記憶體區段
video ENDS
;*******************************************************************************
.DATA
f_handle DW ? ;檔案代碼
fp_low DW 0 ;檔案指標，低字組
fp_high DW 0 ;檔案指標，高字組
f_len_low DW ? ;檔案大小，低字組
f_len_high DW ? ;檔案大小，高字組
field_name DB " Offset 00 01 02 03 04 05 06 07-08 09 0A 0B 0C 0D ",
"0E 0F 01234567-89ABCDEF"
line DB 78 DUP (0c4h)
help_text DB "Esc=Exit J=Jump PgDn/PgUp=Forward/Backward Home/",
"End=Begin/End"
msg00 DB "No assign file. Usage:",0dh,0ah," VIEWFILE filename$"
msg01 DB "Input filename to view : $"
msg02 DB "Input file pointer (range:0-12345678) : "
msg03 DB "Only Arabic number or English A-F. Press any key."
msg04 DB "Input too large number. Press any key. "
msg05 DB 50 DUP (" ")
msg06 DB 13,10,"Can not ope"
filename DB 66,?,64 DUP ("$")
buffer DB 256 DUP (0)
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
;在第rw列中以color的顏色顯示一字串，此字串位址在pstr處，長度為len位元組
print_a_line PROC rw:WORD, pstr:WORD, len:WORD, color:BYTE
mov ax,rw ;計算第rw列第零行在視訊記
call video_address ;憶體中的位址，並存於DI裏
mov ah,color
mov si,pstr
next: lodsb
stosw
dec len
jnz next
ret
print_a_line ENDP
;-------------------------------------------------------------------------------
;讓使用者輸入32位元的十六進位數。正確：NC，CX:DX＝使用者輸入的32位元數；錯誤：CY
input_number PROC
INVOKE print_a_line,22,OFFSET msg02,SIZEOF msg02,7
sub di,24 ;把視訊記憶體位址設定為「所能輸入的最大
mov dx,f_len_high ;範圍字串」的位址
call print_dx ;印出使用者所能輸入的最大高字組
mov dx,f_len_low
dec dx
call print_dx ;印出使用者所能輸入的最大低字組
mov dx,1628h
mov bh,0
mov ah,2
int 10h ;設定游標位置於第16H列第28H行
mov bx,8 ;一個字組的十六進位數有四位
xor cx,cx ;使CX:DX歸零，使用者輸入的數值存於此
sub dx,dx
next_digit: mov ah,1 ;DOS服務程式，鍵盤輸入字元
int 21h ;AL＝輸入字元的ASCII碼
.IF (al>="0")&&(al<="9")
sub al,"0"
.ELSEIF (al>="A")&&(al<="F")
sub al,37h
.ELSEIF (al>="a")&&(al<="f")
sub al,57h
.ELSEIF al==0dh
jmp input_ok
.ELSE
mov dx,OFFSET msg03
mov cx,SIZEOF msg03
print_err_msg: INVOKE print_a_line,22,dx,cx,7
mov ah,0
int 16h
INVOKE print_a_line,22,OFFSET msg05,SIZEOF msg05,7
stc
jmp exit_input
.ENDIF
shld cx,dx,4 ;此行跟下一行執行CX:DX＝CX:DX×10H
shl dx,4
add dl,al ;CX:DX＝CX:DX＋AL
dec bx
jnz next_digit
input_ok: cmp f_len_high,cx
ja finish
jb too_large
mov ax,f_len_low
dec ax
cmp dx,ax
jbe finish
too_large: mov dx,OFFSET msg04
mov cx,SIZEOF msg04
jmp print_err_msg
finish: and dx,0ff00h
INVOKE print_a_line,22,OFFSET msg05,SIZEOF msg05,7
clc
exit_input: ret
input_number ENDP
;-------------------------------------------------------------------------------
;在螢幕上印出DL的十六進位數值
print_dl PROC
rol dl,4
call print_4_bits
rol dl,4
print_4_bits:: mov al,dl
and al,0fh
add al,30h
cmp al,39h
jbe ok
add al,7
ok: stosw
ret
print_dl ENDP
;-------------------------------------------------------------------------------
;在螢幕上印出DX之十六進位數值
print_dx PROC
mov cx,4
next: rol dx,4
call print_4_bits
loop next
ret
print_dx ENDP
;-------------------------------------------------------------------------------
video_address PROC ;計算第AX列第零行在視訊記憶體中的位址後存於DI返回
mov bl,160 ;每一列有80個字元，每字元佔用一個ASCII碼及顏色
mul bl ;因此每一列佔用160個位元組
mov di,ax
ret
video_address ENDP
;-------------------------------------------------------------------------------
;在螢幕的第rw列印出pdata所指位址的ln個位元組的資料，而最左欄印出pt_hi:pt_lw
print_data PROC rw:WORD, pdata:WORD, pt_lw:WORD, pt_hi:WORD, ln:WORD
LOCAL clm:WORD ;第幾行
;清除第四列到第十九列，共16列，每列80個字元，每個字元有ASCII碼及顏色兩個位元組
mov ax,rw
call video_address
mov cx,16*80
mov ax,720h ;20h＝空白字元，7表示前景灰色背景黑色
rep stosw
;設定clm為零，SI為讀取檔案後的存放位址
mov clm,cx ;使clm歸零
mov si,pdata
;計算每列視訊記憶體起始位址及印出ASCII字元的起始位址（即每列第59行的位址）
next_row: mov ax,rw
call video_address
mov bx,di ;ES:DI＝每列視訊記憶體起始位址
add bx,118 ;ES:BX＝每列印出ASCII字元的起始位址
;印出要傾印的檔案內容位置
mov dx,pt_hi ;印出要傾印的檔案內容位置（較高字組）
mov ah,0fh ;AH＝0FH表示前景白色，背景黑色
call print_dx
mov al,":" ;印出「:」
stosw
mov dx,pt_lw ;印出要傾印的檔案內容位置（較低字組）
mov ah,0fh
call print_dx
;以十六進位印出檔案每個位元組的內容，及其ASCII字元
next_byte: mov ax,0e20h
cmp clm,8 ;檢查是否每行已印出八個位元組了
jne print_it ;若是，印出分隔符號「-」
mov WORD PTR es:[bx],0d2dh
mov ax,0d2dh
add bx,2
print_it: stosw ;若否，印出空白或不印
mov cx,4
self: loop self
mov dl,[si] ;取得一個位元組的檔案內容
mov dh,0bh
mov es:[bx],dx ;印在右邊以ASCII字元表示的檔案內容
mov ah,0eh
call print_dl ;印在中間以十六進位表示的檔案內容
inc si ;指向下一個位元組的檔案內容
add bx,2
inc clm
dec ln ;如果ln為零，表示已經印完了
jz finish
cmp clm,10h ;若clm＝10h，表示已印完一列了
jne next_byte
inc rw
mov clm,0
add pt_lw,10h
adc pt_hi,0
jmp next_row
finish: ret
print_data ENDP
;-------------------------------------------------------------------------------
.STARTUP
mov ah,9
mov dx,OFFSET msg01
int 21h
mov ah,0ah ;輸入要觀察內容的檔案
mov dx,OFFSET filename
int 21h
mov bx,OFFSET filename+1
movzx cx,BYTE PTR [bx] ;CX＝檔案名稱長度
add bx,cx
mov BYTE PTR [bx+1],0 ;把filename裡的字串變成ASCIZ
mov dx,OFFSET filename+2 ;開啟檔案
mov ax,3d00h
int 21h
jnc set_video ;若正確開啟檔案，跳至set_video
mov bx,OFFSET filename ;若無法開啟檔案，把msg06與
mov WORD PTR [bx],206eh ;filename兩字串連在一起，成為
mov dx,OFFSET msg06 ;「Can not open xxxx」，然後印出
mov ah,9 ;來，結束程式
int 21h
jmp exit
set_video: mov f_handle,ax
mov ax,3 ;把螢幕設為16色80×25文字模式
int 10h
;印出要觀察的檔案名稱、欄位、上下兩條分隔線及按鍵說明
cld
mov ax,video
mov di,80 ;把檔案名稱印在螢幕第零列的中間
mov es,ax
mov si,OFFSET filename+2
sub di,cx ;檔名在螢幕的行數＝(80-檔名長)/2
mov ah,0fh ;但每個字元佔用兩個位元組，一是
and di,0fffeh ;ASCII碼，另一個是顏色，所以還要再
nxt_chr_of_fn: lodsb ;乘以2，剛好抵消，但奇數位址是顏色
cmp al,"a" ;故用「AND DI,0FFFEh」變偶數位址
jb @f
cmp al,"z"
ja @f
and al,0dfh ;改成大寫
@@: stosw
loop nxt_chr_of_fn
INVOKE print_a_line,2,OFFSET field_name,SIZEOF field_name,7
INVOKE print_a_line,3,OFFSET line,SIZEOF line,9
INVOKE print_a_line,20,OFFSET line,SIZEOF line,9
INVOKE print_a_line,21,OFFSET help_text,SIZEOF help_text,7
;取得檔案長度，並存入f_len_high:f_len_low
mov ax,4202h
mov bx,f_handle
xor cx,cx
xor dx,dx
int 21h
mov f_len_high,dx
mov f_len_low,ax
set_fp_on_bgn: mov cx,fp_high
mov dx,fp_low
mov al,0 ;以檔案起頭為基準
set_fp: mov ah,42h ;設定檔案指標在CX:DX處
mov bx,f_handle
int 21h
read_file: mov ah,3fh
mov bx,f_handle
mov cx,100h ;讀取100H個位元組
mov dx,OFFSET buffer
int 21h
INVOKE print_data,4,OFFSET buffer,fp_low,fp_high,ax
get_key: mov ah,0
int 16h ;使用者輸入按鍵
.IF ah==24h ;使用者按下「J」鍵
call input_number
jc get_key
mov fp_high,cx
mov fp_low,dx
jmp set_fp_on_bgn
.ELSEIF ah==49h ;使用者按下「PgUp」鍵
cmp fp_high,0 ;檢查檔案指標是否在檔案頭，即檢查
jnz not_bgn ;fp_high:fp_low是否為0:0，若為零表示
cmp fp_low,0 ;在檔案頭，即使按下「PgUp」鍵，也
jz get_key ;無作用，跳至get_key:處
not_bgn: sub fp_low,100h ;若不在檔案頭，使檔案指標往檔案頭
sbb fp_high,0 ;移100H個位元組
jmp set_fp_on_bgn
.ELSEIF ah==51h ;使用者按下「PgDn」鍵
mov dx,f_len_low
mov cx,f_len_high
mov ax,dx
and dx,0ff00h ;CX:DX＝最後一頁
cmp cx,fp_high
ja next_page
cmp dx,fp_low ;如果CX:DX＝fp_high:fp_low，表示
je get_key ;已到最後一頁跳至get_key:處
next_page: add fp_low,100h ;如果如果CX:DX＜fp_high:fp_low，
adc fp_high,0 ;表示未到最後一頁
test ax,0ffh ;檢查檔案大小是否能被100H整除
jnz read_file ;如果不能整除，就讀取檔案
cmp cx,fp_high ;如果能整除，檢查是否已到後一頁
ja read_file ;如果不是，讀取檔案
cmp dx,fp_low ;如果是，最後一頁要顯示的位元組
jz divisible ;個數為零，與「End」鍵一樣
.ELSEIF ah==47h ;使用者按下「Home」鍵
mov fp_low,0 ;設定檔案指標為fp_high:fp_low＝0:0
mov fp_high,0
jmp set_fp_on_bgn
.ELSEIF ah==4fh ;使用者按下「End」鍵
mov cx,f_len_high
mov ax,f_len_low
mov fp_high,cx
mov fp_low,ax ;使fp_high:fp_low＝檔案尾
and ax,0ffh ;檢查檔案長度是否能被100H整除
jz divisible ;如果能整除，跳至divisible:
and fp_low,0ff00h ;設定檔案指標為距離檔案頭(f_len_high
sub cx,cx ;:f_len_low AND FF00)個位元組
sub dx,dx
sub dx,ax ;CX:DX＝0-(f_len_low AND FF)
sbb cx,0
mov al,2
jmp set_fp
divisible: sub fp_low,100h
sbb fp_high,0
jmp set_fp_on_bgn
divisible: sub fp_low,100h ;如果能，檔案指標往檔案頭移100H
sbb fp_high,0
jmp set_fp_on_bgn
.ELSEIF ah==1 ;使用者按下Esc鍵
mov ah,3eh ;關閉檔案，退出程式
mov bx,f_handle
int 21h
jmp exit
.ELSE
jmp get_key
.ENDIF
jmp read_file
exit: .EXIT 0
;*******************************************************************************
END |
VIEW.ASM 雖然有三百多行，但有許多副程式，在前面的章節都已介紹過了，而主程式的架構也已講完。小木偶覺得有必要介紹的是在「input_number」副程式中，輸入一個三十二位元的數值，儲存在兩個十六位元的暫存器，CX:DX，的指令，SHLD。
SHLD 是指雙精度向左移的縮寫，原文是 double precision shift left，其中「double precision」是指雙精度，意思是用 64 位元的二進位數來表示浮點數或整數，順帶說一說單精度是用 32 位元表示。在這裡的雙精度則是表示，SHLD 指令最多可以處理 64 位元的記憶體變數或暫存器。SHLD 指令語法是：
SHLD 目的運算元,來源運算元,計數運算元
SHLD 會把目的運算元向左移幾個位元，至於移幾個位元在計數運算元中指定；目的運算元左移數個位元後，右邊多出來的數個位元由來源運算元較高的數個位元填滿，左邊移出的位元都移入進位旗標中且會覆寫前次的結果，而來源運算元在整個過程中其值不變。
目的運算元可以是 16、32、64 位元的暫存器或記憶體變數，來源運算元只能是與目的運算元相同位元數的暫存器 ( 意思是目的運算元是 16 位元，來源運算元只能是 16 位元的暫存器；若目的運算元是 32 位元，來源運算元只能是 32 位元的暫存器……)。
計數運算元只能是 CL 暫存器或八位元的常數，在 64 位元預設模式下或非 64 位元 ( 包含真實模式、32 位元保護模式 ) 時，計數位元最多是 1Fh，亦即最多只能向左位移 31 位元。如果左移超過 31 位元，那麼計算結果未定義。
如果計數運算元等於一或超過一，進位旗標是最後一次從目的運算元移出的結果。如果運算後，目的運算元為零，零值旗標設為一，否則設為零。如果運算結果，最高位元為一，符號旗標設為一，否則設為零。如果計數運算元為一，且目的運算元發生變號，溢位旗標設為一，否則設為零；如果計數位元超過一，溢位旗標的結果為未定義。
SHRD 的運算過程與 SHLD 類似，只有一個地方不同，SHRD 是把目的旗標向右移動數個位元，其餘都與 SHLD 一樣。SHRD 的語法是：
SHRD 目的運算元,來源運算元,計數運算元
SHLD 與 SHRD 兩指令的工作方式已介紹完，底下舉一個例子說明 SHLD，使讀者更加瞭解：
mov dx,876h
mov ax,0abcdh
shld dx,ax,4
參考下圖，DX 變成二進位數之後是「0000 1000 0111 0110」，AX 是「1010 1011 1100 1101」。執行「shld dx,ax,4」時，DX 所有位元均向左移四次每次左移一個位元。第一次左移時，第 15 位元 ( 見紫色字，15 ) 移出 DX 至進位旗標 ( CF )，第 14 位元移至第 15 位元、第 13 位元移至第 14 位元……，如下圖中的最上圖紅色箭頭，結果變成下圖「第一次左移後」。但此指令的計數運算元是 4，所以還要左移三次，如下圖所示「最後結果」
總結來說，DX 由 0876H 變成 876AH，左移後空出來的最低四個位元，由 AX 最高四個位元填補，而 AX 在整個過程中不變。進位旗標是最後一次左移的結果，會被清除 ( 進位旗標為零 )。符號旗標會被設定 ( 表示符號旗標為一 )，因為目的運算元最高位是一。零值旗標被清除 ( 零值旗標為零 )，因為目的運算元不為零。