第18章　結構體（二）：作為參數

原理

存取結構體欄位

在呼叫副程式的時候，有時相關資料會宣告成一個結構體，然後以此結構體定義結構體變數，將此結構體變數作為參數呼叫副程式。那麼這時候，有個問題產生了，在副程式中應該如何讀取或者寫入結構體內的各欄位呢？答案是藉由位址，把結構體變數的位址作為參數傳入副程式，在副程式中也是以各欄位相對於結構體起始位址讀取或寫入該欄位。

在已知結構體變數的起始位址後，至少有三種方法能存取其中的欄位。底下小木偶舉個例子說明，假設有個叫 what_day_is 的副程式，它的功用是計算出某年某月某一天是星期幾。可想而知，它應該有三個參數，分別是年份、月份、日，但小木偶想用一個結構體包含這三筆資料，因此宣告 DATE 結構體如下：

DATE            STRUCT
  year          DW      ?       ;西元年份
  month         DB      ?       ;月份
  day           DB      ?       ;日
DATE            ENDS

現在 what_day_is 就僅僅需要一個參數即可，那就是 DATE 的起始位址。例如，要計算西元 2022 年七月二十六日星期幾，程式片段如下：

.DATA
today       DATE    {2022,7,26}
            .
            .
.CODE
what_day_is PROC    pdate:WORD ─┐
            .                   ├──what_day_is 副程式內，有讀取 pdate 所指位址的結構體變數內之欄位
what_day_is ENDP               ─┘
            .
            .
            INVOKE  what_day_is,OFFSET today

在 what_day_is 副程式裏，必定要讀取 today 裏的三個欄位。剛剛小木偶說至少有三種方法：

  1.   ASSUME  si:PTR DATE
  mov     si,pdate
  mov     ax,[si].year
  mov     bl,[si].month
  mov     cl,[si].day
  ASUME   si:NOTHING
  2.   mov     si,pdate
  mov     ax,(DATE PTR [si]).year
  mov     bl,(DATE PTR [si]).month
  mov     cl,(DATE PTR [si]).day
  3.   mov     si,pdate
  mov     ax,[si].date.year
  mov     bl,[si].date.month
  mov     cl,[si].date.day

這三種方法中，不管用哪一種方法，一開始都要把一個指標或索引暫存器 ( 例如 BX、SI、DI ) 指向結構體起始位址，然後以「.」分隔結構體與欄位名的方式存取。因為結構體後面已表明了欄位，因此組譯器能計算出欄位距離結構體起始位址多少個位元組的偏移位址，這三種方法最後都會被組譯成一模一樣的程式碼：

      mov     si,pdate
      mov     ax,[si]
      mov     bl,[si+2]
      mov     cl,[si+3]

這樣我們就不需要自己去計算欄位的偏移位址了。

原始碼

底下是 WHATDAY.ASM 的原始碼：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
.MODEL          SMALL,STDCALL
.386
DATE            STRUCT
  year          DW      ?       ;西元年份
  month         DB      ?       ;月份
  day           DB      ?       ;日
DATE            ENDS
;*******************************************************************************
.STACK
;*******************************************************************************
.DATA
today           DATE    {?}
str0            DB      "Input year : $"
str1            DB      0dh,0ah,"Input month : $"
str2            DB      0dh,0ah,"Input day : $"
str_sunday      DB      0dh,0ah,"Sunday$"
str_monday      DB      0dh,0ah,"Monday$"
str_tuesday     DB      0dh,0ah,"Tuesday$"
str_wednesday   DB      0dh,0ah,"Wednesday$"
str_thursday    DB      0dh,0ah,"Thursday$"
str_friday      DB      0dh,0ah,"Friday$"
str_saturday    DB      0dh,0ah,"Saturday$"
error_message   DB      0dh,0ah,"Input Arabic numerals only.$"
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
print_string    PROC    pStr:WORD
                mov     dx,pStr
                mov     ah,9
                int     21h
                ret
print_string    ENDP
;-------------------------------------------------------------------------------
;輸入0∼65535的十進位整數。
;返回：CX＝00，發生錯誤
;　　　CX非零，輸入正確，AX＝使用者輸入的數值
input           PROC
                LOCAL   value:WORD
                mov     cx,5            ;最多輸入五位
                mov     value,0         ;使value歸零
.WHILE cx
                mov     ah,1            ;DOS服務程式，鍵盤輸入字元
                int     21h             ;AL＝輸入字元的ASCII碼
     .IF (al>="0")&&(al<="9")
                sub     al,"0"
                mov     dx,value
                shl     value,3         ;8*value
                shl     dx,1            ;2*value
                cbw
                add     value,dx        ;value＝8*value+2*value＝10*value
                add     value,ax        ;value＝value＋AX
     .ELSEIF al==0dh
                jmp     finish
     .ELSE
                jmp     short quit1
     .ENDIF
                dec     cx
