很明顯的，這個畫面是模仿 DEBUG 以「D」指令觀察記憶體內容所顯示的畫面。不同的是，它每次就只能顯示 100H 個位元組的記憶體內容，使用者可以按「Page Up」、「Page Down」鍵觀察，也可以按「S」或「O」鍵更改區段位址或偏移位址。如果要離開此程式，那麼就按下「Esc」鍵。
這一章小木偶不打算繼續教學內容，而是利用前面的觀念實作一程式，觀察記憶體裏的內容，這樣做有兩個目的：一是讓讀者對真實模式 ( real mode ) 下的記憶體位址有較清楚的認識，如果能觀察更多記憶體內容，當然能認識得更清楚；第二是，觀察記憶體內容本身就是很有趣的事情，舉個例子，打電玩時主角的血必定是記錄在某個記憶體內，如果能想辦法讓此記憶體數值不會減少，那麼主角就是不死之軀了。
這個程式名稱是「MEMDUMP.ASM」，MEM 是 memory，記憶體的簡寫，DUMP 是傾印的意思，亦即把記憶體內容印在螢光幕上。此程式執行畫面如下：
很明顯的，這個畫面是模仿 DEBUG 以「D」指令觀察記憶體內容所顯示的畫面。不同的是，它每次就只能顯示 100H 個位元組的記憶體內容，使用者可以按「Page Up」、「Page Down」鍵觀察，也可以按「S」或「O」鍵更改區段位址或偏移位址。如果要離開此程式，那麼就按下「Esc」鍵。
有了這個工具程式，可以觀察到 DOS 1MB 的所有記憶體內容，底下舉幾個例子，讀者可以試試看更改記憶體的區段位址和偏移位址觀察：
當然還有許多資料，不在這裏一一列舉，讀者可以自行查閱網路上的資料。
底下先介紹「MEMDUMP」使用到的幾個中斷服務程式。
這個服務中斷可以讓程式從控制台接收字元，或者把字元輸出到控制台，這裏所謂的控制台就是鍵盤或螢幕。至於要輸入還是輸出字元，請看底下的說明：
控制台直接輸入輸出 輸入：AH＝06H DL＝0FFH，輸入字元；DL≠0FFH，輸出字元，DL 即為要輸出的字元 執行：INT 21H 返回：若輸出字元時，沒有回傳值 若輸入字元時 若 ZR，使用者沒有輸入字元 若 NZ，AL＝使用者按下的鍵所代表字元的 ASCII 碼或掃描碼
AH＝06H/INT 21H DOS 服務程式有兩種供功用，一是把字元印在螢幕上，另一種是由鍵盤輸入字元。先說第一種功用，把字元印在螢幕上。這時把要印在螢幕上的字元 ASCII 碼放到 DL 裏，AH 設為 06H，呼叫 INT 21H 即可。
第二種功能是由鍵盤輸入字元，這時候要在呼叫 INT 21H 之前，把 DL 設為 0FFH，AH 設為 06H，然後呼叫 INT 21H。這時候不管使用者是否已輸入資料，DOS 都不會停下來等使用者輸入，而是直接執行 INT 21H 的下一行指令。當然這時會產生兩種情形：
也許有人會有疑問，AH＝01H/INT 21H、AH＝0/INT 16H 也都能從鍵盤上輸入字元，那麼有什麼不同，為何要有這麼多看起來像是一樣的服務程式呢？事實上，它們還是有一些差異的，用底下的表來比較可能會清楚一些：
| 服務程式 | 是否等待輸入 | 是否受 Ctrl－C 影響 | 是否在螢幕上回應 | 是否取得掃描碼 |
| AH＝00H/INT 16H | 是 | 否 | 否 | 是 |
| AH＝01H/INT 21H | 是 | 是 | 是 | 否 |
| AH＝06H/INT 21H | 否 | 否 | 否 | 有限制 |
由上表，可以看出來，呼叫 AH＝00H/INT 16H 或 AH＝01H/INT 21H 後會等待使用者輸入字元，但是 AH＝06H/INT 21H 卻不等待繼續執行下一道指令；當使用者按下 Ctrl－C 時 ( DOS 的 Ctrl－C 鍵是讓程式中斷而停止執行，返回 DOS 系統，並非 Windows 的複製快捷鍵 )，AH＝00H/INT 16H、AH＝06H/INT 21H 不受影響，但 AH＝01H/INT 21H 會跳出程式回到 DOS。這些類似的服務程式不同之處還有：是否會把使用者按下的鍵顯示在螢幕上，是否能取得掃描碼等等，程式設計師可依需求不同使用。
INT 10H 是由燒錄在 BIOS 的程式，專門提供呼叫顯示卡功能的服務程式，並不是 DOS 提供的。在第十三章提過彩色顯示卡的螢幕可分為文字模式與圖形模式兩種，這兩種又有許多不同的解析度。在 DOS 開機時，預設的模式是 80×25 十六色文字模式，當然，程式可以依需求呼叫 AH＝00H/INT 10H 改變顯示模式，使用方法如下：
設定顯示模式 ( display mode ) 輸入：AH＝00H AL＝想要設定的顯示模式 執行：INT 10H 返回：無
下表是 CGA 所能支援的顯示模式。後來又推出了 EGA、VGA 等更高階的顯示卡，可以使用的顯示模式就更多了，再到後來連 DOS 也已淘汰，因此就沒有列出來了。
| 顯示模式 | 文字或圖形 | 解析度 | 顏色 |
| 0H | 文字 | 40×25 | 黑白 |
| 1H | 文字 | 40×25 | 16 色 |
| 2H | 文字 | 80×25 | 黑白 |
| 3H | 文字 | 80×25 | 16 色 |
| 4H | 圖形 | 320×200 | 4 色 |
| 5H | 圖形 | 320×200 | 4 色灰階 |
| 6H | 圖形 | 640×200 | 黑白 |
AH＝00H/INT 10H 若是成功執行，還會清除螢幕畫面，即使沒有改變顯示模式，因此可以用此 BIOS 服務程式充當清除螢幕的功能 ( BIOS 沒有專門提供這個功能 )。但是如果 AL 的最高位元為 1 時，就不會清除視訊記憶體的內容，因此在改變顯示模式時，螢幕上還會有一些資料殘存。
雖然標題是寫「設定游標形狀」，但是千萬不要誤會此服務程式可以把游標變成三角形、圓形、星形……這些形狀，它只能把游標變成高度不同的矩形而已。呼叫方式如下：
設定螢幕文字模式的游標形狀 輸入：AH＝01H CH＝游標開始繪出的位置及是否顯現游標 CL＝游標結束繪出的位置 執行：INT 10H 返回：無
在 CGA 顯示卡上，可以把游標看成是一個矩形，分成八等分，由上而下分別是 0、1、2……7。但是在 DOS 開機時，只有最底下兩部分為電腦以白色繪出來，並不斷閃爍，也就是游標開始繪出的位置是 6，結束繪出的位置是 7。假如要把游標都填滿，可以用下面的程式：
mov ah,1
mov cx,0007
int 10h
CH 的位元 7，應設為 0；位元 5、6 均為 0 時，游標正常顯示；其他數值時，游標消失。位元 0∼4 表示游標開始繪出位置。CL 只用位元 0∼4 來表示游標結束繪出位置，位元 5∼7 應設為 0。
此服務程式的用法是：
設定游標位置 輸入：AH＝02H BH＝顯示頁 DH＝列 ( 最上面一列是 0 ) DL＝行 ( 最左邊一行是 0 ) 執行：INT 10H 返回：無
BH 是顯示頁號碼，什麼是顯示頁 ( display page ) 呢？原來 CGA 顯示卡有 16KB 的視訊記憶體，如果顯示模式設為 3，也就是 80×25 的文字模式，那麼所需的記憶體空間是 82×25×2＝4000 個位元組 ( 為什麼這樣算，可參考第十三章視訊記憶體 )，僅需 4KB 左右。所以 CGA 把這個模式分成四個顯示頁，編號由零到三。
在一開機時，系統將顯示模式設為 3，顯示在螢幕上的是第零號顯示頁，其位址是 B8000:0000 開始至 B800:0F9F 為止；而第一號顯示頁位址 B800:1000 開始，到 B800:1F9F；第二號顯示頁由位址 B800:2000 開始到 B800:2F9F；第三號顯示頁由 B800:3000 開始至 B800:3F9F。顯示頁和顯示頁之間有一點空隙。顯示模式 2 的顯示頁位址分法與上面一樣，但顯示模式 0 與 1，顯示頁的起始位址是 0000、0800、1000、1800……。
為什麼要設計顯示頁呢？原來是電腦運算速度比人的輸入快得多了，程式可以在等待人輸入的時間的這一瞬間 ( 對人而言是一瞬間，但對 CPU 而言卻能執行數百萬次甚至更多次的運算 )，先把下次要顯示的畫面運算出來，填在下一個顯示頁上。等人輸入好後，程式就可以切換顯示頁而節省運算時間，螢幕畫面也就很快能顯示出來了。
不同顯示模式，顯示頁的多寡也不同，BH 的範圍也不同。顯示模式為 0 或 1 時，有 8 個顯示頁，故 BH 為 0 到 7 的整數；顯示模式為 2 或 3 時，有 4 個顯示頁，故 BH 為 0 到 3 的整數；圖形模式，BH 必為 0。
選擇顯示頁的意思，就是將該顯示頁的內容顯示在螢幕上，雖然 MEMDUMP 用不著這個 BIOS 服務程式，但小木偶還是順便介紹使用方法如下：
選擇顯示頁 輸入：AH＝05H AL＝顯示頁 執行：INT 10H 返回：無
如果顯示模式為 0 或 1，AL 可以是 0 到 7；如果顯示模式為 2 或 3，AL 可以是 0 到 3。如果顯示模式為 4、5、6，AL 只能是 0。
其內容如下：
1 2 3 4
5 6 7 8
9 10 11 12
13 14 15 16
17 18 19 20
21 22 23 24
25 26 27 28
29 30 31 32
33 34 35 36
37 38 39 40
41 42 43 44
45 46 47 48
49 50 51 52
53 54 55 56
57 58 59 60
61 62 63 64
65 66 67 68
69 70 71 72
73 74 75 76
77 78 79 80
81 82 83 84
85 86 87 88
89 90 91 92
93 94 95 96
97 98 99 100
101 102 103 104
105 106 107 108
109 110 111 112
113 114 115 116
117 118 119 120
121 122 123 124
125 126 127 128
129 130 131 132
133 134 135 136
137 138 139 140
141 142 143 144
145 146 147 148
149 150 151 152
153 154 155 156
157 158 159 160
161 162 163 164
165 166 167 168
169 170 171 172
173 174 175 176
177 178 179 180
181 182 183 184
185 186 187 188
189 190 191 192
193 194 195 196
197 198 199 200
201 202 203 204
205 206 207 208
209 210 211 212
213 214 215 216
217 218 219 220
221 222 223 224
225 226 227 228
229 230 231 232
233 234 235 |
.MODEL SMALL,C
.386
;*******************************************************************************
.STACK
;*******************************************************************************
video SEGMENT PARA AT 0b800h ;video區段設在視訊記憶體上
video ENDS
;*******************************************************************************
.DATA
dump_segment DW ? ;要傾印的記憶體區段位址
dump_offset DW 0 ;要傾印的記憶體偏移位址
prog_name DB " M E M O R Y D U M P"
field_name DB " Seg:Off 00 01 02 03 04 05 06 07-08 09 0A 0B 0C 0D ",
"0E 0F 01234567-89ABCDEF"
line DB 77 DUP (0c4h)
help_text DB "Esx=EXIT S=Change Segment O=Change Offset PgDn",
"/PgUp=Forward/Backward"
input_offset DB " Input offset address : "
input_segment DB "Input segment address : "
error_msg DB "Please input 0-9 or A-F. "
;*******************************************************************************
.CODE
;-------------------------------------------------------------------------------
invisible_cursor PROC ;使游標消失不見
mov ah,1
mov cx,2000h ;CH的bit 5,6分別是1,0，可讓游標消失
int 10h
ret
invisible_cursor ENDP
;-------------------------------------------------------------------------------
visible_cursor PROC ;顯示游標從第6部分到第7部分
mov ah,1
mov cx,607h ;CH的nit 5,6均為0，顯示游標，CH的0∼4
int 10h ;位元表示游標開始為6，CL為游標結束為7
ret
visible_cursor ENDP
;-------------------------------------------------------------------------------
input PROC
LOCAL value:WORD
mov ah,2 ;設定游標位置
mov dh,22 ;在第22列第24行
mov dl,SIZEOF input_offset
mov bh,0
int 10h
call visible_cursor ;恢復游標為可見
mov cx,4 ;一個字組的十六進位數有四位
mov value,0 ;使value歸零
.WHILE cx
mov ah,1 ;DOS服務程式，鍵盤輸入字元
int 21h ;AL＝輸入字元的ASCII碼
.IF (al>="0")&&(al<="9")
sub al,"0"
.ELSEIF (al>="A")&&(al<="F")
sub al,37h
.ELSEIF (al>="a")&&(al<="f")
sub al,57h
.ELSEIF al==0dh
.BREAK .IF 1
.ELSE
stc
.BREAK .IF 1
.ENDIF
shl value,4 ;value＝value×10H
cbw ;使AH變為0
add value,ax ;value＝value＋AX
dec cx
.ENDW
call invisible_cursor
mov ax,value
ret
input ENDP
;-------------------------------------------------------------------------------
;在螢幕上印出DL的十六進位數值
print_dl PROC
rol dl,4
call print_4_bits
rol dl,4
print_4_bits:: mov al,dl
and al,0fh
add al,30h
cmp al,39h
jbe ok
add al,7
ok: stosw
ret
print_dl ENDP
;-------------------------------------------------------------------------------
;在螢幕上印出DX之十六進位數值
print_dx PROC
mov cx,4
next: rol dx,4
call print_4_bits
loop next
ret
print_dx ENDP
;-------------------------------------------------------------------------------
video_address PROC ;計算第AX列第零行在視訊記憶體中的位址後存於DI返回
mov cl,160 ;每一列有80個字元，每字元佔用一個ASCII碼及顏色
mul cl ;因此每一列佔用160個位元組
mov di,ax
ret
video_address ENDP
;-------------------------------------------------------------------------------
;在螢幕第rw列傾印一列，16個位元組的記憶體內容，除此之外還傾印記憶體位址、與此16個
;位元組內容所代表的ASCII碼。要傾印的記憶體位址在sg:ofst
print_data PROC rw:WORD, sg:WORD, ofst:WORD
LOCAL counter:WORD
mov ax,rw
call video_address ;計算第rw列在視訊記憶體的偏移位址
;印出要傾印的記憶體區段位址與偏移位址
mov dx,sg ;印出要傾印的區段位址
mov ah,0fh ;AH＝0FH表示前景白色，背景黑色
call print_dx
mov al,":" ;印出「:」
stosw
mov dx,ofst ;印出要傾印的偏移位址
mov ah,0fh
call print_dx
;印出該記憶體位址開始的16個位元組的記憶體內容
mov counter,10h ;10H為16個位元組
mov ah,0eh ;AH＝0EH表示前景黃色，背景黑色
mov fs,sg ;FS＝要傾印的區段位址
mov bx,ofst ;BX＝要傾印的偏移位址
nxt_by: .IF counter==8 ;如果已處理8個位元組時，不用空白
mov al,"-" ;分隔，而用「-」分隔
.ELSE
mov al," "
.ENDIF
stosw
mov dl,fs:[bx] ;DL＝將印在螢幕上的記憶體內容
inc bx
call print_dl
dec counter ;檢查是否已印出16個位元組的資料了
jnz nxt_by ;若NZ尚未印完，到nxt_by印下一個位元組
mov eax,0e200e20h ;若ZRu3已印完，印出兩個空白分隔ASCII區域
stosd
;印出上述16個位元組的記憶體內容所代表的ASCII字元
mov bx,ofst
mov counter,10h
mov ah,0bh
nxt_ch: .IF counter==8
mov al,"-"
stosw
.ENDIF
mov al,fs:[bx]
stosw
inc bx
dec counter
jnz nxt_ch
ret
print_data ENDP
;-------------------------------------------------------------------------------
;在第rw列中以color的顏色顯示一字串，此字串位址在pstr處，長度為len位元組
print_a_line PROC rw:WORD, pstr:WORD, len:WORD, color:BYTE
mov ax,rw ;計算第rw列第零行在視訊記
call video_address ;憶體中的位址，並存於DI裏
mov cx,len
mov ah,color
mov si,pstr
next: lodsb
stosw
loop next
ret
print_a_line ENDP
;-------------------------------------------------------------------------------
;print_screen印出整個螢幕資料，包含程式名稱、分隔線、使用說明及256個位元組的資料
;要印出的256個位元組資料在記憶體位址的dump_s:dump_o處開始的256個位元組
print_screen PROC dump_s:WORD,dump_o:WORD
LOCAL row:WORD
;印出程式名稱、欄位、分隔線
INVOKE print_a_line,0,OFFSET prog_name,SIZEOF prog_name,0fh
INVOKE print_a_line,2,OFFSET field_name,SIZEOF field_name,7
INVOKE print_a_line,3,OFFSET line,SIZEOF line,9
;印出16列的記憶體內容，每列16個位元組
mov row,4
next_line: INVOKE print_data,row,dump_s,dump_o
add dump_o,10h
inc row
cmp row,20
jne next_line
;印出分隔線與使用說明
INVOKE print_a_line,row,OFFSET line,SIZEOF line,9
INVOKE print_a_line,21,OFFSET help_text,SIZEOF help_text,7
ret
print_screen ENDP
;-------------------------------------------------------------------------------
.STARTUP
mov ax,3 ;把螢幕設為80×25文字模式
int 10h
mov dump_segment,es ;初始化dump_segment
mov ax,video ;把ES設為視訊記憶體位址
mov es,ax
call invisible_cursor;使游標消失
display: INVOKE print_screen,dump_segment,dump_offset
mov ah,6
mov dl,0ffh
int 21h ;控制台直接輸入輸出
jz display ;若ZR表示使用者未輸入，到display處繼續執行
or al,al ;若NZ表示已輸入。到下一行檢查AL是否為零
jnz gotten ;若AL不為零表示使用者按的鍵有ASCII碼
int 21h ;若AL為零表示使用者按的鍵沒有ASCII碼
jmp short scan_code
gotten: .IF al==1bh ;檢查是否按下「Esc」鍵
je exit
.ELSEIF al=="o"||al=="O" ;檢查是否按下「o」鍵或「O」鍵
INVOKE print_a_line,22,OFFSET input_offset,SIZEOF input_offset,7
call input
jc error
and ax,0fff0h
mov dump_offset,ax
.ELSEIF al=="s"||al=="S" ;檢查是否按下「s」鍵間或「S」鍵
INVOKE print_a_line,22,OFFSET input_segment,SIZEOF input_segment,7
call input
jc error
mov dump_segment,ax
.ENDIF
INVOKE print_a_line,22,OFFSET prog_name,SIZEOF input_offset+4,7
jmp display
scan_code: cmp al,49h ;檢查是否按下「PageUp」鍵
jne chk_pgdn_key
sub dump_offset,100h
jmp display
chk_pgdn_key: cmp al,51h ;檢查是否按下「PageDown」鍵
jne display
add dump_offset,100h
jmp display
error: INVOKE print_a_line,22,OFFSET error_msg,SIZEOF error_msg,7
exit: call visible_cursor
mov ah,2
mov dx,1700h
mov bh,0
int 10h
.EXIT 0
;*******************************************************************************
END |
把上面程式碼存入「E:\DOS\MEMORY」子目錄裏，輸入下面指令組譯及連結：
C:\>e: [Enter] E:\>cd dos\second [Enter] E:\DOS\SECOND>ml memdump.asm [Enter] Microsoft (R) Macro Assembler Version 6.11 Copyright (C) Microsoft Corp 1981-1993. All rights reserved. Assembling: memdump.asm Microsoft (R) Segmented Executable Linker Version 5.31.009 Jul 13 1992 Copyright (C) Microsoft Corp 1984-1992. All rights reserved. Object Modules [.obj]: memdump.obj Run File [memdump.exe]: "memdump.exe" List File [nul.map]: NUL Libraries [.lib]: Definitions File [nul.def]: E:\DOS\SECOND>
你可以自行執行看看這個程式。底下來解說 MEMDUMP.ASM。
MEMDUMP 會顯示 256 個位元組的資料，再加上標題位址、使用方法等資料，都在一個螢幕上顯示，且使用彩色文字，因此設定顯示模式 3，亦即 80×25 十六色文字模式。這段設定顯示模式的程式碼應該在程式一開始就執行，它還有個額外的好處，就是順帶能清除螢幕。
上面原始碼的第 188∼189 行，就是設定顯示模式 3，而第 187 行就是程式進入點。
MEMDUMP 不是利用 DOS 服務程式在螢幕上顯示字元，而是把要顯示的字元直接填入視訊記憶體內。參閱第十三章，螢幕最上面為第零列，其下為第一列、第二列……第 24 列 ( 列是由左而右 )，每列 80 個字元，每個字元須佔用兩個位元組 ( 位址較低位元組存放字元的 ASCII 碼，較高位址的位元組為前景色和背景色 )。因此在螢幕上，第 Y 列第 X 行 ( 也就是第 Y 列第 X 個字元 )，在視訊記憶體內的偏移位址可由下式計算：
偏移位址＝160Y＋2X
不過小木偶設計 MEMDUMP 都是由每列的第零個字元開始，因此只需將第幾列乘以 160 即可得偏移位址。小木偶把這段程式寫成副程式 video_address ( 第 97∼102 行 )。
MEMDUMP 會使用到五個區段，除了程式碼區段、堆疊區段、資料區段這三個區段之外，還會使用到視訊記憶體所在的區段，小木偶用 ES 區段暫存器來指向視訊記憶體位址 ( 第 191∼192 行 )。理由很簡單，小木偶把要顯示字元的 ASCII 碼放在 AL，前景色與背景色放在 AH 裏，然後利用 x86 指令 STOSW 很快就能把 AX 的內容直接填入 ES:DI 所指位址裏 ( 第 84、129、146、161 行 )。此處 ES 是視訊記憶體區段位址，即 B800H，DI 是偏移位址，可由上面的公式：160Y＋2X 所計算的結果。
MEMDUMP 除了會使用前述四個區段之外，還會使用另一個區段，這個區段就是使用者想要傾印的記憶體區段位址，小木偶用 dump_segment 記錄此區段的位址。當 MEMDUMP 剛開始執行時，會把 dump_segment 指定為 ES 所指區段 ( 第 190 行，見註一 )，此時 ES 還未指向 B800 區段，在稍後才讓 ES 指向 B800。在這之後，如果使用者修改要傾印的記憶體區段位址 ( 就是按下「S」鍵 )，程式就會呼叫 input 副程式，待使用者輸入完成後，dump_segment 就會變更新輸入的數值。
要傾印的記憶體偏移位址存在 dump_offset，預設值是 0，同樣也能修改此偏移位址。使用者只需按下「O」鍵，程式就會呼叫 input 副程式，待使用者輸入完成後，dump_offset 就會變更新輸入的數值。
當程式要傾印記憶體的內容時，必須讀取 dump_segment:dump_offset 位址的記憶體內容，但 CPU 指令中不能以變數直接當做區段位址讀取記憶體，像底下的語法是錯誤的：
mov bx,dump_offset
mov dl,dump_segment:[bx] ←不能直接以變數當做區段位址讀取記憶體
而 CS、DS、ES、SS 等區段暫存器都各有各的用途了，雖然也能有方法把 DS 或 ES 騰出來使用，但是很麻煩。幸好 80386 及其更高階的 CPU 還有另外兩個區段暫存器：FS 與 GS，可供使用。方法如下：
mov fs,dump_segment
mov bx,dump_offset
mov dl,fs:[bx]
第三行指令就能強迫讀取 FS 所指的區段，而讀取的記憶體偏移位址是 BX 所指的位址 ( 第 130 行 )。像這樣讀取某個指定區段暫存器的方式，稱為凌越區段。
另外值得一提的是，如果用 DEBUG 或 SYMDEB 追蹤此程式到這一階段時，會見到底下的樣子：
20E6:00DA 64 DB 64 20E6:00DB 8A17 MOV DL,[BX]
而不是「MOV DL,FS:[BX]」，這是因為 DEBUG 或 SYMDEB 不認得 80386 新增的指令，因此顯示不出來正確的樣子，但卻不妨害正常除錯或追蹤，仍可安心使用。
MEMDUMP.ASM 最重要的部分，是把標題、分隔線、按鍵說明及 256 個位元組的內容顯示在螢幕上，小木偶把這部分的程式，製作成副程式，稱為 print_screen。而 print_screen 在處理標題、分隔線、按鍵說明的方式與處理 256 個位元組內容不同。前三者是不會改變的常數字串，小木偶用 print_a_line 副程式，一次一個字串顯示在螢幕上的一列裏。最後一個處理 256 個位元組的內容，會隨記憶體位置不同而變化，小木偶用 print_data 副程式處理。
在螢幕上傾印所有資料之後，就是處理使用者按鍵的程式。這裏，小木偶有個想法，當使用者沒有按下鍵時，MEMDUMP 並不會一直枯等使用者輸入按鍵，而是直接跳過輸入按鍵，然後會不斷地把同一位置的記憶體內容顯示在螢幕上。這樣做有個好處，某些記憶體內容會不斷地被作業系統或 BIOS 更新，如此一來，使用者就能很輕鬆地看見這些資料動態的變化。
例如，鍵盤緩衝區就是一個例子。你可以讓 MEMDUMP 顯示 40:1A 處的記憶體內容，然後按下鍵盤上的鍵 ( 這個鍵不能是「PgaeUp/PageDown」或「S」、「O」)，你就能看見 40:1A 和 40:1C 處這兩個指標的變化，也可以觀察 40:1E∼40:3D 緩衝區內的變化。另一個例子是在 40:6C 的雙字組計數器，每 55 毫秒會使這個計數器增加一。
為了達到這個目的，MEMDUMP 不用 AH＝00H/INT 16H、AH＝01H/INT 21H 處理鍵盤輸入，改用 AH＝06H/INT 21H。程式碼在第 194∼202 行，第一次呼叫 AH＝06H/INT 21H 後，在第 198 行會先檢查使用者是否按了鍵，若沒有就把原來要傾印的記憶體再顯示一遍；如果使用者已按了鍵，則檢查此鍵是否有 ASCII 碼，如果 AL 為零，表示沒有 ASCII 碼，那麼使用者可能是按下「Page Up」或「Page Down」鍵；如果 AL 不為零就是按鍵的 ASCII 碼，或是沒有 ASCII 碼按鍵的掃描碼。
在 MEMDUMP 裏印出區段位址的方法是把它存入 DX 裏，然後呼叫 print_dx 副程式，見程式第 111∼113 行。而印出某個位址的記憶體內容則是把它放在 DL 裏，再呼叫 print_dl 副程式，見第 130∼132 行。而這兩個副程式類似，只是前者須印出四位的十六進位數值，後者僅須印出兩位，這段程式在第 78∼84 行。
小木偶把這段程式寫在 print_dl 裏，為了節省程式碼大小，print_dx 不必再寫一次只須呼叫 print_dl 裏的這段程式即可。雖然標記和副程式的名稱都是位址，但標記只在這個副程式內「有效」，其他的副程式是無法跳躍到此標記，也不能呼叫另一個副程式的標記。儘管如此，還是有兩種方法可以達到此目的：
第一種方法：在一個副程式中再宣告另一個副程式，變成像下面的的樣子：
print_dl PROC
rol dl,4
call print_4_bits
rol dl,4
print_4_bits PROC
mov al,dl
and al,0fh
add al,30h
cmp al,39h
jbe ok
add al,7
ok: stosw
ret
print_4_bits ENDP
print_dl ENDP
這樣也能在別的地方中，執行「call print_4_bits」指令。( 在高階語言裏，迴圈內套著另一個迴圈稱作巢狀迴圈，此處不知能否叫巢狀副程式？)
第二種方法：把標記設為「公共」的，方法是標記結尾改成「::」像下面的樣子：
print_dl PROC
rol dl,4
call print_4_bits
rol dl,4
print_4_bits:: mov al,dl
and al,0fh
add al,30h
cmp al,39h
jbe ok
add al,7
ok: stosw
ret
print_dl ENDP
這種以「::」結尾的標記，可以被其他副程式呼叫，也能當成其他副程式跳躍的目標。
本章就在此結束，本章實作了一個較大的程式，大約兩百三十多行，但大部分的觀念前面都介紹過，應該不會太難。新介紹的觀念是一個 AH＝06H/INT 21H DOS 服務程式及一些螢幕操作。前者無法用 DEBUG/SYMDEB 動態追蹤，較不好理解；後者可以在螢幕上直接見到結果，應該是很容易的。
另外介紹了如何使用 80386 及更高階的 CPU 所提供的區段暫存器 FS，當程式要用到五個區段時，FS 就能派上用場，當然還有一個 GS 暫存器也能待命使用。