.ENDW
finish:         mov     ax,value
                mov     cx,1
                jmp     short quit2
quit1:          xor     cx,cx
quit2:          ret
input           ENDP
;-------------------------------------------------------------------------------
;計算某年某月某一天是星期幾
;輸入：pdate：DATE結構體的位址，其中year、month、day必須已填入正確日期
;輸出：AX＝星期幾：0＝星期日、1＝星期一，2＝星期二……
;      AX＝-1，輸入錯誤的DATE結構體
what_day_is     PROC    pdate:WORD
                LOCAL   w:WORD
                ;ASSUME  si:PTR DATE
;what_day_is利用Zeller's公式求出某個日期是星期幾，以W表示
;W={C/4－2*C＋Y＋Y/4＋13*(M＋1)/5＋D－1} Mod 7
;  月份：1月 2月 3月 4月 5月 6月 7月 8月 9月 10月 11月 12月
;  --------------------------------------------------------
;     M＝13  14  3   4   5   6   7   8   9   10   11   12
;     A＝ 1   1  0   0   0   0   0   0   0    0    0    0
;  B＝四位數字年份－A
;  C＝B的前兩位數(千位數和百位數所組成的兩位數)
;  Y＝B的後兩位數(十位數和個位數所組成的兩位數)
;  D＝日
                mov     si,pdate
                mov     cl,100
                movzx   bx,(DATE PTR [si]).month
                mov     ax,(DATE PTR [si]).year
                cmp     bx,2    ;檢查是否為元月份或二月份
                ja      not_adj
                add     bx,12   ;如果月份為元月份或二月份，要調整成前一年的13月、
                dec     ax      ;14月，亦即月份變成13月、14月同時年份減一
not_adj:        div     cl      ;年份＝B＝AX
                movzx   cx,ah   ;CX＝Y
                movzx   dx,al   ;DX＝C
                mov     w,cx    ;W＝Y
                shr     cx,2    ;CX＝Y/4
                add     w,cx    ;W＝Y＋Y/4
                mov     cx,dx
                shr     cx,2    ;CX＝C/4
                shl     dx,1    ;DX＝2*C
                movzx   ax,(DATE PTR [si]).day
                add     w,cx    ;W＝C/4＋Y＋Y/4
                sub     w,dx    ;W＝C/4－2*C＋Y＋Y/4
                add     w,ax    ;W＝C/4－2*C＋Y＋Y/4＋D
                inc     bx      ;BX＝M＋1
                mov     cx,50dh ;CL＝13，CH＝5
                mov     ax,bx
                mul     cl
                div     ch
                cbw             ;AX＝13*(M＋1)/5
                add     ax,w
                mov     cx,7
                dec     ax      ;AX＝C/4－2*C＋Y＋Y/4＋13*(M＋1)/5＋D－1
                cwd
                idiv    cx      ;因為DX:AX有可能是負數，因此用IDIV
                cmp     dx,0    ;如果DX:AX是負數所得餘數(存於DX)也是負數
                jge     ok
                add     dx,cx   ;因此餘數要加上七，確保為正數
ok:             mov     ax,dx
                ret
what_day_is     ENDP
;-------------------------------------------------------------------------------
                .STARTUP
                INVOKE  print_string,OFFSET str0
                call    input
                jcxz    error
                mov     today.year,ax
                INVOKE  print_string,OFFSET str1
                call    input
                jcxz    error
                mov     today.month,al
                INVOKE  print_string,OFFSET str2
                call    input
                jcxz    error
                mov     today.day,al
                INVOKE  what_day_is,OFFSET today
        .IF ax==0
                mov     dx,OFFSET str_sunday
        .ELSEIF ax==1
                mov     dx,OFFSET str_monday
        .ELSEIF ax==2
                mov     dx,OFFSET str_tuesday
        .ELSEIF ax==3
                mov     dx,OFFSET str_wednesday
        .ELSEIF ax==4
                mov     dx,OFFSET str_thursday
        .ELSEIF ax==5
                mov     dx,OFFSET str_friday
        .ELSE
                mov     dx,OFFSET str_saturday
        .ENDIF
                INVOKE  print_string,dx
                mov     al,0
                jmp     short exit
error:          INVOKE print_string,OFFSET error_message
                mov     al,1
exit:           .EXIT   al
;*******************************************************************************
END

組譯與連結

組譯連結這個原始程式很簡單，只需在「Virtual PC 2007 SP1」開啟「MS-DOS 6.20」虛擬機器，切換到 WHATDAY.ASM 的子目錄裏，輸入「ML WHATDAY.ASM」，按下「Enter」鍵即可。如下圖：

解說

有關 WHATDAY.ASM 的解說，最主要的是有關存取結構體中的欄位，前面已經描述過了。在這個程式裏，還有兩個地方值得注意：①蔡勒公式；②有號數的條件跳躍。


蔡勒公式 ( Zeller's congruence )

蔡勒公式是用來計算西曆某年某月某日是星期幾的公式。它寫成下面的式子：

底下說明這些變數的意義及計算過程，推導過程見天文曆法或 fater 的文章。

  1. M：如果月份大於或等於三，M 等於月份，但如果是元月或二月，要看成是前一年的十三月或十四月，因此 M 等於十三或十四 ( M 是在 3∼14 之間的整數 )，且年份要減去一。
  2. C 與 Y：上一步的年份除 100 所得的商為 C，餘數為 Y。
  3. D：日。
  4. [ ]：在中括號內的除法如果不能除盡，只取整數部分，亦即無條件捨去。
  5. MOD 是求餘數的意思，把小括號內的數值計算出來除以七的餘數即為 W。
  6. 最後計算的結果：W＝0，為星期日；W＝1，為星期一；W＝2，為星期二……依此類推。

例如要計算西元 2000 年元月元日星期幾，因為是一月份，所以應該看成是 1999 年 13 月 1 日。因此 C＝19，Y＝99，M＝13，D＝1，代入蔡勒公式：

因此西元 2000 年元月元日是星期六。

在蔡勒公式中，小括號內所計算出來的數有可能是負值，這樣的話就不能用 DIV 指令求除以 7 的餘數，必須使用 IDIV。理由很簡單，因為 DIV 是計算無號數的除法，IDIV 才能計算有號數的除法。此外，如果是負數除以 7 所得的餘數也是負值，用這負值無法經由位址取得星期幾的字串，因此要加上一段程式檢查如果餘數為負，該如何處理。要檢查餘數是不是負數，最直覺的方式就是把餘數和零做比較，餘數小於零就是負數。如果餘數為負，那麼還要再加上七，使之變為正的餘數。( 注意！不是變號，而是加七 )


有號數的條件跳躍 ( JG/JGE/JL/JLE )

要比較有號數的大小要用 CMP 指令，並搭配條件跳躍指令 JG/JGE/JL/JLE 四種中的其中一種。

JG 是「jump short if greater」的意思，如果大於就跳躍。JGE 是「jump short if greater or equal」的意思，如果大於或等於就跳躍。JL 指令是「jump short if less」的意思，如果小於就跳躍。JLE 是「jump short if less or equal」的意思，如果小於或等於就跳躍。注意！比較有號數的大小，用 CMP 搭配 JL/JG/JLE/JGE；比較無號數的高低，也是用 CMP 但搭配 JA/JB/JAE/JBE。

底下小木偶用一個例子說明。假設有下面兩段很相似的程式，僅有一處不同，那就是 JG 與 JA 的差別。這兩程式執行到 ok: 處時，CX 分別會是多少呢？

        程式一                                  程式二
        mov     cx,0                            mov     cx,0
        mov     al,0FFh                         mov     al,0FFh
        mov     bl,3                            mov     bl,3
        cmp     al,bl                           cmp     al,bl
        jg      ok                              ja      ok
        mov     cx,1                            mov     cx,1
ok:     .                               ok:     .
        .                                       .
        .                                       .

根據剛才說的，程式一中，JG 是比較有號數的大小，所以要把 AL 看成是 －1，BL 是 3，得到 AL＜BL。但是「CMP AL,BL/JG OK」的意思是 AL＞BL 才會跳躍，所以此時並不會跳到 ok: 處，而是執行下一行，故 CX 等於 1。

程式二中，JA 是比較無號數的高低，所以要把 AL 看成是 255，BL 是 3，得到 AL＞BL。而「CMP AL,BL/JA OK」的意思是 AL＞BL 才會跳躍，所以程式二會發生跳越到 ok: 處執行，故 CX 等於 0。

回到 WHATDAY.ASM 原始程式裏，程式第 118∼119 行為：

                cmp     dx,0    ;如果DX:AX是負數所得餘數(存於DX)也是負數
                jge     ok

DX:AX 除以 7 後所得的餘數在 DX 裏，而 DX:AX 有可能是負數，要如何確定是正數還是負數，只需比較 DX 與 0，如果 DX 大於零或等於零，不需要額外的處理；如果 DX 小於零就是負數，必須讓餘數加一才能得到正數的餘數。